configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT([GStreamer Bad Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-bad])
   7
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([docs/plugins/gst-plugins-bad-plugins-docs.sgml])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use GST_API_VERSION in the filename
  37 dnl to allow side-by-side installation of different API versions
  38 GST_API_VERSION=1.0
  39 AC_SUBST(GST_API_VERSION)
  40 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  41   [GStreamer API Version])
  42
  43 AG_GST_LIBTOOL_PREPARE
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 2, 0, 2)
  52
  53 dnl *** required versions of GStreamer stuff ***
  54 GST_REQ=1.1.0
  55 GSTPB_REQ=1.1.0
  56
  57 dnl *** autotools stuff ****
  58
  59 dnl allow for different autotools
  60 AS_AUTOTOOLS_ALTERNATE
  61
  62 dnl Add parameters for aclocal
  63 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  64
  65 dnl set up gettext
  66 dnl the version check needs to stay here because autopoint greps for it
  67 AM_GNU_GETTEXT_VERSION([0.17])
  68 AM_GNU_GETTEXT([external])
  69 AG_GST_GETTEXT([gst-plugins-bad-$GST_API_VERSION])
  70
  71 dnl *** check for arguments to configure ***
  72
  73 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 AG_GST_ARG_WITH_PLUGINS
  87
  88 AG_GST_ARG_ENABLE_EXTERNAL
  89
  90 AG_GST_ARG_ENABLE_EXPERIMENTAL
  91
  92 dnl *** checks for platform ***
  93 AG_GST_PLATFORM
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 AC_PROG_OBJC
 116
 117 dnl check if the compiler supports '-c' and '-o' options
 118 AM_PROG_CC_C_O
 119
 120 dnl check if the compiler supports do while(0) macros
 121 AG_GST_CHECK_DOWHILE_MACROS
 122
 123 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 124 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 125
 126 dnl check for documentation tools
 127 GTK_DOC_CHECK([1.12])
 128 AG_GST_PLUGIN_DOCS([1.12])
 129
 130 dnl *** checks for libraries ***
 131
 132 dnl check for libm, for sin() etc.
 133 LT_LIB_M
 134 AC_SUBST(LIBM)
 135
 136 AC_FUNC_MMAP
 137
 138 dnl *** checks for header files ***
 139
 140 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 141 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 142
 143 if test "x$HAVE_UNISTD_H" != "xyes"; then
 144   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 145 fi
 146
 147 AC_CHECK_HEADERS([sys/time.h])
 148
 149 dnl used by ext/dts
 150 AX_CREATE_STDINT_H
 151
 152 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 153 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 154
 155 if test "x$HAVE_PTHREAD_H" != "xyes"; then
 156   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/dccp//`
 157 fi
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration
 162 dnl used in gst/dccp
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl *** checks for library functions ***
 170 AC_CHECK_FUNCS([gmtime_r])
 171
 172 dnl *** checks for headers ***
 173 AC_CHECK_HEADERS([sys/utsname.h])
 174
 175 dnl *** checks for dependency libraries ***
 176
 177 dnl *** checks for socket and nsl libraries ***
 178 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 179 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 180
 181 dnl GLib is required
 182 GLIB_REQ=2.32.0
 183 AG_GST_GLIB_CHECK([$GLIB_REQ])
 184
 185 dnl checks for gstreamer
 186 dnl uninstalled is selected preferentially -- see pkg-config(1)
 187 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 188 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 189 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 190 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 191 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 192
 193 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 194
 195 dnl check for uninstalled plugin directories for unit tests
 196 AG_GST_CHECK_UNINSTALLED_SETUP([
 197   AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [0.11.0])
 198   AG_GST_CHECK_GST_PLUGINS_UGLY($GST_API_VERSION, [0.11.0])
 199   AG_GST_CHECK_GST_PLUGINS_FFMPEG($GST_API_VERSION, [0.11.0])
 200 ])
 201
 202 dnl Check for documentation xrefs
 203 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 204 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 205 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 206 AC_SUBST(GLIB_PREFIX)
 207 AC_SUBST(GST_PREFIX)
 208 AC_SUBST(GSTPB_PREFIX)
 209
 210 dnl GTK is optional and used in examples
 211 HAVE_GTK=NO
 212 GTK2_REQ=2.14.0
 213 GTK3_REQ=2.91.3
 214 if test "x$BUILD_EXAMPLES" = "xyes"; then
 215   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 216   AC_ARG_WITH([gtk],
 217     AS_HELP_STRING([--with-gtk=3.0|2.0],[which gtk+ version to compile against (default: 2.0)]),
 218     [case "$with_gtk" in
 219         2.0) GTK_REQ=$GTK2_REQ ;;
 220         3.0) GTK_REQ=$GTK3_REQ ;;
 221         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 222     esac],
 223     [with_gtk=2.0
 224      GTK_REQ=$GTK2_REQ])
 225   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 226   PKG_CHECK_MODULES(GTK, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 227   AC_SUBST(GTK_LIBS)
 228   AC_SUBST(GTK_CFLAGS)
 229 fi
 230 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 231
 232
 233
 234 dnl Needed for GtkBuilder to autoconnect signals
 235 PKG_CHECK_MODULES(GMODULE_EXPORT, gmodule-export-2.0, HAVE_GMODULE_EXPORT=yes, HAVE_GMODULE_EXPORT=no)
 236
 237 dnl Needed by plugins that use g_module_*() API
 238 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 239
 240 dnl x11 is optional for librfb and eglglessink
 241 HAVE_X11=NO
 242 PKG_CHECK_MODULES(X11, x11, HAVE_X11=yes, HAVE_X11=no)
 243 AC_SUBST(X11_LIBS)
 244 AC_SUBST(X11_CFLAGS)
 245 AC_SUBST(HAVE_X11)
 246 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "xyes")
 247 if test "x$HAVE_X11" = "xyes"; then
 248   AC_DEFINE(HAVE_X11, 1, [Define if you have X11 library])
 249 fi
 250
 251 dnl exif (used on jifmux tests) ****
 252 PKG_CHECK_MODULES(EXIF, libexif >= 0.6.16, HAVE_EXIF="yes", HAVE_EXIF="no")
 253 AC_SUBST(EXIF_LIBS)
 254 AC_SUBST(EXIF_CFLAGS)
 255 AM_CONDITIONAL(USE_EXIF, test "x$HAVE_EXIF" = "xyes")
 256
 257 dnl Orc
 258 ORC_CHECK([0.4.16])
 259
 260 dnl set license and copyright notice
 261 GST_LICENSE="LGPL"
 262 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 263 AC_SUBST(GST_LICENSE)
 264
 265 dnl define LIBDIR so we can inform people where we live
 266 AS_AC_EXPAND(LIBDIR, $libdir)
 267 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 268
 269 dnl set location of plugin directory
 270 AG_GST_SET_PLUGINDIR
 271
 272 dnl set release date/time
 273 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 274   ["${srcdir}/gst-plugins-bad.doap"],
 275   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 276
 277 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 278 dnl make sure it doesn't complain about unused variables if debugging is disabled
 279 NO_WARNINGS=""
 280 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 281
 282 dnl define an ERROR_CFLAGS Makefile variable
 283 dnl -Waggregate-return - libexif returns aggregates
 284 dnl -Wundef - Windows headers check _MSC_VER unconditionally
 285 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 286     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 287     -Wwrite-strings -Wformat-security -Wold-style-definition
 288     -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 289     -Wnested-externs $NO_WARNINGS])
 290
 291 dnl define an ERROR_CXXFLAGS Makefile variable
 292 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 293     -Wmissing-declarations -Wredundant-decls
 294     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 295     -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar $NO_WARNINGS])
 296
 297 dnl define an ERROR_OBJCFLAGS Makefile variable
 298 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 299     -Wmissing-declarations -Wredundant-decls
 300     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 301     -Winit-self -Wmissing-include-dirs -Wno-multichar $NO_WARNINGS])
 302
 303 dnl define correct level for debugging messages
 304 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 305
 306 dnl used in examples
 307 AG_GST_DEFAULT_ELEMENTS
 308
 309 dnl *** plug-ins to include ***
 310 dnl Non ported plugins (non-dependant, then dependant)
 311 dnl Make sure you have a space before and after all plugins
 312 GST_PLUGINS_NONPORTED=" aiff \
 313  cdxaparse \
 314  dccp faceoverlay \
 315  freeverb \
 316  hdvparse ivfparse jp2kdecimator \
 317  kate librfb \
 318  mve mythtv nsf nuvdemux \
 319  patchdetect real \
 320  sdi stereo tta videofilters \
 321  videomeasure videosignal vmnc \
 322  decklink fbdev linsys vcd \
 323  apexsink cdaudio cog dc1394 dirac directfb \
 324  gsettings ladspa \
 325  musepack musicbrainz nas neon ofa openal rsvg sdl sndfile timidity \
 326  directdraw direct3d9 acm wininet \
 327  wildmidi xvid lv2 teletextdec sndio uvch264 wasapi"
 328 AC_SUBST(GST_PLUGINS_NONPORTED)
 329
 330 dnl these are all the gst plug-ins, compilable without additional libs
 331 AG_GST_CHECK_PLUGIN(accurip)
 332 AG_GST_CHECK_PLUGIN(adpcmdec)
 333 AG_GST_CHECK_PLUGIN(adpcmenc)
 334 AG_GST_CHECK_PLUGIN(aiff)
 335 AG_GST_CHECK_PLUGIN(asfmux)
 336 AG_GST_CHECK_PLUGIN(audiovisualizers)
 337 AG_GST_CHECK_PLUGIN(autoconvert)
 338 AG_GST_CHECK_PLUGIN(bayer)
 339 AG_GST_CHECK_PLUGIN(camerabin2)
 340 AG_GST_CHECK_PLUGIN(cdxaparse)
 341 AG_GST_CHECK_PLUGIN(coloreffects)
 342 AG_GST_CHECK_PLUGIN(dataurisrc)
 343 AG_GST_CHECK_PLUGIN(dccp)
 344 AG_GST_CHECK_PLUGIN(debugutils)
 345 AG_GST_CHECK_PLUGIN(dtmf)
 346 AG_GST_CHECK_PLUGIN(dvbsuboverlay)
 347 AG_GST_CHECK_PLUGIN(dvdspu)
 348 AG_GST_CHECK_PLUGIN(faceoverlay)
 349 AG_GST_CHECK_PLUGIN(festival)
 350 AG_GST_CHECK_PLUGIN(fieldanalysis)
 351 AG_GST_CHECK_PLUGIN(freeverb)
 352 AG_GST_CHECK_PLUGIN(frei0r)
 353 AG_GST_CHECK_PLUGIN(gaudieffects)
 354 AG_GST_CHECK_PLUGIN(geometrictransform)
 355 AG_GST_CHECK_PLUGIN(gdp)
 356 AG_GST_CHECK_PLUGIN(hdvparse)
 357 AG_GST_CHECK_PLUGIN(hls)
 358 AG_GST_CHECK_PLUGIN(id3tag)
 359 AG_GST_CHECK_PLUGIN(inter)
 360 AG_GST_CHECK_PLUGIN(interlace)
 361 AG_GST_CHECK_PLUGIN(ivfparse)
 362 AG_GST_CHECK_PLUGIN(jp2kdecimator)
 363 AG_GST_CHECK_PLUGIN(jpegformat)
 364 AG_GST_CHECK_PLUGIN(librfb)
 365 AG_GST_CHECK_PLUGIN(liveadder)
 366 AG_GST_CHECK_PLUGIN(mpegdemux)
 367 AG_GST_CHECK_PLUGIN(mpegtsdemux)
 368 AG_GST_CHECK_PLUGIN(mpegtsmux)
 369 AG_GST_CHECK_PLUGIN(mpegpsmux)
 370 AG_GST_CHECK_PLUGIN(mve)
 371 AG_GST_CHECK_PLUGIN(mxf)
 372 AG_GST_CHECK_PLUGIN(nsf)
 373 AG_GST_CHECK_PLUGIN(nuvdemux)
 374 AG_GST_CHECK_PLUGIN(patchdetect)
 375 AG_GST_CHECK_PLUGIN(pcapparse)
 376 AG_GST_CHECK_PLUGIN(pnm)
 377 AG_GST_CHECK_PLUGIN(rawparse)
 378 AG_GST_CHECK_PLUGIN(real)
 379 AG_GST_CHECK_PLUGIN(removesilence)
 380 AG_GST_CHECK_PLUGIN(sdi)
 381 AG_GST_CHECK_PLUGIN(sdp)
 382 AG_GST_CHECK_PLUGIN(segmentclip)
 383 AG_GST_CHECK_PLUGIN(siren)
 384 AG_GST_CHECK_PLUGIN(smooth)
 385 AG_GST_CHECK_PLUGIN(speed)
 386 AG_GST_CHECK_PLUGIN(subenc)
 387 AG_GST_CHECK_PLUGIN(stereo)
 388 AG_GST_CHECK_PLUGIN(tta)
 389 AG_GST_CHECK_PLUGIN(videofilters)
 390 AG_GST_CHECK_PLUGIN(videomeasure)
 391 AG_GST_CHECK_PLUGIN(videoparsers)
 392 AG_GST_CHECK_PLUGIN(videosignal)
 393 AG_GST_CHECK_PLUGIN(vmnc)
 394 AG_GST_CHECK_PLUGIN(y4m)
 395
 396 dnl *** plug-ins to exclude ***
 397
 398 dnl real plugin only works on i386 and x86_64 for the time being.
 399 if test "x$HAVE_CPU_I386" != "xyes" && test "x$HAVE_CPU_X86_64" != "xyes"; then
 400   AC_MSG_WARN([Not building real plugin, only works on 32bit and 64bit x86 platforms])
 401   AG_GST_DISABLE_PLUGIN(real)
 402 fi
 403
 404 dnl disable gst plugins we might not be able to build on this
 405 dnl platform: librfb (ugly but minimally invasive)
 406 dnl FIXME: maybe move to sys, or make work with winsock2
 407 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 408 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 409
 410 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 411   WINSOCK2_LIBS="-lws2_32"
 412   AC_SUBST(WINSOCK2_LIBS)
 413 fi
 414
 415 if test "x$HAVE_PTHREAD_H" = "xyes"; then
 416   DCCP_LIBS="$DCCP_LIBS -lpthread"
 417   AC_SUBST(DCCP_LIBS)
 418 else
 419   AG_GST_DISABLE_PLUGIN(dccp)
 420 fi
 421
 422 dnl *** sys plug-ins ***
 423
 424 dnl DirectSound
 425 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 426 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound], directsoundsrc, [
 427   HAVE_DIRECTSOUND="no"
 428   save_CFLAGS="$CFLAGS"
 429   save_LDFLAGS="$LDFLAGS"
 430   save_LIBS="$LIBS"
 431   CFLAGS="$CFLAGS $DIRECTX_CFLAGS"
 432   LDFLAGS="$LDFLAGS $DIRECTX_LDFLAGS"
 433   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 434   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 435   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 436 #include <windows.h>
 437 #include <dxerr9.h>
 438 #include <dsound.h>
 439 ]], [[
 440   DXGetErrorString9 (0);
 441   DirectSoundCreate(NULL, NULL, NULL);
 442 ]])],
 443     [HAVE_DIRECTSOUND="yes"],
 444     [HAVE_DIRECTSOUND="no"])
 445   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 446   CFLAGS=$save_CFLAGS
 447   LDFLAGS=$save_LDFLAGS
 448   LIBS=$save_LIBS
 449
 450   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 451     dnl this is much more than we want
 452     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 453     AC_SUBST(DIRECTX_CFLAGS)
 454     AC_SUBST(DIRECTX_LDFLAGS)
 455     AC_SUBST(DIRECTSOUND_LIBS)
 456   fi
 457   AC_SUBST(HAVE_DIRECTSOUND)
 458 ])
 459
 460 dnl WASAPI
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_WASAPI, true)
 462 AG_GST_CHECK_FEATURE(WASAPI, [WASAPI plug-in], wasapi, [
 463   HAVE_WASAPI="no"
 464   save_CFLAGS="$CFLAGS"
 465   save_LDFLAGS="$LDFLAGS"
 466   save_LIBS="$LIBS"
 467   CFLAGS="$CFLAGS $DIRECTX_CFLAGS"
 468   LDFLAGS="$LDFLAGS $DIRECTX_LDFLAGS"
 469   LIBS="$LIBS -lole32 -lwinmm -lksuser"
 470   AC_MSG_CHECKING(for WASAPI LDFLAGS)
 471   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 472 #include <windows.h>
 473 #include <stdio.h>
 474 #include <mmsystem.h>
 475 #include <mmdeviceapi.h>
 476 ]], [[
 477 int main ()
 478 {
 479     HRESULT hr = S_OK;
 480
 481     hr = CoInitialize(NULL);
 482     if (FAILED(hr)) {
 483         printf("CoInitialize failed: hr = 0x%08x", hr);
 484         return __LINE__;
 485     }
 486
 487         int result = 0;
 488     // result = do_everything(argc, argv);
 489
 490     CoUninitialize();
 491     return result;
 492 }
 493 ]])],
 494     [HAVE_WASAPI="yes"],
 495     [HAVE_WASAPI="no"])
 496   AC_MSG_RESULT($HAVE_WASAPI)
 497   CFLAGS=$save_CFLAGS
 498   LDFLAGS=$save_LDFLAGS
 499   LIBS=$save_LIBS
 500
 501   if test "x$HAVE_WASAPI" = "xyes";  then
 502     WASAPI_LIBS="-lole32 -lwinmm -lksuser"
 503     AC_SUBST(WASAPI_LIBS)
 504   fi
 505   AC_SUBST(HAVE_WASAPI)
 506 ])
 507
 508 dnl Direct3D
 509 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECT3D, true)
 510 AG_GST_CHECK_FEATURE(DIRECT3D, [Direct3D plug-in], direct3dsink, [
 511   HAVE_DIRECT3D="no"
 512   save_CFLAGS="$CFLAGS"
 513   save_LDFLAGS="$LDFLAGS"
 514   save_LIBS="$LIBS"
 515   CFLAGS="$CFLAGS $DIRECTX_CFLAGS"
 516   LDFLAGS="$LDFLAGS $DIRECTX_LDFLAGS"
 517   LIBS="$LIBS -ld3d9 -lgdi32"
 518   AC_MSG_CHECKING(for Direct3D LDFLAGS)
 519   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 520 #include <windows.h>
 521 #include <d3d9.h>
 522 ]], [[
 523   Direct3DCreate9(D3D_SDK_VERSION);
 524 ]])],
 525     [HAVE_DIRECT3D="yes"],
 526     [HAVE_DIRECT3D="no"])
 527   AC_MSG_RESULT($HAVE_DIRECT3D)
 528   CFLAGS=$save_CFLAGS
 529   LDFLAGS=$save_LDFLAGS
 530   LIBS=$save_LIBS
 531
 532   if test "x$HAVE_DIRECT3D" = "xyes";  then
 533     DIRECT3D_LIBS="-ld3d9 -lgdi32"
 534     AC_SUBST(DIRECT3D_LIBS)
 535   fi
 536   AC_SUBST(HAVE_DIRECT3D)
 537 ])
 538
 539 dnl DirectDraw
 540 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 541 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 542   HAVE_DIRECTDRAW="no"
 543   save_CFLAGS="$CFLAGS"
 544   save_LDFLAGS="$LDFLAGS"
 545   save_LIBS="$LIBS"
 546   CFLAGS="$CFLAGS $DIRECTX_CFLAGS"
 547   LDFLAGS="$LDFLAGS $DIRECTX_LDFLAGS"
 548   LIBS="$LIBS -lddraw -lgdi32"
 549   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 550   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 551 #include <windows.h>
 552 #include <ddraw.h>
 553 ]], [[
 554   GetStockObject(0);
 555   DirectDrawCreate(NULL, NULL, NULL);
 556 ]])],
 557     [HAVE_DIRECTDRAW="yes"],
 558     [HAVE_DIRECTDRAW="no"])
 559   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 560   CFLAGS=$save_CFLAGS
 561   LDFLAGS=$save_LDFLAGS
 562   LIBS=$save_LIBS
 563
 564   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 565     dnl this is much more than we want
 566     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 567     AC_SUBST(DIRECTX_CFLAGS)
 568     AC_SUBST(DIRECTX_LDFLAGS)
 569     AC_SUBST(DIRECTDRAW_LIBS)
 570   fi
 571   AC_SUBST(HAVE_DIRECTDRAW)
 572 ])
 573
 574 dnl Direct3D9
 575 AM_CONDITIONAL(USE_DIRECT3D9, true)
 576 AG_GST_CHECK_FEATURE(DIRECT3D9, [Direct3D9], winscreencap, [
 577   HAVE_DIRECT3D9="no"
 578   save_CFLAGS="$CFLAGS"
 579   save_LDFLAGS="$LDFLAGS"
 580   save_LIBS="$LIBS"
 581   CFLAGS="$CFLAGS $DIRECTX_CFLAGS"
 582   LDFLAGS="$LDFLAGS $DIRECTX_LDFLAGS"
 583   LIBS="$LIBS -ld3d9 -lgdi32"
 584   AC_MSG_CHECKING(for Direct3D9 LDFLAGS)
 585   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 586 #include <windows.h>
 587 #include <d3d9.h>
 588 ]], [[
 589   Direct3DCreate9(D3D_SDK_VERSION);
 590 ]])],
 591     [HAVE_DIRECT3D9="yes"],
 592     [HAVE_DIRECT3D9="no"])
 593   AC_MSG_RESULT($HAVE_DIRECT3D9)
 594   CFLAGS=$save_CFLAGS
 595   LDFLAGS=$save_LDFLAGS
 596   LIBS=$save_LIBS
 597
 598   if test "x$HAVE_DIRECT3D9" = "xyes";  then
 599
 600     DIRECT3D9_LIBS="-ld3d9 -lgdi32"
 601     AC_SUBST(DIRECT3D9_LIBS)
 602   fi
 603   AC_SUBST(HAVE_DIRECT3D9)
 604 ])
 605
 606 dnl DirectShow
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSHOW, true)
 608 AG_GST_CHECK_FEATURE(DIRECTSHOW, [DirectShow plug-in], winks, [
 609   HAVE_DIRECTSHOW="no"
 610   save_CFLAGS="$CFLAGS"
 611   save_LDFLAGS="$LDFLAGS"
 612   save_LIBS="$LIBS"
 613   CFLAGS="$CFLAGS $DIRECTX_CFLAGS"
 614   LDFLAGS="$LDFLAGS $DIRECTX_LDFLAGS"
 615   LIBS="$LIBS -lole32 -luuid -lstrmiids"
 616   AC_MSG_CHECKING(for DirectShow LDFLAGS)
 617   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 618 #include <windows.h>
 619 #include <strmif.h>
 620 #include <uuids.h>
 621
 622 int main () {
 623   IGraphBuilder *pGraph = NULL;
 624   HRESULT hr = CoInitialize(NULL);
 625   hr = CoCreateInstance(&CLSID_FilterGraph, NULL, CLSCTX_INPROC_SERVER,
 626                         &IID_IGraphBuilder, (void **)&pGraph);
 627
 628   return 0;
 629 }
 630 ]])],
 631     [HAVE_DIRECTSHOW="yes"],
 632     [HAVE_DIRECTSHOW="no"])
 633   AC_MSG_RESULT($HAVE_DIRECTSHOW)
 634   CFLAGS=$save_CFLAGS
 635   LDFLAGS=$save_LDFLAGS
 636   LIBS=$save_LIBS
 637
 638   if test "x$HAVE_DIRECTSHOW" = "xyes";  then
 639     dnl this is much more than we want
 640     DIRECTSHOW_LIBS="-ldxguid -lole32 -luuid -lstrmiids -lksuser -lsetupapi"
 641     AC_SUBST(DIRECTX_CFLAGS)
 642     AC_SUBST(DIRECTX_LDFLAGS)
 643     AC_SUBST(DIRECTSHOW_LIBS)
 644   fi
 645   AC_SUBST(HAVE_DIRECTSHOW)
 646 ])
 647
 648 dnl *** Android Media ***
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_ANDROID_MEDIA, true)
 650 HAVE_ANDROID_MEDIA="no"
 651 AG_GST_CHECK_FEATURE(ANDROID_MEDIA, [Android Media], androidmedia, [
 652   case "$host" in
 653     *android*)
 654       AC_CHECK_HEADER(jni.h, HAVE_ANDROID_MEDIA="yes", HAVE_ANDROID_MEDIA="no")
 655       ;;
 656     *)
 657       HAVE_ANDROID_MEDIA="no"
 658       ;;
 659   esac
 660 ])
 661
 662 dnl *** AppleMedia (OS X and iOS) ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_APPLE_MEDIA, true)
 664 HAVE_APPLE_MEDIA="no"
 665 dnl SystemConfiguration.h is common to OS X and iOS, so we check for that
 666 AG_GST_CHECK_FEATURE(APPLE_MEDIA, [Apple video], applemedia, [
 667   AC_CHECK_HEADER(SystemConfiguration/SystemConfiguration.h, HAVE_APPLE_MEDIA="yes", HAVE_APPLE_MEDIA="no")
 668 ])
 669 dnl in case header SystemConfiguration/SystemConfiguration.h is found on other platforms
 670 case "$host" in
 671   *-*darwin*)
 672     ;;
 673   *)
 674     HAVE_APPLE_MEDIA="no"
 675     ;;
 676 esac
 677 HAVE_IOS="no"
 678 if test "x$HAVE_APPLE_MEDIA" = "xyes"; then
 679   AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_IOS="yes", HAVE_IOS="no", [-])
 680 fi
 681
 682 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 683 if test "x$HAVE_IOS" = "xyes"; then
 684   AC_DEFINE(HAVE_IOS, 1, [Define if building for Apple iOS])
 685 fi
 686
 687 dnl *** OS X videosrc ***
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 689 HAVE_OSX_VIDEO="no"
 690 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosrc, [
 691   AC_CHECK_TYPE([SeqGrabComponent], HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no",
 692       [#include <Quicktime/Quicktime.h>])
 693 ])
 694 dnl in case header Quicktime/Quicktime.h is found on other platforms
 695 case "$host" in
 696   *-*darwin*)
 697     ;;
 698   *)
 699     HAVE_OSX_VIDEO="no"
 700     ;;
 701 esac
 702
 703 dnl *** OS/X AVCVideoServices ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_AVC, true)
 705 HAVE_AVC="no"
 706 AG_GST_CHECK_FEATURE(AVC, [AVC Video Services], avcsrc, [
 707   AC_LANG_PUSH([C++])
 708   save_CPPFLAGS="$CPPFLAGS"
 709   CPPFLAGS="$CPPFLAGS -framework AVCVideoServices -framework CoreFoundation"
 710   save_LIBS="$LIBS"
 711   LIBS="$LIBS -framework AVCVideoServices -framework CoreFoundation"
 712   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[HAVE_AVC=yes],[HAVE_AVC=no])
 713   LIBS=$save_LIBS
 714   CPPFLAGS=$save_CPPFLAGS
 715   AC_LANG_POP([C++])
 716 ])
 717 dnl in case header AVCVideoServices/AVCVideoServices.h is found on other platforms
 718 case "$host" in
 719   *-*darwin*)
 720     ;;
 721   *)
 722     HAVE_AVC="no"
 723     ;;
 724 esac
 725
 726 dnl check for QuickTime
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_QUICKTIME, true)
 728 AG_GST_CHECK_FEATURE(QUICKTIME, [QuickTime wrapper], qtwrapper, [
 729   AC_CHECK_TYPE([SampleReferenceRecord], HAVE_QUICKTIME="yes", HAVE_QUICKTIME="no",
 730       [#include <Quicktime/Quicktime.h>])
 731 ])
 732
 733 dnl check for shm_open (for shm plugin)
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_SHM, true)
 735 AG_GST_CHECK_FEATURE(SHM, [POSIX shared memory source and sink], shm, [
 736     if test "x$HAVE_SYS_SOCKET_H" = "xyes"; then
 737         case $host in
 738         *-darwin* | *-macos10*)
 739             AC_DEFINE(HAVE_OSX,[1],[Apple Mac OS X operating system detected])
 740             HAVE_SHM=yes
 741             ;;
 742         *)
 743             AC_CHECK_LIB([rt], [shm_open],
 744                 AC_CHECK_DECL([MSG_NOSIGNAL], HAVE_SHM=yes, HAVE_SHM=no, [
 745                 #include <sys/socket.h>
 746                     ]),
 747                 HAVE_SHM=no)
 748             AC_SUBST(SHM_LIBS, "-lrt")
 749             ;;
 750         esac
 751     else
 752         HAVE_SHM=no
 753     fi
 754 ])
 755
 756 dnl *** Video 4 Linux 2 ***
 757 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 758 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 759 translit(dnm, m, l) AM_CONDITIONAL(USE_MFC, true)
 760 AG_GST_CHECK_FEATURE(MFC, [Multi Format Codec], mfc, [
 761   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 762   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 763 #include <sys/types.h>
 764 #ifdef __sun /* Solaris */
 765 #include <sys/types.h>
 766 #include <sys/videodev2.h>
 767 #elif __FreeBSD__
 768 #include <linux/videodev2.h>
 769 #else /* Linux */
 770 #include <linux/types.h>
 771 #define _LINUX_TIME_H
 772 #define __user
 773 #include <linux/videodev2.h>
 774 #endif
 775 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 776 #error too early v4l2 version or no v4l2 at all
 777 #endif
 778     ]], [[
 779 return 0;
 780     ]])],[
 781       HAVE_MFC="yes"
 782       AC_MSG_RESULT(yes)
 783     ],[
 784       HAVE_MFC="no"
 785       AC_MSG_RESULT(no)
 786
 787       HAVE_VIDEODEV=no
 788       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 789       [
 790         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 791       ])
 792
 793       if test "x$HAVE_VIDEODEV" = "xyes"; then
 794         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 795         AC_MSG_WARN([Please update v4l2 to compile the MFC plugins])
 796       else
 797         AC_MSG_WARN([v4l2 was not found])
 798       fi
 799     ])
 800 ])
 801
 802 dnl check for Video CD
 803 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 804 AG_GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 805   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 806 ])
 807
 808 dnl check for OpenSL ES
 809 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENSLES, true)
 810 AG_GST_CHECK_FEATURE(OPENSLES, [OpenSL ES], opensl, [
 811   AC_CHECK_HEADER(SLES/OpenSLES.h, HAVE_OPENSLES="yes", HAVE_OPENSLES="no")
 812 ])
 813
 814 dnl *** UVC H264 ***
 815 translit(dnm, m, l) AM_CONDITIONAL(USE_UVCH264, true)
 816 AG_GST_CHECK_FEATURE(UVCH264, [UVC H264], uvch264, [
 817   AC_CHECK_HEADER(linux/uvcvideo.h, HAVE_UVCVIDEO_H=yes, HAVE_UVCVIDEO_H=no)
 818   AG_GST_PKG_CHECK_MODULES(GST_VIDEO, gstreamer-video-0.10 >= 0.10.36)
 819   PKG_CHECK_MODULES(G_UDEV, gudev-1.0 , [
 820           AC_DEFINE([HAVE_GUDEV], 1, [Define if gudev is installed])
 821           HAVE_GUDEV="yes" ],
 822           [HAVE_GUDEV="no"])
 823   PKG_CHECK_MODULES(LIBUSB, libusb-1.0 , [
 824           AC_DEFINE([HAVE_LIBUSB], 1, [Define if libusb 1.x is installed])
 825           HAVE_LIBUSB="yes" ],
 826           [HAVE_LIBUSB="no"])
 827   if test "x$HAVE_UVCVIDEO_H" == "xyes" && \
 828      test "x$HAVE_GUDEV" == "xyes" && \
 829      test "x$HAVE_LIBUSB" == "xyes"; then
 830     HAVE_UVCH264=yes
 831   else
 832     HAVE_UVCH264=no
 833   fi
 834 ])
 835 AC_SUBST(LIBUDEV_CFLAGS)
 836 AC_SUBST(LIBUDEV_LIBS)
 837 AC_SUBST(LIBUSB_CFLAGS)
 838 AC_SUBST(LIBUSB_LIBS)
 839
 840
 841 dnl *** ext plug-ins ***
 842 dnl keep this list sorted alphabetically !
 843
 844 if test "x$BUILD_EXTERNAL" = "xyes"; then
 845
 846 dnl *** assrender ***
 847 translit(dnm, m, l) AM_CONDITIONAL(USE_ASSRENDER, true)
 848 AG_GST_CHECK_FEATURE(ASSRENDER, [ASS/SSA renderer], assrender, [
 849   PKG_CHECK_MODULES(ASSRENDER, libass >= 0.9.4, [
 850     HAVE_ASSRENDER="yes" ], [
 851     HAVE_ASSRENDER="no"
 852   ])
 853 ])
 854 AC_SUBST(ASSRENDER_CFLAGS)
 855 AC_SUBST(ASSRENDER_LIBS)
 856
 857 dnl *** vo-amrwbenc ***
 858 translit(dnm, m, l) AM_CONDITIONAL(USE_VOAMRWBENC, true)
 859 AG_GST_CHECK_FEATURE(VOAMRWBENC, [vo-amrwbenc library], vo-amrwbenc, [
 860   AG_GST_PKG_CHECK_MODULES(VOAMRWBENC, vo-amrwbenc >= 0.1.0)
 861 ])
 862
 863 dnl *** vo-aacenc ***
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_VOAACENC, true)
 865 AG_GST_CHECK_FEATURE(VOAACENC, [vo-aacenc library], vo-aacenc, [
 866   AG_GST_PKG_CHECK_MODULES(VOAACENC, vo-aacenc >= 0.1.0)
 867 ])
 868
 869 dnl *** apexsink ***
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_APEXSINK, true)
 871 AG_GST_CHECK_FEATURE(APEXSINK, [AirPort Express Wireless sink], apexsink, [
 872   PKG_CHECK_MODULES(APEXSINK, [ openssl >= 0.9.5  libcrypto ], [
 873     HAVE_APEXSINK="yes"
 874     saved_LIBS="$LIBS"
 875     LIBS=""
 876     AC_SEARCH_LIBS(socket, [socket], [ ], [ APEXSINK="no" ])
 877     AC_SEARCH_LIBS(gethostbyname, [nsl], [ ], [ APEXSINK="no" ])
 878     APEXSINK_LIBS="$APEXSINK_LIBS $LIBS"
 879     LIBS="$saved_LIBS"
 880     AC_SUBST(APEXSINK_CFLAGS)
 881     AC_SUBST(APEXSINK_LIBS)
 882   ], [
 883     APEXSINK="no"
 884   ])
 885 ])
 886
 887 dnl *** BZ2 ***
 888 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 889 AG_GST_CHECK_FEATURE(BZ2, [bz2 library], bz2, [
 890   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 891   AC_SUBST(BZ2_LIBS)
 892 ])
 893
 894 #dnl *** cairo ***
 895 #translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 896 #AG_GST_CHECK_FEATURE(CAIRO, [cairo plug-in], cairo, [
 897 #  PKG_CHECK_MODULES(CAIRO, cairo >= 1.0 glitz-glx, HAVE_CAIRO=yes, [
 898 #    HAVE_CAIRO=no
 899 #  ])
 900 #  AC_SUBST(CAIRO_CFLAGS)
 901 #  AC_SUBST(CAIRO_LIBS)
 902 #])
 903
 904 dnl *** cdaudio ***
 905 translit(dnm, m, l) AM_CONDITIONAL(USE_CDAUDIO, true)
 906 AG_GST_CHECK_FEATURE(CDAUDIO, [cdaudio], cdaudio, [
 907   PKG_CHECK_MODULES(CDAUDIO, libcdaudio, [
 908           HAVE_CDAUDIO="yes"
 909   ], [
 910           HAVE_CDAUDIO="no"
 911   ])
 912   AC_SUBST(CDAUDIO_CFLAGS)
 913   AC_SUBST(CDAUDIO_LIBS)
 914 ])
 915
 916 dnl *** celt ***
 917 translit(dnm, m, l) AM_CONDITIONAL(USE_CELT, true)
 918 AG_GST_CHECK_FEATURE(CELT, [celt], celt, [
 919   PKG_CHECK_MODULES(CELT, celt >= 0.5.0, [
 920           AC_DEFINE([HAVE_CELT], 1, [Define if libcelt 0.5 is installed])
 921           HAVE_CELT="yes"
 922   ], [
 923           HAVE_CELT="no"
 924   ])
 925
 926   PKG_CHECK_MODULES(CELT_0_7, celt >= 0.7.0, [
 927           AC_DEFINE([HAVE_CELT_0_7], 1, [Define if libcelt 0.7 is installed])
 928   ], [
 929           dnl to prevent an error
 930           true
 931   ])
 932
 933   PKG_CHECK_MODULES(CELT_0_8, celt >= 0.8.0, [
 934           AC_DEFINE([HAVE_CELT_0_8], 1, [Define if libcelt 0.8 is installed])
 935   ], [
 936           dnl to prevent an error
 937           true
 938   ])
 939
 940   PKG_CHECK_MODULES(CELT_0_11, celt >= 0.11.0, [
 941           AC_DEFINE([HAVE_CELT_0_11], 1, [Define if libcelt 0.11 is installed])
 942   ], [
 943           dnl to prevent an error
 944           true
 945   ])
 946   AC_SUBST(CELT_CFLAGS)
 947   AC_SUBST(CELT_LIBS)
 948 ])
 949
 950 dnl *** chromaprint ***
 951 translit(dnm, m, l) AM_CONDITIONAL(USE_CHROMAPRINT, true)
 952 AG_GST_CHECK_FEATURE(CHROMAPRINT, [chromaprint], chromaprint, [
 953   PKG_CHECK_MODULES(CHROMAPRINT, libchromaprint, HAVE_CHROMAPRINT="yes", [
 954     HAVE_CHROMAPRINT="no"
 955   ])
 956   AC_SUBST(CHROMAPRINT_CFLAGS)
 957   AC_SUBST(CHROMAPRINT_LIBS)
 958 ])
 959
 960 dnl *** Cog ***
 961 translit(dnm, m, l) AM_CONDITIONAL(USE_COG, true)
 962 AG_GST_CHECK_FEATURE(COG, [Cog plugin], cog, [
 963   PKG_CHECK_MODULES(COG, libpng >= 1.2, HAVE_COG="yes", [
 964     HAVE_COG="no"
 965   ])
 966   AC_SUBST(COG_CFLAGS)
 967   AC_SUBST(COG_LIBS)
 968 ])
 969
 970 dnl *** Curl ***
 971 translit(dnm, m, l) AM_CONDITIONAL(USE_CURL, true)
 972 AG_GST_CHECK_FEATURE(CURL, [Curl plugin], curl, [
 973   PKG_CHECK_MODULES(CURL, libcurl >= 7.21.0, [
 974     HAVE_CURL="yes"
 975     AC_CHECK_HEADERS([unistd.h sys/socket.h sys/types.h netinet/in.h netinet/ip.h netinet/tcp.h fcntl.h], [ ], [
 976       AC_CHECK_HEADERS([unistd.h sys/types.h winsock2.h ws2tcpip.h fcntl.h], [ ], [HAVE_CURL="no"])
 977     ])
 978     AC_MSG_CHECKING([for socket support needed by curlsink])
 979     AC_MSG_RESULT($HAVE_CURL)
 980   ], [
 981     HAVE_CURL="no"
 982   ])
 983   AC_SUBST(CURL_CFLAGS)
 984   AC_SUBST(CURL_LIBS)
 985 ])
 986
 987 dnl *** dc1394  ***
 988 translit(dnm, m, l) AM_CONDITIONAL(USE_DC1394, true)
 989 AG_GST_CHECK_FEATURE(DC1394, [libdc1394], dc1394, [
 990    PKG_CHECK_MODULES(LIBDC1394, libdc1394-2 >= 2.0.0, [
 991         if test -z "`$PKG_CONFIG --modversion libdc1394-2 | grep 2.0.0-rc`"; then
 992                 HAVE_DC1394="yes"
 993         else
 994                 HAVE_DC1394="no"
 995         fi
 996    ], [
 997         HAVE_DC1394="no"
 998         AC_MSG_RESULT(no)
 999    ])
1000    AC_SUBST(LIBDC1394_CFLAGS)
1001    AC_SUBST(LIBDC1394_LIBS)
1002 ])
1003
1004 dnl *** decklink  ***
1005 translit(dnm, m, l) AM_CONDITIONAL(USE_DECKLINK, true)
1006 AG_GST_CHECK_FEATURE(DECKLINK, [decklink], decklink, [
1007    HAVE_DECKLINK=no
1008    case "$host" in
1009      *-*linux*)
1010        if test "x$HAVE_PTHREAD_H" = "xyes"; then
1011          AC_CHECK_LIB(dl, dlopen,
1012            [
1013             HAVE_DECKLINK=yes
1014             DECKLINK_CXXFLAGS=
1015             DECKLINK_LIBS="-lpthread -ldl"
1016            ])
1017        fi
1018        ;;
1019      *-*darwin*)
1020        if test "x$HAVE_PTHREAD_H" = "xyes"; then
1021          AC_CHECK_LIB(dl, dlopen,
1022            [
1023             HAVE_DECKLINK=yes
1024             DECKLINK_CXXFLAGS=
1025             DECKLINK_LIBS="-lpthread -ldl"
1026             HAVE_DECKLINK_OSX=yes
1027            ])
1028        fi
1029        ;;
1030      *)
1031        HAVE_DECKLINK=no
1032        ;;
1033    esac
1034
1035    AC_SUBST(DECKLINK_CXXFLAGS)
1036    AC_SUBST(DECKLINK_LIBS)
1037 ])
1038 AM_CONDITIONAL(DECKLINK_OSX, test "x$HAVE_DECKLINK_OSX" = xyes)
1039
1040 dnl **** DirectFB ****
1041 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTFB, true)
1042 AG_GST_CHECK_FEATURE(DIRECTFB, [directfb], dfbvideosink , [
1043   PKG_CHECK_MODULES(DIRECTFB, directfb >= 0.9.24, HAVE_DIRECTFB="yes", [
1044     HAVE_DIRECTFB="no"
1045   ])
1046 ])
1047
1048 dnl **** Wayland ****
1049 translit(dnm, m, l) AM_CONDITIONAL(USE_WAYLAND, true)
1050 AG_GST_CHECK_FEATURE(WAYLAND, [wayland sink], wayland , [
1051   PKG_CHECK_MODULES(WAYLAND, wayland-client >= 1.0.0, [
1052     HAVE_WAYLAND="yes" ], [ HAVE_WAYLAND="no"
1053   ])
1054 ])
1055
1056 dnl **** Dirac ****
1057 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRAC, true)
1058 AG_GST_CHECK_FEATURE(DIRAC, [dirac], dirac, [
1059   PKG_CHECK_MODULES(DIRAC, dirac >= 0.10, HAVE_DIRAC="yes", [
1060     HAVE_DIRAC="no"
1061   ])
1062 ])
1063
1064 dnl *** DTS ***
1065 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
1066 AG_GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
1067   HAVE_DTS="yes"
1068   AG_GST_CHECK_LIBHEADER(DTS, dca, dca_init, $LIBM, dca.h,
1069     DTS_LIBS="-ldca $LIBM", HAVE_DTS="no")
1070   if test $HAVE_DTS = "no"; then
1071     AG_GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, $LIBM, dts.h,
1072       [ DTS_LIBS="-ldts_pic $LIBM"
1073         AC_DEFINE(DTS_OLD, 1, [Define if an old libdts is used])
1074       ])
1075   fi
1076   AC_SUBST(DTS_LIBS)
1077 ])
1078
1079 dnl *** resindvd ***
1080 translit(dnm, m, l) AM_CONDITIONAL(USE_RESINDVD, true)
1081 AG_GST_CHECK_FEATURE(RESINDVD, [resindvd plugin], resindvd, [
1082   PKG_CHECK_MODULES(DVDNAV, dvdnav >= 4.1.2 dvdread >= 4.1.2, HAVE_RESINDVD="yes", [
1083     HAVE_RESINDVD="no"
1084   ])
1085 ])
1086
1087 dnl **** Free AAC Encoder (FAAC) ****
1088 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
1089 AG_GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
1090   AG_GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, $LIBM, faac.h,
1091     FAAC_LIBS="-lfaac $LIBM")
1092   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
1093   AC_SUBST(FAAC_LIBS)
1094 ])
1095
1096 dnl **** Free AAC Decoder (FAAD) ****
1097 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
1098 AG_GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
1099   HAVE_FAAD="yes"
1100   faad_hdr=""
1101   AG_GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, $LIBM, faad.h,
1102     FAAD_LIBS="-lfaad $LIBM", HAVE_FAAD="no")
1103   if test $HAVE_FAAD = "no"; then
1104     AG_GST_CHECK_LIBHEADER(FAAD, faad, NeAACDecOpen, $LIBM, neaacdec.h,
1105       [ FAAD_LIBS="-lfaad $LIBM"
1106         AC_DEFINE(FAAD_IS_NEAAC, 1, [Define if AAC is using new api prefix])
1107         faad_hdr="neaacdec.h"
1108       ], [
1109         HAVE_FAAD="no"
1110       ],)
1111   else
1112     faad_hdr="faad.h"
1113   fi
1114   if test $HAVE_FAAD = "yes"; then
1115     AC_MSG_CHECKING([Checking for FAAD >= 2.0])
1116     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <faad.h>]], [[
1117         #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
1118         #error Not faad2
1119         #else
1120         /* Release candidate of 2.0 is not good enough for us. This field
1121          * was added only in 2.0 final and does not exist in 2.0-RC3 */
1122         faacDecConfiguration conf; conf.dontUpSampleImplicitSBR = 1;
1123         #endif
1124     ]])],[
1125       HAVE_FAAD="yes"
1126
1127       AC_MSG_CHECKING([Checking FAAD2 version in $faad_hdr])
1128       for minor in 10 9 8 7 6 5 0; do
1129         if test x$faad2_minor_version = "x"; then
1130           AC_EGREP_CPP([GST_CHECK_FAAD_VERSION \"2\.$minor\"], [
1131               #include <$faad_hdr>
1132               GST_CHECK_FAAD_VERSION FAAD2_VERSION
1133             ], [
1134               faad2_minor_version=$minor
1135             ])
1136         fi
1137       done
1138       if test x$faad2_minor_version = "x"; then
1139         AC_MSG_RESULT([no idea])
1140       else
1141         AC_MSG_RESULT([2.$faad2_minor_version])
1142         AC_DEFINE_UNQUOTED([FAAD2_MINOR_VERSION], [$faad2_minor_version], [The x in 2.x])
1143       fi
1144     ],[
1145       HAVE_FAAD="no"
1146     ])
1147   fi
1148   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
1149   AC_SUBST(FAAD_LIBS)
1150   AC_SUBST(FAAD_IS_NEAAC)
1151 ])
1152
1153 dnl *** fbdev ***
1154 translit(dnm, m, l) AM_CONDITIONAL(USE_FBDEV, true)
1155 AG_GST_CHECK_FEATURE(FBDEV, [linux framebuffer], fbdevsink, [
1156   if test "x$HAVE_FBDEV" != "xyes"; then
1157     AC_CHECK_HEADER([linux/fb.h], HAVE_FBDEV=yes, HAVE_FBDEV=no)
1158   fi
1159 ])
1160
1161 dnl *** flite ***
1162 translit(dnm, m, l) AM_CONDITIONAL(USE_FLITE, true)
1163 AG_GST_CHECK_FEATURE(FLITE, [Flite plugin], flite, [
1164   AG_GST_CHECK_LIBHEADER(FLITE, flite, flite_init, $LIBM, flite/flite.h,
1165     FLITE_LIBS="-lflite -lflite_cmu_us_kal -lflite_usenglish -lflite_cmulex $LIBM")
1166
1167   AC_SUBST(FLITE_CFLAGS)
1168   AC_SUBST(FLITE_LIBS)
1169 ])
1170
1171 dnl *** gsm ***
1172 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
1173 AG_GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
1174   AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
1175   if test $HAVE_GSM != "yes"; then
1176     AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
1177     if test $HAVE_GSM = "yes"; then
1178       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
1179     fi
1180   fi
1181   AC_SUBST(GSM_LIBS)
1182 ])
1183
1184 dnl *** kate ***
1185 translit(dnm, m, l) AM_CONDITIONAL(USE_KATE, true)
1186 AG_GST_CHECK_FEATURE(KATE, [Kate], kate, [
1187   PKG_CHECK_MODULES(KATE, kate >= 0.1.7, HAVE_KATE="yes", [
1188     HAVE_KATE="no"
1189   ])
1190   AC_SUBST(KATE_CFLAGS)
1191   AC_SUBST(KATE_LIBS)
1192   PKG_CHECK_MODULES(TIGER, tiger >= 0.3.2,
1193     [
1194       HAVE_TIGER="yes"
1195       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available])
1196     ],
1197     [
1198       HAVE_TIGER="no"
1199     ]
1200   )
1201   AM_CONDITIONAL(USE_TIGER, test "x$HAVE_TIGER" = "xyes")
1202   AC_SUBST(TIGER_CFLAGS)
1203   AC_SUBST(TIGER_LIBS)
1204 ],,,[AM_CONDITIONAL(USE_TIGER, false)])
1205
1206 dnl *** ladspa ***
1207 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
1208 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
1209   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
1210
1211   PKG_CHECK_MODULES(LRDF, lrdf, HAVE_LRDF=yes, HAVE_LRDF=no)
1212   if test $HAVE_LRDF = "yes"; then
1213     AC_DEFINE(HAVE_LRDF, 1, [Define if we have liblrdf])
1214   fi
1215   AC_SUBST(LRDF_LIBS)
1216   AC_SUBST(LRDF_CFLAGS)
1217 ])
1218
1219 dnl *** LV2 ***
1220 translit(dnm, m, l) AM_CONDITIONAL(USE_LV2, true)
1221 AG_GST_CHECK_FEATURE(LV2, [lv2], lv2, [
1222   PKG_CHECK_MODULES(SLV2, slv2 >= 0.6.6, HAVE_LV2="yes", HAVE_LV2="no")
1223   AC_SUBST(SLV2_CFLAGS)
1224   AC_SUBST(SLV2_LIBS)
1225 ])
1226
1227 dnl *** libmms ***
1228 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBMMS, true)
1229 AG_GST_CHECK_FEATURE(LIBMMS, [mms protocol library], libmms, [
1230   dnl check with pkg-config first
1231   PKG_CHECK_MODULES(LIBMMS, libmms >= 0.4, HAVE_LIBMMS="yes", [
1232     HAVE_LIBMMS="no"
1233   ])
1234 ])
1235 AC_SUBST(LIBMMS_LIBS)
1236
1237 dnl *** linsys ***
1238 translit(dnm, m, l) AM_CONDITIONAL(USE_LINSYS, true)
1239 AG_GST_CHECK_FEATURE(LINSYS, [Linear Systems SDI plugin], linsys, [
1240   case "$host" in
1241     *-*linux*)
1242       HAVE_LINSYS=yes
1243       ;;
1244     *)
1245       HAVE_LINSYS=no
1246       ;;
1247   esac
1248 ])
1249
1250 dnl *** modplug ***
1251 translit(dnm, m, l) AM_CONDITIONAL(USE_MODPLUG, true)
1252 AG_GST_CHECK_FEATURE(MODPLUG, modplug, modplug, [
1253   if test "x$HAVE_CXX" != "xyes"; then
1254     AC_MSG_WARN([Not compiling modplug plugin as it requires a C++ compiler])
1255     HAVE_MODPLUG="no"
1256   else
1257     PKG_CHECK_MODULES(MODPLUG, libmodplug, HAVE_MODPLUG="yes", HAVE_MODPLUG="no")
1258   fi
1259   AC_SUBST(MODPLUG_CFLAGS)
1260   AC_SUBST(MODPLUG_LIBS)
1261 ])
1262
1263 dnl *** mimic ***
1264 translit(dnm, m, l) AM_CONDITIONAL(USE_MIMIC, true)
1265 AG_GST_CHECK_FEATURE(MIMIC, [libmimic library], mimic, [
1266   MIMIC_REQUIRED=1.0
1267   PKG_CHECK_MODULES(MIMIC, libmimic >= $MIMIC_REQUIRED,
1268       HAVE_MIMIC=yes, HAVE_MIMIC=no)
1269   AC_SUBST(MIMIC_CFLAGS)
1270   AC_SUBST(MIMIC_LIBS)
1271 ])
1272
1273 dnl *** mjpegtools version info ***
1274 dnl some may prefer older version (given quirks above)
1275 dnl hm, no version info seems available within mjpegtools headers
1276 dnl and API really moves along
1277 echo
1278 PKG_CHECK_EXISTS(mjpegtools >= 1.6.1.93 mjpegtools < 1.8.0, [
1279   mjpegtools_api=10601
1280 ], [
1281   PKG_CHECK_EXISTS(mjpegtools >= 1.8.0 mjpegtools < 1.9.0, [
1282     mjpegtools_api=10800
1283   ], [
1284     PKG_CHECK_EXISTS(mjpegtools >= 2.0.0, [
1285       mjpegtools_api=20000
1286     ], [
1287       PKG_CHECK_MODULES(MJPEG, mjpegtools >= 1.9.0 mjpegtools < 2.0.0, [
1288         dnl logging API changed in release candidates
1289         OLD_CFLAGS="$CFLAGS"
1290         OLD_LIBS="$LIBS"
1291         CFLAGS="$MJPEG_CFLAGS"
1292         LIBS="$LIBS $MJPEG_LIBS -lmjpegutils $LIBM -lpthread"
1293         AC_CHECK_FUNC(mjpeg_loglev_t, [
1294           mjpegtools_api=10903
1295           ], [
1296           mjpegtools_api=10900
1297           ])
1298         CFLAGS="$OLD_CFLAGS"
1299         LIBS="$OLD_LIBS"
1300       ], [
1301         mjpegtools_api=0
1302       ])
1303     ])
1304   ])
1305 ])
1306 AC_DEFINE_UNQUOTED(GST_MJPEGTOOLS_API, $mjpegtools_api,
1307   [mjpegtools API evolution])
1308
1309 dnl *** mpeg2enc ***
1310 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
1311 AG_GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
1312   HAVE_MPEG2ENC="no"
1313   dnl we require a c++ compiler for this one
1314   if [ test x$HAVE_CXX = xyes ]; then
1315     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
1316     dnl since many distros include mjpegtools specifically without mplex
1317     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
1318     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
1319       dnl HACK because mpeg2enc 1.8.0 header files have a spurious 'include config.h'
1320       touch config.h
1321       dnl switch over to c++ to test things
1322       AC_LANG([C++])
1323       OLD_CPPFLAGS="$CPPFLAGS"
1324       dnl HACK as above
1325       CPPFLAGS_GOOD="$CPPFLAGS $MPEG2ENC_CFLAGS"
1326       CPPFLAGS="$CPPFLAGS_GOOD -I."
1327       dnl check headers
1328       mpeg2enc_headers_ok=no
1329       AC_CHECK_HEADER([mpeg2encoder.hh], [
1330         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp $LIBM -lpthread"
1331         OLD_LIBS="$LIBS"
1332         LIBS="$LIBS $MPEG2ENC_LIBS"
1333         AC_MSG_CHECKING([for valid mpeg2enc objects])
1334         AC_RUN_IFELSE([AC_LANG_SOURCE([[
1335           #include <mpeg2encoder.hh>
1336           #include <mpeg2encoptions.hh>
1337
1338           int
1339           main (int   argc,
1340                 char *argv[])
1341           {
1342             MPEG2EncOptions *options = new MPEG2EncOptions ();
1343             MPEG2Encoder *encoder = new MPEG2Encoder (*options);
1344             return 0;
1345           }
1346         ]])],[
1347           AC_MSG_RESULT(yes)
1348           dnl so far so good, let's check more things:
1349           dnl mjpegtools-1.8.0 does not install the required
1350           dnl mpeg2syntaxcodes.h header by default, and a new release
1351           dnl is not in sight, so check for this oversight in case
1352           dnl distros or folks have fixed this themselves
1353           if test "$mjpegtools_api" -ge "10800"; then
1354             AC_CHECK_HEADER([mpeg2syntaxcodes.h], [
1355                 mpeg2enc_headers_ok=yes
1356               ], [
1357                 mpeg2enc_headers_ok=no
1358               ])
1359           else
1360             mpeg2enc_headers_ok=yes
1361           fi
1362           if test "x$mpeg2enc_headers_ok" = "xyes"; then
1363             HAVE_MPEG2ENC="yes"
1364           fi
1365           CPPFLAGS="$CPPFLAGS_GOOD"
1366           AC_SUBST(MPEG2ENC_CFLAGS)
1367           AC_SUBST(MPEG2ENC_LIBS)
1368         ],[
1369           AC_MSG_RESULT(no)
1370         ],[])
1371         LIBS="$OLD_LIBS"
1372       ])
1373
1374       CPPFLAGS="$OLD_CPPFLAGS"
1375       AC_LANG([C])
1376     ], [
1377       HAVE_MPEG2ENC="no"
1378     ])
1379   fi
1380 ])
1381
1382 dnl *** mpg123 ***
1383 translit(dnm, m, l) AM_CONDITIONAL(USE_MPG123, true)
1384 AG_GST_CHECK_FEATURE(MPG123, [mpg123 audio decoder], mpg123, [
1385   PKG_CHECK_MODULES(MPG123, libmpg123 >= 1.13, HAVE_MPG123="yes", HAVE_MPG123="no")
1386   AC_SUBST(MPG123_CFLAGS)
1387   AC_SUBST(MPG123_LIBS)
1388 ])
1389
1390 dnl *** mplex ***
1391 translit(dnm, m, l) AM_CONDITIONAL(USE_MPLEX, true)
1392 AG_GST_CHECK_FEATURE(MPLEX, [mplex], mplex, [
1393   HAVE_MPLEX="no"
1394   dnl we require a c++ compiler for this one
1395   if [ test x$HAVE_CXX = xyes ]; then
1396     dnl libmplex was first included in mjpegtools-1.6.2-rc4 (1.6.1.93)
1397     dnl since many distros include mjpegtools specifically without mplex
1398     dnl and mpeg2enc, we check for mplex on its own, too.
1399     dnl libmplex < 1.9rc? has fuzzy ABI, valgrind and other problems
1400     PKG_CHECK_MODULES(MPLEX, mjpegtools >= 1.9.0, [
1401       dnl HACK because mplex 2.0.0 header files have a spurious 'include config.h'
1402       touch config.h
1403       dnl switch over to c++ to test things
1404       AC_LANG([C++])
1405       OLD_CPPFLAGS="$CPPFLAGS"
1406       dnl HACK as above
1407       CPPFLAGS_GOOD="$CPPFLAGS $MPLEX_CFLAGS"
1408       CPPFLAGS="$CPPFLAGS_GOOD -I."
1409       AC_CHECK_HEADER(interact.hpp, [
1410         MPLEX_LIBS="$MPLEX_LIBS -lmplex2 $LIBM"
1411         OLD_LIBS="$LIBS"
1412         LIBS="$LIBS $MPLEX_LIBS"
1413         OLD_LDFLAGS="$LDFLAGS"
1414         LDFLAGS="$LDFLAGS $MPLEX_LDFLAGS"
1415         dnl older libmplex uses off_t SegmentSize (), which leads to fuzzy ABI;
1416         dnl don't want this here
1417         AC_MSG_CHECKING([for valid mplex objects])
1418         AC_RUN_IFELSE([AC_LANG_SOURCE([[
1419
1420 #include <interact.hpp>
1421 #include <outputstrm.hpp>
1422 #include <multiplexor.hpp>
1423 int
1424 main (int   argc,
1425       char *argv[])
1426 {
1427   class TestOutputStream : public OutputStream {
1428   public:
1429     TestOutputStream () : OutputStream () { }
1430     void Write (uint8_t *a, unsigned int b) { }
1431     void NextSegment () { }
1432     uint64_t SegmentSize () { }
1433     void Close () { }
1434     int Open () { }
1435 };
1436   MultiplexJob *job = new MultiplexJob ();
1437   vector<IBitStream *> inputs;
1438   job->SetupInputStreams (inputs);
1439   TestOutputStream *out = new TestOutputStream ();
1440   Multiplexor *mux = new Multiplexor(*job, *out, NULL);
1441   return 0;
1442 }
1443         ]])],[
1444           HAVE_MPLEX="yes"
1445           CPPFLAGS="$CPPFLAGS_GOOD"
1446           AC_SUBST(MPLEX_CFLAGS)
1447           AC_SUBST(MPLEX_LIBS)
1448           AC_SUBST(MPLEX_LDFLAGS)
1449           AC_MSG_RESULT(yes)
1450         ],[AC_MSG_RESULT(no)],[])
1451         LIBS="$OLD_LIBS"
1452         LDFLAGS="$OLD_LDFLAGS"
1453       ])
1454       CPPFLAGS="$OLD_CPPFLAGS"
1455       AC_LANG([C])
1456     ], HAVE_MPLEX="no")
1457   fi
1458 ])
1459
1460 dnl *** musepack ***
1461 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSEPACK, true)
1462 AG_GST_CHECK_FEATURE(MUSEPACK, [musepackdec], musepack, [
1463   AC_CHECK_HEADER([mpc/mpcdec.h], [
1464     HAVE_MUSEPACK="yes"
1465     MUSEPACK_LIBS="-lmpcdec"
1466     AC_SUBST(MUSEPACK_LIBS)
1467     ], [AC_CHECK_HEADER([mpcdec/mpcdec.h], [
1468       HAVE_MUSEPACK="yes"
1469       MUSEPACK_LIBS="-lmpcdec"
1470       AC_DEFINE(MPC_IS_OLD_API, 1, [Define if the old MusePack API is used])
1471       AC_SUBST(MUSEPACK_LIBS)
1472     ], [HAVE_MUSEPACK="no"])])
1473 ])
1474
1475 dnl *** musicbrainz ***
1476 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
1477 AG_GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz tag generation], musicbrainz, [
1478   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz >= 2.1.0, HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
1479   AC_SUBST(MUSICBRAINZ_CFLAGS)
1480   AC_SUBST(MUSICBRAINZ_LIBS)
1481 ])
1482
1483 dnl *** MythTV ***
1484 translit(dnm, m, l) AM_CONDITIONAL(USE_MYTHTV, true)
1485 AG_GST_CHECK_FEATURE(MYTHTV, [MythTV client plugins], mythtvsrc, [
1486   PKG_CHECK_MODULES(GMYTH, gmyth >= 0.4 gmyth <= 0.7.99, HAVE_MYTHTV="yes", [
1487     HAVE_MYTHTV="no"
1488   ])
1489   AC_SUBST(GMYTH_CFLAGS)
1490   AC_SUBST(GMYTH_LIBS)
1491 ])
1492
1493 dnl *** nas ***
1494 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
1495 AG_GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
1496   HAVE_NAS="no"
1497   AG_GST_CHECK_X
1498   if test "x$HAVE_X" = "xyes"; then
1499     save_cppflags=$CFLAGS
1500     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1501     AG_GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
1502       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
1503     CPPFLAGS="$save_cppflags"
1504   fi
1505   AC_SUBST(NAS_CFLAGS)
1506   AC_SUBST(NAS_LIBS)
1507 ])
1508
1509 dnl *** neon ***
1510 translit(dnm, m, l) AM_CONDITIONAL(USE_NEON, true)
1511 AG_GST_CHECK_FEATURE(NEON, [neon http client plugins], neonhttpsrc, [
1512   PKG_CHECK_MODULES(NEON, neon >= 0.27.0  neon <= 0.29.99, HAVE_NEON="yes", [
1513     HAVE_NEON="no"
1514   ])
1515   AC_SUBST(NEON_CFLAGS)
1516   AC_SUBST(NEON_LIBS)
1517 ])
1518
1519 dnl *** ofa ***
1520 translit(dnm, m, l) AM_CONDITIONAL(USE_OFA, true)
1521 AG_GST_CHECK_FEATURE(OFA, [ofa plugins], ofa, [
1522   PKG_CHECK_MODULES(OFA, libofa >= 0.9.3, HAVE_OFA="yes", [
1523     HAVE_OFA="no"
1524   ])
1525   AC_SUBST(OFA_CFLAGS)
1526   AC_SUBST(OFA_LIBS)
1527 ])
1528
1529 dnl *** OpenAL ***
1530 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENAL, true)
1531 AG_GST_CHECK_FEATURE(OPENAL, [OpenAL plugin], openal, [
1532   PKG_CHECK_MODULES(OPENAL, openal, HAVE_OPENAL="yes", [
1533     HAVE_OPENAL="no"
1534   ])
1535   AC_SUBST(OPENAL_CFLAGS)
1536   AC_SUBST(OPENAL_LIBS)
1537 ])
1538
1539 dnl *** opencv ***
1540 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENCV, true)
1541 AG_GST_CHECK_FEATURE(OPENCV, [opencv plugins], opencv, [
1542   dnl we specify a max. version too because we set CV_NO_BACKWARD_COMPATIBILITY
1543   dnl and don't want the build to break when a new opencv version comes out.
1544   dnl Need to adjust this upwards once we know that our code compiles fine with
1545   dnl a new version and the no-backward-compatibility define. (There doesn't
1546   dnl seem to be a switch to suppress the warnings the cvcompat.h header
1547   dnl causes.)
1548   PKG_CHECK_MODULES(OPENCV, opencv >= 2.0.0 opencv <= 2.4.3 , [
1549     AC_PROG_CXX
1550     AC_LANG([C++])
1551     OLD_CPPFLAGS=$CPPFLAGS
1552     CPPFLAGS=$OPENCV_CFLAGS
1553     AC_CHECK_HEADERS([highgui.h opencv2/highgui/highgui_c.h])
1554     CPPFLAGS=$OLD_CPPFLAGS
1555     AC_LANG([C])
1556
1557     if test $ac_cv_header_highgui_h = "yes" -o $ac_cv_header_opencv2_highgui_highgui_c_h = "yes" ; then
1558       HAVE_OPENCV="yes"
1559     else
1560       AC_MSG_RESULT([neither highgui.h nor opencv2/highgui/highgui_c.h could not be found])
1561       HAVE_OPENCV="no"
1562     fi
1563   ], [
1564     HAVE_OPENCV="no"
1565   ])
1566   OPENCV_PREFIX="`$PKG_CONFIG --variable=prefix opencv`"
1567   AC_DEFINE_UNQUOTED(OPENCV_PREFIX, "$OPENCV_PREFIX", [opencv install prefix])
1568   AC_SUBST(OPENCV_PREFIX)
1569   AC_SUBST(OPENCV_CFLAGS)
1570   AC_SUBST(OPENCV_LIBS)
1571 ])
1572
1573 dnl *** OpenJPEG ***
1574 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENJPEG, true)
1575 AG_GST_CHECK_FEATURE(OPENJPEG, [openjpeg library], openjpeg, [
1576   HAVE_OPENJPEG="no"
1577   PKG_CHECK_MODULES(OPENJPEG, libopenjpeg1,
1578     HAVE_OPENJPEG="yes",
1579     AG_GST_CHECK_LIBHEADER(OPENJPEG, openjpeg, opj_version, , openjpeg.h, OPENJPEG_LIBS="-lopenjpeg")
1580   )
1581   AC_SUBST(OPENJPEG_CFLAGS)
1582   AC_SUBST(OPENJPEG_LIBS)
1583 ])
1584
1585 dnl *** Opus ***
1586 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
1587 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
1588   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
1589           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
1590           HAVE_OPUS="yes"
1591   ], [
1592           HAVE_OPUS="no"
1593   ])
1594   AC_SUBST(OPUS_CFLAGS)
1595   AC_SUBST(OPUS_LIBS)
1596 ])
1597
1598 dnl *** pvr ***
1599 translit(dnm, m, l) AM_CONDITIONAL(USE_PVR, true)
1600 AG_GST_CHECK_FEATURE(PVR, [pvrvideosink], pvr, [
1601   PKG_CHECK_MODULES([PVR], [libtimemmgr], HAVE_PVR=yes, HAVE_PVR=no)
1602   AC_SUBST(PVR_CFLAGS)
1603   AC_SUBST(PVR_LIBS)
1604 ])
1605
1606  AC_ARG_WITH([pvr-external-headers],
1607               AS_HELP_STRING([--with-pvr-external-headers],[Use system installed PVR2D headers]),
1608               [AS_IF([test "x$with_pvr_external_headers" = "xno"],
1609                      [PVR_CFLAGS="$PVR_CFLAGS -I\$(srcdir)/pvr_includes"])],
1610               [PVR_CFLAGS="$PVR_CFLAGS -I\$(srcdir)/pvr_includes"])
1611
1612 dnl *** rsvg ***
1613 translit(dnm, m, l) AM_CONDITIONAL(USE_RSVG, true)
1614 AG_GST_CHECK_FEATURE(RSVG, [rsvg decoder], rsvg, [
1615   PKG_CHECK_MODULES(RSVG, librsvg-2.0 >= 2.14 cairo, [
1616     HAVE_RSVG="yes"
1617     PKG_CHECK_MODULES(RSVG_2_35_0, librsvg-2.0 >= 2.35.0, HAVE_RSVG_2_35_0="yes", HAVE_RSVG_2_35_0="no")
1618     if test "x$HAVE_RSVG_2_35_0" = "xyes"; then
1619       AC_DEFINE(HAVE_RSVG_2_35_0, [1], [Have RSVG 2.35.0 or newer])
1620     fi
1621   ], [
1622     HAVE_RSVG="no"
1623   ])
1624   AC_SUBST(RSVG_CFLAGS)
1625   AC_SUBST(RSVG_LIBS)
1626 ])
1627
1628 dnl *** eglgles ***
1629 AC_ARG_WITH([egl-window-system],
1630               AS_HELP_STRING([--with-egl-window-system],[EGL window system to use (x11, mali-fb, none)]),
1631               [EGL_WINDOW_SYSTEM="$withval"],
1632               [EGL_WINDOW_SYSTEM="none"])
1633
1634 translit(dnm, m, l) AM_CONDITIONAL(USE_EGLGLES, true)
1635 AG_GST_CHECK_FEATURE(EGLGLES, [eglgles sink], eglgles, [
1636   HAVE_EGLGLES="no"
1637
1638   case "$EGL_WINDOW_SYSTEM" in
1639     x11|none)
1640       PKG_CHECK_MODULES(EGLGLES, egl glesv2, HAVE_EGLGLES="yes", [
1641         HAVE_EGLGLES="no"
1642         old_LIBS=$LIBS
1643         old_CFLAGS=$CFLAGS
1644         AC_CHECK_LIB([GLESv2], [glEnable],
1645           [
1646             AC_CHECK_HEADER([GLES2/gl2.h],
1647               [
1648                 AC_CHECK_LIB([EGL], [eglGetProcAddress],
1649                   [
1650                     AC_CHECK_HEADER([EGL/egl.h],
1651                       [
1652                         HAVE_EGLGLES="yes"
1653                         EGLGLES_LIBS="-lGLESv2 -lEGL"
1654                         EGLGLES_CFLAGS=""
1655                       ])
1656                   ])
1657               ])
1658           ])
1659         LIBS=$old_LIBS
1660         CFLAGS=$old_CFLAGS
1661       ])
1662
1663       if test x"$HAVE_EGLGLES" = x"yes" -a x"$EGL_WINDOW_SYSTEM" = x"x11"; then
1664         if test x"$HAVE_X11" != x"yes"; then
1665           AC_MSG_ERROR([libX11 not found and is required for EGL X11 window system])
1666         else
1667           AC_DEFINE(USE_EGL_X11, [1], [Use X11 EGL window system])
1668           EGLGLES_CFLAGS="$EGLGLES_CFLAGS $X11_CFLAGS"
1669           EGLGLES_LIBS="$EGLGLES_LIBS $X11_LIBS"
1670         fi
1671       fi
1672       ;;
1673     mali-fb)
1674       HAVE_EGLGLES="no"
1675       AC_CHECK_HEADER([EGL/fbdev_window.h],
1676         [
1677           old_LIBS=$LIBS
1678           old_CFLAGS=$CFLAGS
1679
1680           LIBS="$LIBS -lUMP"
1681           AC_CHECK_LIB([Mali], [mali_image_create],
1682             [
1683               LIBS="$LIBS -lMali"
1684               AC_CHECK_LIB([GLESv2], [glEnable],
1685                 [
1686                   AC_CHECK_HEADER([GLES2/gl2.h],
1687                     [
1688                       AC_CHECK_LIB([EGL], [eglGetProcAddress],
1689                         [
1690                           AC_CHECK_HEADER([EGL/egl.h],
1691                             [
1692                               HAVE_EGLGLES="yes"
1693                               EGLGLES_LIBS="-lGLESv2 -lEGL -lMali -lUMP"
1694                               EGLGLES_CFLAGS=""
1695                               AC_DEFINE(USE_EGL_MALI_FB, [1], [Use Mali FB EGL window system])
1696                             ])
1697                         ])
1698                     ])
1699                 ])
1700             ])
1701
1702           LIBS=$old_LIBS
1703           CFLAGS=$old_CFLAGS
1704         ])
1705       ;;
1706     *)
1707       AC_MSG_ERROR([invalid EGL window system specified])
1708       ;;
1709   esac
1710
1711   AC_SUBST(EGLGLES_CFLAGS)
1712   AC_SUBST(EGLGLES_LIBS)
1713 ])
1714
1715 dnl *** timidity ***
1716 translit(dnm, m, l) AM_CONDITIONAL(USE_TIMIDITY, true)
1717 AG_GST_CHECK_FEATURE(TIMIDITY, [timidity midi soft synth plugin], timidity, [
1718   PKG_CHECK_MODULES(TIMIDITY, libtimidity, [
1719     HAVE_TIMIDITY="yes",
1720         AC_MSG_CHECKING([for timidity.cfg])
1721         timidity_cfg=""
1722         if test -r /etc/timidity.cfg; then
1723           timidity_cfg=/etc/timidity.cfg
1724         elif test -r /etc/timidity/timidity.cfg; then
1725           timidity_cfg=/etc/timidity/timidity.cfg
1726         elif test -r /usr/share/timidity/timidity.cfg; then
1727           timidity_cfg=/usr/share/timidity/timidity.cfg
1728         elif test -r /usr/local/share/timidity/timidity.cfg; then
1729           timidity_cfg=/usr/local/share/timidity/timidity.cfg
1730         fi
1731         if test "x$timidity_cfg" != "x"; then
1732           AC_MSG_RESULT($timidity_cfg)
1733       AC_DEFINE_UNQUOTED(TIMIDITY_CFG, "$timidity_cfg", [Define location of timidity.cfg])
1734         else
1735           AC_MSG_RESULT([not found])
1736         fi
1737   ], [
1738     HAVE_TIMIDITY="no"
1739   ])
1740   AC_SUBST(TIMIDITY_CFLAGS)
1741   AC_SUBST(TIMIDITY_LIBS)
1742 ])
1743
1744 dnl *** teletextdec ***
1745 translit(dnm, m, l) AM_CONDITIONAL(USE_TELETEXTDEC, true)
1746 AG_GST_CHECK_FEATURE(TELETEXTDEC, [Teletext decoder], teletextdec, [
1747   AG_GST_PKG_CHECK_MODULES(TELETEXTDEC, zvbi-0.2)
1748  ])
1749
1750 dnl *** wildmidi ***
1751 translit(dnm, m, l) AM_CONDITIONAL(USE_WILDMIDI, true)
1752 AG_GST_CHECK_FEATURE(WILDMIDI, [wildmidi midi soft synth plugin], wildmidi, [
1753   AG_GST_CHECK_LIBHEADER(WILDMIDI, WildMidi,
1754                          WildMidi_Init, ,
1755                          wildmidi_lib.h,
1756                          WILDMIDI_LIBS="-lWildMidi")
1757   AC_CHECK_LIB(WildMidi, WildMidi_LoadSamples, AC_DEFINE(HAVE_WILDMIDI_0_2_2, [1], [Have WildMidi 0.2.2 or earlier library]))
1758
1759   if test "x$HAVE_WILDMIDI" = "xyes"; then
1760          WILDMIDI_CFLAGS=
1761          WILDMIDI_LIBS=-lWildMidi
1762          AC_MSG_NOTICE(compiling gstWildMidi)
1763   else
1764          WILDMIDI_CFLAGS=
1765          WILDMIDI_LIBS=
1766          AC_MSG_WARN(no WildMidi library found (libWildMidi))
1767   fi
1768   AC_SUBST(WILDMIDI_CFLAGS)
1769   AC_SUBST(WILDMIDI_LIBS)
1770 ])
1771
1772 dnl *** SDL ***
1773 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
1774 AG_GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink sdlaudiosink, [
1775     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
1776 ])
1777
1778 dnl *** sndfile ***
1779 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
1780 AG_GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
1781   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.16, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
1782   AC_SUBST(SNDFILE_CFLAGS)
1783   AC_SUBST(SNDFILE_LIBS)
1784 ])
1785
1786 dnl *** soundtouch ***
1787 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUNDTOUCH, true)
1788 AG_GST_CHECK_FEATURE(SOUNDTOUCH, [soundtouch plug-in], soundtouch, [
1789   dnl We only need -lBPM on soundtouch < 1.4
1790   dnl We check for libSoundTouch since Debian used it before upstream
1791   dnl added a pkgconfig file.
1792   HAVE_SOUNDTOUCH_1_4=yes
1793   PKG_CHECK_MODULES(SOUNDTOUCH, soundtouch,
1794     [HAVE_SOUNDTOUCH=yes],
1795     [PKG_CHECK_MODULES(SOUNDTOUCH, soundtouch-1.4,
1796       [HAVE_SOUNDTOUCH=yes],
1797       [PKG_CHECK_MODULES(SOUNDTOUCH, soundtouch-1.0,
1798         [HAVE_SOUNDTOUCH=yes
1799           HAVE_SOUNDTOUCH_1_4=no
1800           SOUNDTOUCH_LIBS="$SOUNDTOUCH_LIBS -lBPM"],
1801         [PKG_CHECK_MODULES(SOUNDTOUCH, libSoundTouch >= 1.4,
1802           [HAVE_SOUNDTOUCH=yes],
1803           [PKG_CHECK_MODULES(SOUNDTOUCH, libSoundTouch,
1804             [HAVE_SOUNDTOUCH=yes
1805               HAVE_SOUNDTOUCH_1_4=no
1806               SOUNDTOUCH_LIBS="$SOUNDTOUCH_LIBS -lBPM"],
1807             HAVE_SOUNDTOUCH=no)])])])])
1808   AC_SUBST(SOUNDTOUCH_CFLAGS)
1809   AC_SUBST(SOUNDTOUCH_LIBS)
1810   if test "x$HAVE_CXX" != "xyes"; then
1811     USE_SOUNDTOUCH=false
1812     AC_MSG_NOTICE([Not building soundtouch plugin: no C++ compiler found])
1813   fi
1814   if test "x$HAVE_SOUNDTOUCH" = "xyes" -a "x$HAVE_SOUNDTOUCH_1_4" = "xyes"; then
1815      AC_DEFINE([HAVE_SOUNDTOUCH_1_4], [1],
1816          [Defined if the available libSoundTouch is >= 1.4])
1817   fi
1818 ])
1819
1820 dnl *** spc ***
1821 translit(dnm, m, l) AM_CONDITIONAL(USE_SPC, true)
1822 AG_GST_CHECK_FEATURE(SPC, [spc decoder], spc, [
1823   AC_CHECK_HEADER(openspc.h, [
1824     AC_CHECK_LIB(openspc, OSPC_Init, [
1825       SPC_LIBS="-lopenspc"
1826       AC_SUBST(SPC_LIBS)
1827       HAVE_SPC=yes
1828     ], [
1829       HAVE_SPC=no
1830     ])
1831   ], [
1832     HAVE_SPC=no
1833   ])
1834 ])
1835
1836 dnl *** gme ***
1837 translit(dnm, m, l) AM_CONDITIONAL(USE_GME, true)
1838 AG_GST_CHECK_FEATURE(GME, [gme decoder], gme, [
1839   AC_CHECK_HEADER(gme/gme.h, [
1840     AC_CHECK_LIB(gme, gme_new_emu, [
1841       GME_LIBS="-lgme"
1842       AC_SUBST(GME_LIBS)
1843       HAVE_GME=yes
1844     ], [
1845       HAVE_GME=no
1846     ])
1847   ], [
1848     HAVE_GME=no
1849   ])
1850
1851   if test "x$HAVE_GME" = "xyes"; then
1852     AC_CHECK_LIB(gme, gme_enable_accuracy, [
1853       AC_DEFINE(HAVE_LIBGME_ACCURACY, 1, [Define if gme 0.5.6 or newer is available])
1854       ])
1855   fi
1856 ])
1857
1858 dnl *** swfdec ***
1859 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
1860 AG_GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
1861   PKG_CHECK_MODULES(SWFDEC, swfdec-0.3 >= 0.3.6, HAVE_SWFDEC=yes, [
1862     HAVE_SWFDEC=no
1863   ])
1864   AC_SUBST(SWFDEC_CFLAGS)
1865   AC_SUBST(SWFDEC_LIBS)
1866 ])
1867
1868 dnl *** XVID ***
1869 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
1870 AG_GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
1871   HAVE_XVID=no
1872   AC_CHECK_HEADER(xvid.h, [
1873     OLD_LIBS="$LIBS"
1874     LIBS="-lpthread $LIBM"
1875     AC_CHECK_LIB(xvidcore, xvid_encore, [
1876       AC_CHECK_LIB(xvidcore, xvid_decore, [
1877         AC_CHECK_LIB(xvidcore, xvid_global, [
1878           AC_MSG_CHECKING([for uptodate XviD API version])
1879           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <xvid.h>]], [[
1880               #if XVID_API_MAJOR(XVID_API) != 4
1881               #error "Incompatible XviD API version"
1882               #endif
1883               #if XVID_API_MAJOR(XVID_API) == 4 && XVID_API_MINOR(XVID_API) < 3
1884               #error "Incompatible XviD API version"
1885               #endif
1886           ]])],[ AC_MSG_RESULT(yes)
1887             XVID_LIBS="-lxvidcore $LIBM"
1888             AC_SUBST(XVID_LIBS)
1889             HAVE_XVID=yes
1890           ],[AC_MSG_RESULT(no) ])
1891         ], )
1892       ], )
1893     ], )
1894     LIBS="$OLD_LIBS"
1895   ], )
1896 ])
1897
1898 dnl *** dvb ***
1899 translit(dnm, m, l) AM_CONDITIONAL(USE_DVB, true)
1900 AG_GST_CHECK_FEATURE(DVB, [DVB Source], dvb, [
1901   AC_MSG_CHECKING([Checking for up to date dvb installation])
1902   AC_CHECK_HEADER(linux/dvb/frontend.h, [HAVE_DVB="yes"], [HAVE_DVB="no"])
1903 ])
1904
1905 dnl *** wininet ***
1906 translit(dnm, m, l) AM_CONDITIONAL(USE_WININET, true)
1907 AG_GST_CHECK_FEATURE(WININET, [Windows internet library], wininet, [
1908   AC_MSG_CHECKING([Checking for windows internet support])
1909   AC_CHECK_HEADERS([windows.h wininet.h],
1910       [HAVE_WININET="yes"], [HAVE_WININET="no"],
1911       [AC_INCLUDES_DEFAULT
1912 #include <windows.h>])
1913 ])
1914
1915 dnl *** acm ***
1916 translit(dnm, m, l) AM_CONDITIONAL(USE_ACM, true)
1917 AG_GST_CHECK_FEATURE(ACM, [Windows ACM library], acm, [
1918   AC_MSG_CHECKING([Checking for ACM support])
1919   AC_CHECK_HEADERS([windows.h msacm.h],
1920       [HAVE_ACM="yes"
1921        AC_SUBST(ACMENC_CFLAGS)
1922        AC_SUBST(ACMMP3DEC_CFLAGS)
1923       ], [HAVE_ACM="no"],
1924       [AC_INCLUDES_DEFAULT
1925 #include <windows.h>])
1926 ])
1927
1928 dnl *** vdpau ***
1929 translit(dnm, m, l) AM_CONDITIONAL(USE_VDPAU, true)
1930 AG_GST_CHECK_FEATURE(VDPAU, [VDPAU], vdpau, [
1931   VDPAU_CFLAGS=
1932   VDPAU_LIBS=-lvdpau
1933   HAVE_VDPAU=no
1934
1935   PKG_CHECK_MODULES(VDPAU, vdpau, [HAVE_VDPAU="yes"],
1936   [
1937     if test "$HAVE_VDPAU" = "no"; then
1938       saved_CPPFLAGS="$CPPFLAGS"
1939       AC_CHECK_HEADER([vdpau/vdpau.h], [HAVE_VDPAU_H=yes])
1940
1941       if test -z "$HAVE_VDPAU_H"; then
1942         dnl Didn't find VDPAU header straight away.
1943         dnl Try /usr/include/nvidia. Need to clear caching vars first
1944         AC_MSG_NOTICE([VDPAU header not in standard path. Checking /usr/include/nvidia])
1945         unset ac_cv_header_vdpau_vdpau_h
1946         unset ac_cv_header_vdpau_vdpau_x11_h
1947         VDPAU_CFLAGS="-I/usr/include/nvidia"
1948         VDPAU_LIBS="-L/usr/lib/nvidia -lvdpau"
1949         CPPFLAGS="$VDPAU_CFLAGS $saved_CPPFLAGS"
1950         AC_CHECK_HEADER([vdpau/vdpau.h], [HAVE_VDPAU_H=yes])
1951       fi
1952
1953       AC_CHECK_HEADER([vdpau/vdpau_x11.h], [HAVE_VDPAU_X11_H=yes])
1954
1955       if test "x$HAVE_VDPAU_H" = "xyes" -a "x$HAVE_VDPAU_X11_H" = "xyes"; then
1956         dnl Found the headers - look for the lib
1957         AC_MSG_NOTICE([VDPAU headers found. Checking libraries])
1958         saved_LIBS="$LIBS"
1959         LIBS="$VDPAU_LIBS $saved_LIBS"
1960         AC_CHECK_LIB(vdpau,vdp_device_create_x11,[HAVE_VDPAU="yes"])
1961         LIBS="$saved_LIBS"
1962       fi
1963     fi
1964   ])
1965
1966   if test "$HAVE_VDPAU" = "yes"; then
1967     AC_MSG_NOTICE([Found up to date VDPAU installation])
1968     AC_SUBST(VDPAU_CFLAGS)
1969     AC_SUBST(VDPAU_LIBS)
1970   fi
1971 ])
1972
1973 dnl *** schroedinger ***
1974 translit(dnm, m, l) AM_CONDITIONAL(USE_SCHRO, true)
1975 AG_GST_CHECK_FEATURE(SCHRO, [Schroedinger video codec], schro, [
1976   AG_GST_PKG_CHECK_MODULES(SCHRO, schroedinger-1.0 >= 1.0.10)
1977 ])
1978
1979 dnl *** zbar ***
1980 translit(dnm, m, l) AM_CONDITIONAL(USE_ZBAR, true)
1981 AG_GST_CHECK_FEATURE(ZBAR, [ZBar barcode detector], zbar, [
1982   AG_GST_PKG_CHECK_MODULES(ZBAR, zbar >= 0.9)
1983 ])
1984
1985 dnl *** rtmp ***
1986 translit(dnm, m, l) AM_CONDITIONAL(USE_RTMP, true)
1987 AG_GST_CHECK_FEATURE(RTMP, [rtmp library], rtmp, [
1988   AG_GST_PKG_CHECK_MODULES(RTMP, librtmp)
1989 ])
1990
1991 dnl *** spandsp ***
1992 translit(dnm, m, l) AM_CONDITIONAL(USE_SPANDSP, true)
1993 AG_GST_CHECK_FEATURE(SPANDSP, [Spandsp], spandsp, [
1994   PKG_CHECK_MODULES(SPANDSP, spandsp >= 0.0.6, [
1995     HAVE_SPANDSP="yes" ], [
1996     HAVE_SPANDSP="no"
1997   ])
1998 ])
1999 AC_SUBST(SPANDSP_CFLAGS)
2000 AC_SUBST(SPANDSP_LIBS)
2001
2002 dnl *** GSettings ***
2003 translit(dnm, m, l) AM_CONDITIONAL(USE_GSETTINGS, true)
2004 AG_GST_CHECK_FEATURE(GSETTINGS, [GSettings plugin], gsettings, [
2005   AG_GST_PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.25.0)
2006   if test "x$HAVE_GSETTINGS" = "xyes"; then
2007     GLIB_GSETTINGS
2008   fi
2009 ])
2010
2011 dnl *** sndio ***
2012 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDIO, true)
2013 AG_GST_CHECK_FEATURE(SNDIO, [sndio audio], sndio, [
2014   AC_CHECK_HEADER(sndio.h, HAVE_SNDIO="yes", HAVE_SNDIO="no")
2015   if test "x$HAVE_SNDIO" = "xyes"; then
2016     AC_CHECK_LIB(sndio, sio_open, HAVE_SNDIO="yes", HAVE_SNDIO="no")
2017     if test "x$HAVE_SNDIO" = "xyes"; then
2018       SNDIO_LIBS=-lsndio
2019       AC_SUBST(SNDIO_LIBS)
2020     fi
2021   fi
2022 ])
2023
2024 else
2025
2026 dnl not building plugins with external dependencies,
2027 dnl but we still need to set the conditionals
2028
2029 AM_CONDITIONAL(USE_ASSRENDER, false)
2030 AM_CONDITIONAL(USE_VOAMRWBENC, false)
2031 AM_CONDITIONAL(USE_VOAACENC, false)
2032 AM_CONDITIONAL(USE_APEXSINK, false)
2033 AM_CONDITIONAL(USE_BZ2, false)
2034 AM_CONDITIONAL(USE_CDAUDIO, false)
2035 AM_CONDITIONAL(USE_CELT, false)
2036 AM_CONDITIONAL(USE_CHROMAPRINT, false)
2037 AM_CONDITIONAL(USE_COG, false)
2038 AM_CONDITIONAL(USE_CURL, false)
2039 AM_CONDITIONAL(USE_DC1394, false)
2040 AM_CONDITIONAL(USE_DECKLINK, false)
2041 AM_CONDITIONAL(DECKLINK_OSX, false)
2042 AM_CONDITIONAL(USE_DIRECTFB, false)
2043 AM_CONDITIONAL(USE_WAYLAND, false)
2044 AM_CONDITIONAL(USE_DIRAC, false)
2045 AM_CONDITIONAL(USE_DTS, false)
2046 AM_CONDITIONAL(USE_EXIF, false)
2047 AM_CONDITIONAL(USE_RESINDVD, false)
2048 AM_CONDITIONAL(USE_FAAC, false)
2049 AM_CONDITIONAL(USE_FAAD, false)
2050 AM_CONDITIONAL(USE_FBDEV, false)
2051 AM_CONDITIONAL(USE_FLITE, false)
2052 AM_CONDITIONAL(USE_GSM, false)
2053 AM_CONDITIONAL(USE_KATE, false)
2054 AM_CONDITIONAL(USE_TIGER, false)
2055 AM_CONDITIONAL(USE_LADSPA, false)
2056 AM_CONDITIONAL(USE_LV2, false)
2057 AM_CONDITIONAL(USE_LIBMMS, false)
2058 AM_CONDITIONAL(USE_LINSYS, false)
2059 AM_CONDITIONAL(USE_MODPLUG, false)
2060 AM_CONDITIONAL(USE_MIMIC, false)
2061 AM_CONDITIONAL(USE_MPEG2ENC, false)
2062 AM_CONDITIONAL(USE_MPG123, false)
2063 AM_CONDITIONAL(USE_MPLEX, false)
2064 AM_CONDITIONAL(USE_MUSEPACK, false)
2065 AM_CONDITIONAL(USE_MUSICBRAINZ, false)
2066 AM_CONDITIONAL(USE_MYTHTV, false)
2067 AM_CONDITIONAL(USE_NAS, false)
2068 AM_CONDITIONAL(USE_NEON, false)
2069 AM_CONDITIONAL(USE_OFA, false)
2070 AM_CONDITIONAL(USE_OPENAL, false)
2071 AM_CONDITIONAL(USE_OPENCV, false)
2072 AM_CONDITIONAL(USE_OPENJPEG, false)
2073 AM_CONDITIONAL(USE_OPUS, false)
2074 AM_CONDITIONAL(USE_PVR, false)
2075 AM_CONDITIONAL(USE_RSVG, false)
2076 AM_CONDITIONAL(USE_TIMIDITY, false)
2077 AM_CONDITIONAL(USE_WILDMIDI, false)
2078 AM_CONDITIONAL(USE_SDL, false)
2079 AM_CONDITIONAL(USE_SNDFILE, false)
2080 AM_CONDITIONAL(USE_SOUNDTOUCH, false)
2081 AM_CONDITIONAL(USE_SPANDSP, false)
2082 AM_CONDITIONAL(USE_SPC, false)
2083 AM_CONDITIONAL(USE_GME, false)
2084 AM_CONDITIONAL(USE_GSETTINGS, false)
2085 AM_CONDITIONAL(USE_SWFDEC, false)
2086 AM_CONDITIONAL(USE_XVID, false)
2087 AM_CONDITIONAL(USE_DVB, false)
2088 AM_CONDITIONAL(USE_WININET, false)
2089 AM_CONDITIONAL(USE_ACM, false)
2090 AM_CONDITIONAL(USE_VDPAU, false)
2091 AM_CONDITIONAL(USE_SCHRO, false)
2092 AM_CONDITIONAL(USE_ZBAR, false)
2093 AM_CONDITIONAL(USE_RTMP, false)
2094 AM_CONDITIONAL(USE_TELETEXTDEC, false)
2095 AM_CONDITIONAL(USE_SNDIO, false)
2096 AM_CONDITIONAL(USE_UVCH264, false)
2097
2098 fi dnl of EXT plugins
2099
2100 dnl *** finalize CFLAGS, LDFLAGS, LIBS
2101
2102 dnl Overview:
2103 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
2104 dnl GST_*:              flags shared by built objects to link against GStreamer
2105 dnl GST_ALL_LDFLAGS:    linker flags shared by all
2106 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
2107 dnl GST_LT_LDFLAGS:     library versioning of our libraries
2108 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
2109
2110 dnl GST_OPTION_CFLAGS
2111 if test "x$USE_DEBUG" = xyes; then
2112    PROFILE_CFLAGS="-g"
2113 fi
2114 AC_SUBST(PROFILE_CFLAGS)
2115
2116 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
2117   dnl Define _only_ during CVS (not pre-releases or releases)
2118   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
2119 else
2120   DEPRECATED_CFLAGS=""
2121 fi
2122 AC_SUBST(DEPRECATED_CFLAGS)
2123
2124 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
2125 dnl at make time with e.g. make ERROR_CFLAGS=""
2126 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
2127 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
2128 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
2129 AC_SUBST(GST_OPTION_CFLAGS)
2130 AC_SUBST(GST_OPTION_CXXFLAGS)
2131 AC_SUBST(GST_OPTION_OBJCFLAGS)
2132
2133 dnl FIXME: do we want to rename to GST_ALL_* ?
2134 dnl prefer internal headers to already installed ones
2135 dnl also add builddir include for enumtypes and marshal
2136 dnl add GST_OPTION_CFLAGS, but overridable
2137 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
2138 GST_CXXFLAGS="$GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
2139 GST_OBJCFLAGS="$GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
2140 GST_CFLAGS="$GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
2141 AC_SUBST(GST_CFLAGS)
2142 AC_SUBST(GST_CXXFLAGS)
2143 AC_SUBST(GST_OBJCFLAGS)
2144 AC_SUBST(GST_LIBS)
2145 GST_PLUGINS_BAD_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
2146 GST_PLUGINS_BAD_OBJCFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
2147 GST_PLUGINS_BAD_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
2148 AC_SUBST(GST_PLUGINS_BAD_CFLAGS)
2149 AC_SUBST(GST_PLUGINS_BAD_CXXFLAGS)
2150 AC_SUBST(GST_PLUGINS_BAD_OBJCFLAGS)
2151
2152 dnl LDFLAGS really should only contain flags, not libs - they get added before
2153 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
2154 GST_ALL_LDFLAGS="-no-undefined"
2155 AC_SUBST(GST_ALL_LDFLAGS)
2156
2157 dnl GST_LIB_LDFLAGS
2158 dnl linker flags shared by all libraries
2159 dnl LDFLAGS modifier defining exported symbols from built libraries
2160 dnl (export _gst_foo but not __gst_foo)
2161 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
2162 AC_SUBST(GST_LIB_LDFLAGS)
2163
2164 dnl this really should only contain flags, not libs - they get added before
2165 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
2166 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
2167 AC_SUBST(GST_PLUGIN_LDFLAGS)
2168
2169 dnl *** output files ***
2170
2171 dnl po/Makefile.in
2172
2173 AC_CONFIG_FILES(
2174 Makefile
2175 common/Makefile
2176 common/m4/Makefile
2177 gst-plugins-bad.spec
2178 gst/Makefile
2179 gst/accurip/Makefile
2180 gst/adpcmdec/Makefile
2181 gst/adpcmenc/Makefile
2182 gst/aiff/Makefile
2183 gst/asfmux/Makefile
2184 gst/audiovisualizers/Makefile
2185 gst/autoconvert/Makefile
2186 gst/bayer/Makefile
2187 gst/camerabin2/Makefile
2188 gst/cdxaparse/Makefile
2189 gst/coloreffects/Makefile
2190 gst/dataurisrc/Makefile
2191 gst/dccp/Makefile
2192 gst/debugutils/Makefile
2193 gst/dtmf/Makefile
2194 gst/dvbsuboverlay/Makefile
2195 gst/dvdspu/Makefile
2196 gst/faceoverlay/Makefile
2197 gst/festival/Makefile
2198 gst/fieldanalysis/Makefile
2199 gst/freeverb/Makefile
2200 gst/frei0r/Makefile
2201 gst/gaudieffects/Makefile
2202 gst/geometrictransform/Makefile
2203 gst/gdp/Makefile
2204 gst/hdvparse/Makefile
2205 gst/hls/Makefile
2206 gst/id3tag/Makefile
2207 gst/inter/Makefile
2208 gst/interlace/Makefile
2209 gst/ivfparse/Makefile
2210 gst/jp2kdecimator/Makefile
2211 gst/jpegformat/Makefile
2212 gst/librfb/Makefile
2213 gst/liveadder/Makefile
2214 gst/mpegdemux/Makefile
2215 gst/mpegtsdemux/Makefile
2216 gst/mpegtsmux/Makefile
2217 gst/mpegtsmux/tsmux/Makefile
2218 gst/mpegpsmux/Makefile
2219 gst/mve/Makefile
2220 gst/mxf/Makefile
2221 gst/nsf/Makefile
2222 gst/nuvdemux/Makefile
2223 gst/patchdetect/Makefile
2224 gst/pcapparse/Makefile
2225 gst/pnm/Makefile
2226 gst/rawparse/Makefile
2227 gst/real/Makefile
2228 gst/removesilence/Makefile
2229 gst/sdi/Makefile
2230 gst/sdp/Makefile
2231 gst/segmentclip/Makefile
2232 gst/siren/Makefile
2233 gst/smooth/Makefile
2234 gst/speed/Makefile
2235 gst/subenc/Makefile
2236 gst/stereo/Makefile
2237 gst/tta/Makefile
2238 gst/videofilters/Makefile
2239 gst/videomeasure/Makefile
2240 gst/videoparsers/Makefile
2241 gst/videosignal/Makefile
2242 gst/vmnc/Makefile
2243 gst/y4m/Makefile
2244 gst-libs/Makefile
2245 gst-libs/gst/Makefile
2246 gst-libs/gst/basecamerabinsrc/Makefile
2247 gst-libs/gst/interfaces/Makefile
2248 gst-libs/gst/signalprocessor/Makefile
2249 gst-libs/gst/codecparsers/Makefile
2250 gst-libs/gst/video/Makefile
2251 sys/Makefile
2252 sys/dshowdecwrapper/Makefile
2253 sys/acmenc/Makefile
2254 sys/acmmp3dec/Makefile
2255 sys/androidmedia/Makefile
2256 sys/applemedia/Makefile
2257 sys/avc/Makefile
2258 sys/d3dvideosink/Makefile
2259 sys/decklink/Makefile
2260 sys/directdraw/Makefile
2261 sys/directsound/Makefile
2262 sys/dshowsrcwrapper/Makefile
2263 sys/dshowvideosink/Makefile
2264 sys/dvb/Makefile
2265 sys/fbdev/Makefile
2266 sys/linsys/Makefile
2267 sys/opensles/Makefile
2268 sys/osxvideo/Makefile
2269 sys/qtwrapper/Makefile
2270 sys/mfc/Makefile
2271 sys/shm/Makefile
2272 sys/uvch264/Makefile
2273 sys/vcd/Makefile
2274 sys/vdpau/Makefile
2275 sys/vdpau/gstvdp/Makefile
2276 sys/vdpau/basevideodecoder/Makefile
2277 sys/pvr2d/Makefile
2278 sys/wasapi/Makefile
2279 sys/wininet/Makefile
2280 sys/winks/Makefile
2281 sys/winscreencap/Makefile
2282 tests/Makefile
2283 tests/check/Makefile
2284 tests/files/Makefile
2285 tests/examples/Makefile
2286 tests/examples/camerabin2/Makefile
2287 tests/examples/directfb/Makefile
2288 tests/examples/mxf/Makefile
2289 tests/examples/opencv/Makefile
2290 tests/examples/uvch264/Makefile
2291 tests/icles/Makefile
2292 ext/voamrwbenc/Makefile
2293 ext/voaacenc/Makefile
2294 ext/assrender/Makefile
2295 ext/apexsink/Makefile
2296 ext/bz2/Makefile
2297 ext/cdaudio/Makefile
2298 ext/celt/Makefile
2299 ext/chromaprint/Makefile
2300 ext/cog/Makefile
2301 ext/curl/Makefile
2302 ext/dc1394/Makefile
2303 ext/dirac/Makefile
2304 ext/directfb/Makefile
2305 ext/wayland/Makefile
2306 ext/dts/Makefile
2307 ext/eglgles/Makefile
2308 ext/faac/Makefile
2309 ext/faad/Makefile
2310 ext/flite/Makefile
2311 ext/gsm/Makefile
2312 ext/kate/Makefile
2313 ext/ladspa/Makefile
2314 ext/lv2/Makefile
2315 ext/libmms/Makefile
2316 ext/Makefile
2317 ext/modplug/Makefile
2318 ext/mpeg2enc/Makefile
2319 ext/mpg123/Makefile
2320 ext/mimic/Makefile
2321 ext/mplex/Makefile
2322 ext/musepack/Makefile
2323 ext/musicbrainz/Makefile
2324 ext/mythtv/Makefile
2325 ext/nas/Makefile
2326 ext/neon/Makefile
2327 ext/ofa/Makefile
2328 ext/openal/Makefile
2329 ext/opencv/Makefile
2330 ext/openjpeg/Makefile
2331 ext/opus/Makefile
2332 ext/rsvg/Makefile
2333 ext/resindvd/Makefile
2334 ext/rtmp/Makefile
2335 ext/schroedinger/Makefile
2336 ext/sdl/Makefile
2337 ext/sndfile/Makefile
2338 ext/soundtouch/Makefile
2339 ext/spandsp/Makefile
2340 ext/sndio/Makefile
2341 ext/teletextdec/Makefile
2342 ext/gme/Makefile
2343 ext/gsettings/Makefile
2344 ext/gsettings/org.freedesktop.gstreamer.default-elements.gschema.xml
2345 ext/spc/Makefile
2346 ext/swfdec/Makefile
2347 ext/timidity/Makefile
2348 ext/xvid/Makefile
2349 ext/zbar/Makefile
2350 po/Makefile.in
2351 docs/Makefile
2352 docs/plugins/Makefile
2353 docs/libs/Makefile
2354 docs/version.entities
2355 pkgconfig/Makefile
2356 pkgconfig/gstreamer-plugins-bad.pc
2357 pkgconfig/gstreamer-plugins-bad-uninstalled.pc
2358 pkgconfig/gstreamer-codecparsers.pc
2359 pkgconfig/gstreamer-codecparsers-uninstalled.pc
2360 pkgconfig/gstreamer-basevideo.pc
2361 pkgconfig/gstreamer-basevideo-uninstalled.pc
2362 tools/Makefile
2363 m4/Makefile
2364 win32/common/config.h
2365 )
2366 AC_OUTPUT
2367
2368 AG_GST_OUTPUT_PLUGINS
2369 ORC_OUTPUT
2370