configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.18.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.26
  51 GSTPB_REQ=0.10.26.1
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 dnl check if the compiler supports do while(0) macros
 120 AG_GST_CHECK_DOWHILE_MACROS
 121
 122 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 123 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 124
 125 dnl check for gconftool-2
 126 dnl this macro defines an am conditional, so it needs to be run always
 127 AM_GCONF_SOURCE_2
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.3])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 AC_CHECK_LIBM
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/rtp/gstasteriskh263.c
 149 AC_CHECK_HEADERS([netinet/in.h])
 150 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 151 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl *** checks for types/defines ***
 157
 158 dnl Check for FIONREAD ioctl declaration.  This check is needed
 159 dnl for the UDP plugin to build on Solaris
 160 GST_CHECK_FIONREAD
 161
 162 dnl *** checks for structures ***
 163
 164 dnl *** checks for compiler characteristics ***
 165
 166 dnl check if we have GCC inline-asm
 167 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 168 if test x$HAVE_GCC_ASM = xyes ; then
 169   AC_DEFINE(HAVE_GCC_ASM, 1,
 170     [Define if compiler supports gcc inline assembly])
 171 fi
 172 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 173
 174 dnl *** checks for library functions ***
 175
 176 LIBS_SAVE=$LIBS
 177 LIBS="$LIBS $LIBM"
 178 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 179 LIBS=$LIBS_SAVE
 180
 181 dnl Check whether isinf() is defined by math.h
 182 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 183     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 184 if test "$ac_cv_have_isinf" = "yes"
 185 then
 186     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 187 fi
 188
 189 dnl Check for mmap (needed by electricfence plugin)
 190 AC_FUNC_MMAP
 191 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194
 195 AC_CHECK_TYPE([struct ip_mreqn], [
 196               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 197               [#include <netinet/in.h>])
 198
 199 dnl *** checks for dependency libraries ***
 200
 201 dnl GLib is required
 202 AG_GST_GLIB_CHECK([2.18])
 203
 204 dnl liboil is required
 205 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 206 if test "x$HAVE_LIBOIL" != "xyes"; then
 207   AC_ERROR([liboil-0.3.8 or later is required])
 208 fi
 209
 210 dnl checks for gstreamer
 211 dnl uninstalled is selected preferentially -- see pkg-config(1)
 212 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 213 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 214 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 217 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 218
 219 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 220 if test -z $GST_TOOLS_DIR; then
 221   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 222 fi
 223 AC_SUBST(GST_TOOLS_DIR)
 224
 225 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 226 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 227
 228 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 229
 230 dnl Check for documentation xrefs
 231 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 232 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 233 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 234 AC_SUBST(GLIB_PREFIX)
 235 AC_SUBST(GST_PREFIX)
 236 AC_SUBST(GSTPB_PREFIX)
 237
 238 dnl GTK is optional and used in examples
 239 if test "x$BUILD_EXAMPLES" = "xyes"; then
 240   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 241   AC_SUBST(GTK_LIBS)
 242   AC_SUBST(GTK_CFLAGS)
 243 fi
 244 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 245
 246 dnl should we install schemas ?
 247 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 248 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 249   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 250   if test x$GCONFTOOL = xno; then
 251     AC_MSG_WARN(Not installing GConf schemas)
 252     HAVE_GCONFTOOL="no"
 253   else
 254     HAVE_GCONFTOOL="yes"
 255   fi
 256   AC_SUBST(HAVE_GCONFTOOL)
 257 ])
 258
 259 dnl *** set variables based on configure arguments ***
 260
 261 dnl set license and copyright notice
 262 GST_LICENSE="LGPL"
 263 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 264 AC_SUBST(GST_LICENSE)
 265
 266 dnl set location of plugin directory
 267 AG_GST_SET_PLUGINDIR
 268
 269 dnl define an ERROR_CFLAGS Makefile variable
 270 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 271
 272 dnl define an ERROR_CXXFLAGS Makefile variable
 273 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT)
 274
 275 dnl define correct level for debugging messages
 276 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 277
 278 dnl used in examples
 279 AG_GST_DEFAULT_ELEMENTS
 280
 281 dnl *** plug-ins to include ***
 282
 283 dnl these are all the gst plug-ins, compilable without additional libs
 284 dnl videofilter is at the top because others depend on it
 285 AG_GST_CHECK_PLUGIN(videofilter)
 286 AG_GST_CHECK_PLUGIN(alpha)
 287 AG_GST_CHECK_PLUGIN(apetag)
 288 AG_GST_CHECK_PLUGIN(audiofx)
 289 AG_GST_CHECK_PLUGIN(auparse)
 290 AG_GST_CHECK_PLUGIN(autodetect)
 291 AG_GST_CHECK_PLUGIN(avi)
 292 AG_GST_CHECK_PLUGIN(cutter)
 293 AG_GST_CHECK_PLUGIN(debugutils)
 294 AG_GST_CHECK_PLUGIN(deinterlace)
 295 AG_GST_CHECK_PLUGIN(effectv)
 296 AG_GST_CHECK_PLUGIN(equalizer)
 297 AG_GST_CHECK_PLUGIN(flv)
 298 AG_GST_CHECK_PLUGIN(id3demux)
 299 AG_GST_CHECK_PLUGIN(icydemux)
 300 AG_GST_CHECK_PLUGIN(interleave)
 301 AG_GST_CHECK_PLUGIN(flx)
 302 AG_GST_CHECK_PLUGIN(goom)
 303 AG_GST_CHECK_PLUGIN(goom2k1)
 304 AG_GST_CHECK_PLUGIN(law)
 305 AG_GST_CHECK_PLUGIN(level)
 306 AG_GST_CHECK_PLUGIN(matroska)
 307 AG_GST_CHECK_PLUGIN(monoscope)
 308 AG_GST_CHECK_PLUGIN(multifile)
 309 AG_GST_CHECK_PLUGIN(multipart)
 310 AG_GST_CHECK_PLUGIN(qtdemux)
 311 AG_GST_CHECK_PLUGIN(replaygain)
 312 AG_GST_CHECK_PLUGIN(rtp)
 313 AG_GST_CHECK_PLUGIN(rtpmanager)
 314 AG_GST_CHECK_PLUGIN(rtsp)
 315 AG_GST_CHECK_PLUGIN(shapewipe)
 316 AG_GST_CHECK_PLUGIN(smpte)
 317 AG_GST_CHECK_PLUGIN(spectrum)
 318 AG_GST_CHECK_PLUGIN(udp)
 319 AG_GST_CHECK_PLUGIN(videobox)
 320 AG_GST_CHECK_PLUGIN(videocrop)
 321 AG_GST_CHECK_PLUGIN(videomixer)
 322 AG_GST_CHECK_PLUGIN(wavenc)
 323 AG_GST_CHECK_PLUGIN(wavparse)
 324 AG_GST_CHECK_PLUGIN(y4m)
 325
 326 dnl *** checks for socket and nsl libraries ***
 327 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 328
 329 dnl disable gst plugins we might not be able to build on this
 330 dnl platform: udp and rtsp (ugly but minimally invasive)
 331 dnl FIXME: maybe move to sys
 332 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 333 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 334
 335 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 336   AG_GST_DISABLE_PLUGIN(udp)
 337   AG_GST_DISABLE_PLUGIN(rtsp)
 338 fi
 339
 340 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 341   WIN32_LIBS="-lws2_32"
 342   AC_SUBST(WIN32_LIBS)
 343 fi
 344
 345 dnl disable experimental plug-ins
 346 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 347   AG_GST_DISABLE_PLUGIN(monoscope)
 348 fi
 349
 350 dnl *** sys plug-ins ***
 351
 352 echo
 353 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 354 echo
 355
 356 dnl DirectSound
 357 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 358 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 359   HAVE_DIRECTSOUND="no"
 360   save_CFLAGS="$CFLAGS"
 361   save_LDFLAGS="$LDFLAGS"
 362   save_LIBS="$LIBS"
 363   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 364   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 365   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 366   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 367   AC_LINK_IFELSE([
 368 #include <windows.h>
 369 #include <dxerr9.h>
 370 #include <dsound.h>
 371
 372 int main ()
 373 {
 374   DXGetErrorString9 (0);
 375   DirectSoundCreate(NULL, NULL, NULL);
 376
 377   return 0;
 378 }
 379 ],
 380     [HAVE_DIRECTSOUND="yes"],
 381     [HAVE_DIRECTSOUND="no"])
 382   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 383   CFLAGS=$save_CFLAGS
 384   LDFLAGS=$save_LDFLAGS
 385   LIBS=$save_LIBS
 386
 387   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 388     dnl this is much more than we want
 389     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 390     AC_SUBST(DIRECTSOUND_CFLAGS)
 391     AC_SUBST(DIRECTSOUND_LDFLAGS)
 392     AC_SUBST(DIRECTSOUND_LIBS)
 393   fi
 394   AC_SUBST(HAVE_DIRECTSOUND)
 395 ])
 396
 397 dnl *** OSS audio *** (Linux, *BSD)
 398 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 399 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 400  HAVE_OSS="yes"
 401 dnl Linux and newer BSD versions :
 402  AC_CHECK_HEADER(sys/soundcard.h, [
 403    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 404    ] , [
 405 dnl Some old BSD versions and also newer OpenBSD versions :
 406    AC_CHECK_HEADER(soundcard.h, [
 407      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 408      ], [
 409   dnl Some old BSD versions :
 410      AC_CHECK_HEADER(machine/soundcard.h, [
 411        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 412          [Define if OSS includes are in /machine/])
 413        ], [
 414        HAVE_OSS="no"
 415      ])
 416    ])
 417  ])
 418 ])
 419
 420 dnl *** Sun Audio ***
 421 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 422 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 423   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 424 ])
 425
 426 dnl *** OSX Audio ***
 427 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 428 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 429   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 430 ])
 431
 432 dnl *** OS X video ***
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 434 HAVE_OSX_VIDEO="no"
 435 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 436   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 437 ])
 438 dnl in case header OpenGL/gl.h is found on other platforms
 439 case "$host" in
 440   *-*darwin*)
 441     dnl do nothing
 442     ;;
 443   *)
 444     HAVE_OSX_VIDEO="no"
 445     ;;
 446 esac
 447
 448
 449 dnl *** Video 4 Linux 2 ***
 450 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 451 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 453 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 454   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 455   AC_TRY_COMPILE([
 456 #include <sys/types.h>
 457 #ifdef __sun /* Solaris */
 458 #include <sys/types.h>
 459 #include <sys/videodev2.h>
 460 #else /* Linux */
 461 #include <linux/types.h>
 462 #define _LINUX_TIME_H
 463 #define __user
 464 #include <linux/videodev2.h>
 465 #endif
 466 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 467 #error too early v4l2 version or no v4l2 at all
 468 #endif
 469     ], [
 470 return 0;
 471     ], [
 472       HAVE_GST_V4L2="yes"
 473       AC_MSG_RESULT(yes)
 474     ], [
 475       HAVE_GST_V4L2="no"
 476       AC_MSG_RESULT(no)
 477
 478       HAVE_VIDEODEV=no
 479       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 480       [
 481         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 482       ])
 483
 484       if test "x$HAVE_VIDEODEV" = "xyes"; then
 485         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 486         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 487       else
 488         AC_MSG_WARN([video4linux2 was not found])
 489       fi
 490     ])
 491
 492   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 493     dnl check for missing v4l2_buffer declaration (see #135919)
 494     MISSING_DECL=0
 495     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 496     AC_TRY_COMPILE([
 497 #include <sys/types.h>
 498 #ifdef __sun /* Solaris */
 499 #include <sys/types.h>
 500 #include <sys/videodev2.h>
 501 #else /* Linux */
 502 #include <linux/types.h>
 503 #define _LINUX_TIME_H
 504 #define __user
 505 #include <linux/videodev2.h>
 506 #endif
 507     ],[
 508 struct v4l2_buffer buf;
 509 buf.index = 0;
 510 return 0;
 511     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 512     if [ test x$MISSING_DECL = x1 ]; then
 513       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 514     fi
 515
 516     dnl check for XOverlay libraries
 517     AG_GST_CHECK_XV
 518   fi
 519 ])
 520
 521 # Optional gudev for device probing
 522 AC_ARG_WITH([gudev],
 523   AC_HELP_STRING([--with-gudev],
 524     [device detection with gudev]),
 525   [],
 526   [with_gudev=check])
 527 if test x$HAVE_GST_V4L2 = xyes; then
 528   if test x$with_gudev != xno; then
 529       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 530           [ have_gudev=yes
 531             AC_DEFINE(HAVE_GUDEV, 1,
 532                [Whether gudev is available for device detection])
 533             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 534           ], [
 535           have_gudev=no
 536           ])
 537   else
 538     have_gudev=no
 539   fi
 540 fi
 541 AC_SUBST(GUDEV_CFLAGS)
 542 AC_SUBST(GUDEV_LIBS)
 543
 544 # Make libv4l2 non-automagic
 545 AC_ARG_WITH([libv4l2],
 546   AC_HELP_STRING([--with-libv4l2],
 547     [support video buffer conversion using libv4l2]),
 548   [],
 549   [with_libv4l2=check])
 550 if test x$HAVE_GST_V4L2 = xyes; then
 551   if test x$with_libv4l2 != xno; then
 552       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 553           [ have_libv4l2=yes
 554             AC_DEFINE(HAVE_LIBV4L2, 1,
 555                 [Whether libv4l2 is available for video buffer conversion])
 556           ], [
 557           have_libv4l2=no
 558           ])
 559   else
 560     have_libv4l2=no
 561   fi
 562 fi
 563
 564 dnl Check for X11
 565 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 566 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 567                   [ximagesrc], [
 568   AC_PATH_XTRA
 569
 570   dnl now try to find the HEADER
 571   ac_cflags_save="$CFLAGS"
 572   ac_cppflags_save="$CPPFLAGS"
 573   CFLAGS="$CFLAGS $X_CFLAGS"
 574   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 575   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 576
 577   if test "x$HAVE_X" = "xno"
 578   then
 579     AC_MSG_NOTICE([cannot find X11 development files])
 580   else
 581     dnl this is much more than we want
 582     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 583     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 584     dnl it does not add the libs; therefore we add them here
 585     X_LIBS="$X_LIBS -lX11"
 586     AC_SUBST(X_CFLAGS)
 587     AC_SUBST(X_LIBS)
 588
 589     dnl check for Xfixes
 590     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 591     if test "x$HAVE_XFIXES" = "xyes"
 592     then
 593         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 594     fi
 595     AC_SUBST(XFIXES_LIBS)
 596     AC_SUBST(XFIXES_CFLAGS)
 597
 598     dnl check for Xdamage
 599     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 600     if test "x$HAVE_XDAMAGE" = "xyes"
 601     then
 602         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 603     fi
 604     AC_SUBST(XDAMAGE_LIBS)
 605     AC_SUBST(XDAMAGE_CFLAGS)
 606   fi
 607   AC_SUBST(HAVE_X)
 608   CFLAGS="$ac_cflags_save"
 609   CPPFLAGS="$ac_cppflags_save"
 610 ])
 611
 612 dnl FIXME: this should be rolled into the test above, it's just an additional
 613 dnl feature of the ximagesrc plug-in
 614 dnl This is the same as in gst-plugins-base
 615 dnl check for X Shm
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 617 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 618   if test x$HAVE_X = xyes; then
 619     AC_CHECK_LIB(Xext, XShmAttach,
 620                  HAVE_XSHM="yes", HAVE_XSHM="no",
 621                  $X_LIBS)
 622     if test "x$HAVE_XSHM" = "xyes"; then
 623       XSHM_LIBS="-lXext"
 624     else
 625       dnl On AIX, it is in XextSam instead, but we still need -lXext
 626       AC_CHECK_LIB(XextSam, XShmAttach,
 627                    HAVE_XSHM="yes", HAVE_XSHM="no",
 628                    $X_LIBS)
 629       if test "x$HAVE_XSHM" = "xyes"; then
 630         XSHM_LIBS="-lXext -lXextSam"
 631       fi
 632     fi
 633   fi
 634 ], ,[
 635   AC_SUBST(HAVE_XSHM)
 636   AC_SUBST(XSHM_LIBS)
 637 ])
 638
 639 dnl for V4L2, we also need to know if we have XVIDEO
 640 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 641 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 642                   [], [
 643   AG_GST_CHECK_XV
 644 ])
 645
 646 dnl *** ext plug-ins ***
 647 dnl keep this list sorted alphabetically !
 648
 649 if test "x$BUILD_EXTERNAL" = "xyes"; then
 650
 651 echo
 652 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 653 echo
 654
 655 dnl *** aalib ***
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 657 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 658   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 659   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 660 ])
 661
 662 dnl *** annodex ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 664 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 665   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 666 ])
 667
 668 dnl *** cairo ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 670 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 671   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 672 ])
 673
 674 dnl **** ESound ****
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 676 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 677   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 678   if test $HAVE_ESD = no
 679   then
 680     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 681     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 682   fi
 683 ])
 684
 685 dnl *** FLAC ***
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 687 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 688   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 689 ])
 690
 691 dnl *** GConf ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 693 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 694   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 695 ])
 696
 697 dnl *** GDK pixbuf ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 699 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 700   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 701 ])
 702
 703 dnl *** HAL ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 705 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 706   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 707 ])
 708
 709 dnl *** jpeg ***
 710 dnl FIXME: we could use header checks here as well IMO
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 712 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 713   AC_ARG_WITH(jpeg-mmx,
 714     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 715   OLD_LIBS="$LIBS"
 716   if test x$with_jpeg_mmx != x; then
 717     LIBS="$LIBS -L$with_jpeg_mmx"
 718   fi
 719   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 720   JPEG_LIBS="$LIBS -ljpeg-mmx"
 721   LIBS="$OLD_LIBS"
 722   if test x$HAVE_JPEG != xyes; then
 723     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 724     JPEG_LIBS="-ljpeg"
 725   fi
 726   AC_SUBST(JPEG_LIBS)
 727 ])
 728
 729 dnl *** libcaca ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 731 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 732   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 733   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 734   if test "x$HAVE_LIBCACA" != "xyes"; then
 735     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 736     dnl see if it compilation works too, might not if we are cross-compiling
 737     if test "x$HAVE_LIBCACA" = "xyes"; then
 738       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 739                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 740     fi
 741   fi
 742 ])
 743
 744 dnl *** libdv ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 746 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 747   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 748 ])
 749
 750 dnl *** libpng ***
 751 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 752 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 753   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 754 ])
 755
 756 dnl *** pulseaudio ***
 757 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 758 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 759   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 760   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 761   if test x$HAVE_PULSE_0_9_11 = xyes; then
 762     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 763   fi
 764   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 765   if test x$HAVE_PULSE_0_9_12 = xyes; then
 766     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 767   fi
 768   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 769   if test x$HAVE_PULSE_0_9_13 = xyes; then
 770     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 771   fi
 772   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 773   if test x$HAVE_PULSE_0_9_15 = xyes; then
 774     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 775   fi
 776   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 777   if test x$HAVE_PULSE_0_9_20 = xyes; then
 778     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 779   fi
 780 ])
 781
 782 dnl *** dv1394 ***
 783 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 784 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 785   dnl first test for libraw1394 >= 1.2.1
 786   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 787   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 788   dnl now see how far we got
 789   if test x$HAVE_RAW1394 = xyes && \
 790      test x$HAVE_LIBIEC61883 = xyes; then
 791        AG_GST_CHECK_LIBHEADER(AVC1394,
 792         avc1394, avc1394_send_command, $RAW1394_LIBS,
 793         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 794        AG_GST_CHECK_LIBHEADER(ROM1394,
 795         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 796         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 797        if test x$HAVE_AVC1394 = xyes && \
 798           test x$HAVE_AVC1394 = xyes && \
 799           test x$HAVE_ROM1394 = xyes; then
 800           HAVE_DV1394=yes
 801           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 802           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 803           AC_SUBST(DV1394_CFLAGS)
 804           AC_SUBST(DV1394_LIBS)
 805         fi
 806   else
 807        if test x$HAVE_RAW1394 = xno; then
 808           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 809           AG_GST_CHECK_LIBHEADER(AVC1394,
 810            avc1394, avc1394_send_command, $RAW1394_LIBS,
 811            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 812           AG_GST_CHECK_LIBHEADER(ROM1394,
 813            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 814            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 815           if test x$HAVE_RAW1394 = xyes && \
 816              test x$HAVE_AVC1394 = xyes && \
 817              test x$HAVE_ROM1394 = xyes; then
 818              HAVE_DV1394=yes
 819              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 820              DV1394_CFLAGS="$RAW1394_CFLAGS"
 821              if test x$HAVE_LIBIEC61883 = xyes; then
 822                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 823                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 824              fi
 825              AC_SUBST(DV1394_CFLAGS)
 826              AC_SUBST(DV1394_LIBS)
 827            fi
 828          fi
 829   fi
 830 ])
 831
 832 dnl *** shout2 ***
 833 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 834 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 835   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 836   if test $HAVE_SHOUT2 = no
 837   then
 838     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 839     AC_SUBST(SHOUT2_CFLAGS)
 840     AC_SUBST(SHOUT2_LIBS)
 841   fi
 842 ])
 843
 844 dnl *** soup ***
 845 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 846 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 847   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 848     HAVE_SOUP="yes"
 849     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 850   ],[
 851     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 852       HAVE_SOUP="no"
 853       AC_MSG_RESULT(no)
 854     ])
 855   ])
 856   AC_SUBST(SOUP_CFLAGS)
 857   AC_SUBST(SOUP_LIBS)
 858 ])
 859
 860 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 861 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 862 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 863 dnl   speex_jitter.h is 1.1.x only
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 865 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 866   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 867   if test $HAVE_SPEEX = no
 868   then
 869     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 870       AC_CHECK_HEADER(speex/speex_jitter.h, [
 871         dnl speex 1.1.x :
 872         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 873           dnl speex 1.1.5 or + :
 874           HAVE_SPEEX="yes"
 875           SPEEX_LIBS="-lspeex"
 876           AC_SUBST(SPEEX_CFLAGS)
 877           AC_SUBST(SPEEX_LIBS)
 878         ],[
 879           HAVE_SPEEX="no"
 880         ])
 881       ],[
 882         dnl speex 1.0.x :
 883           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 884             dnl speex 1.0.4
 885             HAVE_SPEEX="yes"
 886             SPEEX_LIBS="-lspeex"
 887             AC_SUBST(SPEEX_CFLAGS)
 888             AC_SUBST(SPEEX_LIBS)
 889
 890             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 891               [defined if speex 1.0.x API detected])
 892         ],[
 893             HAVE_SPEEX="no"
 894             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 895         ], [
 896 #include <speex/speex.h>
 897         ])
 898       ])
 899     ])
 900   fi
 901 ])
 902
 903 dnl *** taglib ***
 904 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 905 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 906   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 907   if test "x$HAVE_CXX" != "xyes"; then
 908     USE_TAGLIB=false
 909     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 910   else
 911     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 912     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 913         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 914       ], [
 915         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 916     ])
 917     AC_SUBST(TAGLIB_CXXFLAGS)
 918   fi
 919 ])
 920
 921 dnl *** wavpack ***
 922 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 923 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 924   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 925     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 926       HAVE_WAVPACK=yes
 927       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 928     ],[
 929       HAVE_WAVPACK=no
 930       AC_MSG_RESULT(no)
 931     ])
 932   ])
 933   AC_SUBST(WAVPACK_CFLAGS)
 934   AC_SUBST(WAVPACK_LIBS)
 935 ])
 936
 937 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 938 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 939 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 940   AG_GST_CHECK_LIBHEADER(ZLIB,
 941     z, uncompress,, zlib.h, [
 942     HAVE_ZLIB="yes"
 943     ZLIB_LIBS="-lz"
 944     AC_SUBST(ZLIB_LIBS)
 945   ])
 946 ])
 947
 948 dnl *** matroska prefers to have bz2 ***
 949 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 950 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 951   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 952   AC_SUBST(BZ2_LIBS)
 953 ])
 954
 955 else
 956
 957 dnl not building plugins with external dependencies,
 958 dnl but we still need to set the conditionals
 959 AM_CONDITIONAL(USE_AALIB, false)
 960 AM_CONDITIONAL(USE_ANNODEX, false)
 961 AM_CONDITIONAL(USE_BZ2, false)
 962 AM_CONDITIONAL(USE_CAIRO, false)
 963 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 964 AM_CONDITIONAL(USE_DV1394, false)
 965 AM_CONDITIONAL(USE_ESD, false)
 966 AM_CONDITIONAL(USE_FLAC, false)
 967 AM_CONDITIONAL(USE_GCONF, false)
 968 AM_CONDITIONAL(USE_GCONFTOOL, false)
 969 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 970 AM_CONDITIONAL(USE_GST_V4L2, false)
 971 AM_CONDITIONAL(USE_HAL, false)
 972 AM_CONDITIONAL(USE_JPEG, false)
 973 AM_CONDITIONAL(USE_LIBCACA, false)
 974 AM_CONDITIONAL(USE_LIBDV, false)
 975 AM_CONDITIONAL(USE_LIBPNG, false)
 976 AM_CONDITIONAL(USE_OSS, false)
 977 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 978 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 979 AM_CONDITIONAL(USE_PULSE, false)
 980 AM_CONDITIONAL(USE_SHOUT2, false)
 981 AM_CONDITIONAL(USE_SOUP, false)
 982 AM_CONDITIONAL(USE_SPEEX, false)
 983 AM_CONDITIONAL(USE_SUNAUDIO, false)
 984 AM_CONDITIONAL(USE_TAGLIB, false)
 985 AM_CONDITIONAL(USE_WAVPACK, false)
 986 AM_CONDITIONAL(USE_X, false)
 987 AM_CONDITIONAL(USE_XSHM, false)
 988 AM_CONDITIONAL(USE_XVIDEO, false)
 989 AM_CONDITIONAL(USE_ZLIB, false)
 990
 991 fi dnl of EXT plugins
 992
 993 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 994
 995 dnl Overview:
 996 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 997 dnl GST_*:              flags shared by all built objects
 998 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 999 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1000 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1001 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1002
