configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Bad Plug-ins, 0.10.7.2,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-plugins-bad)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([docs/plugins/gst-plugins-bad-plugins-docs.sgml])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$GST_PLUGINS_BAD_VERSION_MAJOR.$GST_PLUGINS_BAD_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl FIXME: this macro doesn't actually work;
  40 dnl the generated libtool script has no support for the listed tags.
  41 dnl So this needs to be fixed first if we want to use this
  42 dnl AS_LIBTOOL_TAGS([CXX])
  43
  44 AC_LIBTOOL_WIN32_DLL
  45 AM_PROG_LIBTOOL
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=0.10.20
  49 GSTPB_REQ=0.10.20
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION([0.11.5])
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-bad-$GST_MAJORMINOR])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DEBUG
  68 AG_GST_ARG_PROFILING
  69 AG_GST_ARG_VALGRIND
  70 AG_GST_ARG_GCOV
  71
  72 AG_GST_ARG_EXAMPLES
  73
  74 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  75 AG_GST_ARG_WITH_PACKAGE_NAME
  76 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  77
  78 AG_GST_ARG_WITH_PLUGINS
  79
  80 AG_GST_ARG_ENABLE_EXTERNAL
  81
  82 AG_GST_ARG_ENABLE_EXPERIMENTAL
  83
  84 dnl *** checks for platform ***
  85
  86 dnl * hardware/architecture *
  87
  88 dnl common/m4/gst-arch.m4
  89 dnl check CPU type
  90 AG_GST_ARCH
  91
  92 dnl Determine endianness
  93 AC_C_BIGENDIAN
  94
  95 dnl *** checks for programs ***
  96
  97 dnl find a compiler
  98 AC_PROG_CC
  99
 100 dnl determine c++ compiler
 101 AC_PROG_CXX
 102 dnl determine if c++ is available on this system
 103 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 104
 105 AS_PROG_OBJC
 106
 107 dnl check if the compiler supports '-c' and '-o' options
 108 AM_PROG_CC_C_O
 109
 110 dnl check if the compiler supports do while(0) macros
 111 AG_GST_CHECK_DOWHILE_MACROS
 112
 113 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 114 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 115
 116 dnl check for documentation tools
 117 GTK_DOC_CHECK([1.3])
 118 AS_PATH_PYTHON([2.1])
 119 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 120
 121 dnl *** checks for libraries ***
 122
 123 dnl check for libm, for sin() etc.
 124 AC_CHECK_LIBM
 125 AC_SUBST(LIBM)
 126
 127 dnl *** checks for header files ***
 128
 129 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 130 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 131
 132 if test "x$HAVE_UNISTD_H" != "xyes"; then
 133   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 134 fi
 135
 136 dnl used by ext/dts
 137 AX_CREATE_STDINT_H
 138
 139 dnl *** checks for types/defines ***
 140
 141 dnl *** checks for structures ***
 142
 143 dnl *** checks for compiler characteristics ***
 144 dnl check if we have GCC inline-asm
 145 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 146 if test x$HAVE_GCC_ASM = xyes ; then
 147   AC_DEFINE(HAVE_GCC_ASM, 1,
 148     [Define if compiler supports gcc inline assembly])
 149 fi
 150 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 151
 152 dnl *** checks for library functions ***
 153
 154 dnl *** checks for dependency libraries ***
 155
 156 dnl GLib is required
 157 AG_GST_GLIB_CHECK([2.6])
 158
 159 dnl liboil is required
 160 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 161 if test "x$HAVE_LIBOIL" != "xyes"; then
 162   AC_ERROR([liboil-0.3.8 or later is required])
 163 fi
 164
 165 dnl checks for gstreamer
 166 dnl uninstalled is selected preferentially -- see pkg-config(1)
 167 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 168 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 169 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 170 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 171 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 172 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 173 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 174
 175 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 176 AC_SUBST(GSTPB_PLUGINS_DIR)
 177 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 178
 179 dnl Check for documentation xrefs
 180 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 181 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 182 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 183 AC_SUBST(GLIB_PREFIX)
 184 AC_SUBST(GST_PREFIX)
 185 AC_SUBST(GSTPB_PREFIX)
 186
 187 dnl GTK is optional and used in examples
 188 HAVE_GTK=NO
 189 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 190 if test "x$HAVE_GTK_22" = "xyes"; then
 191   HAVE_GTK=yes
 192   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 193   AC_SUBST(GTK_VERSION)
 194   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 195   AC_SUBST(GTK_BASE_DIR)
 196   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 197   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 198   AC_SUBST(GTK_BASE_DIR)
 199 else
 200   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 201 fi
 202 if test "x$HAVE_GTK_20" = "xyes"; then
 203   HAVE_GTK=yes
 204 fi
 205 GTK_CFLAGS=$GTK2_CFLAGS
 206 GTK_LIBS=$GTK2_LIBS
 207 AC_SUBST(GTK_LIBS)
 208 AC_SUBST(GTK_CFLAGS)
 209 AC_SUBST(HAVE_GTK)
 210 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 211
 212 dnl libglade is optional and only used in examples
 213 HAVE_GLADE=NO
 214 PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0, HAVE_GLADE=yes, HAVE_GLADE=no)
 215 AC_SUBST(GLADE_LIBS)
 216 AC_SUBST(GLADE_CFLAGS)
 217 AC_SUBST(HAVE_GLADE)
 218 AM_CONDITIONAL(HAVE_GLADE, test "x$HAVE_GLADE" = "xyes")
 219
 220 dnl set license and copyright notice
 221 GST_LICENSE="LGPL"
 222 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 223 AC_SUBST(GST_LICENSE)
 224
 225 dnl set location of plugin directory
 226 AG_GST_SET_PLUGINDIR
 227
 228 dnl define an ERROR_CFLAGS Makefile variable
 229 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 230
 231 dnl define an ERROR_CXXFLAGS Makefile variable
 232 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 233
 234 dnl define correct level for debugging messages
 235 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 236
 237 dnl *** plug-ins to include ***
 238
 239 dnl these are all the gst plug-ins, compilable without additional libs
 240 AG_GST_CHECK_PLUGIN(app)
 241 AG_GST_CHECK_PLUGIN(bayer)
 242 AG_GST_CHECK_PLUGIN(cdxaparse)
 243 AG_GST_CHECK_PLUGIN(deinterlace)
 244 AG_GST_CHECK_PLUGIN(deinterlace2)
 245 AG_GST_CHECK_PLUGIN(dvdspu)
 246 AG_GST_CHECK_PLUGIN(festival)
 247 AG_GST_CHECK_PLUGIN(filter)
 248 AG_GST_CHECK_PLUGIN(flv)
 249 AG_GST_CHECK_PLUGIN(freeze)
 250 AG_GST_CHECK_PLUGIN(h264parse)
 251 AG_GST_CHECK_PLUGIN(librfb)
 252 AG_GST_CHECK_PLUGIN(modplug)
 253 AG_GST_CHECK_PLUGIN(mpegtsparse)
 254 AG_GST_CHECK_PLUGIN(mpeg4videoparse)
 255 AG_GST_CHECK_PLUGIN(mpegvideoparse)
 256 AG_GST_CHECK_PLUGIN(mve)
 257 AG_GST_CHECK_PLUGIN(nsf)
 258 AG_GST_CHECK_PLUGIN(nuvdemux)
 259 AG_GST_CHECK_PLUGIN(rawparse)
 260 AG_GST_CHECK_PLUGIN(real)
 261 AG_GST_CHECK_PLUGIN(rtpmanager)
 262 AG_GST_CHECK_PLUGIN(sdp)
 263 AG_GST_CHECK_PLUGIN(selector)
 264 AG_GST_CHECK_PLUGIN(speed)
 265 AG_GST_CHECK_PLUGIN(speexresample)
 266 AG_GST_CHECK_PLUGIN(subenc)
 267 AG_GST_CHECK_PLUGIN(stereo)
 268 AG_GST_CHECK_PLUGIN(tta)
 269 AG_GST_CHECK_PLUGIN(videosignal)
 270 AG_GST_CHECK_PLUGIN(vmnc)
 271 AG_GST_CHECK_PLUGIN(y4m)
 272
 273 dnl *** plug-ins to exclude ***
 274
 275 dnl see if we can build C++ plug-ins
 276 if test "x$HAVE_CXX" != "xyes"; then
 277   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 278   AG_GST_DISABLE_PLUGIN(modplug)
 279 fi
 280
 281 dnl real plugin only works on i386 and x86_64 for the time being.
 282 if test "x$HAVE_CPU_I386" != "xyes" && test "x$HAVE_CPU_X86_64" != "xyes"; then
 283   AC_MSG_WARN([Not building real plugin, only works on 32bit and 64bit x86 platforms])
 284   AG_GST_DISABLE_PLUGIN(real)
 285 fi
 286
 287 dnl disable experimental plug-ins
 288 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 289   AG_GST_DISABLE_PLUGIN(deinterlace2)
 290 fi
 291
 292 dnl disable gst plugins we might not be able to build on this
 293 dnl platform: librfb (ugly but minimally invasive)
 294 dnl FIXME: maybe move to sys, or make work with winsock2
 295 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 296 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 297
 298 dnl needed for festival
 299 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 300
 301 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 302   AG_GST_DISABLE_PLUGIN(librfb)
 303 fi
 304
 305 dnl *** sys plug-ins ***
 306
 307 dnl check for QuickTime
 308 translit(dnm, m, l) AM_CONDITIONAL(USE_QUICKTIME, true)
 309 AG_GST_CHECK_FEATURE(QUICKTIME, [QuickTime wrapper], qtwrapper, [
 310   AC_CHECK_HEADER(QuickTime/Movies.h, HAVE_QUICKTIME="yes", HAVE_QUICKTIME="no")
 311 ])
 312
 313 dnl check for Video CD
 314 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 315 AG_GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 316   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 317 ])
 318
 319 dnl *** ext plug-ins ***
 320 dnl keep this list sorted alphabetically !
 321
 322 if test "x$BUILD_EXTERNAL" = "xyes"; then
 323
 324 dnl *** alsa ***
 325 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 326 AG_GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 327   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 328     HAVE_ALSA="yes"
 329     AC_SUBST(ALSA_CFLAGS)
 330     AC_SUBST(ALSA_LIBS)
 331   ], [
 332     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 333   ])
 334 ])
 335
 336 dnl *** amrwb ***
 337 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 338 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwb, [
 339   AG_GST_CHECK_LIBHEADER(AMRWB, amrwb,
 340                         GP3D_IF_decode, ,
 341                         amrwb/dec.h,
 342                         AMRWB_LIBS="-lamrwb"
 343                         AC_SUBST(AMRWB_LIBS))
 344 ])
 345
 346 dnl *** BZ2 ***
 347 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 348 AG_GST_CHECK_FEATURE(BZ2, [bz2 library], bz2, [
 349   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 350   AC_SUBST(BZ2_LIBS)
 351 ])
 352
 353 #dnl *** cairo ***
 354 #translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 355 #AG_GST_CHECK_FEATURE(CAIRO, [cairo plug-in], cairo, [
 356 #  PKG_CHECK_MODULES(CAIRO, cairo >= 1.0 glitz-glx, HAVE_CAIRO=yes, [
 357 #    HAVE_CAIRO=no
 358 #    AC_MSG_RESULT(no)
 359 #  ])
 360 #  AC_SUBST(CAIRO_CFLAGS)
 361 #  AC_SUBST(CAIRO_LIBS)
 362 #])
 363
 364 dnl *** cdaudio ***
 365 translit(dnm, m, l) AM_CONDITIONAL(USE_CDAUDIO, true)
 366 AG_GST_CHECK_FEATURE(CDAUDIO, [cdaudio], cdaudio, [
 367   AG_GST_CHECK_CONFIGPROG(CDAUDIO, libcdaudio-config)
 368   AC_SUBST(CDAUDIO_CFLAGS)
 369   AC_SUBST(CDAUDIO_LIBS)
 370 ])
 371
 372
 373 dnl *** dc1394  ***
 374 translit(dnm, m, l) AM_CONDITIONAL(USE_DC1394, true)
 375 AG_GST_CHECK_FEATURE(DC1394, [libdc1394], dc1394, [
 376    PKG_CHECK_MODULES(LIBDC1394, libdc1394-2 >= 2.0.0, [
 377         if test -z "`pkg-config --modversion libdc1394-2 | grep 2.0.0-rc`"; then
 378                 HAVE_DC1394="yes"
 379         else
 380                 HAVE_DC1394="no"
 381                 AC_MSG_RESULT(no)
 382         fi
 383    ], [
 384         HAVE_DC1394="no"
 385         AC_MSG_RESULT(no)
 386    ])
 387    AC_SUBST(LIBDC1394_CFLAGS)
 388    AC_SUBST(LIBDC1394_LIBS)
 389 ])
 390
 391
 392 dnl **** DirectFB ****
 393 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTFB, true)
 394 AG_GST_CHECK_FEATURE(DIRECTFB, [directfb], dfbvideosink , [
 395   PKG_CHECK_MODULES(DIRECTFB, directfb >= 0.9.24, HAVE_DIRECTFB="yes", [
 396     HAVE_DIRECTFB="no"
 397     AC_MSG_RESULT(no)
 398   ])
 399 ])
 400
 401 dnl **** Dirac ****
 402 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRAC, true)
 403 AG_GST_CHECK_FEATURE(DIRAC, [dirac], dirac, [
 404   PKG_CHECK_MODULES(DIRAC, dirac >= 0.10, HAVE_DIRAC="yes", [
 405     HAVE_DIRAC="no"
 406     AC_MSG_RESULT(no)
 407   ])
 408 ])
 409
 410 dnl *** DTS ***
 411 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
 412 AG_GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
 413   HAVE_DTS="yes"
 414   AG_GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, -lm, dts.h,
 415     DTS_LIBS="-ldts_pic -lm", HAVE_DTS="no")
 416   if test $HAVE_DTS = "no"; then
 417     AG_GST_CHECK_LIBHEADER(DTS, dca, dca_init, -lm, dts.h,
 418       DTS_LIBS="-ldca -lm")
 419   fi
 420   AC_SUBST(DTS_LIBS)
 421 ])
 422
 423 dnl *** DIVX ***
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 425 AG_GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 426   HAVE_DIVX=yes
 427   AC_CHECK_HEADER(encore2.h, , [
 428     AC_MSG_WARN([Divx4linux encore headers not found])
 429     HAVE_DIVX=no
 430   ])
 431   if [ test x$HAVE_DIVX = xyes ]; then
 432     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 433     AC_TRY_COMPILE([
 434 #include <encore2.h>
 435 #if ENCORE_VERSION != 20021024
 436 #error Wrong version of divx encore libraries
 437 #endif
 438     ], [
 439 return 0;
 440     ], [
 441       HAVE_DIVX=yes
 442       AC_MSG_RESULT(yes)
 443     ], [
 444       HAVE_DIVX=no
 445       AC_MSG_RESULT(no)
 446       AC_MSG_WARN([Wrong version of divx4linux installed])
 447     ])
 448   fi
 449   if [ test x$HAVE_DIVX = xyes ]; then
 450     AC_CHECK_HEADER(decore.h, , [
 451       AC_MSG_WARN([Divx4linux decoder headers not found])
 452       HAVE_DIVX=no
 453     ])
 454   fi
 455   if [ test x$HAVE_DIVX = xyes ]; then
 456     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 457     AC_TRY_COMPILE([
 458 #include <decore.h>
 459 #if DECORE_VERSION != 20021112
 460 #error Wrong version of divx decore libraries
 461 #endif
 462     ], [
 463 return 0;
 464     ], [
 465       HAVE_DIVX=yes
 466       AC_MSG_RESULT(yes)
 467     ], [
 468       HAVE_DIVX=no
 469       AC_MSG_RESULT(no)
 470       AC_MSG_WARN([Wrong version of divx4linux installed])
 471     ])
 472   fi
 473   LIBS="-lm"
 474   if test x$HAVE_DIVX = xyes; then
 475     AC_CHECK_LIB(divxencore, encore, , [
 476       AC_MSG_WARN([Divx4linux encore libs not found])
 477       HAVE_DIVX=no
 478     ])
 479   fi
 480   if test x$HAVE_DIVX = xyes; then
 481     AC_CHECK_LIB(divxdecore, decore, , [
 482       AC_MSG_WARN([Divx4linux decore libs not found])
 483       HAVE_DIVX=no
 484   ])
 485   fi
 486   if test x$HAVE_DIVX = xyes; then
 487     DIVXENC_LIBS="-ldivxencore -lm"
 488     DIVXDEC_LIBS="-ldivxdecore -lm"
 489     AC_SUBST(DIVXENC_LIBS)
 490     AC_SUBST(DIVXDEC_LIBS)
 491   fi
 492 ])
 493
 494 dnl *** dvdnav for resindvd ***
 495 USE_DVDNAV=$BUILD_EXPERIMENTAL
 496 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 497 AG_GST_CHECK_FEATURE(DVDNAV, [dvdnav library], resindvd, [
 498   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 499   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 500   AG_GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 501   if test x"$HAVE_DVDNAV" = x"yes"; then
 502     dnl check version
 503     DVDNAV_VERSION=`dvdnav-config --version|head -n 1|sed 's/^.*) //'|sed 's/ (.*)//'`
 504     DVDNAV_MAJOR=`echo $DVDNAV_VERSION | cut -d. -f1 | sed s/[a-zA-Z\-].*//g`
 505     DVDNAV_MINOR=`echo $DVDNAV_VERSION | cut -d. -f2 | sed s/[a-zA-Z\-].*//g`
 506     DVDNAV_MICRO=`echo $DVDNAV_VERSION | cut -d. -f3 | sed s/[a-zA-Z\-].*//g`
 507     if [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 508        [[ "$DVDNAV_MINOR" -lt "1" ]]; then
 509       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 510       HAVE_DVDNAV="no"
 511     elif [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 512          [[ "$DVDNAV_MINOR" -eq "1" ]] && \
 513          [[ "$DVDNAV_MICRO" -lt "7" ]]; then
 514       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 515       HAVE_DVDNAV="no"
 516     elif [[ "$DVDNAV_MAJOR" -eq "0" ]]; then
 517       AC_DEFINE(DVDNAV_OLD, 1, [Define if an old libdvdnav is used])
 518     fi
 519   fi
 520   dnl now check for dvdread/nav_print.h - see #133002
 521   AC_CHECK_HEADER(dvdread/nav_print.h, , [
 522       AC_MSG_WARN([header dvdread/nav_print.h from dvdread missing])
 523       HAVE_DVDNAV="no"
 524   ], [ #include "_stdint.h" ])
 525   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 526 ])
 527
 528 dnl *** METADATA ***
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_METADATA, true)
 530 AG_GST_CHECK_FEATURE(METADATA, [METADATA muxer and demuxer], metadata, [
 531   HAVE_METADATA="no"
 532   PKG_CHECK_MODULES(EXIF, libexif >= 0.6.16, HAVE_EXIF="yes", [
 533     HAVE_EXIF="no"
 534   ])
 535   PKG_CHECK_MODULES(IPTC, libiptcdata >= 1.0.2, HAVE_IPTC="yes", [
 536     HAVE_IPTC="no"
 537   ])
 538   PKG_CHECK_MODULES(XMP, exempi-2.0, HAVE_XMP="yes", [
 539     HAVE_XMP="no"
 540   ])
 541   PKG_CHECK_MODULES(XMP_1_99_5, exempi-2.0 >= 1.99.5, XMP_CFLAGS="-DXMP_1_99_5 $XMP_CFLAGS", AC_MSG_RESULT(no))
 542   if test x$HAVE_EXIF = xyes; then
 543     METADATA_CFLAGS="-DHAVE_EXIF $EXIF_CFLAGS $METADATA_CFLAGS"
 544     METADATA_LIBS="$EXIF_LIBS $METADATA_LIBS -lm"
 545     HAVE_METADATA="yes"
 546   fi
 547   if test x$HAVE_IPTC = xyes; then
 548     METADATA_CFLAGS="-DHAVE_IPTC $IPTC_CFLAGS $METADATA_CFLAGS"
 549     METADATA_LIBS="$IPTC_LIBS $METADATA_LIBS"
 550     HAVE_METADATA="yes"
 551   fi
 552   if test x$HAVE_XMP = xyes; then
 553     METADATA_CFLAGS="-DHAVE_XMP $XMP_CFLAGS $METADATA_CFLAGS"
 554     METADATA_LIBS="$XMP_LIBS $METADATA_LIBS"
 555     HAVE_METADATA="yes"
 556   fi
 557   if test x$HAVE_METADATA = xno; then
 558     AC_MSG_WARN(no of metadata libraries (exif, iptc or xmp) found)
 559   fi
 560   dnl metadata plugin will parse whole chunks anyway
 561   HAVE_METADATA="yes"
 562   AC_SUBST(METADATA_CFLAGS)
 563   AC_SUBST(METADATA_LIBS)
 564 ])
 565
 566 dnl **** Free AAC Encoder (FAAC) ****
 567 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 568 AG_GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 569   AG_GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h,
 570     FAAC_LIBS="-lfaac -lm")
 571   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 572   AC_SUBST(FAAC_LIBS)
 573 ])
 574
 575 dnl **** Free AAC Decoder (FAAD) ****
 576 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 577 AG_GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 578   HAVE_FAAD="yes"
 579   AG_GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h,
 580     FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 581   if test $HAVE_FAAD = "no"; then
 582     AG_GST_CHECK_LIBHEADER(FAAD, faad, NeAACDecOpen, -lm, neaacdec.h,
 583       [ FAAD_LIBS="-lfaad -lm"
 584                 AC_DEFINE(FAAD_IS_NEAAC, 1, [Define if AAC is using new api prefix])
 585           ],
 586           HAVE_FAAD="no",)
 587   fi
 588   if test $HAVE_FAAD = "yes"; then
 589     AC_MSG_CHECKING([Checking for FAAD >= 2.0])
 590     AC_TRY_COMPILE([#include <faad.h>], [
 591         #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 592         #error Not faad2
 593         #else
 594         /* Release candidate of 2.0 is not good enough for us. This field
 595          * was added only in 2.0 final and does not exist in 2.0-RC3 */
 596         faacDecConfiguration conf; conf.dontUpSampleImplicitSBR = 1;
 597         #endif
 598     ], [
 599       HAVE_FAAD="yes"
 600       AC_MSG_RESULT(yes)
 601     ], [
 602       HAVE_FAAD="no"
 603       AC_MSG_RESULT(no)
 604     ])
 605   fi
 606   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 607   AC_SUBST(FAAD_LIBS)
 608   AC_SUBST(FAAD_IS_NEAAC)
 609 ])
 610
 611 dnl *** fbdev ***
 612 translit(dnm, m, l) AM_CONDITIONAL(USE_FBDEV, true)
 613 AG_GST_CHECK_FEATURE(FBDEV, [linux framebuffer], fbdevsink, [
 614   if test "x$HAVE_FBDEV" != "xyes"; then
 615     AC_CHECK_HEADER([linux/fb.h], HAVE_FBDEV=yes, HAVE_FBDEV=no)
 616   fi
 617 ])
 618
 619 dnl *** gsm ***
 620 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 621 AG_GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 622   AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 623   if test $HAVE_GSM != "yes"; then
 624     AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 625     if test $HAVE_GSM = "yes"; then
 626       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 627     fi
 628   fi
 629   AC_SUBST(GSM_LIBS)
 630 ])
 631
 632 dnl *** ivorbis ***
 633 dnl AM_PATH_IVORBIS only takes two options
 634 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 635 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 636   IVORBIS_LIBS=
 637   IVORBIS_CFLAGS=
 638   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 639     [IVORBIS_LIBS=-lvorbisidec
 640      HAVE_IVORBIS=yes
 641      case $host in
 642      arm-*-*)
 643        IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 644      esac
 645     ],
 646     HAVE_IVORBIS=no)
 647   AC_SUBST(IVORBIS_LIBS)
 648   AC_SUBST(IVORBIS_CFLAGS)
 649 ])
 650
 651 dnl *** Jack ***
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 653 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 654   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 655   AC_SUBST(JACK_CFLAGS)
 656   AC_SUBST(JACK_LIBS)
 657 ])
 658
 659 dnl *** ladspa ***
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 661 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 662   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 663   save_cflags="$CFLAGS"
 664   CFLAGS="$CFLAGS -D_GNU_SOURCE"
 665
 666   AC_CHECK_LIB(dl, dlopen,
 667     LADSPA_LIBS="-ldl",
 668     HAVE_LADSPA="no")
 669   CFLAGS="$save_cflags"
 670 ])
 671 AC_SUBST(LADSPA_LIBS)
 672
 673 dnl *** libmms ***
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBMMS, true)
 675 AG_GST_CHECK_FEATURE(LIBMMS, [mms protocol library], libmms, [
 676   dnl check with pkg-config first
 677   PKG_CHECK_MODULES(LIBMMS, libmms >= 0.2, HAVE_LIBMMS="yes", [
 678     HAVE_LIBMMS="no"
 679     AC_MSG_RESULT(no)
 680   ])
 681 ])
 682 AC_SUBST(LIBMMS_LIBS)
 683
 684 dnl *** mjpegtools version info ***
 685 dnl some may prefer older version (given quirks above)
 686 dnl hm, no version info seems available within mjpegtools headers
 687 dnl and API really moves along
 688 echo
 689 PKG_CHECK_EXISTS(mjpegtools >= 1.6.1.93 mjpegtools < 1.8.0, [
 690   mjpegtools_api=10601
 691 ], [
 692   PKG_CHECK_EXISTS(mjpegtools >= 1.8.0 mjpegtools < 1.9.0, [
 693     mjpegtools_api=10800
 694   ], [
 695     PKG_CHECK_MODULES(MJPEG, mjpegtools >= 1.9.0, [
 696       dnl logging API changed in release candidates
 697       OLD_CFLAGS="$CFLAGS"
 698       OLD_LIBS="$LIBS"
 699       CFLAGS="$MJPEG_CFLAGS"
 700       LIBS="$LIBS $MJPEG_LIBS -lmjpegutils -lm -lpthread"
 701       AC_CHECK_FUNC(mjpeg_loglev_t, [
 702         mjpegtools_api=10903
 703         ], [
 704         mjpegtools_api=10900
 705         ])
 706       CFLAGS="$OLD_CFLAGS"
 707       LIBS="$OLD_LIBS"
 708     ], [
 709       mjpegtools_api=0
 710     ])
 711   ])
 712 ])
 713 AC_DEFINE_UNQUOTED(GST_MJPEGTOOLS_API, $mjpegtools_api,
 714   [mjpegtools API evolution])
 715
 716 dnl *** mpeg2enc ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
 718 AG_GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
 719   HAVE_MPEG2ENC="no"
 720   dnl we require a c++ compiler for this one
 721   if [ test x$HAVE_CXX = xyes ]; then
 722     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
 723     dnl since many distros include mjpegtools specifically without mplex
 724     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
 725     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
 726       dnl HACK because mpeg2enc 1.8.0 header files have a spurious 'include config.h'
 727       touch config.h
 728       dnl switch over to c++ to test things
 729       AC_LANG_CPLUSPLUS
 730       OLD_CPPFLAGS="$CPPFLAGS"
 731       dnl HACK as above
 732       CPPFLAGS_GOOD="$CPPFLAGS $MPEG2ENC_CFLAGS"
 733       CPPFLAGS="$CPPFLAGS_GOOD -I."
 734       dnl check headers
 735       mpeg2enc_headers_ok=no
 736       AC_CHECK_HEADER([mpeg2encoder.hh], [
 737         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
 738         OLD_LIBS="$LIBS"
 739         LIBS="$LIBS $MPEG2ENC_LIBS"
 740         AC_MSG_CHECKING([for valid mpeg2enc objects])
 741         AC_TRY_RUN([
 742           #include <mpeg2encoder.hh>
 743           #include <mpeg2encoptions.hh>
 744
 745           int
 746           main (int   argc,
 747                 char *argv[])
 748           {
 749             MPEG2EncOptions *options = new MPEG2EncOptions ();
 750             MPEG2Encoder *encoder = new MPEG2Encoder (*options);
 751             return 0;
 752           }
 753         ],[
 754           AC_MSG_RESULT(yes)
 755           dnl so far so good, let's check more things:
 756           dnl mjpegtools-1.8.0 does not install the required
 757           dnl mpeg2syntaxcodes.h header by default, and a new release
 758           dnl is not in sight, so check for this oversight in case
 759           dnl distros or folks have fixed this themselves
 760           if test "$mjpegtools_api" -ge "10800"; then
 761             AC_CHECK_HEADER([mpeg2syntaxcodes.h], [
 762                 mpeg2enc_headers_ok=yes
 763               ], [
 764                 mpeg2enc_headers_ok=no
 765               ])
 766           else
 767             mpeg2enc_headers_ok=yes
 768           fi
 769           if test "x$mpeg2enc_headers_ok" = "xyes"; then
 770             HAVE_MPEG2ENC="yes"
 771           fi
 772           CPP_FLAGS="$CPPFLAGS_GOOD"
 773           AC_SUBST(MPEG2ENC_CFLAGS)
 774           AC_SUBST(MPEG2ENC_LIBS)
 775         ], [
 776           AC_MSG_RESULT(no)
 777         ])
 778         LIBS="$OLD_LIBS"
 779       ])
 780
 781       CPPFLAGS="$OLD_CPPFLAGS"
 782       AC_LANG_C
 783     ], [
 784       HAVE_MPEG2ENC="no"
 785     ])
 786   fi
 787 ])
 788
 789 dnl *** mplex ***
 790 translit(dnm, m, l) AM_CONDITIONAL(USE_MPLEX, true)
 791 AG_GST_CHECK_FEATURE(MPLEX, [mplex], mplex, [
 792   HAVE_MPLEX="no"
 793   dnl we require a c++ compiler for this one
 794   if [ test x$HAVE_CXX = xyes ]; then
 795     dnl libmplex was first included in mjpegtools-1.6.2-rc4 (1.6.1.93)
 796     dnl since many distros include mjpegtools specifically without mplex
 797     dnl and mpeg2enc, we check for mplex on its own, too.
 798     dnl libmplex < 1.9rc? has fuzzy ABI, valgrind and other problems
 799     PKG_CHECK_MODULES(MPLEX, mjpegtools >= 1.9.0, [
 800       dnl switch over to c++ to test things
 801       AC_LANG_CPLUSPLUS
 802       OLD_CPPFLAGS="$CPPFLAGS"
 803       CPPFLAGS="$CPPFLAGS $MPLEX_CFLAGS"
 804       AC_CHECK_HEADER(interact.hpp, [
 805         MPLEX_LIBS="$MPLEX_LIBS -lmplex2 -lm"
 806         OLD_LIBS="$LIBS"
 807         LIBS="$LIBS $MPLEX_LIBS"
 808         dnl older libmplex uses off_t SegmentSize (), which leads to fuzzy ABI;
 809         dnl don't want this here
 810         AC_MSG_CHECKING([for valid mplex objects])
 811         AC_TRY_RUN([
 812
 813 #include <interact.hpp>
 814 #include <outputstrm.hpp>
 815 #include <multiplexor.hpp>
 816 int
 817 main (int   argc,
 818       char *argv[])
 819 {
 820   class TestOutputStream : public OutputStream {
 821   public:
 822     TestOutputStream () : OutputStream () { }
 823     void Write (uint8_t *a, unsigned int b) { }
 824     void NextSegment () { }
 825     uint64_t SegmentSize () { }
 826     void Close () { }
 827     int Open () { }
 828 };
 829   MultiplexJob *job = new MultiplexJob ();
 830   vector<IBitStream *> inputs;
 831   job->SetupInputStreams (inputs);
 832   TestOutputStream *out = new TestOutputStream ();
 833   Multiplexor *mux = new Multiplexor(*job, *out, NULL);
 834   return 0;
 835 }
 836         ],[
 837           HAVE_MPLEX="yes"
 838           AC_SUBST(MPLEX_CFLAGS)
 839           AC_SUBST(MPLEX_LIBS)
 840           AC_MSG_RESULT(yes)
 841         ], AC_MSG_RESULT(no))
 842         LIBS="$OLD_LIBS"
 843       ])
 844       CPPFLAGS="$OLD_CPPFLAGS"
 845       AC_LANG_C
 846     ], HAVE_MPLEX="no")
 847   fi
 848 ])
 849
 850 dnl *** musepack ***
 851 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSEPACK, true)
 852 AG_GST_CHECK_FEATURE(MUSEPACK, [musepackdec], musepack, [
 853   AC_CHECK_HEADER([mpc/mpcdec.h], [
 854     HAVE_MUSEPACK="yes"
 855     MUSEPACK_LIBS="-lmpcdec"
 856     AC_SUBST(MUSEPACK_LIBS)
 857     ], [AC_CHECK_HEADER([mpcdec/mpcdec.h], [
 858       HAVE_MUSEPACK="yes"
 859       MUSEPACK_LIBS="-lmpcdec"
 860       AC_DEFINE(MPC_IS_OLD_API, 1, [Define if the old MusePack API is used])
 861       AC_SUBST(MUSEPACK_LIBS)
 862     ], [HAVE_MUSEPACK="no"])])
 863 ])
 864
 865 dnl *** musicbrainz ***
 866 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
 867 AG_GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz tag generation], musicbrainz, [
 868   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz >= 2.1.0, HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
 869   AC_SUBST(MUSICBRAINZ_CFLAGS)
 870   AC_SUBST(MUSICBRAINZ_LIBS)
 871 ])
 872
 873 dnl *** MythTV ***
 874 translit(dnm, m, l) AM_CONDITIONAL(USE_MYTHTV, true)
 875 AG_GST_CHECK_FEATURE(MYTHTV, [MythTV client plugins], mythtvsrc, [
 876   PKG_CHECK_MODULES(GMYTH, gmyth >= 0.4 gmyth <= 0.7.99, HAVE_MYTHTV="yes", [
 877     HAVE_MYTHTV="no"
 878     AC_MSG_RESULT(no)
 879   ])
 880   AC_SUBST(GMYTH_CFLAGS)
 881   AC_SUBST(GMYTH_LIBS)
 882 ])
 883
 884 dnl *** nas ***
 885 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
 886 AG_GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
 887   HAVE_NAS="no"
 888   AG_GST_CHECK_X
 889   if test "x$HAVE_X" = "xyes"; then
 890     save_cppflags=$CFLAGS
 891     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 892     AG_GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
 893       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
 894     CPPFLAGS="$save_cppflags"
 895   fi
 896   AC_SUBST(NAS_CFLAGS)
 897   AC_SUBST(NAS_LIBS)
 898 ])
 899
 900 dnl *** neon ***
 901 translit(dnm, m, l) AM_CONDITIONAL(USE_NEON, true)
 902 AG_GST_CHECK_FEATURE(NEON, [neon http client plugins], neonhttpsrc, [
 903   PKG_CHECK_MODULES(NEON, neon >= 0.26.0  neon <= 0.28.99, HAVE_NEON="yes", [
 904     HAVE_NEON="no"
 905     AC_MSG_RESULT(no)
 906   ])
 907   AC_SUBST(NEON_CFLAGS)
 908   AC_SUBST(NEON_LIBS)
 909 ])
 910
 911 dnl *** ofa ***
 912 translit(dnm, m, l) AM_CONDITIONAL(USE_OFA, true)
 913 AG_GST_CHECK_FEATURE(OFA, [ofa plugins], ofa, [
 914   PKG_CHECK_MODULES(OFA, libofa >= 0.9.3, HAVE_OFA="yes", [
 915     HAVE_OFA="no"
 916     AC_MSG_RESULT(no)
 917   ])
 918   AC_SUBST(OFA_CFLAGS)
 919   AC_SUBST(OFA_LIBS)
 920 ])
 921
 922 dnl *** timidity ***
 923 translit(dnm, m, l) AM_CONDITIONAL(USE_TIMIDITY, true)
 924 AG_GST_CHECK_FEATURE(TIMIDITY, [timidity midi soft synth plugin], timidity, [
 925   PKG_CHECK_MODULES(TIMIDITY, libtimidity, [
 926     HAVE_TIMIDITY="yes",
 927         AC_MSG_CHECKING([for timidity.cfg])
 928         timidity_cfg=""
 929         if test -r /etc/timidity.cfg; then
 930           timidity_cfg=/etc/timidity.cfg
 931         elif test -r /etc/timidity/timidity.cfg; then
 932           timidity_cfg=/etc/timidity/timidity.cfg
 933         elif test -r /usr/share/timidity/timidity.cfg; then
 934           timidity_cfg=/usr/share/timidity/timidity.cfg
 935         elif test -r /usr/local/share/timidity/timidity.cfg; then
 936           timidity_cfg=/usr/local/share/timidity/timidity.cfg
 937         fi
 938         if test "x$timidity_cfg" != "x"; then
 939           AC_MSG_RESULT($timidity_cfg)
 940       AC_DEFINE_UNQUOTED(TIMIDITY_CFG, "$timidity_cfg", [Define location of timidity.cfg])
 941         else
 942           AC_MSG_RESULT([not found])
 943         fi
 944   ], [
 945     HAVE_TIMIDITY="no"
 946     AC_MSG_RESULT(no)
 947   ])
 948   AC_SUBST(TIMIDITY_CFLAGS)
 949   AC_SUBST(TIMIDITY_LIBS)
 950 ])
 951
 952 dnl *** wildmidi ***
 953 translit(dnm, m, l) AM_CONDITIONAL(USE_WILDMIDI, true)
 954 AG_GST_CHECK_FEATURE(WILDMIDI, [wildmidi midi soft synth plugin], wildmidi, [
 955   AC_CHECK_HEADER([wildmidi_lib.h],HAVE_WILDMIDI=yes, HAVE_WILDMIDI=no)
 956   if test "x$HAVE_WILDMIDI" = "xyes"; then
 957          WILDMIDI_CFLAGS=
 958          WILDMIDI_LIBS=-lWildMidi
 959          AC_MSG_NOTICE(compiling gstWildMidi)
 960   else
 961          WILDMIDI_CFLAGS=
 962          WILDMIDI_LIBS=
 963          AC_MSG_WARN(no WildMidi library found (libWildMidi))
 964   fi
 965   AC_SUBST(WILDMIDI_CFLAGS)
 966   AC_SUBST(WILDMIDI_LIBS)
 967 ])
 968
 969 dnl *** SDL ***
 970 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
 971 AG_GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink sdlaudiosink, [
 972     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
 973 ])
 974
 975 dnl *** sndfile ***
 976 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
 977 AG_GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
 978   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.16, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
 979   AC_SUBST(SNDFILE_CFLAGS)
 980   AC_SUBST(SNDFILE_LIBS)
 981 ])
 982
 983 dnl *** soundtouch ***
 984 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUNDTOUCH, true)
 985 AG_GST_CHECK_FEATURE(SOUNDTOUCH, [soundtouch plug-in], soundtouch, [
 986   PKG_CHECK_MODULES(SOUNDTOUCH, soundtouch-1.0,
 987     HAVE_SOUNDTOUCH=yes,
 988     [PKG_CHECK_MODULES(SOUNDTOUCH, libSoundTouch,
 989       HAVE_SOUNDTOUCH=yes,
 990       HAVE_SOUNDTOUCH=no)])
 991   AC_SUBST(SOUNDTOUCH_CFLAGS)
 992   AC_SUBST(SOUNDTOUCH_LIBS)
 993   if test "x$HAVE_CXX" != "xyes"; then
 994     USE_SOUNDTOUCH=false
 995     AC_MSG_NOTICE([Not building soundtouch plugin: no C++ compiler found])
 996   fi
 997 ])
 998
 999 dnl *** spc ***
