configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT([GStreamer Ugly Plug-ins],[1.9.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-ugly])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS(config.h)
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AS_LIBTOOL(GST, 900, 0, 900)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.9.0.1
  49 GSTPB_REQ=1.9.0.1
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION(0.17)
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  68 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl check if the compiler supports '-c' and '-o' options
 110 AM_PROG_CC_C_O
 111
 112 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 113 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 114
 115 dnl check if the compiler supports do while(0) macros
 116 AG_GST_CHECK_DOWHILE_MACROS
 117
 118 dnl check for documentation tools
 119 GTK_DOC_CHECK([1.12])
 120 AG_GST_PLUGIN_DOCS([1.12])
 121
 122 dnl *** checks for libraries ***
 123
 124 dnl check for libm, for sin()
 125 LT_LIB_M
 126 AC_SUBST(LIBM)
 127
 128 dnl *** checks for header files ***
 129
 130 dnl used by ext/a52dec
 131 AX_CREATE_STDINT_H
 132
 133 dnl Check for malloc.h
 134 AC_CHECK_HEADERS([malloc.h])
 135
 136 dnl *** checks for types/defines ***
 137
 138 dnl *** checks for structures ***
 139
 140 dnl *** checks for compiler characteristics ***
 141
 142 dnl *** checks for library functions ***
 143
 144 dnl Check for a way to display the function name in debug output
 145 AG_GST_CHECK_FUNCTION
 146
 147 dnl *** checks for dependency libraries ***
 148
 149 dnl GLib is required
 150 GLIB_REQ=2.40.0
 151 AG_GST_GLIB_CHECK([$GLIB_REQ])
 152
 153 ORC_CHECK([0.4.16])
 154
 155 dnl checks for gstreamer
 156 dnl uninstalled is selected preferentially -- see pkg-config(1)
 157 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 158 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 159 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 160 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 161 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 162
 163 dnl Check for documentation xrefs
 164 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 165 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 166 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 167 AC_SUBST(GLIB_PREFIX)
 168 AC_SUBST(GST_PREFIX)
 169 AC_SUBST(GSTPB_PREFIX)
 170
 171 dnl Needed by plugins that use g_module_*() API
 172 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 173
 174 dnl Check for -Bsymbolic-functions linker flag used to avoid
 175 dnl intra-library PLT jumps, if available.
 176 AC_ARG_ENABLE(Bsymbolic,
 177               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 178               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 179                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 180                LDFLAGS=-Wl,-Bsymbolic-functions
 181                LIBS=
 182                AC_TRY_LINK([], [return 0],
 183                            AC_MSG_RESULT(yes)
 184                            enable_Bsymbolic=yes,
 185                            AC_MSG_RESULT(no)
 186                            enable_Bsymbolic=no)
 187                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 188
 189 dnl *** set variables based on configure arguments ***
 190
 191 dnl set license and copyright notice
 192 GST_LICENSE="LGPL"
 193 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 194 AC_SUBST(GST_LICENSE)
 195
 196 dnl set location of plugin directory
 197 AG_GST_SET_PLUGINDIR
 198
 199 dnl set release date/time
 200 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 201   ["${srcdir}/gst-plugins-ugly.doap"],
 202   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 203
 204 dnl build static plugins or not
 205 AC_MSG_CHECKING([whether to build static plugins or not])
 206 AC_ARG_ENABLE(
 207   static-plugins,
 208   AC_HELP_STRING(
 209     [--enable-static-plugins],
 210     [build static plugins @<:@default=no@:>@]),
 211   [AS_CASE(
 212     [$enableval], [no], [], [yes], [],
 213     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 214   [enable_static_plugins=no])
 215 AC_MSG_RESULT([$enable_static_plugins])
 216 if test "x$enable_static_plugins" = xyes; then
 217   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 218     [Define if static plugins should be built])
 219   GST_PLUGIN_LIBTOOLFLAGS=""
 220 else
 221   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 222 fi
 223 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 224 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 225
 226 dnl define an ERROR_CFLAGS Makefile variable
 227 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 228     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 229     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 230     -Winit-self -Wmissing-include-dirs -Waddress
 231     -Waggregate-return -Wno-multichar -Wnested-externs ])
 232
 233 dnl define an ERROR_CXXFLAGS Makefile variable
 234 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 235     -Wmissing-declarations -Wredundant-decls
 236     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 237     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 238     -Wno-multichar])
 239
 240 dnl define correct level for debugging messages
 241 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 242
 243 dnl used in examples
 244 AG_GST_DEFAULT_ELEMENTS
 245
 246 dnl *** plug-ins to include ***
 247
 248 dnl these are all the gst plug-ins, compilable without additional libs
 249 AG_GST_CHECK_PLUGIN(asfdemux)
 250 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 251 AG_GST_CHECK_PLUGIN(dvdsub)
 252 AG_GST_CHECK_PLUGIN(xingmux)
 253 AG_GST_CHECK_PLUGIN(realmedia)
 254
 255 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 256
 257 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 258   WIN32_LIBS="-lws2_32"
 259   AC_SUBST(WIN32_LIBS)
 260 fi
 261
 262 dnl *** ext plug-ins ***
 263 dnl keep this list sorted alphabetically !
 264
 265 if test "x$BUILD_EXTERNAL" = "xyes"; then
 266
 267 echo
 268 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 269 echo
 270
 271 dnl *** a52dec ***
 272 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 273 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 274   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 275 ])
 276
 277 dnl *** amr-nb ***
 278 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 279 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 280   AG_GST_PKG_CHECK_MODULES(AMRNB, opencore-amrnb >= 0.1.3)
 281 ])
 282
 283 dnl *** amr-wb dec ***
 284 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 285 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 286   AG_GST_PKG_CHECK_MODULES(AMRWB, opencore-amrwb >= 0.1.3)
 287 ])
 288
 289 dnl *** cdio ***
 290 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 291 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 292   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 293 ])
 294
 295 dnl *** dvdread ***
 296 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 297 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 298   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 299   AC_SUBST(DVDREAD_LIBS)
 300 ])
 301
 302 dnl *** lame ***
 303 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 304 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 305   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 306   [
 307     HAVE_LAME="yes"
 308     LAME_LIBS="-lmp3lame $LIBM"
 309     dnl is lame presets available
 310     LAME_CFLAGS=""
 311     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 312     ])
 313     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 314         void *ptr = &lame_set_VBR_quality
 315       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 316     ])
 317   AC_SUBST(LAME_CFLAGS)
 318   AC_SUBST(LAME_LIBS)
 319   ])
 320 ])
 321
 322 dnl *** mad ***
 323 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 324 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 325
 326   dnl check with pkg-config first
 327   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 328   MAD_LIBS="$MAD_LIBS"
 329   if test "x$HAVE_MAD" = "xno"; then
 330     dnl fall back to oldskool detection
 331     AC_CHECK_HEADER(mad.h, [
 332       AC_CHECK_LIB(mad, mad_decoder_finish,
 333         HAVE_MAD="yes" MAD_LIBS="-lmad")
 334     ])
 335   fi
 336 ])
 337 AC_SUBST(MAD_LIBS)
 338
 339 dnl *** mpeg2dec ***
 340 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 341 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 342   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 343 ])
 344
 345 dnl *** mpg123 ***
 346 translit(dnm, m, l) AM_CONDITIONAL(USE_MPG123, true)
 347 AG_GST_CHECK_FEATURE(MPG123, [mpg123 audio decoder], mpg123, [
 348   PKG_CHECK_MODULES(MPG123, libmpg123 >= 1.13, HAVE_MPG123="yes", HAVE_MPG123="no")
 349   AC_SUBST(MPG123_CFLAGS)
 350   AC_SUBST(MPG123_LIBS)
 351 ])
 352
 353 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 354 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 355 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 356   GST_PATH_SIDPLAY()
 357 ])
 358
 359 dnl *** twolame ***
 360 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 361 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 362   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 363       HAVE_TWOLAME="yes"], [
 364       HAVE_TWOLAME="no"
 365   ])
 366   AC_SUBST(TWOLAME_CFLAGS)
 367   AC_SUBST(TWOLAME_LIBS)
 368 ])
 369
 370 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 372 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 373   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120)
 374 ])
 375
 376 else
 377
 378 dnl not building plugins with external dependencies,
 379 dnl but we still need to set the conditionals
 380
 381 AM_CONDITIONAL(USE_A52DEC, false)
 382 AM_CONDITIONAL(USE_AMRNB, false)
 383 AM_CONDITIONAL(USE_AMRWB, false)
 384 AM_CONDITIONAL(USE_CDIO, false)
 385 AM_CONDITIONAL(USE_DVDREAD, false)
 386 AM_CONDITIONAL(USE_LAME, false)
 387 AM_CONDITIONAL(USE_MAD, false)
 388 AM_CONDITIONAL(USE_MPEG2DEC, false)
 389 AM_CONDITIONAL(USE_MPG123, false)
 390 AM_CONDITIONAL(USE_SIDPLAY, false)
 391 AM_CONDITIONAL(USE_TWOLAME, false)
 392 AM_CONDITIONAL(USE_X264, false)
 393
 394 fi dnl of EXT plugins
 395
 396 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 397
 398 dnl Overview:
 399 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 400 dnl GST_*:              flags shared by built objects to link against GStreamer
 401 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 402 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 403 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 404 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 405
 406 dnl GST_OPTION_CFLAGS
 407 if test "x$USE_DEBUG" = xyes; then
 408    PROFILE_CFLAGS="-g"
 409 fi
 410 AC_SUBST(PROFILE_CFLAGS)
 411
 412 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 413   dnl Define _only_ during CVS (not pre-releases or releases)
 414   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 415 else
 416   DEPRECATED_CFLAGS=""
 417 fi
 418 AC_SUBST(DEPRECATED_CFLAGS)
 419
 420 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 421 dnl at make time with e.g. make ERROR_CFLAGS=""
 422 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 423 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 424 AC_SUBST(GST_OPTION_CFLAGS)
 425 AC_SUBST(GST_OPTION_CXXFLAGS)
 426
 427 dnl FIXME: do we want to rename to GST_ALL_* ?
 428 dnl prefer internal headers to already installed ones
 429 dnl also add builddir include for enumtypes and marshal
 430 dnl add GST_OPTION_CFLAGS, but overridable
 431 GST_CFLAGS="$GST_CFLAGS"
 432 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 433 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 434 AC_SUBST(GST_CFLAGS)
 435 AC_SUBST(GST_CXXFLAGS)
 436 AC_SUBST(GST_LIBS)
 437
 438 dnl LDFLAGS really should only contain flags, not libs - they get added before
 439 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 440 GST_ALL_LDFLAGS="-no-undefined"
 441 if test "x${enable_Bsymbolic}" = "xyes"; then
 442   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 443 fi
 444 AC_SUBST(GST_ALL_LDFLAGS)
 445
 446 dnl this really should only contain flags, not libs - they get added before
 447 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 448 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 449 AC_SUBST(GST_PLUGIN_LDFLAGS)
 450
 451 dnl *** output files ***
 452
 453 AC_CONFIG_FILES(
 454 Makefile
 455 common/Makefile
 456 common/m4/Makefile
 457 gst-libs/Makefile
 458 gst-libs/gst/Makefile
 459 gst/Makefile
 460 gst/asfdemux/Makefile
 461 gst/dvdlpcmdec/Makefile
 462 gst/dvdsub/Makefile
 463 gst/realmedia/Makefile
 464 gst/xingmux/Makefile
 465 ext/Makefile
 466 ext/a52dec/Makefile
 467 ext/amrnb/Makefile
 468 ext/amrwbdec/Makefile
 469 ext/cdio/Makefile
 470 ext/dvdread/Makefile
 471 ext/lame/Makefile
 472 ext/mad/Makefile
 473 ext/mpeg2dec/Makefile
 474 ext/mpg123/Makefile
 475 ext/sidplay/Makefile
 476 ext/twolame/Makefile
 477 ext/x264/Makefile
 478 docs/Makefile
 479 docs/plugins/Makefile
 480 docs/version.entities
 481 tests/Makefile
 482 tests/check/Makefile
 483 tests/files/Makefile
 484 m4/Makefile
 485 po/Makefile.in
 486 pkgconfig/Makefile
 487 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 488 gst-plugins-ugly.spec
 489 )
 490
 491 dnl Create the config.h file for Visual Studio builds
 492 dnl Beware of spaces and /'s in some of the shell variable contents.
 493 sed \
 494     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 495     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 496     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 497     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 498     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 499     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 500     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 501     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 502     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 503     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 504     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 505     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 506     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 507     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 508     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 509     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 510     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 511     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 512     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 513     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 514     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 515     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 516     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 517     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 518     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 519     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 520     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 521     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 522     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 523     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 524     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 525     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 526     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 527     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 528     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 529     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 530     config.h.in >win32/common/config.h-new
 531
 532 AC_OUTPUT
 533
 534 AG_GST_OUTPUT_PLUGINS
 535
 536 ORC_OUTPUT