1003 dnl GST_OPTION_CFLAGS
1004 if test "x$USE_DEBUG" = xyes; then
1005    PROFILE_CFLAGS="-g"
1006 fi
1007 AC_SUBST(PROFILE_CFLAGS)
1008
1009 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1010   dnl Define _only_ for git (not pre-releases or releases)
1011   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1012 else
1013   DEPRECATED_CFLAGS=""
1014 fi
1015 AC_SUBST(DEPRECATED_CFLAGS)
1016
1017 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1018 dnl at make time with e.g. make ERROR_CFLAGS=""
1019 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1020 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1021 AC_SUBST(GST_OPTION_CFLAGS)
1022 AC_SUBST(GST_OPTION_CXXFLAGS)
1023
1024 dnl our libraries need to be versioned correctly
1025 AC_SUBST(GST_LT_LDFLAGS)
1026
1027 dnl FIXME: do we want to rename to GST_ALL_* ?
1028 dnl prefer internal headers to already installed ones
1029 dnl also add builddir include for enumtypes and marshal
1030 dnl add ERROR_CFLAGS, but overridable
1031 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1032 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_FLAGS \$(GST_OPTION_CXXFLAGS)"
1033 AC_SUBST(GST_CFLAGS)
1034 AC_SUBST(GST_CXXFLAGS)
1035 AC_SUBST(GST_LIBS)
1036
1037 dnl LDFLAGS really should only contain flags, not libs - they get added before
1038 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1039 GST_ALL_LDFLAGS="-no-undefined"
1040 AC_SUBST(GST_ALL_LDFLAGS)
1041
1042 dnl this really should only contain flags, not libs - they get added before
1043 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1044 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1045 AC_SUBST(GST_PLUGIN_LDFLAGS)
1046
1047 SHAVE_INIT([common],[enable])
1048 dnl *** output files ***
1049
1050 dnl keep this alphabetic per directory, please
1051 AC_CONFIG_FILES(
1052 Makefile
1053 common/shave
1054 common/shave-libtool
1055 gst/Makefile
1056 gst/alpha/Makefile
1057 gst/apetag/Makefile
1058 gst/audiofx/Makefile
1059 gst/auparse/Makefile
1060 gst/autodetect/Makefile
1061 gst/avi/Makefile
1062 gst/cutter/Makefile
1063 gst/deinterlace/Makefile
1064 gst/debugutils/Makefile
1065 gst/effectv/Makefile
1066 gst/equalizer/Makefile
1067 gst/flv/Makefile
1068 gst/id3demux/Makefile
1069 gst/icydemux/Makefile
1070 gst/interleave/Makefile
1071 gst/goom/Makefile
1072 gst/goom2k1/Makefile
1073 gst/law/Makefile
1074 gst/level/Makefile
1075 gst/matroska/Makefile
1076 gst/monoscope/Makefile
1077 gst/multifile/Makefile
1078 gst/multipart/Makefile
1079 gst/qtdemux/Makefile
1080 gst/replaygain/Makefile
1081 gst/rtp/Makefile
1082 gst/rtpmanager/Makefile
1083 gst/rtsp/Makefile
1084 gst/shapewipe/Makefile
1085 gst/smpte/Makefile
1086 gst/spectrum/Makefile
1087 gst/udp/Makefile
1088 gst/videobox/Makefile
1089 gst/videocrop/Makefile
1090 gst/videofilter/Makefile
1091 gst/videomixer/Makefile
1092 gst/wavenc/Makefile
1093 gst/wavparse/Makefile
1094 gst/flx/Makefile
1095 gst/y4m/Makefile
1096 ext/jpeg/Makefile
1097 ext/Makefile
1098 ext/aalib/Makefile
1099 ext/annodex/Makefile
1100 ext/cairo/Makefile
1101 ext/dv/Makefile
1102 ext/esd/Makefile
1103 ext/flac/Makefile
1104 ext/gconf/Makefile
1105 ext/gdk_pixbuf/Makefile
1106 ext/hal/Makefile
1107 ext/libcaca/Makefile
1108 ext/libpng/Makefile
1109 ext/pulse/Makefile
1110 ext/raw1394/Makefile
1111 ext/shout2/Makefile
1112 ext/soup/Makefile
1113 ext/speex/Makefile
1114 ext/taglib/Makefile
1115 ext/wavpack/Makefile
1116 sys/Makefile
1117 sys/directsound/Makefile
1118 sys/oss/Makefile
1119 sys/sunaudio/Makefile
1120 sys/osxaudio/Makefile
1121 sys/osxvideo/Makefile
1122 sys/v4l2/Makefile
1123 sys/waveform/Makefile
1124 sys/ximage/Makefile
1125 po/Makefile.in
1126 tests/Makefile
1127 tests/check/Makefile
1128 tests/examples/Makefile
1129 tests/examples/audiofx/Makefile
1130 tests/examples/equalizer/Makefile
1131 tests/examples/level/Makefile
1132 tests/examples/rtp/Makefile
1133 tests/examples/shapewipe/Makefile
1134 tests/examples/spectrum/Makefile
1135 tests/examples/v4l2/Makefile
1136 tests/files/Makefile
1137 tests/icles/Makefile
1138 gconf/Makefile
1139 gconf/gstreamer.schemas
1140 common/Makefile
1141 common/m4/Makefile
1142 m4/Makefile
1143 docs/Makefile
1144 docs/plugins/Makefile
1145 docs/version.entities
1146 pkgconfig/Makefile
1147 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1148 gst-plugins-good.spec
1149 )
1150
1151 dnl Create the config.h file for Visual Studio builds
1152 dnl Beware of spaces and /'s in some of the shell variable contents.
1153 sed \
1154     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1155     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1156     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1157     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1158     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1159     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1160     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1161     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1162     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1163     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1164     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1165     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1166     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1167     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1168     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1169     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1170     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1171     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1172     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1173     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1174     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1175     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1176     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1177     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1178     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1179     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1180     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1181     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1182     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1183     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1184     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1185     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1186     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1187     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1188     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1189     config.h.in >win32/common/config.h-new
1190
1191 AC_OUTPUT
1192
1193 AG_GST_OUTPUT_PLUGINS