configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/udp
 153 AC_CHECK_HEADERS([sys/time.h])
 154
 155 dnl *** checks for types/defines ***
 156
 157 dnl Check for FIONREAD ioctl declaration.  This check is needed
 158 dnl for the UDP plugin to build on Solaris
 159 GST_CHECK_FIONREAD
 160
 161 dnl *** checks for structures ***
 162
 163 dnl *** checks for compiler characteristics ***
 164
 165 dnl check if we have GCC inline-asm
 166 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 167 if test x$HAVE_GCC_ASM = xyes ; then
 168   AC_DEFINE(HAVE_GCC_ASM, 1,
 169     [Define if compiler supports gcc inline assembly])
 170 fi
 171 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 172
 173 dnl *** checks for library functions ***
 174
 175 LIBS_SAVE=$LIBS
 176 LIBS="$LIBS $LIBM"
 177 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 178 LIBS=$LIBS_SAVE
 179
 180 dnl Check whether isinf() is defined by math.h
 181 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 182     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 183 if test "$ac_cv_have_isinf" = "yes"
 184 then
 185     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 186 fi
 187
 188 dnl Check for mmap (needed by electricfence plugin)
 189 AC_FUNC_MMAP
 190 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193
 194 AC_CHECK_TYPE([struct ip_mreqn], [
 195               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 196               [#include <netinet/in.h>])
 197
 198 dnl *** checks for dependency libraries ***
 199
 200
 201 dnl GLib
 202 GLIB_REQ=2.31.10
 203
 204 AG_GST_GLIB_CHECK([$GLIB_REQ])
 205
 206 dnl Check for GIO
 207 PKG_CHECK_MODULES(GIO, gio-2.0 >= $GLIB_REQ)
 208 GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 209 AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 210     [The GIO modules directory.])
 211 GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 212     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 213         [The GIO library directory.])
 214
 215 AC_SUBST(GIO_CFLAGS)
 216 AC_SUBST(GIO_LIBS)
 217 AC_SUBST(GIO_LDFLAGS)
 218 dnl GLib is required
 219
 220 dnl Orc
 221 ORC_CHECK([0.4.11])
 222
 223 dnl checks for gstreamer
 224 dnl uninstalled is selected preferentially -- see pkg-config(1)
 225 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 226 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 227 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 228 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 229 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 230 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 231
 232 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 233 if test -z $GST_TOOLS_DIR; then
 234   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 235 fi
 236 AC_SUBST(GST_TOOLS_DIR)
 237
 238 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 239 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 240
 241 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 242
 243 dnl Check for documentation xrefs
 244 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 245 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 246 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 247 AC_SUBST(GLIB_PREFIX)
 248 AC_SUBST(GST_PREFIX)
 249 AC_SUBST(GSTPB_PREFIX)
 250
 251 dnl GTK is optional and used in examples
 252 HAVE_GTK=no
 253 GTK2_REQ=2.14.0
 254 GTK3_REQ=2.91.3
 255 if test "x$BUILD_EXAMPLES" = "xyes"; then
 256   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 257   AC_ARG_WITH([gtk],
 258     AC_HELP_STRING([--with-gtk=3.0|2.0],
 259                    [which gtk+ version to compile against (default: 2.0)]),
 260     [case "$with_gtk" in
 261         2.0) GTK_REQ=$GTK2_REQ ;;
 262         3.0) GTK_REQ=$GTK3_REQ ;;
 263         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 264     esac],
 265     [with_gtk=2.0
 266      GTK_REQ=$GTK2_REQ])
 267   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 268   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 269   dnl some examples need gtk+-x11
 270   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 271   AC_SUBST(GTK_LIBS)
 272   AC_SUBST(GTK_CFLAGS)
 273 fi
 274 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 275 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 276
 277 dnl *** set variables based on configure arguments ***
 278
 279 dnl set license and copyright notice
 280 GST_LICENSE="LGPL"
 281 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 282 AC_SUBST(GST_LICENSE)
 283
 284 dnl set location of plugin directory
 285 AG_GST_SET_PLUGINDIR
 286
 287 dnl set release date/time
 288 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 289   ["${srcdir}/gst-plugins-good.doap"],
 290   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 291
 292 dnl define an ERROR_CFLAGS Makefile variable
 293 dnl -Wundef: too many broken headers
 294 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 295   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 296         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 297         -Wwrite-strings -Wold-style-definition -Waggregate-return
 298         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 299         -Wnested-externs ])
 300 else
 301   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 302   dnl doesn't understand all warning flags that the C compiler knows about
 303   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 304   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 305         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 306         -Wwrite-strings -Wold-style-definition
 307         -Winit-self -Wmissing-include-dirs -Wno-multichar
 308         -Wnested-externs ])
 309 fi
 310
 311 dnl define an ERROR_CXXFLAGS Makefile variable
 312 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 313         -Wmissing-declarations -Wredundant-decls
 314         -Wwrite-strings
 315         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl Non ported plugins (non-dependant, then dependant)
 326 dnl Make sure you have a space before and after all plugins
 327 GST_PLUGINS_NONPORTED="deinterlace interleave flx goom2k1 \
 328  imagefreeze interleave monoscope smpte \
 329  videobox videomixer \
 330  cairo cairo_gobject dv1394 gdk_pixbuf libdv libpng \
 331  oss oss4 shout2 \
 332  taglib wavpack \
 333  osx_video osx_audio "
 334 AC_SUBST(GST_PLUGINS_NONPORTED)
 335
 336 dnl these are all the gst plug-ins, compilable without additional libs
 337 dnl videofilter is at the top because others depend on it
 338 AG_GST_CHECK_PLUGIN(alpha)
 339 AG_GST_CHECK_PLUGIN(apetag)
 340 AG_GST_CHECK_PLUGIN(audiofx)
 341 AG_GST_CHECK_PLUGIN(audioparsers)
 342 AG_GST_CHECK_PLUGIN(auparse)
 343 AG_GST_CHECK_PLUGIN(autodetect)
 344 AG_GST_CHECK_PLUGIN(avi)
 345 AG_GST_CHECK_PLUGIN(cutter)
 346 AG_GST_CHECK_PLUGIN(debugutils)
 347 AG_GST_CHECK_PLUGIN(deinterlace)
 348 AG_GST_CHECK_PLUGIN(effectv)
 349 AG_GST_CHECK_PLUGIN(equalizer)
 350 AG_GST_CHECK_PLUGIN(flv)
 351 AG_GST_CHECK_PLUGIN(flx)
 352 AG_GST_CHECK_PLUGIN(goom)
 353 AG_GST_CHECK_PLUGIN(goom2k1)
 354 AG_GST_CHECK_PLUGIN(icydemux)
 355 AG_GST_CHECK_PLUGIN(id3demux)
 356 AG_GST_CHECK_PLUGIN(imagefreeze)
 357 AG_GST_CHECK_PLUGIN(interleave)
 358 AG_GST_CHECK_PLUGIN(isomp4)
 359 AG_GST_CHECK_PLUGIN(law)
 360 AG_GST_CHECK_PLUGIN(level)
 361 AG_GST_CHECK_PLUGIN(matroska)
 362 AG_GST_CHECK_PLUGIN(monoscope)
 363 AG_GST_CHECK_PLUGIN(multifile)
 364 AG_GST_CHECK_PLUGIN(multipart)
 365 AG_GST_CHECK_PLUGIN(replaygain)
 366 AG_GST_CHECK_PLUGIN(rtp)
 367 AG_GST_CHECK_PLUGIN(rtpmanager)
 368 AG_GST_CHECK_PLUGIN(rtsp)
 369 AG_GST_CHECK_PLUGIN(shapewipe)
 370 AG_GST_CHECK_PLUGIN(smpte)
 371 AG_GST_CHECK_PLUGIN(spectrum)
 372 AG_GST_CHECK_PLUGIN(udp)
 373 AG_GST_CHECK_PLUGIN(videobox)
 374 AG_GST_CHECK_PLUGIN(videocrop)
 375 AG_GST_CHECK_PLUGIN(videofilter)
 376 AG_GST_CHECK_PLUGIN(videomixer)
 377 AG_GST_CHECK_PLUGIN(wavenc)
 378 AG_GST_CHECK_PLUGIN(wavparse)
 379 AG_GST_CHECK_PLUGIN(y4m)
 380
 381 dnl disable experimental plug-ins
 382 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 383   AG_GST_DISABLE_PLUGIN(monoscope)
 384 fi
 385
 386 dnl *** sys plug-ins ***
 387
 388 echo
 389 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 390 echo
 391
 392 dnl DirectSound
 393 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 394 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 395   HAVE_DIRECTSOUND="no"
 396   save_CFLAGS="$CFLAGS"
 397   save_LDFLAGS="$LDFLAGS"
 398   save_LIBS="$LIBS"
 399   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 400   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 401   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 402   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 403   AC_LINK_IFELSE([
 404 #include <windows.h>
 405 #include <dxerr9.h>
 406 #include <dsound.h>
 407
 408 int main ()
 409 {
 410   DXGetErrorString9 (0);
 411   DirectSoundCreate(NULL, NULL, NULL);
 412
 413   return 0;
 414 }
 415 ],
 416     [HAVE_DIRECTSOUND="yes"],
 417     [HAVE_DIRECTSOUND="no"])
 418   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 419   CFLAGS=$save_CFLAGS
 420   LDFLAGS=$save_LDFLAGS
 421   LIBS=$save_LIBS
 422
 423   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 424     dnl this is much more than we want
 425     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 426     AC_SUBST(DIRECTSOUND_CFLAGS)
 427     AC_SUBST(DIRECTSOUND_LDFLAGS)
 428     AC_SUBST(DIRECTSOUND_LIBS)
 429   fi
 430   AC_SUBST(HAVE_DIRECTSOUND)
 431 ])
 432
 433 dnl *** Win32 WaveOut ***
 434 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 435 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 436   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 437 ])
 438
 439 dnl *** OSS audio *** (Linux, *BSD)
 440 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 441 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 442  HAVE_OSS="yes"
 443 dnl Linux and newer BSD versions :
 444  AC_CHECK_HEADER(sys/soundcard.h, [
 445    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 446    ] , [
 447 dnl Some old BSD versions and also newer OpenBSD versions :
 448    AC_CHECK_HEADER(soundcard.h, [
 449      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 450      ], [
 451   dnl Some old BSD versions :
 452      AC_CHECK_HEADER(machine/soundcard.h, [
 453        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 454          [Define if OSS includes are in /machine/])
 455        ], [
 456        HAVE_OSS="no"
 457      ])
 458    ])
 459  ])
 460 ])
 461
 462 dnl *** oss4 ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 464 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 465   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 466   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 467       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 468       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 469 ])
 470
 471 dnl *** Sun Audio ***
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 473 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 474   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 475 ])
 476
 477 dnl *** OSX Audio ***
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 479 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 480   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 481 ])
 482
 483 dnl *** OS X video ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 485 HAVE_OSX_VIDEO="no"
 486 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 487   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 488 ])
 489 dnl in case header OpenGL/gl.h is found on other platforms
 490 case "$host" in
 491   *-*darwin*)
 492     dnl do nothing
 493     ;;
 494   *)
 495     HAVE_OSX_VIDEO="no"
 496     ;;
 497 esac
 498
 499
 500 dnl *** Video 4 Linux 2 ***
 501 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 502 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 504 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 505   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 506   AC_TRY_COMPILE([
 507 #include <sys/types.h>
 508 #ifdef __sun /* Solaris */
 509 #include <sys/types.h>
 510 #include <sys/videodev2.h>
 511 #else /* Linux */
 512 #include <linux/types.h>
 513 #define _LINUX_TIME_H
 514 #define __user
 515 #include <linux/videodev2.h>
 516 #endif
 517 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 518 #error too early v4l2 version or no v4l2 at all
 519 #endif
 520     ], [
 521 return 0;
 522     ], [
 523       HAVE_GST_V4L2="yes"
 524       AC_MSG_RESULT(yes)
 525     ], [
 526       HAVE_GST_V4L2="no"
 527       AC_MSG_RESULT(no)
 528
 529       HAVE_VIDEODEV=no
 530       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 531       [
 532         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 533       ])
 534
 535       if test "x$HAVE_VIDEODEV" = "xyes"; then
 536         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 537         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 538       else
 539         AC_MSG_WARN([video4linux2 was not found])
 540       fi
 541     ])
 542
 543   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 544     dnl check for missing v4l2_buffer declaration (see #135919)
 545     MISSING_DECL=0
 546     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 547     AC_TRY_COMPILE([
 548 #include <sys/types.h>
 549 #ifdef __sun /* Solaris */
 550 #include <sys/types.h>
 551 #include <sys/videodev2.h>
 552 #else /* Linux */
 553 #include <linux/types.h>
 554 #define _LINUX_TIME_H
 555 #define __user
 556 #include <linux/videodev2.h>
 557 #endif
 558     ],[
 559 struct v4l2_buffer buf;
 560 buf.index = 0;
 561 return 0;
 562     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 563     if [ test x$MISSING_DECL = x1 ]; then
 564       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 565     fi
 566
 567     dnl check for XOverlay libraries
 568     AG_GST_CHECK_XV
 569   fi
 570 ])
 571
 572 # Optional gudev for device probing
 573 AC_ARG_WITH([gudev],
 574   AC_HELP_STRING([--with-gudev],
 575     [device detection with gudev]),
 576   [],
 577   [with_gudev=check])
 578 if test x$HAVE_GST_V4L2 = xyes; then
 579   if test x$with_gudev != xno; then
 580       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 581           [ have_gudev=yes
 582             AC_DEFINE(HAVE_GUDEV, 1,
 583                [Whether gudev is available for device detection])
 584             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 585           ], [
 586           have_gudev=no
 587           ])
 588   else
 589     have_gudev=no
 590   fi
 591 fi
 592 AC_SUBST(GUDEV_CFLAGS)
 593 AC_SUBST(GUDEV_LIBS)
 594
 595 # Make libv4l2 non-automagic
 596 AC_ARG_WITH([libv4l2],
 597   AC_HELP_STRING([--with-libv4l2],
 598     [support video buffer conversion using libv4l2]),
 599   [],
 600   [with_libv4l2=check])
 601 if test x$HAVE_GST_V4L2 = xyes; then
 602   if test x$with_libv4l2 != xno; then
 603       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 604           [ have_libv4l2=yes
 605             AC_DEFINE(HAVE_LIBV4L2, 1,
 606                 [Whether libv4l2 is available for video buffer conversion])
 607           ], [
 608           have_libv4l2=no
 609           ])
 610   else
 611     have_libv4l2=no
 612   fi
 613 fi
 614
 615 dnl Check for X11
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 617 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 618                   [ximagesrc], [
 619   AC_PATH_XTRA
 620
 621   dnl now try to find the HEADER
 622   ac_cflags_save="$CFLAGS"
 623   ac_cppflags_save="$CPPFLAGS"
 624   CFLAGS="$CFLAGS $X_CFLAGS"
 625   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 626   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 627
 628   if test "x$HAVE_X" = "xno"
 629   then
 630     AC_MSG_NOTICE([cannot find X11 development files])
 631   else
 632     dnl this is much more than we want
 633     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 634     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 635     dnl it does not add the libs; therefore we add them here
 636     X_LIBS="$X_LIBS -lX11"
 637     AC_SUBST(X_CFLAGS)
 638     AC_SUBST(X_LIBS)
 639
 640     dnl check for Xfixes
 641     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 642     if test "x$HAVE_XFIXES" = "xyes"
 643     then
 644         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 645     fi
 646     AC_SUBST(XFIXES_LIBS)
 647     AC_SUBST(XFIXES_CFLAGS)
 648
 649     dnl check for Xdamage
 650     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 651     if test "x$HAVE_XDAMAGE" = "xyes"
 652     then
 653         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 654     fi
 655     AC_SUBST(XDAMAGE_LIBS)
 656     AC_SUBST(XDAMAGE_CFLAGS)
 657   fi
 658   AC_SUBST(HAVE_X)
 659   CFLAGS="$ac_cflags_save"
 660   CPPFLAGS="$ac_cppflags_save"
 661 ])
 662
 663 dnl FIXME: this should be rolled into the test above, it's just an additional
 664 dnl feature of the ximagesrc plug-in
 665 dnl This is the same as in gst-plugins-base
 666 dnl check for X Shm
 667 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 668 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 669   if test x$HAVE_X = xyes; then
 670     AC_CHECK_LIB(Xext, XShmAttach,
 671                  HAVE_XSHM="yes", HAVE_XSHM="no",
 672                  $X_LIBS)
 673     if test "x$HAVE_XSHM" = "xyes"; then
 674       XSHM_LIBS="-lXext"
 675     else
 676       dnl On AIX, it is in XextSam instead, but we still need -lXext
 677       AC_CHECK_LIB(XextSam, XShmAttach,
 678                    HAVE_XSHM="yes", HAVE_XSHM="no",
 679                    $X_LIBS)
 680       if test "x$HAVE_XSHM" = "xyes"; then
 681         XSHM_LIBS="-lXext -lXextSam"
 682       fi
 683     fi
 684   fi
 685 ], ,[
 686   AC_SUBST(HAVE_XSHM)
 687   AC_SUBST(XSHM_LIBS)
 688 ])
 689
 690 dnl for V4L2, we also need to know if we have XVIDEO
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 692 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 693                   [], [
 694   AG_GST_CHECK_XV
 695 ])
 696
 697 dnl *** ext plug-ins ***
 698 dnl keep this list sorted alphabetically !
 699
 700 if test "x$BUILD_EXTERNAL" = "xyes"; then
 701
 702 echo
 703 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 704 echo
 705
 706 dnl *** aalib ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 708 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 709   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 710   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 711 ])
 712
 713 dnl *** annodex ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 715 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 716   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 717 ])
 718
 719 dnl *** cairo ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 721 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 722   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 723 ])
 724
 725 dnl *** cairo-gobject ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 727 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 728   [Cairo graphics rendering gobject bindings], cairooverlay, [
 729   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 730 ])
 731
 732 dnl *** FLAC ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 734 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 735   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 736 ])
 737
 738 dnl *** GDK pixbuf ***
 739 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 740 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 741   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 742 ])
 743
 744 dnl *** Jack ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 746 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 747   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 748   AC_SUBST(JACK_CFLAGS)
 749   AC_SUBST(JACK_LIBS)
 750
 751   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 752   if test x$HAVE_JACK_0_120_1 = xyes; then
 753     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 754   fi
 755   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 756   if test x$HAVE_JACK_1_9_7 = xyes; then
 757     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 758   fi
 759
 760 ])
 761
 762 dnl *** jpeg ***
 763 dnl FIXME: we could use header checks here as well IMO
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 765 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 766   AC_ARG_WITH(jpeg-mmx,
 767     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 768   OLD_LIBS="$LIBS"
 769   if test x$with_jpeg_mmx != x; then
 770     LIBS="$LIBS -L$with_jpeg_mmx"
 771   fi
 772   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 773   JPEG_LIBS="$LIBS -ljpeg-mmx"
 774   LIBS="$OLD_LIBS"
 775   if test x$HAVE_JPEG != xyes; then
 776     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 777     JPEG_LIBS="-ljpeg"
 778   fi
 779   AC_SUBST(JPEG_LIBS)
 780 ])
 781
 782 dnl *** libcaca ***
 783 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 784 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 785   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 786 ])
 787
 788 dnl *** libdv ***
 789 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 790 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 791   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 792 ])
 793
 794 dnl *** libpng ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 796 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 797   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 798 ])
 799
 800 dnl *** pulseaudio ***
 801 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 802 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 803
 804   dnl used in ext/pulse/pulseutil.c
 805   AC_CHECK_HEADERS([process.h])
 806
 807   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 808 ])
 809
 810 dnl *** dv1394 ***
 811 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 812 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 813   dnl first test for libraw1394 >= 2.0.0
 814   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 815   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 816   dnl now see how far we got
 817   if test x$HAVE_RAW1394 = xyes && \
 818      test x$HAVE_LIBIEC61883 = xyes; then
 819        AG_GST_CHECK_LIBHEADER(AVC1394,
 820         avc1394, avc1394_send_command, $RAW1394_LIBS,
 821         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 822        AG_GST_CHECK_LIBHEADER(ROM1394,
 823         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 824         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 825        if test x$HAVE_AVC1394 = xyes && \
 826           test x$HAVE_AVC1394 = xyes && \
 827           test x$HAVE_ROM1394 = xyes; then
 828           HAVE_DV1394=yes
 829           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 830           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 831           AC_SUBST(DV1394_CFLAGS)
 832           AC_SUBST(DV1394_LIBS)
 833         fi
 834   else
 835        if test x$HAVE_RAW1394 = xno; then
 836           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 837           AG_GST_CHECK_LIBHEADER(AVC1394,
 838            avc1394, avc1394_send_command, $RAW1394_LIBS,
 839            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 840           AG_GST_CHECK_LIBHEADER(ROM1394,
 841            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 842            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 843           if test x$HAVE_RAW1394 = xyes && \
 844              test x$HAVE_AVC1394 = xyes && \
 845              test x$HAVE_ROM1394 = xyes; then
 846              HAVE_DV1394=yes
 847              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 848              DV1394_CFLAGS="$RAW1394_CFLAGS"
 849              if test x$HAVE_LIBIEC61883 = xyes; then
 850                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 851                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 852              fi
 853              AC_SUBST(DV1394_CFLAGS)
 854              AC_SUBST(DV1394_LIBS)
 855            fi
 856          fi
 857   fi
 858 ])
 859 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 860
 861 dnl *** shout2 ***
 862 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 863 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 864   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 865 ])
 866
 867 dnl *** soup ***
 868 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 869 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 870   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 871     HAVE_SOUP="yes"
 872     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 873   ],[
 874     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 875       HAVE_SOUP="no"
 876     ])
 877   ])
 878   AC_SUBST(SOUP_CFLAGS)
 879   AC_SUBST(SOUP_LIBS)
 880 ])
 881
 882 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 883 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 884 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 885 dnl   speex_jitter.h is 1.1.x only
 886 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 887 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 888   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 889   if test $HAVE_SPEEX = no
 890   then
 891     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 892       AC_CHECK_HEADER(speex/speex_jitter.h, [
 893         dnl speex 1.1.x :
 894         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 895           dnl speex 1.1.5 or + :
 896           HAVE_SPEEX="yes"
 897           SPEEX_LIBS="-lspeex"
 898           AC_SUBST(SPEEX_CFLAGS)
 899           AC_SUBST(SPEEX_LIBS)
 900         ],[
 901           HAVE_SPEEX="no"
 902         ])
 903       ],[
 904         dnl speex 1.0.x :
 905           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 906             dnl speex 1.0.4
 907             HAVE_SPEEX="yes"
 908             SPEEX_LIBS="-lspeex"
 909             AC_SUBST(SPEEX_CFLAGS)
 910             AC_SUBST(SPEEX_LIBS)
 911
 912             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 913               [defined if speex 1.0.x API detected])
 914         ],[
 915             HAVE_SPEEX="no"
 916             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 917         ], [
 918 #include <speex/speex.h>
 919         ])
 920       ])
 921     ])
 922   fi
 923 ])
 924
 925 dnl *** taglib ***
 926 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 927 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 928   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 929   if test "x$HAVE_CXX" != "xyes"; then
 930     USE_TAGLIB=false
 931     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 932   else
 933     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 934     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 935         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 936       ], [
 937         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 938     ])
 939     AC_SUBST(TAGLIB_CXXFLAGS)
 940   fi
 941 ])
 942
 943 dnl *** wavpack ***
 944 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 945 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 946   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 947     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 948       HAVE_WAVPACK=yes
 949       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 950     ],[
 951       HAVE_WAVPACK=no
 952     ])
 953   ])
 954   AC_SUBST(WAVPACK_CFLAGS)
 955   AC_SUBST(WAVPACK_LIBS)
 956 ])
 957
 958 dnl *** qtdemux & matroska prefer to have zlib ***
 959 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 960 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 961   AG_GST_CHECK_LIBHEADER(ZLIB,
 962     z, uncompress,, zlib.h, [
 963     HAVE_ZLIB="yes"
 964     ZLIB_LIBS="-lz"
 965     AC_SUBST(ZLIB_LIBS)
 966   ])
 967 ])
 968
 969 dnl *** matroska prefers to have bz2 ***
 970 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 971 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 972   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 973   AC_SUBST(BZ2_LIBS)
 974 ])
 975
 976 else
 977
 978 dnl not building plugins with external dependencies,
 979 dnl but we still need to set the conditionals
 980 AM_CONDITIONAL(USE_AALIB, false)
 981 AM_CONDITIONAL(USE_ANNODEX, false)
 982 AM_CONDITIONAL(USE_BZ2, false)
 983 AM_CONDITIONAL(USE_CAIRO, false)
 984 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 985 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 986 AM_CONDITIONAL(USE_DV1394, false)
 987 AM_CONDITIONAL(USE_FLAC, false)
 988 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 989 AM_CONDITIONAL(USE_GST_V4L2, false)
 990 AM_CONDITIONAL(USE_JACK, false)
 991 AM_CONDITIONAL(USE_JPEG, false)
 992 AM_CONDITIONAL(USE_LIBCACA, false)
 993 AM_CONDITIONAL(USE_LIBDV, false)
 994 AM_CONDITIONAL(USE_LIBIEC61883, false)
 995 AM_CONDITIONAL(USE_LIBPNG, false)
 996 AM_CONDITIONAL(USE_OSS, false)
 997 AM_CONDITIONAL(USE_OSS4, false)
 998 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 999 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1000 AM_CONDITIONAL(USE_PULSE, false)
