configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.21.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl where are our m4 macros ?
  27 AC_CONFIG_MACRO_DIR([common/m4])
  28
  29 dnl define the output header for config
  30 AM_CONFIG_HEADER([config.h])
  31
  32 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  33 AM_MAINTAINER_MODE
  34
  35 dnl sets host_* variables
  36 AC_CANONICAL_HOST
  37
  38 dnl our libraries and install dirs use major.minor as a version
  39 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  40 dnl we override it here if we need to for the release candidate of new series
  41 GST_MAJORMINOR=0.10
  42 AC_SUBST(GST_MAJORMINOR)
  43
  44 dnl CURRENT, REVISION, AGE
  45 dnl - library source changed -> increment REVISION
  46 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  47 dnl - interfaces added -> increment AGE
  48 dnl - interfaces removed -> AGE = 0
  49 dnl sets GST_LT_LDFLAGS
  50 AS_LIBTOOL(GST, 15, 0, 15)
  51
  52 dnl FIXME: this macro doesn't actually work;
  53 dnl the generated libtool script has no support for the listed tags.
  54 dnl So this needs to be fixed first if we want to use this
  55 dnl AS_LIBTOOL_TAGS
  56
  57 AC_LIBTOOL_WIN32_DLL
  58 AM_PROG_LIBTOOL
  59
  60 dnl *** required versions of GStreamer stuff ***
  61 GST_REQ=0.10.21.1
  62
  63 dnl *** autotools stuff ****
  64
  65 dnl allow for different autotools
  66 AS_AUTOTOOLS_ALTERNATE
  67
  68 dnl Add parameters for aclocal
  69 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  70
  71 dnl set up gettext
  72 dnl the version check needs to stay here because autopoint greps for it
  73 AM_GNU_GETTEXT_VERSION([0.17])
  74 AM_GNU_GETTEXT([external])
  75 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  76
  77 dnl *** check for arguments to configure ***
  78
  79 AG_GST_ARG_DEBUG
  80 AG_GST_ARG_PROFILING
  81 AG_GST_ARG_VALGRIND
  82 AG_GST_ARG_GCOV
  83
  84 AG_GST_ARG_EXAMPLES
  85
  86 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  87 AG_GST_ARG_WITH_PACKAGE_NAME
  88 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  89
  90 dnl let distro override plugin install helper path
  91 AC_ARG_WITH(install-plugins-helper,
  92   AC_HELP_STRING([--with-install-plugins-helper],
  93     [specify path of helper script to call to install plugins]),
  94   [
  95     case "${withval}" in
  96       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  97       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  98       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  99     esac
 100   ],
 101   [
 102     dnl Default value
 103     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 104   ]
 105 )
 106 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 107 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 108     [plugin install helper script])
 109 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 110
 111 AG_GST_ARG_WITH_PLUGINS
 112
 113 AG_GST_ARG_ENABLE_EXTERNAL
 114
 115 AG_GST_ARG_ENABLE_EXPERIMENTAL
 116
 117 dnl *** checks for platform ***
 118
 119 dnl * hardware/architecture *
 120
 121 dnl common/m4/gst-arch.m4
 122 dnl check CPU type
 123 AG_GST_ARCH
 124
 125 dnl check for large file support
 126 dnl affected plugins must include config.h
 127 AC_SYS_LARGEFILE
 128
 129 dnl *** checks for programs ***
 130
 131 dnl find a compiler
 132 AC_PROG_CC
 133
 134 dnl check if the compiler supports '-c' and '-o' options
 135 AM_PROG_CC_C_O
 136
 137 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 138 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 139
 140 dnl check for documentation tools
 141 GTK_DOC_CHECK([1.3])
 142 AS_PATH_PYTHON([2.1])
 143 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 144
 145 dnl *** checks for libraries ***
 146
 147 dnl libm, for sin() etc.
 148 AC_CHECK_LIBM
 149 AC_SUBST(LIBM)
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used in gst/ffmpegcolorspace/mem.c
 157 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 158 AC_CHECK_HEADERS([malloc.h])
 159
 160 dnl used in gst/subparse/gstsubparse.c
 161 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 162 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 163
 164 if test "x$HAVE_REGEX_H" = "xyes"; then
 165   ac_cppflags_save="$CPPFLAGS"
 166   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 167   AC_COMPILE_IFELSE(
 168     AC_LANG_PROGRAM([
 169 #include <libxml/HTMLparser.h>
 170                      ],[
 171 #ifndef LIBXML_HTML_ENABLED
 172 #error libxml2 has no HTML support
 173 #endif /* LIBXML_HTML_ENABLED */
 174                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 175   CPPFLAGS="$ac_cppflags_save"
 176 else
 177   HAVE_LIBXML_HTML="no"
 178 fi
 179 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 180
 181 dnl used in gst/tcp
 182 AC_CHECK_HEADERS([sys/socket.h],
 183   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 184 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 185
 186 dnl used in gst-libs/gst/rtsp
 187 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 188 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 189   WIN32_LIBS="-lws2_32"
 190   AC_SUBST(WIN32_LIBS)
 191 fi
 192
 193 dnl check for hstrerror, for gst-libs/gst/rtsp
 194 save_libs="$LIBS"
 195 AC_CHECK_FUNC(hstrerror, ,
 196     AC_CHECK_LIB(resolv, hstrerror, ,
 197         [AC_DEFINE(NO_HSTRERROR, 1,
 198              [Define if you have no native hstrerror() function.])]))
 199 HSTRERROR_LIBS=$LIBS
 200 AC_SUBST(HSTRERROR_LIBS)
 201 LIBS="$save_libs"
 202
 203 dnl used in gst-libs/gst/pbutils and associated unit test
 204 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 205
 206 dnl ffmpegcolorspace includes _stdint.h
 207 dnl also, Windows does not have long long
 208 AX_CREATE_STDINT_H
 209
 210 dnl *** checks for functions ***
 211 AC_CHECK_FUNCS([localtime_r gmtime_r])
 212
 213 dnl *** checks for types/defines ***
 214
 215 dnl Check for FIONREAD ioctl declaration
 216 dnl used in gst/tcp
 217 GST_CHECK_FIONREAD
 218
 219 dnl *** checks for structures ***
 220
 221 dnl *** checks for compiler characteristics ***
 222
 223 dnl make sure we can use "inline" from C code
 224 AC_C_INLINE
 225
 226 dnl *** checks for library functions ***
 227
 228 dnl check for fseeko()
 229 AC_FUNC_FSEEKO
 230
 231 dnl Check for fast float to int casting as defined in C99
 232 dnl used in gst-libs/gst/floatcast/floatcast.h
 233 save_libs=$LIBS
 234 LIBS="$LIBS $LIBM"
 235 AC_C99_FUNC_LRINT
 236 AC_C99_FUNC_LRINTF
 237 LIBS=$save_libs
 238
 239 dnl Check for a way to display the function name in debug output
 240 AG_GST_CHECK_FUNCTION
 241
 242 dnl *** checks for dependency libraries ***
 243
 244 dnl GLib is required
 245 AG_GST_GLIB_CHECK([2.12])
 246
 247 dnl liboil is required
 248 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 249 if test "x$HAVE_LIBOIL" != "xyes"; then
 250   AC_ERROR([liboil-0.3.14 or later is required])
 251 fi
 252
 253 dnl checks for gstreamer
 254 dnl uninstalled is selected preferentially -- see pkg-config(1)
 255 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 256 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 260 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 261
 262 dnl Check for documentation xrefs
 263 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 264 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 265 AC_SUBST(GLIB_PREFIX)
 266 AC_SUBST(GST_PREFIX)
 267
 268 dnl GTK is optional and only used in examples
 269 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 270 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 271
 272 dnl *** set variables based on configure arguments ***
 273
 274 dnl set license and copyright notice
 275 GST_LICENSE="LGPL"
 276 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 277 AC_SUBST(GST_LICENSE)
 278
 279 dnl set location of plugin directory
 280 AG_GST_SET_PLUGINDIR
 281
 282 dnl define an ERROR_CFLAGS Makefile variable
 283 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 284
 285 dnl define correct level for debugging messages
 286 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 287
 288 dnl used in examples
 289 AG_GST_DEFAULT_ELEMENTS
 290
 291 dnl *** plug-ins to include ***
 292
 293 dnl these are all the gst plug-ins, compilable without additional libs
 294 AG_GST_CHECK_PLUGIN(adder)
 295 AG_GST_CHECK_PLUGIN(audioconvert)
 296 AG_GST_CHECK_PLUGIN(audiorate)
 297 AG_GST_CHECK_PLUGIN(audiotestsrc)
 298 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 299 AG_GST_CHECK_PLUGIN(gdp)
 300 AG_GST_CHECK_PLUGIN(playback)
 301 AG_GST_CHECK_PLUGIN(speexresample)
 302 AG_GST_CHECK_PLUGIN(subparse)
 303 AG_GST_CHECK_PLUGIN(tcp)
 304 AG_GST_CHECK_PLUGIN(typefind)
 305 AG_GST_CHECK_PLUGIN(videotestsrc)
 306 AG_GST_CHECK_PLUGIN(videorate)
 307 AG_GST_CHECK_PLUGIN(videoscale)
 308 AG_GST_CHECK_PLUGIN(volume)
 309
 310 dnl check for gstreamer core features (subsystems)
 311 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 312 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 313 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 314
 315 dnl disable plug-ins that require libxml2's HTML support if it is not available
 316 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 317   AG_GST_DISABLE_PLUGIN(subparse)
 318 fi
 319
 320 dnl disable plug-ins that require sys/socket.h if it is not available
 321 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 322   AG_GST_DISABLE_PLUGIN(tcp)
 323 fi
 324
 325 dnl *** sys plug-ins ***
 326
 327 echo
 328 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 329 echo
 330
 331 dnl *** X11 ***
 332 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 333 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 334                   [ximagesink], [
 335   AC_PATH_XTRA
 336   ac_cflags_save="$CFLAGS"
 337   ac_cppflags_save="$CPPFLAGS"
 338   CFLAGS="$CFLAGS $X_CFLAGS"
 339   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 340
 341   dnl now try to find the HEADER
 342   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 343
 344   if test "x$HAVE_X" = "xno"
 345   then
 346     AC_MSG_NOTICE([cannot find X11 development files])
 347   else
 348     dnl this is much more than we want
 349     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 350     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 351     dnl it does not add the libs; therefore we add them here
 352     X_LIBS="$X_LIBS -lX11"
 353     AC_SUBST(X_CFLAGS)
 354     AC_SUBST(X_LIBS)
 355   fi
 356   AC_SUBST(HAVE_X)
 357   CFLAGS="$ac_cflags_save"
 358   CPPFLAGS="$ac_cppflags_save"
 359 ])
 360
 361 dnl Check for Xv extension
 362 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 363 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 364                   [xvimagesink], [
 365   AG_GST_CHECK_XV
 366 ])
 367
 368 dnl check for X Shm
 369 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 370 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 371   if test x$HAVE_X = xyes; then
 372     AC_CHECK_LIB(Xext, XShmAttach,
 373                  HAVE_XSHM="yes", HAVE_XSHM="no",
 374                  $X_LIBS)
 375     if test "x$HAVE_XSHM" = "xyes"; then
 376       XSHM_LIBS="-lXext"
 377     else
 378       dnl On AIX, it is in XextSam instead, but we still need -lXext
 379       AC_CHECK_LIB(XextSam, XShmAttach,
 380                    HAVE_XSHM="yes", HAVE_XSHM="no",
 381                    $X_LIBS)
 382       if test "x$HAVE_XSHM" = "xyes"; then
 383         XSHM_LIBS="-lXext -lXextSam"
 384       fi
 385     fi
 386   fi
 387 ], , [
 388   AC_SUBST(HAVE_XSHM)
 389   AC_SUBST(XSHM_LIBS)
 390 ])
 391
 392 dnl v4l/v4l2 checks have been moved down because they require X
 393
 394 dnl *** Video 4 Linux ***
 395 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 396 dnl renamed to GST_V4L in accordance with V4L2 below
 397 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 398 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 399   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 400 #include <sys/types.h>
 401 #define _LINUX_TIME_H
 402 #define __user
 403 #include <linux/videodev.h>
 404   ])
 405
 406   dnl we can build v4l without Xv, but then we won't have XOverlay support
 407   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 408   then
 409     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 410     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 411   fi
 412 ])
 413
 414 dnl *** ext plug-ins ***
 415 dnl keep this list sorted alphabetically !
 416
 417 if test "x$BUILD_EXTERNAL" = "xyes"; then
 418
 419 echo
 420 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 421 echo
 422
 423 dnl *** alsa ***
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 425 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 426   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 427     HAVE_ALSA="yes"
 428     AC_SUBST(ALSA_CFLAGS)
 429     AC_SUBST(ALSA_LIBS)
 430   ], [
 431     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 432   ])
 433 ])
 434
 435 dnl *** CDParanoia ***
 436 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 437 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 438   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 439                       cdda_open, -lm,
 440                       cdda_interface.h,
 441                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 442                       HEADER_DIR="no"
 443                       FOUND_CDPARANOIA="yes")
 444   if test "x$FOUND_CDPARANOIA" != "xyes";
 445   then
 446     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 447                         cdda_open, -lm,
 448                         cdda/cdda_interface.h,
 449                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 450                         HEADER_DIR="yes"
 451                         FOUND_CDPARANOIA="yes")
 452   fi
 453   if test "x$HEADER_DIR" = "xyes";
 454   then
 455     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 456                        defined if cdda headers are in a cdda/ directory)
 457   fi
 458   AC_SUBST(CDPARANOIA_LIBS)
 459 ])
 460 dnl FIXME : add second check somehow if that is necessary
 461 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 462 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 463
 464 dnl *** GNOME VFS ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 466 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 467   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 468 ])
 469
 470 dnl *** libgio ***
 471 USE_GIO=$BUILD_EXPERIMENTAL
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 473 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 474   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 475     HAVE_GIO="no"
 476     AC_MSG_RESULT(no)
 477   ])
 478   AC_SUBST(GIO_CFLAGS)
 479   AC_SUBST(GIO_LIBS)
 480   AC_SUBST(GIO_LDFLAGS)
 481 ])
 482
 483 dnl *** libvisual ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 485 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 486   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 487   if test $HAVE_LIBVISUAL = no
 488   then
 489     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 490   fi
 491 ])
 492
 493 dnl *** ogg ***
 494 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 495 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 496   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 497   if test $HAVE_OGG = no
 498   then
 499     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 500     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 501   fi
 502 ])
 503
 504 dnl *** pango ***
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 506 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 507   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 508 ])
 509
 510 dnl *** theora ***
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 512 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 513   dnl this check will work as long as theora uses 1.0.x or similar for the
 514   dnl first post-alpha release and not just 1.0
 515   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 516 ])
 517
 518 dnl *** vorbis ***
 519 dnl AM_PATH_VORBIS only takes two options
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 521 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 522   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 523   if test $HAVE_VORBIS = no
 524   then
 525     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 526     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 527   fi
 528 ])
 529
 530 if test "x$HAVE_VORBIS" = "xyes"; then
 531   ac_cflags_save="$CFLAGS"
 532   AC_COMPILE_IFELSE(
 533     AC_LANG_PROGRAM([
 534 #include <vorbis/codec.h>
 535                      ],[
 536 vorbis_dsp_state *v;
 537
 538 vorbis_synthesis_restart (v);
 539                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 540   if test "x$HAVE_VSR" = "xyes"; then
 541     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 542                        [defined if vorbis_synthesis_restart is present])
 543   fi
 544   CFLAGS="$ac_cflags_save"
 545 fi
 546
 547 else
 548
 549 dnl not building plugins with external dependencies,
 550 dnl but we still need to set the conditionals
 551 AM_CONDITIONAL(USE_ALSA, false)
 552 AM_CONDITIONAL(USE_CDPARANOIA, false)
 553 AM_CONDITIONAL(USE_GNOME_VFS, false)
 554 AM_CONDITIONAL(USE_GIO, false)
 555 AM_CONDITIONAL(USE_LIBVISUAL, false)
 556 AM_CONDITIONAL(USE_OGG, false)
 557 AM_CONDITIONAL(USE_PANGO, false)
 558 AM_CONDITIONAL(USE_THEORA, false)
 559 AM_CONDITIONAL(USE_VORBIS, false)
 560
 561 fi dnl of EXT plugins
 562
 563 dnl seeking needs freetype, so check for it here
 564 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 565   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 566 ])
 567 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 568 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 569 AC_SUBST(FT2_CFLAGS)
 570 AC_SUBST(FT2_LIBS)
 571
 572 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 573
 574 dnl Overview:
 575 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 576 dnl GST_*:              flags shared by built objects to link against GStreamer
 577 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 578 dnl                          (compare to other modules) or for i18n
 579 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 580 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 581 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 582 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 583
 584 dnl GST_OPTION_CFLAGS
 585 if test "x$USE_DEBUG" = xyes; then
 586    PROFILE_CFLAGS="-g"
 587 fi
 588 AC_SUBST(PROFILE_CFLAGS)
 589
 590 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 591   dnl Define _only_ during CVS (not pre-releases or releases)
 592   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 593 else
 594   DEPRECATED_CFLAGS=""
 595 fi
 596 AC_SUBST(DEPRECATED_CFLAGS)
 597
 598 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 599 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 600 AC_SUBST(GST_OPTION_CFLAGS)
 601
 602 dnl our libraries need to be versioned correctly
 603 AC_SUBST(GST_LT_LDFLAGS)
 604
 605 dnl GST_PLUGINS_BASE_CFLAGS
 606 dnl prefer internal headers to already installed ones
 607 dnl also add builddir include for enumtypes and marshal
 608 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 609 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 610
 611 dnl FIXME: do we want to rename to GST_ALL_* ?
 612 dnl add GST_OPTION_CFLAGS, but overridable
 613 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 614 AC_SUBST(GST_CFLAGS)
 615 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 616 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 617 AC_SUBST(GST_LIBS)
 618
 619 dnl LDFLAGS really should only contain flags, not libs - they get added before
 620 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 621 GST_ALL_LDFLAGS="-no-undefined"
 622 AC_SUBST(GST_ALL_LDFLAGS)
 623
 624 dnl GST_LIB_LDFLAGS
 625 dnl linker flags shared by all libraries
 626 dnl LDFLAGS modifier defining exported symbols from built libraries
 627 dnl (export _gst_foo but not __gst_foo)
 628 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 629 AC_SUBST(GST_LIB_LDFLAGS)
 630
 631 dnl this really should only contain flags, not libs - they get added before
 632 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 633 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 634 AC_SUBST(GST_PLUGIN_LDFLAGS)
 635
 636 dnl *** output files ***
 637
 638 AC_CONFIG_FILES(
 639 Makefile
 640 gst-plugins-base.spec
 641 gst/Makefile
 642 gst/adder/Makefile
 643 gst/audioconvert/Makefile
 644 gst/audiorate/Makefile
 645 gst/audiotestsrc/Makefile
 646 gst/ffmpegcolorspace/Makefile
 647 gst/gdp/Makefile
 648 gst/playback/Makefile
 649 gst/speexresample/Makefile
 650 gst/subparse/Makefile
 651 gst/tcp/Makefile
 652 gst/typefind/Makefile
 653 gst/videotestsrc/Makefile
 654 gst/videorate/Makefile
 655 gst/videoscale/Makefile
 656 gst/volume/Makefile
 657 sys/Makefile
 658 sys/ximage/Makefile
 659 sys/xvimage/Makefile
 660 sys/v4l/Makefile
 661 ext/Makefile
 662 ext/alsa/Makefile
 663 ext/cdparanoia/Makefile
 664 ext/gnomevfs/Makefile
 665 ext/gio/Makefile
 666 ext/libvisual/Makefile
 667 ext/ogg/Makefile
 668 ext/pango/Makefile
 669 ext/theora/Makefile
 670 ext/vorbis/Makefile
 671 gst-libs/Makefile
 672 gst-libs/gst/Makefile
 673 gst-libs/gst/audio/Makefile
 674 gst-libs/gst/cdda/Makefile
 675 gst-libs/gst/fft/Makefile
 676 gst-libs/gst/floatcast/Makefile
 677 gst-libs/gst/interfaces/Makefile
 678 gst-libs/gst/netbuffer/Makefile
 679 gst-libs/gst/riff/Makefile
 680 gst-libs/gst/rtp/Makefile
 681 gst-libs/gst/rtsp/Makefile
 682 gst-libs/gst/sdp/Makefile
 683 gst-libs/gst/tag/Makefile
 684 gst-libs/gst/pbutils/Makefile
 685 gst-libs/gst/video/Makefile
 686 tools/Makefile
 687 win32/common/config.h
 688 pkgconfig/Makefile
 689 pkgconfig/gstreamer-audio.pc
 690 pkgconfig/gstreamer-audio-uninstalled.pc
 691 pkgconfig/gstreamer-cdda.pc
 692 pkgconfig/gstreamer-cdda-uninstalled.pc
 693 pkgconfig/gstreamer-fft.pc
 694 pkgconfig/gstreamer-fft-uninstalled.pc
 695 pkgconfig/gstreamer-floatcast.pc
 696 pkgconfig/gstreamer-floatcast-uninstalled.pc
 697 pkgconfig/gstreamer-interfaces.pc
 698 pkgconfig/gstreamer-interfaces-uninstalled.pc
 699 pkgconfig/gstreamer-netbuffer.pc
 700 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 701 pkgconfig/gstreamer-pbutils.pc
 702 pkgconfig/gstreamer-pbutils-uninstalled.pc
 703 pkgconfig/gstreamer-riff.pc
 704 pkgconfig/gstreamer-riff-uninstalled.pc
 705 pkgconfig/gstreamer-rtp.pc
 706 pkgconfig/gstreamer-rtp-uninstalled.pc
 707 pkgconfig/gstreamer-rtsp.pc
 708 pkgconfig/gstreamer-rtsp-uninstalled.pc
 709 pkgconfig/gstreamer-sdp.pc
 710 pkgconfig/gstreamer-sdp-uninstalled.pc
 711 pkgconfig/gstreamer-tag.pc
 712 pkgconfig/gstreamer-tag-uninstalled.pc
 713 pkgconfig/gstreamer-video.pc
 714 pkgconfig/gstreamer-video-uninstalled.pc
 715 pkgconfig/gstreamer-plugins-base.pc
 716 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 717 tests/Makefile
 718 tests/check/Makefile
 719 tests/examples/Makefile
 720 tests/examples/dynamic/Makefile
 721 tests/examples/seek/Makefile
 722 tests/examples/volume/Makefile
 723 tests/examples/snapshot/Makefile
 724 tests/icles/Makefile
 725 docs/Makefile
 726 docs/design/Makefile
 727 docs/libs/Makefile
 728 docs/plugins/Makefile
 729 docs/version.entities
 730 po/Makefile.in
 731 common/Makefile
 732 common/m4/Makefile
 733 m4/Makefile
 734 )
 735 AC_OUTPUT
 736
 737 AG_GST_OUTPUT_PLUGINS