configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gstreamer, GST_VERSION, 0, 9, 6, 1,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/gst.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  31 dnl we override it here for release candidates for a new series
  32 # GST_MAJORMINOR=0.9
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 8, 0, 0)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** autotools stuff ****
  46
  47 dnl allow for different autotools
  48 AS_AUTOTOOLS_ALTERNATE
  49
  50 dnl Add parameters for aclocal
  51 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  52
  53 dnl set up gettext
  54 dnl the version check needs to stay here because autopoint greps for it
  55 AM_GNU_GETTEXT_VERSION([0.11.5])
  56 AM_GNU_GETTEXT([external])
  57 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  58
  59 dnl *** check for arguments to configure ***
  60
  61 dnl subsystems - can influence other decisions so needs to be high up
  62 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  63 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  64 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  65 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  66 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  67 dnl define a substitution to use in docs/gst/gstreamer.types
  68 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  69 then
  70   GST_LOADSAVE_DOC_TYPES="%"
  71 else
  72   GST_LOADSAVE_DOC_TYPES=
  73 fi
  74 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  75 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  76 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  77 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  78 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  79 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  80 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  81 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  82 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  85 then
  86   GST_REGISTRY_DOC_TYPES="%"
  87 else
  88   GST_REGISTRY_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_REGISTRY_DOC_TYPES)
  91 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  92 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  93 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  94 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  95 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
  96 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
  97 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  98 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  99 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 100 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 101
 102 GST_ARG_DEBUG
 103 GST_ARG_PROFILING
 104 GST_ARG_VALGRIND
 105 GST_ARG_GCOV
 106
 107 GST_ARG_EXAMPLES
 108
 109 GST_ARG_WITH_PKG_CONFIG_PATH
 110 GST_ARG_WITH_PACKAGE_NAME([GStreamer])
 111 GST_ARG_WITH_PACKAGE_ORIGIN
 112
 113 dnl use a cache dir for storing element registry info.
 114 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 115
 116 AC_ARG_WITH(cachedir,
 117   AC_HELP_STRING([--with-cachedir],
 118     [specify path to use for plugin and command completion registries]),
 119   [
 120     case "${withval}" in
 121       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 122       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 123       *)   GST_CACHE_DIR="${withval}" ;;
 124     esac
 125   ],
 126   [:]) dnl Default value
 127
 128 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 129 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 130 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 131
 132 dnl building of tests
 133 AC_ARG_ENABLE(tests,
 134   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 135   [
 136     case "${enableval}" in
 137       yes) BUILD_TESTS=yes ;;
 138       no)  BUILD_TESTS=no ;;
 139       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 140     esac
 141   ],
 142 [BUILD_TESTS=yes]) dnl Default value
 143 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 144
 145 dnl tests known to fail
 146 AC_ARG_ENABLE(failing-tests,
 147   AC_HELP_STRING([--disable-failing-tests],
 148     [disable building tests known to fail]),
 149   [
 150     case "${enableval}" in
 151       yes) BUILD_FAILING_TESTS=yes ;;
 152       no)  BUILD_FAILING_TESTS=no ;;
 153       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 154     esac
 155   ],
 156   [BUILD_FAILING_TESTS=no]) dnl Default value
 157 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 158 if test x$BUILD_FAILING_TESTS = xyes; then
 159   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 160 else
 161   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 162 fi
 163
 164 dnl poison destroyed objects
 165 AC_ARG_ENABLE(poisoning,
 166   AC_HELP_STRING([--enable-poisoning],
 167     [enable poisoning of deallocated objects]),
 168   [
 169     case "${enableval}" in
 170       yes) USE_POISONING=yes ;;
 171       no)  USE_POISONING=no ;;
 172       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 173     esac
 174   ],
 175   [USE_POISONING=no]) dnl Default value
 176 if test "x$USE_POISONING" = xyes; then
 177   AC_DEFINE(USE_POISONING, 1,
 178     [Define if we should poison deallocated memory])
 179 fi
 180
 181 dnl *** checks for platform ***
 182
 183 dnl * hardware/architecture *
 184
 185 dnl common/m4/gst-arch.m4
 186 dnl check CPU type
 187 GST_ARCH
 188
 189 dnl common/m4/gst-arch.m4
 190 dnl check for unaligned access
 191 GST_UNALIGNED_ACCESS
 192 dnl create a configure variable for gst/gstconfig.h
 193 if test x${as_cv_unaligned_access} = xyes ; then
 194   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 195 else
 196   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 197 fi
 198 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 199
 200 dnl * software *
 201
 202 dnl check for large file support
 203 dnl affected plugins must include config.h
 204 AC_SYS_LARGEFILE
 205
 206 dnl HAVE_WIN32 currently means "disable POSIXisms".
 207 case "$host" in
 208   *-*-mingw*)
 209     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 210     ;;
 211   *)
 212     ;;
 213 esac
 214
 215 dnl *** checks for programs ***
 216
 217 dnl find a compiler
 218 AC_PROG_CC
 219
 220 dnl find an assembler
 221 AM_PROG_AS
 222
 223 dnl we use awk in the bison version check
 224 AC_PROG_AWK
 225
 226 dnl we require bison for building the parser
 227 dnl FIXME: check if AC_PROG_YACC is suitable here
 228 dnl FIXME: make precious
 229 AC_PATH_PROG(BISON_PATH, bison, no)
 230 if test x$BISON_PATH = xno; then
 231   AC_MSG_ERROR(Could not find bison)
 232 fi
 233
 234 dnl check bison version
 235 AC_MSG_CHECKING([bison version])
 236
 237 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 238 then
 239   AC_MSG_RESULT([ok])
 240 else
 241   AC_MSG_RESULT([too old.])
 242   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 243 fi
 244
 245 dnl we require flex for building the parser
 246 dnl FIXME: check if AC_PROG_LEX is suitable here
 247 AC_PATH_PROG(FLEX_PATH, flex, no)
 248 if test x$FLEX_PATH = xno; then
 249   AC_MSG_ERROR(Could not find flex)
 250 fi
 251
 252 dnl Perl is used in building documentation
 253 AC_PATH_PROG(PERL_PATH, perl, no)
 254 if test x$PERL_PATH = xno; then
 255   AC_MSG_ERROR(Could not find perl)
 256 fi
 257
 258 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 259 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 260
 261 dnl check for documentation tools
 262 GST_DOCBOOK_CHECK
 263 GTK_DOC_CHECK([1.3])
 264
 265 dnl *** checks for libraries ***
 266
 267 dnl For interactive UNIX (a Sun thing)
 268 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 269 AC_ISC_POSIX
 270
 271 dnl *** checks for header files ***
 272
 273 dnl check if we have ANSI C header files
 274 AC_HEADER_STDC
 275
 276 dnl Check for ucontext.h
 277 AC_CHECK_HEADERS([ucontext.h])
 278 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 279 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 280 AC_CHECK_HEADERS([process.h])
 281
 282 dnl *** checks for types/defines ***
 283
 284 dnl *** checks for structures ***
 285
 286 dnl *** checks for compiler characteristics ***
 287
 288 dnl make sure we can use "inline" from C code
 289 AC_C_INLINE
 290
 291 OPT_CFLAGS=
 292 dnl Check for some compiler flags that optimize our code.
 293 if test "x$GCC" = xyes; then
 294   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 295 fi
 296
 297 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 298 dnl flag
 299 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 300 dnl symbolic register names in inline asm
 301 if test x$HAVE_CPU_PPC = xyes ; then
 302   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 303     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 304 fi
 305
 306 dnl *** checks for library functions ***
 307
 308 AC_CHECK_FUNCS([sigaction])
 309
 310 dnl check for fseeko()
 311 AC_FUNC_FSEEKO
 312 dnl check for ftello()
 313 AC_CHECK_FUNCS([ftello])
 314
 315 AC_CHECK_FUNCS([fgetpos])
 316 AC_CHECK_FUNCS([fsetpos])
 317
 318 dnl check for mmap()
 319 AC_FUNC_MMAP
 320 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 321
 322 dnl common/m4/gst-mcsc.m4
 323 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 324 AC_CHECK_MCSC
 325 if test "$ac_cv_check_mcsc" = "yes"; then
 326   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, 1,
 327                      [defined if we have makecontext ()])
 328 fi
 329
 330 dnl Check for a way to display the function name in debug output
 331 GST_CHECK_FUNCTION
 332
 333 dnl test for register_printf_function
 334 AC_CHECK_FUNC(register_printf_function,
 335   [
 336     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 337     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 338       [Defined if we have register_printf_function ()])
 339   ],
 340   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 341 )
 342 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 343
 344 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 345 save_cflags="$CFLAGS"
 346 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 347 AC_CHECK_LIB(dl, dladdr,
 348    AC_DEFINE(HAVE_DLADDR, 1,
 349              [Defined if we have dladdr ()]))
 350 CFLAGS="$save_cflags"
 351
 352 dnl *** checks for dependancy libraries ***
 353
 354 dnl GLib
 355
 356 GST_GLIB_CHECK([2.6])
 357
 358 dnl GLib 2.8 has some bug fixes that we like, so make sure our code knows
 359 AC_MSG_CHECKING([glib version >= 2.8])
 360 if pkg-config --atleast-version=2.8 glib-2.0; then
 361   AC_MSG_RESULT(yes)
 362   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 363 else
 364   AC_MSG_RESULT(no)
 365   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 366 fi
 367 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 368
 369 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 370 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 371
 372 dnl libxml 2, which is/should be optional (FIXME)
 373 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 374    test "x$GST_DISABLE_REGISTRY" = "xyes"
 375 then
 376   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 377 else
 378   dnl check for libxml2 with minimum req version
 379   GST_LIBXML2_CHECK(2.4.9)
 380 fi
 381
 382 dnl check for "check", unit testing library/header
 383 AM_PATH_CHECK(0.9.2,
 384     [
 385         HAVE_CHECK=yes
 386         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 387         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 388     ],
 389     HAVE_CHECK=no)
 390 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 391
 392 dnl *** set variables based on configure arguments
 393
 394 dnl set license and copyright notice
 395 GST_LICENSE="LGPL"
 396 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 397 AC_SUBST(GST_LICENSE)
 398
 399 dnl define LIBDIR so we can inform people where we live
 400 AS_AC_EXPAND(LIBDIR, $libdir)
 401 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 402
 403 dnl set location of plugin directory
 404 GST_SET_PLUGINDIR
 405
 406 dnl FIXME: add LIBXML_PKG here
 407 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 408 AC_SUBST(GST_PKG_DEPS)
 409
 410 dnl define an ERROR_CFLAGS Makefile variable
 411 GST_SET_ERROR_CFLAGS($GST_CVS)
 412
 413 dnl define correct level for debugging messages
 414 GST_SET_LEVEL_DEFAULT($GST_CVS)
 415
 416 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 417
 418 dnl Overview:
 419 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 420 dnl GST_ALL_*:          vars shared by all built objects
 421 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 422 dnl GST_OBJ_*:          additional vars to link to the core library
 423 dnl                     include GST_ALL_*
 424 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 425 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 426
 427 dnl GST_OPTION_CFLAGS
 428 if test "x$USE_DEBUG" = xyes; then
 429    PROFILE_CFLAGS="-g"
 430 fi
 431 AC_SUBST(PROFILE_CFLAGS)
 432
 433 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 434 AC_SUBST(DEPRECATED_CFLAGS)
 435
 436 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 437 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 438 AC_SUBST(GST_OPTION_CFLAGS)
 439
 440 dnl GST_ALL_*
 441 dnl vars common to for all internal objects (core libs, elements, applications)
 442 dnl CFLAGS:
 443 dnl - XML needs to be added because xmlPtr is used in core
 444 dnl - src and build dirs need to be added because every piece that gets built
 445 dnl   will need the GStreamer source and generated headers
 446 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 447 dnl       from LibXML except for in the core library
 448 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 449 dnl FIXME: check if LTLIBINTL is needed everywhere
 450 dnl I presume it is given that it contains the symbols that _() stuff maps to
 451 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL"
 452 dnl LDFLAGS really should only contain flags, not libs - they get added before
 453 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 454 GST_ALL_LDFLAGS="-no-undefined"
 455
 456 AC_SUBST(GST_ALL_CFLAGS)
 457 AC_SUBST(GST_ALL_LIBS)
 458 AC_SUBST(GST_ALL_LDFLAGS)
 459
 460 dnl GST_LIB_LDFLAGS
 461 dnl linker flags shared by all libraries
 462 dnl LDFLAGS modifier defining exported symbols from built libraries
 463 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 464 AC_SUBST(GST_LIB_LDFLAGS)
 465
 466 dnl GST_OBJ_*
 467 dnl default vars for all internal objects built on libgstreamer
 468 dnl includes GST_ALL_*
 469 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 470 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 471 AC_SUBST(GST_OBJ_CFLAGS)
 472 AC_SUBST(GST_OBJ_LIBS)
 473
 474 dnl GST_PLUGIN_LDFLAGS
 475 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 476 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 477 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 478
 479 dnl ##################################################
 480 dnl # deps for examples from manual                  #
 481 dnl ##################################################
 482
 483 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 484                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 485 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 486
 487 AC_CONFIG_FILES(
 488 Makefile
 489 gst/Makefile
 490 gst/gstconfig.h
 491 gst/gstversion.h
 492 gst/parse/Makefile
 493 libs/Makefile
 494 libs/gst/Makefile
 495 libs/gst/base/Makefile
 496 libs/gst/check/Makefile
 497 libs/gst/controller/Makefile
 498 libs/gst/dataprotocol/Makefile
 499 libs/gst/net/Makefile
 500 plugins/Makefile
 501 plugins/indexers/Makefile
 502 plugins/elements/Makefile
 503 po/Makefile.in
 504 tests/Makefile
 505 tests/benchmarks/Makefile
 506 tests/check/Makefile
 507 tests/misc/Makefile
 508 tools/Makefile
 509 common/Makefile
 510 common/m4/Makefile
 511 docs/Makefile
 512 docs/faq/Makefile
 513 docs/gst/Makefile
 514 docs/gst/gstreamer.types
 515 docs/libs/Makefile
 516 docs/manual/Makefile
 517 docs/pwg/Makefile
 518 docs/xsl/Makefile
 519 docs/version.entities
 520 win32/common/config.h
 521 pkgconfig/Makefile
 522 stamp.h
 523 pkgconfig/gstreamer.pc
 524 pkgconfig/gstreamer-uninstalled.pc
 525 pkgconfig/gstreamer-base.pc
 526 pkgconfig/gstreamer-base-uninstalled.pc
 527 pkgconfig/gstreamer-check.pc
 528 pkgconfig/gstreamer-check-uninstalled.pc
 529 pkgconfig/gstreamer-controller.pc
 530 pkgconfig/gstreamer-controller-uninstalled.pc
 531 pkgconfig/gstreamer-dataprotocol.pc
 532 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 533 pkgconfig/gstreamer-net.pc
 534 pkgconfig/gstreamer-net-uninstalled.pc
 535 gstreamer.spec
 536 )
 537 AC_OUTPUT