1001 AM_CONDITIONAL(USE_SHOUT2, false)
1002 AM_CONDITIONAL(USE_SOUP, false)
1003 AM_CONDITIONAL(USE_SPEEX, false)
1004 AM_CONDITIONAL(USE_SUNAUDIO, false)
1005 AM_CONDITIONAL(USE_TAGLIB, false)
1006 AM_CONDITIONAL(USE_WAVEFORM, false)
1007 AM_CONDITIONAL(USE_WAVPACK, false)
1008 AM_CONDITIONAL(USE_X, false)
1009 AM_CONDITIONAL(USE_XSHM, false)
1010 AM_CONDITIONAL(USE_XVIDEO, false)
1011 AM_CONDITIONAL(USE_ZLIB, false)
1012
1013 fi dnl of EXT plugins
1014
1015 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1016
1017 dnl Overview:
1018 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1019 dnl GST_*:              flags shared by all built objects
1020 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1021 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1022 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1023 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1024
1025 dnl GST_OPTION_CFLAGS
1026 if test "x$USE_DEBUG" = xyes; then
1027    PROFILE_CFLAGS="-g"
1028 fi
1029 AC_SUBST(PROFILE_CFLAGS)
1030
1031 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1032   dnl Define _only_ for git (not pre-releases or releases)
1033   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1034 else
1035   DEPRECATED_CFLAGS=""
1036 fi
1037 AC_SUBST(DEPRECATED_CFLAGS)
1038
1039 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1040 dnl at make time with e.g. make ERROR_CFLAGS=""
1041 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1042 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1043 AC_SUBST(GST_OPTION_CFLAGS)
1044 AC_SUBST(GST_OPTION_CXXFLAGS)
1045
1046 dnl our libraries need to be versioned correctly
1047 AC_SUBST(GST_LT_LDFLAGS)
1048
1049 dnl FIXME: do we want to rename to GST_ALL_* ?
1050 dnl prefer internal headers to already installed ones
1051 dnl also add builddir include for enumtypes and marshal
1052 dnl add ERROR_CFLAGS, but overridable
1053 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1054 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1055 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1056 AC_SUBST(GST_CFLAGS)
1057 AC_SUBST(GST_CXXFLAGS)
1058 AC_SUBST(GST_LIBS)
1059
1060 dnl LDFLAGS really should only contain flags, not libs - they get added before
1061 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1062 GST_ALL_LDFLAGS="-no-undefined"
1063 AC_SUBST(GST_ALL_LDFLAGS)
1064
1065 dnl this really should only contain flags, not libs - they get added before
1066 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1067 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1068 AC_SUBST(GST_PLUGIN_LDFLAGS)
1069
1070 dnl *** output files ***
1071
1072 dnl keep this alphabetic per directory, please
1073 AC_CONFIG_FILES(
1074 Makefile
1075 gst/Makefile
1076 gst/alpha/Makefile
1077 gst/apetag/Makefile
1078 gst/audiofx/Makefile
1079 gst/audioparsers/Makefile
1080 gst/auparse/Makefile
1081 gst/autodetect/Makefile
1082 gst/avi/Makefile
1083 gst/cutter/Makefile
1084 gst/deinterlace/Makefile
1085 gst/debugutils/Makefile
1086 gst/effectv/Makefile
1087 gst/equalizer/Makefile
1088 gst/flv/Makefile
1089 gst/goom/Makefile
1090 gst/goom2k1/Makefile
1091 gst/id3demux/Makefile
1092 gst/icydemux/Makefile
1093 gst/imagefreeze/Makefile
1094 gst/interleave/Makefile
1095 gst/isomp4/Makefile
1096 gst/law/Makefile
1097 gst/level/Makefile
1098 gst/matroska/Makefile
1099 gst/monoscope/Makefile
1100 gst/multifile/Makefile
1101 gst/multipart/Makefile
1102 gst/replaygain/Makefile
1103 gst/rtp/Makefile
1104 gst/rtpmanager/Makefile
1105 gst/rtsp/Makefile
1106 gst/shapewipe/Makefile
1107 gst/smpte/Makefile
1108 gst/spectrum/Makefile
1109 gst/udp/Makefile
1110 gst/videobox/Makefile
1111 gst/videocrop/Makefile
1112 gst/videofilter/Makefile
1113 gst/videomixer/Makefile
1114 gst/wavenc/Makefile
1115 gst/wavparse/Makefile
1116 gst/flx/Makefile
1117 gst/y4m/Makefile
1118 ext/Makefile
1119 ext/aalib/Makefile
1120 ext/annodex/Makefile
1121 ext/cairo/Makefile
1122 ext/dv/Makefile
1123 ext/flac/Makefile
1124 ext/gdk_pixbuf/Makefile
1125 ext/jack/Makefile
1126 ext/jpeg/Makefile
1127 ext/libcaca/Makefile
1128 ext/libpng/Makefile
1129 ext/pulse/Makefile
1130 ext/raw1394/Makefile
1131 ext/shout2/Makefile
1132 ext/soup/Makefile
1133 ext/speex/Makefile
1134 ext/taglib/Makefile
1135 ext/wavpack/Makefile
1136 sys/Makefile
1137 sys/directsound/Makefile
1138 sys/oss/Makefile
1139 sys/oss4/Makefile
1140 sys/osxaudio/Makefile
1141 sys/osxvideo/Makefile
1142 sys/sunaudio/Makefile
1143 sys/v4l2/Makefile
1144 sys/waveform/Makefile
1145 sys/ximage/Makefile
1146 po/Makefile.in
1147 tests/Makefile
1148 tests/check/Makefile
1149 tests/examples/Makefile
1150 tests/examples/audiofx/Makefile
1151 tests/examples/cairo/Makefile
1152 tests/examples/equalizer/Makefile
1153 tests/examples/jack/Makefile
1154 tests/examples/level/Makefile
1155 tests/examples/pulse/Makefile
1156 tests/examples/rtp/Makefile
1157 tests/examples/shapewipe/Makefile
1158 tests/examples/spectrum/Makefile
1159 tests/examples/v4l2/Makefile
1160 tests/files/Makefile
1161 tests/icles/Makefile
1162 common/Makefile
1163 common/m4/Makefile
1164 m4/Makefile
1165 docs/Makefile
1166 docs/plugins/Makefile
1167 docs/version.entities
1168 pkgconfig/Makefile
1169 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1170 gst-plugins-good.spec
1171 )
1172
1173 dnl Create the config.h file for Visual Studio builds
1174 dnl Beware of spaces and /'s in some of the shell variable contents.
1175 sed \
1176     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1177     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1178     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1179     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1180     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1181     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1182     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1183     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1184     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1185     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1186     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1187     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1188     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1189     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1190     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1191     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1192     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1193     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1194     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1195     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1196     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1197     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1198     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1199     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1200     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1201     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1202     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1203     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1204     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1205     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1206     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1207     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1208     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1209     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1210     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1211     config.h.in >win32/common/config.h-new
1212
1213 AC_OUTPUT
1214
1215 AG_GST_OUTPUT_PLUGINS
1216 ORC_OUTPUT
1217