1000 translit(dnm, m, l) AM_CONDITIONAL(USE_SPC, true)
1001 AG_GST_CHECK_FEATURE(SPC, [spc decoder], spc, [
1002   AC_CHECK_HEADER(openspc.h, [
1003     AC_CHECK_LIB(openspc, OSPC_Init, [
1004       SPC_LIBS="-lopenspc"
1005       AC_SUBST(SPC_LIBS)
1006       HAVE_SPC=yes
1007     ], [
1008       HAVE_SPC=no
1009     ])
1010   ], [
1011     HAVE_SPC=no
1012   ])
1013 ])
1014
1015 dnl *** swfdec ***
1016 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
1017 AG_GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
1018   PKG_CHECK_MODULES(SWFDEC, swfdec-0.3 >= 0.3.6, HAVE_SWFDEC=yes, [
1019     HAVE_SWFDEC=no
1020     AC_MSG_RESULT(no)
1021   ])
1022   AC_SUBST(SWFDEC_CFLAGS)
1023   AC_SUBST(SWFDEC_LIBS)
1024 ])
1025
1026 dnl *** theora ***
1027 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORADEC, true)
1028 AG_GST_CHECK_FEATURE(THEORADEC, [ogg theora codec], theoraexpdec, [
1029   PKG_CHECK_MODULES(THEORADEC, theoradec, HAVE_THEORADEC="yes", [
1030     HAVE_THEORADEC="no"
1031     AC_MSG_RESULT(no)
1032   ])
1033   AC_SUBST(THEORADEC_LIBS)
1034   AC_SUBST(THEORADEC_CFLAGS)
1035 ])
1036
1037 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
1038 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
1039 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
1040   AG_GST_CHECK_LIBHEADER(X264, x264, x264_nal_encode, -lm, x264.h,
1041       X264_LIBS="$LDFLAGS -lx264 -lm"
1042       X264_CFLAGS="$CFLAGS"
1043       AC_SUBST(X264_LIBS)
1044       AC_SUBST(X264_CFLAGS))
1045 ])
1046
1047 dnl *** XVID ***
1048 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
1049 AG_GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
1050   HAVE_XVID=no
1051   AC_CHECK_HEADER(xvid.h, [
1052     OLD_LIBS="$LIBS"
1053     LIBS="-lm"
1054     AC_CHECK_LIB(xvidcore, xvid_encore, [
1055       AC_CHECK_LIB(xvidcore, xvid_decore, [
1056         AC_CHECK_LIB(xvidcore, xvid_global, [
1057           AC_MSG_CHECKING([for uptodate XviD API version])
1058           AC_TRY_COMPILE([#include <xvid.h>], [
1059               #if XVID_API_MAJOR(XVID_API) != 4
1060               #error "Incompatible XviD API version"
1061               #endif
1062           ],[ AC_MSG_RESULT(yes)
1063             XVID_LIBS="-lxvidcore -lm"
1064             AC_SUBST(XVID_LIBS)
1065             HAVE_XVID=yes
1066           ], AC_MSG_RESULT(no) )
1067         ], )
1068       ], )
1069     ], )
1070     LIBS="$OLD_LIBS"
1071   ], )
1072 ])
1073
1074 dnl *** dvb ***
1075 translit(dnm, m, l) AM_CONDITIONAL(USE_DVB, true)
1076 AG_GST_CHECK_FEATURE(DVB, [DVB Source], dvb, [
1077   AC_MSG_CHECKING([Checking for up to date dvb installation])
1078   AC_CHECK_HEADER(linux/dvb/frontend.h, [HAVE_DVB="yes"], [HAVE_DVB="no"])
1079 ])
1080
1081 dnl *** oss4 ***
1082 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
1083 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
1084   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
1085   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
1086       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
1087       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
1088 ])
1089
1090 dnl *** wininet ***
1091 translit(dnm, m, l) AM_CONDITIONAL(USE_WININET, true)
1092 AG_GST_CHECK_FEATURE(WININET, [Windows internet library], wininet, [
1093   AC_MSG_CHECKING([Checking for windows internet support])
1094   AC_CHECK_HEADERS([windows.h wininet.h],
1095       [HAVE_WININET="yes"], [HAVE_WININET="no"])
1096 ])
1097
1098 else
1099
1100 dnl not building plugins with external dependencies,
1101 dnl but we still need to set the conditionals
1102
1103 AM_CONDITIONAL(USE_QUICKTIME, false)
1104 AM_CONDITIONAL(USE_VCD, false)
1105 AM_CONDITIONAL(USE_ALSA, false)
1106 AM_CONDITIONAL(USE_AMRWB, false)
1107 AM_CONDITIONAL(USE_BZ2, false)
1108 AM_CONDITIONAL(USE_CDAUDIO, false)
1109 AM_CONDITIONAL(USE_DC1394, false)
1110 AM_CONDITIONAL(USE_DIRECTFB, false)
1111 AM_CONDITIONAL(USE_DTS, false)
1112 AM_CONDITIONAL(USE_DIRAC, false)
1113 AM_CONDITIONAL(USE_DIVX, false)
1114 AM_CONDITIONAL(USE_DVB, false)
1115 AM_CONDITIONAL(USE_FAAC, false)
1116 AM_CONDITIONAL(USE_FAAD, false)
1117 AM_CONDITIONAL(USE_FBDEV, false)
1118 AM_CONDITIONAL(USE_GSM, false)
1119 AM_CONDITIONAL(USE_IVORBIS, false)
1120 AM_CONDITIONAL(USE_JACK, false)
1121 AM_CONDITIONAL(USE_LADSPA, false)
1122 AM_CONDITIONAL(USE_LIBMMS, false)
1123 AM_CONDITIONAL(USE_METADATA, false)
1124 AM_CONDITIONAL(USE_MPEG2ENC, false)
1125 AM_CONDITIONAL(USE_MPLEX, false)
1126 AM_CONDITIONAL(USE_MUSEPACK, false)
1127 AM_CONDITIONAL(USE_MUSICBRAINZ, false)
1128 AM_CONDITIONAL(USE_MYTHTV, false)
1129 AM_CONDITIONAL(USE_NAS, false)
1130 AM_CONDITIONAL(USE_NEON, false)
1131 AM_CONDITIONAL(USE_OFA, false)
1132 AM_CONDITIONAL(USE_OSS4, false)
1133 AM_CONDITIONAL(USE_SDL, false)
1134 AM_CONDITIONAL(USE_SNDFILE, false)
1135 AM_CONDITIONAL(USE_SOUNDTOUCH, false)
1136 AM_CONDITIONAL(USE_SPC, false)
1137 AM_CONDITIONAL(USE_SWFDEC, false)
1138 AM_CONDITIONAL(USE_THEORADEC, false)
1139 AM_CONDITIONAL(USE_TIMIDITY, false)
1140 AM_CONDITIONAL(USE_X264, false)
1141 AM_CONDITIONAL(USE_XVID, false)
1142 AM_CONDITIONAL(USE_WILDMIDI, false)
1143 AM_CONDITIONAL(USE_WININET, false)
1144
1145 fi dnl of EXT plugins
1146
1147 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1148
1149 dnl Overview:
1150 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1151 dnl GST_*:              flags shared by built objects to link against GStreamer
1152 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1153 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
1154 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1155 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1156
1157 dnl GST_OPTION_CFLAGS
1158 if test "x$USE_DEBUG" = xyes; then
1159    PROFILE_CFLAGS="-g"
1160 fi
1161 AC_SUBST(PROFILE_CFLAGS)
1162
1163 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1164   dnl Define _only_ during CVS (not pre-releases or releases)
1165   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1166 else
1167   DEPRECATED_CFLAGS=""
1168 fi
1169 AC_SUBST(DEPRECATED_CFLAGS)
1170
1171 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1172 dnl at make time with e.g. make ERROR_CFLAGS=""
1173 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1174 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1175 AC_SUBST(GST_OPTION_CFLAGS)
1176 AC_SUBST(GST_OPTION_CXXFLAGS)
1177
1178 dnl FIXME: do we want to rename to GST_ALL_* ?
1179 dnl prefer internal headers to already installed ones
1180 dnl also add builddir include for enumtypes and marshal
1181 dnl add GST_OPTION_CFLAGS, but overridable
1182 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1183 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1184 AC_SUBST(GST_CFLAGS)
1185 AC_SUBST(GST_CXXFLAGS)
1186 AC_SUBST(GST_LIBS)
1187
1188 dnl LDFLAGS really should only contain flags, not libs - they get added before
1189 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1190 GST_ALL_LDFLAGS="-no-undefined"
1191 AC_SUBST(GST_ALL_LDFLAGS)
1192
1193 dnl this really should only contain flags, not libs - they get added before
1194 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1195 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1196 AC_SUBST(GST_PLUGIN_LDFLAGS)
1197
1198 dnl *** output files ***
1199
1200 dnl po/Makefile.in
1201
1202
1203 AC_CONFIG_FILES(
1204 Makefile
1205 gst-plugins-bad.spec
1206 gst/Makefile
1207 gst/app/Makefile
1208 gst/bayer/Makefile
1209 gst/cdxaparse/Makefile
1210 gst/deinterlace/Makefile
1211 gst/deinterlace2/Makefile
1212 gst/dvdspu/Makefile
1213 gst/festival/Makefile
1214 gst/filter/Makefile
1215 gst/flv/Makefile
1216 gst/freeze/Makefile
1217 gst/h264parse/Makefile
1218 gst/librfb/Makefile
1219 gst/modplug/Makefile
1220 gst/modplug/libmodplug/Makefile
1221 gst/mpegtsparse/Makefile
1222 gst/mpeg4videoparse/Makefile
1223 gst/mpegvideoparse/Makefile
1224 gst/mve/Makefile
1225 gst/nsf/Makefile
1226 gst/nuvdemux/Makefile
1227 gst/rawparse/Makefile
1228 gst/rtpmanager/Makefile
1229 gst/sdp/Makefile
1230 gst/selector/Makefile
1231 gst/speed/Makefile
1232 gst/speexresample/Makefile
1233 gst/subenc/Makefile
1234 gst/stereo/Makefile
1235 gst/tta/Makefile
1236 gst/videosignal/Makefile
1237 gst/vmnc/Makefile
1238 gst/real/Makefile
1239 gst/y4m/Makefile
1240 gst-libs/Makefile
1241 gst-libs/gst/Makefile
1242 gst-libs/gst/app/Makefile
1243 gst-libs/gst/dshow/Makefile
1244 sys/Makefile
1245 sys/dshowdecwrapper/Makefile
1246 sys/dshowsrcwrapper/Makefile
1247 sys/dshowvideosink/Makefile
1248 sys/dvb/Makefile
1249 sys/fbdev/Makefile
1250 sys/oss4/Makefile
1251 sys/qtwrapper/Makefile
1252 sys/vcd/Makefile
1253 sys/wininet/Makefile
1254 examples/Makefile
1255 examples/app/Makefile
1256 examples/directfb/Makefile
1257 examples/switch/Makefile
1258 ext/amrwb/Makefile
1259 ext/alsaspdif/Makefile
1260 ext/bz2/Makefile
1261 ext/cdaudio/Makefile
1262 ext/dc1394/Makefile
1263 ext/dirac/Makefile
1264 ext/directfb/Makefile
1265 ext/divx/Makefile
1266 ext/dts/Makefile
1267 ext/metadata/Makefile
1268 ext/faac/Makefile
1269 ext/faad/Makefile
1270 ext/gsm/Makefile
1271 ext/ivorbis/Makefile
1272 ext/jack/Makefile
1273 ext/ladspa/Makefile
1274 ext/libmms/Makefile
1275 ext/Makefile
1276 ext/nas/Makefile
1277 ext/mpeg2enc/Makefile
1278 ext/mplex/Makefile
1279 ext/musepack/Makefile
1280 ext/musicbrainz/Makefile
1281 ext/mythtv/Makefile
1282 ext/neon/Makefile
1283 ext/ofa/Makefile
1284 ext/resindvd/Makefile
1285 ext/sdl/Makefile
1286 ext/sndfile/Makefile
1287 ext/soundtouch/Makefile
1288 ext/spc/Makefile
1289 ext/swfdec/Makefile
1290 ext/theora/Makefile
1291 ext/timidity/Makefile
1292 ext/x264/Makefile
1293 ext/xvid/Makefile
1294 po/Makefile.in
1295 docs/Makefile
1296 docs/plugins/Makefile
1297 docs/version.entities
1298 common/Makefile
1299 common/m4/Makefile
1300 m4/Makefile
1301 tests/Makefile
1302 tests/check/Makefile
1303 tests/icles/Makefile
1304 win32/common/config.h
1305 )
1306 AC_OUTPUT
1307
1308 AG_GST_OUTPUT_PLUGINS