configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT([GStreamer Ugly Plug-ins],[1.3.91],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-ugly])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS(config.h)
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AS_LIBTOOL(GST, 391, 0, 391)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.3.91
  49 GSTPB_REQ=1.3.91
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION(0.17)
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101 AC_PROG_CC_STDC
 102
 103 dnl determine c++ compiler
 104 AC_PROG_CXX
 105 dnl determine if c++ is available on this system
 106 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 107
 108 dnl check if the compiler supports '-c' and '-o' options
 109 AM_PROG_CC_C_O
 110
 111 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 112 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 113
 114 dnl check if the compiler supports do while(0) macros
 115 AG_GST_CHECK_DOWHILE_MACROS
 116
 117 dnl check for documentation tools
 118 GTK_DOC_CHECK([1.12])
 119 AG_GST_PLUGIN_DOCS([1.12])
 120
 121 dnl *** checks for libraries ***
 122
 123 dnl check for libm, for sin()
 124 LT_LIB_M
 125 AC_SUBST(LIBM)
 126
 127 dnl *** checks for header files ***
 128
 129 dnl used by ext/a52dec
 130 AX_CREATE_STDINT_H
 131
 132 dnl Check for malloc.h
 133 AC_CHECK_HEADERS([malloc.h])
 134
 135 dnl *** checks for types/defines ***
 136
 137 dnl *** checks for structures ***
 138
 139 dnl *** checks for compiler characteristics ***
 140
 141 dnl *** checks for library functions ***
 142
 143 dnl Check for a way to display the function name in debug output
 144 AG_GST_CHECK_FUNCTION
 145
 146 dnl *** checks for dependency libraries ***
 147
 148 dnl GLib is required
 149 GLIB_REQ=2.32.0
 150 AG_GST_GLIB_CHECK([$GLIB_REQ])
 151
 152 ORC_CHECK([0.4.16])
 153
 154 dnl checks for gstreamer
 155 dnl uninstalled is selected preferentially -- see pkg-config(1)
 156 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 157 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 158 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 159 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 160 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 161
 162 dnl Check for documentation xrefs
 163 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 164 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 165 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 166 AC_SUBST(GLIB_PREFIX)
 167 AC_SUBST(GST_PREFIX)
 168 AC_SUBST(GSTPB_PREFIX)
 169
 170 dnl Needed by plugins that use g_module_*() API
 171 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 172
 173 dnl *** set variables based on configure arguments ***
 174
 175 dnl set license and copyright notice
 176 GST_LICENSE="LGPL"
 177 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 178 AC_SUBST(GST_LICENSE)
 179
 180 dnl set location of plugin directory
 181 AG_GST_SET_PLUGINDIR
 182
 183 dnl set release date/time
 184 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 185   ["${srcdir}/gst-plugins-ugly.doap"],
 186   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 187
 188 dnl build static plugins or not
 189 AC_MSG_CHECKING([whether to build static plugins or not])
 190 AC_ARG_ENABLE(
 191   static-plugins,
 192   AC_HELP_STRING(
 193     [--enable-static-plugins],
 194     [build static plugins @<:@default=no@:>@]),
 195   [AS_CASE(
 196     [$enableval], [no], [], [yes], [],
 197     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 198   [enable_static_plugins=no])
 199 AC_MSG_RESULT([$enable_static_plugins])
 200 if test "x$enable_static_plugins" = xyes; then
 201   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 202     [Define if static plugins should be built])
 203   GST_PLUGIN_LIBTOOLFLAGS=""
 204 else
 205   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 206 fi
 207 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 208 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 209
 210 dnl define an ERROR_CFLAGS Makefile variable
 211 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 212     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 213     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 214     -Winit-self -Wmissing-include-dirs -Waddress
 215     -Waggregate-return -Wno-multichar -Wnested-externs ])
 216
 217 dnl define an ERROR_CXXFLAGS Makefile variable
 218 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 219     -Wmissing-declarations -Wredundant-decls
 220     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 221     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 222     -Wno-multichar])
 223
 224 dnl define correct level for debugging messages
 225 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 226
 227 dnl used in examples
 228 AG_GST_DEFAULT_ELEMENTS
 229
 230 dnl *** plug-ins to include ***
 231
 232 dnl Non ported plugins (non-dependant, then dependant)
 233 dnl Make sure you have a space before and after all plugins
 234 GST_PLUGINS_NONPORTED=" "
 235 AC_SUBST(GST_PLUGINS_NONPORTED)
 236
 237 dnl these are all the gst plug-ins, compilable without additional libs
 238 AG_GST_CHECK_PLUGIN(asfdemux)
 239 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 240 AG_GST_CHECK_PLUGIN(dvdsub)
 241 AG_GST_CHECK_PLUGIN(xingmux)
 242 AG_GST_CHECK_PLUGIN(realmedia)
 243
 244 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 245
 246 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 247   WIN32_LIBS="-lws2_32"
 248   AC_SUBST(WIN32_LIBS)
 249 fi
 250
 251 dnl *** ext plug-ins ***
 252 dnl keep this list sorted alphabetically !
 253
 254 if test "x$BUILD_EXTERNAL" = "xyes"; then
 255
 256 echo
 257 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 258 echo
 259
 260 dnl *** a52dec ***
 261 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 262 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 263   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 264 ])
 265
 266 dnl *** amr-nb ***
 267 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 268 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 269   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 270     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 271       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 272     fi
 273     HAVE_AMRNB="yes"
 274   ], [
 275     HAVE_AMRNB="no"
 276   ])
 277   AC_SUBST(AMRNB_CFLAGS)
 278   AC_SUBST(AMRNB_LIBS)
 279 ])
 280
 281 dnl *** amr-wb dec ***
 282 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 283 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 284   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 285     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 286       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 287     fi
 288     HAVE_AMRWB="yes"
 289   ], [
 290     HAVE_AMRWB="no"
 291   ])
 292   AC_SUBST(AMRWB_CFLAGS)
 293   AC_SUBST(AMRWB_LIBS)
 294 ])
 295
 296 dnl *** cdio ***
 297 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 298 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 299   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 300 ])
 301
 302 dnl *** dvdread ***
 303 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 304 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 305   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 306   AC_SUBST(DVDREAD_LIBS)
 307 ])
 308
 309 dnl *** lame ***
 310 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 311 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 312   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 313   [
 314     HAVE_LAME="yes"
 315     LAME_LIBS="-lmp3lame $LIBM"
 316     dnl is lame presets available
 317     LAME_CFLAGS=""
 318     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 319     ])
 320     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 321         void *ptr = &lame_set_VBR_quality
 322       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 323     ])
 324   AC_SUBST(LAME_CFLAGS)
 325   AC_SUBST(LAME_LIBS)
 326   ])
 327 ])
 328
 329 dnl *** mad ***
 330 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 331 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 332
 333   dnl check with pkg-config first
 334   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 335   MAD_LIBS="$MAD_LIBS"
 336   if test "x$HAVE_MAD" = "xno"; then
 337     dnl fall back to oldskool detection
 338     AC_CHECK_HEADER(mad.h, [
 339       AC_CHECK_LIB(mad, mad_decoder_finish,
 340         HAVE_MAD="yes" MAD_LIBS="-lmad")
 341     ])
 342   fi
 343 ])
 344 AC_SUBST(MAD_LIBS)
 345
 346 dnl *** mpeg2dec ***
 347 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 348 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 349   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 350 ])
 351
 352 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 353 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 354 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 355   GST_PATH_SIDPLAY()
 356 ])
 357
 358 dnl *** twolame ***
 359 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 360 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 361   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 362       HAVE_TWOLAME="yes"], [
 363       HAVE_TWOLAME="no"
 364   ])
 365   AC_SUBST(TWOLAME_CFLAGS)
 366   AC_SUBST(TWOLAME_LIBS)
 367 ])
 368
 369 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 370 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 371 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 372   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120)
 373 ])
 374
 375 else
 376
 377 dnl not building plugins with external dependencies,
 378 dnl but we still need to set the conditionals
 379
 380 AM_CONDITIONAL(USE_A52DEC, false)
 381 AM_CONDITIONAL(USE_AMRNB, false)
 382 AM_CONDITIONAL(USE_AMRWB, false)
 383 AM_CONDITIONAL(USE_CDIO, false)
 384 AM_CONDITIONAL(USE_DVDREAD, false)
 385 AM_CONDITIONAL(USE_LAME, false)
 386 AM_CONDITIONAL(USE_MAD, false)
 387 AM_CONDITIONAL(USE_MPEG2DEC, false)
 388 AM_CONDITIONAL(USE_SIDPLAY, false)
 389 AM_CONDITIONAL(USE_TWOLAME, false)
 390 AM_CONDITIONAL(USE_X264, false)
 391
 392 fi dnl of EXT plugins
 393
 394 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 395
 396 dnl Overview:
 397 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 398 dnl GST_*:              flags shared by built objects to link against GStreamer
 399 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 400 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 401 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 402 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 403
 404 dnl GST_OPTION_CFLAGS
 405 if test "x$USE_DEBUG" = xyes; then
 406    PROFILE_CFLAGS="-g"
 407 fi
 408 AC_SUBST(PROFILE_CFLAGS)
 409
 410 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 411   dnl Define _only_ during CVS (not pre-releases or releases)
 412   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 413 else
 414   DEPRECATED_CFLAGS=""
 415 fi
 416 AC_SUBST(DEPRECATED_CFLAGS)
 417
 418 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 419 dnl at make time with e.g. make ERROR_CFLAGS=""
 420 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 421 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 422 AC_SUBST(GST_OPTION_CFLAGS)
 423 AC_SUBST(GST_OPTION_CXXFLAGS)
 424
 425 dnl FIXME: do we want to rename to GST_ALL_* ?
 426 dnl prefer internal headers to already installed ones
 427 dnl also add builddir include for enumtypes and marshal
 428 dnl add GST_OPTION_CFLAGS, but overridable
 429 GST_CFLAGS="$GST_CFLAGS"
 430 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 431 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 432 AC_SUBST(GST_CFLAGS)
 433 AC_SUBST(GST_CXXFLAGS)
 434 AC_SUBST(GST_LIBS)
 435
 436 dnl LDFLAGS really should only contain flags, not libs - they get added before
 437 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 438 GST_ALL_LDFLAGS="-no-undefined"
 439 AC_SUBST(GST_ALL_LDFLAGS)
 440
 441 dnl this really should only contain flags, not libs - they get added before
 442 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 443 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 444 AC_SUBST(GST_PLUGIN_LDFLAGS)
 445
 446 dnl *** output files ***
 447
 448 AC_CONFIG_FILES(
 449 Makefile
 450 common/Makefile
 451 common/m4/Makefile
 452 gst-libs/Makefile
 453 gst-libs/gst/Makefile
 454 gst/Makefile
 455 gst/asfdemux/Makefile
 456 gst/dvdlpcmdec/Makefile
 457 gst/dvdsub/Makefile
 458 gst/realmedia/Makefile
 459 gst/xingmux/Makefile
 460 ext/Makefile
 461 ext/a52dec/Makefile
 462 ext/amrnb/Makefile
 463 ext/amrwbdec/Makefile
 464 ext/cdio/Makefile
 465 ext/dvdread/Makefile
 466 ext/lame/Makefile
 467 ext/mad/Makefile
 468 ext/mpeg2dec/Makefile
 469 ext/sidplay/Makefile
 470 ext/twolame/Makefile
 471 ext/x264/Makefile
 472 docs/Makefile
 473 docs/plugins/Makefile
 474 docs/version.entities
 475 tests/Makefile
 476 tests/check/Makefile
 477 m4/Makefile
 478 po/Makefile.in
 479 pkgconfig/Makefile
 480 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 481 gst-plugins-ugly.spec
 482 )
 483
 484 dnl Create the config.h file for Visual Studio builds
 485 dnl Beware of spaces and /'s in some of the shell variable contents.
 486 sed \
 487     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 488     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 489     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 490     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 491     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 492     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 493     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 494     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 495     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 496     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 497     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 498     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 499     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 500     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 501     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 502     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 503     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 504     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 505     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 506     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 507     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 508     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 509     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 510     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 511     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 512     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 513     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 514     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 515     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 516     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 517     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 518     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 519     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 520     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 521     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 522     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 523     config.h.in >win32/common/config.h-new
 524
 525 AC_OUTPUT
 526
 527 AG_GST_OUTPUT_PLUGINS
 528
 529 ORC_OUTPUT