configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl GStreamer versioning, this is mostly informational
  37 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  38 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  39 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  40 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  41 AC_SUBST(GST_VERSION_MAJOR)
  42 AC_SUBST(GST_VERSION_MINOR)
  43 AC_SUBST(GST_VERSION_MICRO)
  44 AC_SUBST(GST_VERSION_NANO)
  45
  46 dnl our libraries and install dirs use GST_API_VERSION in the filename
  47 dnl to allow side-by-side installation of different API versions
  48 GST_API_VERSION=1.0
  49 AC_SUBST(GST_API_VERSION)
  50 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  51   [GStreamer API Version])
  52
  53 dnl CURRENT, REVISION, AGE
  54 dnl - library source changed -> increment REVISION
  55 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  56 dnl - interfaces added -> increment AGE
  57 dnl - interfaces removed -> AGE = 0
  58 dnl
  59 dnl Keep CURRENT as MINOR * 100 + MICRO
  60 dnl Ex : 1.0.0 => 0
  61 dnl      1.0.3 => 3
  62 dnl      1.1.0 => 100
  63 dnl      1.2.5 => 205
  64 dnl      1.10.9 (who knows) => 1009
  65 dnl
  66 dnl sets GST_LT_LDFLAGS
  67 AS_LIBTOOL(GST, 100, 0, 100)
  68
  69 dnl *** autotools stuff ****
  70
  71 dnl allow for different autotools
  72 AS_AUTOTOOLS_ALTERNATE
  73
  74 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  75 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  76
  77 dnl set up gettext
  78 dnl the version check needs to stay here because autopoint greps for it
  79 AM_GNU_GETTEXT_VERSION([0.17])
  80 AM_GNU_GETTEXT([external])
  81 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  82
  83 dnl *** check for arguments to configure ***
  84
  85 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  86
  87 dnl subsystems - can influence other decisions so needs to be high up
  88 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  90 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 118 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 119
 120 AG_GST_ARG_DEBUG
 121 AG_GST_ARG_PROFILING
 122 AG_GST_ARG_VALGRIND
 123 AG_GST_ARG_GCOV
 124
 125 AG_GST_ARG_EXAMPLES
 126
 127 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 128 AG_GST_ARG_WITH_PACKAGE_NAME
 129 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 130
 131 AG_GST_PKG_CONFIG_PATH
 132
 133 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 134   ["${srcdir}/gstreamer.doap"],
 135   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 136
 137 dnl building of tests
 138 AC_ARG_ENABLE(tests,
 139   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 140   [
 141     case "${enableval}" in
 142       yes) BUILD_TESTS=yes ;;
 143       no)  BUILD_TESTS=no ;;
 144       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 145     esac
 146   ],
 147 [BUILD_TESTS=yes]) dnl Default value
 148 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 149
 150 dnl tests known to fail
 151 AC_ARG_ENABLE(failing-tests,
 152   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 153   [
 154     case "${enableval}" in
 155       yes) BUILD_FAILING_TESTS=yes ;;
 156       no)  BUILD_FAILING_TESTS=no ;;
 157       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 158     esac
 159   ],
 160   [BUILD_FAILING_TESTS=no]) dnl Default value
 161 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 162 if test x$BUILD_FAILING_TESTS = xyes; then
 163   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 164 else
 165   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 166 fi
 167
 168 dnl building of benchmarks
 169 AC_ARG_ENABLE(benchmarks,
 170   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 171   [
 172     case "${enableval}" in
 173       yes) BUILD_BENCHMARKS=yes ;;
 174       no)  BUILD_BENCHMARKS=no ;;
 175       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 176     esac
 177   ],
 178 [BUILD_BENCHMARKS=yes]) dnl Default value
 179 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 180
 181 dnl building of tools
 182 AC_ARG_ENABLE(tools,
 183   AS_HELP_STRING([--disable-tools],[disable building tools]),
 184   [
 185     case "${enableval}" in
 186       yes) BUILD_TOOLS=yes ;;
 187       no)  BUILD_TOOLS=no ;;
 188       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 189     esac
 190   ],
 191 [BUILD_TOOLS=yes]) dnl Default value
 192 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 193
 194 dnl poison destroyed objects
 195 AC_ARG_ENABLE(poisoning,
 196   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 197   [
 198     case "${enableval}" in
 199       yes) USE_POISONING=yes ;;
 200       no)  USE_POISONING=no ;;
 201       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 202     esac
 203   ],
 204   [USE_POISONING=no]) dnl Default value
 205 if test "x$USE_POISONING" = xyes; then
 206   AC_DEFINE(USE_POISONING, 1,
 207     [Define if we should poison deallocated memory])
 208 fi
 209
 210 dnl *** checks for platform ***
 211
 212 dnl * hardware/architecture *
 213
 214 dnl common/m4/gst-arch.m4
 215 dnl check CPU type
 216 AG_GST_ARCH
 217 dnl substitution for win32/common/config.h
 218 HOST_CPU=$host_cpu
 219 AC_SUBST(HOST_CPU)
 220
 221 dnl common/m4/gst-arch.m4
 222 dnl check for unaligned access
 223 AG_GST_UNALIGNED_ACCESS
 224 dnl create a configure variable for gst/gstconfig.h
 225 if test x${as_cv_unaligned_access} = xyes ; then
 226   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 227 else
 228   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 229 fi
 230 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 231
 232 dnl check for platform specific settings
 233 AG_GST_PLATFORM
 234
 235 dnl * software *
 236
 237 dnl check for large file support
 238 dnl affected plugins must include config.h
 239 AC_SYS_LARGEFILE
 240
 241 dnl *** checks for programs ***
 242
 243 dnl find a compiler
 244 AC_PROG_CC
 245 AC_PROG_CC_STDC
 246
 247 dnl check if the compiler supports '-c' and '-o' options
 248 AM_PROG_CC_C_O
 249
 250 dnl find an assembler
 251 AM_PROG_AS
 252
 253 dnl determine if c++ is available on this system
 254 AC_PROG_CXX
 255 dnl CXX may be set to some default even if no c++ compiler is available
 256 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 257 AC_LANG_PUSH([C++])
 258 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 259 AC_LANG_POP([C++])
 260 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 261 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 262
 263 dnl Perl is used in building documentation and in the version checks
 264 AC_PATH_PROG(PERL_PATH, perl, no)
 265 if test x$PERL_PATH = xno; then
 266   AC_MSG_ERROR(Could not find perl)
 267 fi
 268
 269 dnl we require flex and bison for building the parser
 270 if test "x$GST_DISABLE_PARSE" != xyes; then
 271   AG_GST_BISON_CHECK
 272   AG_GST_FLEX_CHECK
 273 fi
 274
 275 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 276 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 277
 278 dnl check for gobject-introspection
 279 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 280
 281 dnl check for documentation tools
 282 AG_GST_DOCBOOK_CHECK
 283 GTK_DOC_CHECK([1.12])
 284 AG_GST_PLUGIN_DOCS([1.12])
 285
 286 dnl *** checks for libraries ***
 287
 288 dnl check for libm, for sin()
 289 LT_LIB_M
 290 AC_SUBST(LIBM)
 291
 292 dnl *** checks for header files ***
 293
 294 dnl check if we have ANSI C header files
 295 AC_HEADER_STDC
 296
 297 dnl Check for ucontext.h
 298 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 299
 300 dnl Check for sys/socket.h
 301 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 302 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 303
 304 dnl check for sys/times.h for tests/examples/adapter/
 305 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 306 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 307 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 308
 309 dnl Check for process.h for getpid() on win32
 310 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 311
 312 dnl Check for sys/utsname.h for uname
 313 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 314
 315 dnl Check for stdio_ext.f for __fbufsize
 316 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 317
 318 dnl check for pthreads
 319 AX_PTHREAD([HAVE_PTHREAD=yes], [HAVE_PTHREAD=no])
 320 AM_CONDITIONAL(HAVE_PTHREAD, test "x$HAVE_PTHREAD" = "xyes")
 321
 322 dnl check for sys/prctl for setting thread name on Linux
 323 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 324
 325 dnl Check for valgrind.h
 326 dnl separate from HAVE_VALGRIND because you can have the program, but not
 327 dnl the dev package
 328 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 329
 330 dnl used in gst/gstpoll.c
 331 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 332 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 333 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 334   WIN32_LIBS="-lws2_32"
 335   AC_SUBST(WIN32_LIBS)
 336 fi
 337
 338 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 339 if test "x$BUILD_TESTS" = "xyes"; then
 340   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 341                          __gmpz_init_set_d, ,
 342                          gmp.h,
 343                          GMP_LIBS="-lgmp"
 344                          AC_SUBST(GMP_LIBS)
 345                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 346   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 347                          gsl_rng_uniform_int, -lgslcblas,
 348                          gsl/gsl_rng.h,
 349                          GSL_LIBS="-lgsl -lgslcblas"
 350                          AC_SUBST(GSL_LIBS)
 351                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 352 fi
 353
 354 dnl *** checks for types/defines ***
 355
 356 dnl *** checks for structures ***
 357
 358 dnl *** checks for compiler characteristics ***
 359
 360 dnl check if the compiler supports __uint128_t (gcc)
 361 dnl Actually check for 128-bit division, since that's what we use
 362 dnl uint128_t for.
 363 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 364     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 365       static __uint128_t v1 = 100;
 366       static __uint128_t v2 = 10;
 367       static __uint128_t u;
 368       u = v1 / v2;
 369     ]])],[
 370       gst_cv_uint128_t=yes
 371     ],[
 372       gst_cv_uint128_t=no
 373     ])
 374 )
 375 if test x$gst_cv_uint128_t = xyes; then
 376   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 377 fi
 378
 379 dnl *** checking for tm_gmtoff ***
 380 AC_MSG_CHECKING([for tm_gmtoff])
 381 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 382         #include <time.h>
 383         int main(void) {
 384           struct tm t;
 385           t.tm_gmtoff = 0;
 386           exit(0);
 387         }]])],
 388   [have_tm_gmtoff=yes
 389    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 390   [have_tm_gmtoff=no],
 391   [have_tm_gmtoff="no (cross compiling)"])
 392 AC_MSG_RESULT($have_tm_gmtoff)
 393
 394
 395 dnl *** checks for library functions ***
 396
 397 AC_CHECK_FUNCS([gmtime_r])
 398 AC_CHECK_FUNCS([localtime_r])
 399 AC_CHECK_FUNCS([sigaction])
 400
 401 dnl check for fseeko()
 402 AC_FUNC_FSEEKO
 403 dnl check for ftello()
 404 AC_CHECK_FUNCS([ftello])
 405
 406 AC_CHECK_FUNCS([fgetpos])
 407 AC_CHECK_FUNCS([fsetpos])
 408
 409 dnl check for poll(), ppoll() and pselect()
 410 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 411 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 412 AC_CHECK_FUNCS([poll])
 413 AC_CHECK_FUNCS([ppoll])
 414 AC_CHECK_FUNCS([pselect])
 415
 416 dnl ****************************************
 417 dnl *** GLib POLL* compatibility defines ***
 418 dnl ****************************************
 419
 420 AC_MSG_CHECKING([for broken poll])
 421 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 422         #include <stdlib.h>
 423         #include <fcntl.h>
 424         #ifdef HAVE_SYS_POLL_H
 425         #include <sys/poll.h>
 426         #endif
 427         #ifdef HAVE_POLL_H
 428         #include <poll.h>
 429         #endif
 430         int main(void) {
 431           struct pollfd fds[1];
 432           int fd;
 433           fd = open("/dev/null", 1);
 434           fds[0].fd = fd;
 435           fds[0].events = POLLIN;
 436           fds[0].revents = 0;
 437           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 438                 exit(1);  /* Does not work for devices -- fail */
 439           }
 440           exit(0);
 441         }]])],
 442   [broken_poll=no],
 443   [broken_poll=yes
 444    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 445   [broken_poll="no (cross compiling)"])
 446 AC_MSG_RESULT($broken_poll)
 447
 448 dnl check for mmap()
 449 AC_FUNC_MMAP
 450 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 451
 452 dnl check for posix_memalign(), getpagesize()
 453 AC_CHECK_FUNCS([posix_memalign])
 454 AC_CHECK_FUNCS([getpagesize])
 455
 456 dnl Check for POSIX timers
 457 AC_CHECK_FUNCS(clock_gettime, [], [
 458   AC_CHECK_LIB(rt, clock_gettime, [
 459     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 460     LIBS="$LIBS -lrt"
 461   ], [
 462     AC_CHECK_LIB(pthread, clock_gettime, [
 463       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 464       LIBS="$LIBS -lpthread"
 465     ])
 466   ])
 467 ])
 468
 469 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 470     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 471 #include <time.h>
 472 #ifdef HAVE_UNISTD_H
 473 #include <unistd.h>
 474 #endif
 475     ]], [[
 476 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 477 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 478 #endif
 479     ]])],[
 480       gst_cv_posix_timers=yes
 481     ],[
 482       gst_cv_posix_timers=no
 483     ])
 484 )
 485
 486 if test "$gst_cv_posix_timers" = "yes"; then
 487   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 488   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 489 else
 490   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 491 fi
 492 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 493 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 494
 495 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 496     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 497 #include <time.h>
 498 #ifdef HAVE_UNISTD_H
 499 #include <unistd.h>
 500 #endif
 501     ]], [[
 502 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 503 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 504 #endif
 505     ]])],[
 506       gst_cv_monotonic_clock=yes
 507     ],[
 508       gst_cv_monotonic_clock=no
 509     ])
 510 )
 511
 512 if test "$gst_cv_monotonic_clock" = "yes"; then
 513   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 514   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 515 else
 516   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 517 fi
 518 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 519 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 520
 521 dnl Check for a way to display the function name in debug output
 522 AG_GST_CHECK_FUNCTION
 523
 524 dnl test for register_printf_specifier or register_printf_function
 525 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 526     [HAVE_PRINTF_EXTENSION=yes])
 527
 528 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 529   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 530   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 531   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 532   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 533       [Defined if we have printf specifier extensions available])
 534 else
 535     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 536     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 537     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 538 fi
 539 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 540 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 541 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 542
 543 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 544 save_cflags="$CFLAGS"
 545 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 546 AC_CHECK_LIB(dl, dladdr,
 547    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 548    LIBS="$LIBS -ldl")
 549 CFLAGS="$save_cflags"
 550
 551 dnl *** checks for dependency libraries ***
 552
 553 dnl GLib
 554 GLIB_REQ=2.32.0
 555 AG_GST_GLIB_CHECK([$GLIB_REQ])
 556
 557 dnl Check for documentation xrefs
 558 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 559 AC_SUBST(GLIB_PREFIX)
 560
 561 dnl building of unit test libraries
 562 AC_ARG_ENABLE(check,
 563   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 564   [
 565     case "${enableval}" in
 566       yes) BUILD_CHECK=yes ;;
 567       no)  BUILD_CHECK=no ;;
 568       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 569     esac
 570   ], [
 571     dnl Default value
 572     case $host_os in
 573       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 574       *) BUILD_CHECK=yes ;;
 575     esac
 576 ])
 577 dnl bit of a misnomer, but keep the conditional named like this so we don't
 578 dnl have to change too much elsewhere
 579 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 580
 581 dnl configure the desired memory alignment
 582 AC_ARG_WITH([memory-alignment],
 583   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 584   [
 585     if test "x$withval" = "xyes"
 586     then
 587       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 588     else
 589       case "${withval}" in
 590         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 591         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 592         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 593       esac
 594     fi
 595   ], [
 596     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 597   ]
 598 )
 599
 600 dnl Check for -Bsymbolic-functions linker flag used to avoid
 601 dnl intra-library PLT jumps, if available.
 602 AC_ARG_ENABLE(Bsymbolic,
 603               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 604               [SAVED_LDFLAGS="${LDFLAGS}"
 605                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 606                LDFLAGS=-Wl,-Bsymbolic-functions
 607                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 608                            AC_MSG_RESULT(yes)
 609                            enable_Bsymbolic=yes],[
 610                            AC_MSG_RESULT(no)
 611                            enable_Bsymbolic=no])
 612                LDFLAGS="${SAVED_LDFLAGS}"])
 613
 614
 615 dnl *** set variables based on configure arguments
 616
 617 dnl set license and copyright notice
 618 GST_LICENSE="LGPL"
 619 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 620 AC_SUBST(GST_LICENSE)
 621
 622 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 623 AS_AC_EXPAND(LIBDIR, $libdir)
 624 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 625 AS_AC_EXPAND(DATADIR, $datadir)
 626 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 627
 628 dnl set location of plugin directory
 629 AG_GST_SET_PLUGINDIR
 630
 631 dnl make sure it doesn't complain about unused variables if debugging is disabled
 632 NO_WARNINGS=""
 633 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 634   NO_WARNINGS="-Wno-unused"
 635 fi
 636
 637 dnl define an ERROR_CFLAGS Makefile variable
 638 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 639
 640 dnl define correct level for debugging messages
 641 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 642
 643 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 644
 645 dnl Overview:
 646 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 647 dnl GST_ALL_*:          vars shared by all built objects
 648 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 649 dnl GST_OBJ_*:          additional vars to link to the core library
 650 dnl                     include GST_ALL_*
 651 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 652 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 653
 654 dnl GST_OPTION_CFLAGS
 655 if test "x$USE_DEBUG" = xyes; then
 656    PROFILE_CFLAGS="-g"
 657 fi
 658 AC_SUBST(PROFILE_CFLAGS)
 659
 660 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 661 # functionality from the API that gstreamer uses
 662 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 663 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 664   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 665   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 666 else
 667   DEPRECATED_CFLAGS=""
 668 fi
 669 AC_SUBST(DEPRECATED_CFLAGS)
 670
 671 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 672 dnl make DEPRECATED_CFLAGS=''
 673 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 674 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 675 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 676 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 677 AC_SUBST(GST_OPTION_CFLAGS)
 678 AC_SUBST(GST_OPTION_CXXFLAGS)
 679
 680 dnl GST_ALL_*
 681 dnl vars common to for all internal objects (core libs, elements, applications)
 682 dnl CFLAGS:
 683 dnl - src and build dirs need to be added because every piece that gets built
 684 dnl   will need the GStreamer source and generated headers
 685 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 686 dnl       from LibXML except for in the core library
 687 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 688 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 689
 690 dnl FIXME: check if LTLIBINTL is needed everywhere
 691 dnl I presume it is given that it contains the symbols that _() stuff maps to
 692 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 693
 694 dnl LDFLAGS really should only contain flags, not libs - they get added before
 695 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 696 GST_ALL_LDFLAGS="-no-undefined"
 697 if test "x${enable_Bsymbolic}" = "xyes"; then
 698   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 699 fi
 700
 701 AC_SUBST(GST_ALL_CFLAGS)
 702 AC_SUBST(GST_ALL_CXXFLAGS)
 703 AC_SUBST(GST_ALL_LIBS)
 704 AC_SUBST(GST_ALL_LDFLAGS)
 705
 706 dnl GST_LIB_LDFLAGS
 707 dnl linker flags shared by all libraries
 708 dnl LDFLAGS modifier defining exported symbols from built libraries
 709 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 710 AC_SUBST(GST_LIB_LDFLAGS)
 711
 712 dnl GST_OBJ_*
 713 dnl default vars for all internal objects built on libgstreamer
 714 dnl includes GST_ALL_*
 715 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 716 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 717 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 718 AC_SUBST(GST_OBJ_CFLAGS)
 719 AC_SUBST(GST_OBJ_CXXFLAGS)
 720 AC_SUBST(GST_OBJ_LIBS)
 721
 722 dnl GST_PLUGIN_LDFLAGS
 723 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 724 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 725 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 726
 727 dnl plugin scanner locations
 728 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 729 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 730     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 731 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 732
 733 dnl things for our internal libcheck (must be called even if building
 734 dnl libcheck is disabled because it defines conditionals)
 735 AG_GST_CHECK_CHECKS()
 736
 737 AC_CONFIG_FILES(
 738 Makefile
 739 gst/Makefile
 740 gst/gstconfig.h
 741 gst/gstversion.h
 742 gst/parse/Makefile
 743 gst/printf/Makefile
 744 libs/Makefile
 745 libs/gst/Makefile
 746 libs/gst/base/Makefile
 747 libs/gst/check/Makefile
 748 libs/gst/check/libcheck/Makefile
 749 libs/gst/check/libcheck/check.h
 750 libs/gst/controller/Makefile
 751 libs/gst/helpers/Makefile
 752 libs/gst/net/Makefile
 753 plugins/Makefile
 754 plugins/elements/Makefile
 755 po/Makefile.in
 756 tests/Makefile
 757 tests/benchmarks/Makefile
 758 tests/check/Makefile
 759 tests/misc/Makefile
 760 tests/examples/Makefile
 761 tests/examples/adapter/Makefile
 762 tests/examples/controller/Makefile
 763 tests/examples/stepping/Makefile
 764 tests/examples/helloworld/Makefile
 765 tests/examples/launch/Makefile
 766 tests/examples/manual/Makefile
 767 tests/examples/memory/Makefile
 768 tests/examples/metadata/Makefile
 769 tests/examples/queue/Makefile
 770 tests/examples/streams/Makefile
 771 tests/examples/typefind/Makefile
 772 tools/Makefile
 773 common/Makefile
 774 common/m4/Makefile
 775 docs/Makefile
 776 docs/design/Makefile
 777 docs/faq/Makefile
 778 docs/gst/Makefile
 779 docs/gst/gstreamer.types
 780 docs/libs/Makefile
 781 docs/plugins/Makefile
 782 docs/manual/Makefile
 783 docs/pwg/Makefile
 784 docs/slides/Makefile
 785 docs/xsl/Makefile
 786 docs/version.entities
 787 m4/Makefile
 788 pkgconfig/Makefile
 789 stamp.h
 790 pkgconfig/gstreamer.pc
 791 pkgconfig/gstreamer-uninstalled.pc
 792 pkgconfig/gstreamer-base.pc
 793 pkgconfig/gstreamer-base-uninstalled.pc
 794 pkgconfig/gstreamer-check.pc
 795 pkgconfig/gstreamer-check-uninstalled.pc
 796 pkgconfig/gstreamer-controller.pc
 797 pkgconfig/gstreamer-controller-uninstalled.pc
 798 pkgconfig/gstreamer-net.pc
 799 pkgconfig/gstreamer-net-uninstalled.pc
 800 gstreamer.spec
 801 )
 802
 803 dnl Create the config.h file for Visual Studio builds
 804 dnl Beware of spaces and /'s in some of the shell variable contents.
 805 sed \
 806     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 807     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 808     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 809     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 810     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 811     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 812     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 813     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 814     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 815     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 816     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 817     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 818     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 819     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 820     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 821     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 822     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 823     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 824     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 825     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 826     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 827     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 828     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 829     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 830     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 831     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 832     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 833     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 834     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 835     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 836     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 837     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 838     config.h.in >win32/common/config.h-new
 839
 840 AC_OUTPUT
 841
 842 dnl negate for output
 843 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 844 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 845 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 846 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 847 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 848 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 849 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 850
 851 echo "
 852
 853 Configuration
 854         Version                    : ${VERSION}
 855         Source code location       : ${srcdir}
 856         Prefix                     : ${prefix}
 857         Compiler                   : ${CC}
 858         Package name               : ${GST_PACKAGE_NAME}
 859         Package origin             : ${GST_PACKAGE_ORIGIN}
 860
 861         Documentation (manuals)    : ${enable_docbook}
 862         Documentation (API)        : ${enable_gtk_doc}
 863
 864         Debug Logging              : ${enable_gst_debug}
 865         Command-line parser        : ${enable_parse}
 866         Option parsing in gst_init : ${enable_option_parsing}
 867         Tracing subsystem          : ${enable_trace}
 868         Allocation tracing         : ${enable_alloc_trace}
 869         Plugin registry            : ${enable_registry}
 870         Plugin support             : ${enable_plugin}
 871         Unit testing support       : ${BUILD_CHECK}
 872
 873         Debug                      : ${USE_DEBUG}
 874         Profiling                  : ${USE_PROFILING}
 875
 876         Building benchmarks        : ${BUILD_BENCHMARKS}
 877         Building examples          : ${BUILD_EXAMPLES}
 878         Building test apps         : ${BUILD_TESTS}
 879         Building tests that fail   : ${BUILD_FAILING_TESTS}
 880         Building tools             : ${BUILD_TOOLS}
 881 "