configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.91.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AG_GST_LIBTOOL_PREPARE
  48 AS_LIBTOOL(GST, 0, 0, 0)
  49
  50 dnl *** required versions of GStreamer stuff ***
  51 GST_REQ=0.11.91
  52 GSTPB_REQ=0.11.91
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl set up gettext
  63 dnl the version check needs to stay here because autopoint greps for it
  64 AM_GNU_GETTEXT_VERSION([0.17])
  65 AM_GNU_GETTEXT([external])
  66 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  67
  68 dnl *** check for arguments to configure ***
  69
  70 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  71
  72 AG_GST_ARG_DEBUG
  73 AG_GST_ARG_PROFILING
  74 AG_GST_ARG_VALGRIND
  75 AG_GST_ARG_GCOV
  76
  77 AG_GST_ARG_EXAMPLES
  78
  79 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  80 AG_GST_ARG_WITH_PACKAGE_NAME
  81 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  82
  83 AG_GST_ARG_WITH_PLUGINS
  84
  85 AG_GST_ARG_ENABLE_EXTERNAL
  86
  87 AG_GST_ARG_ENABLE_EXPERIMENTAL
  88
  89 dnl *** checks for platform ***
  90
  91 dnl * hardware/architecture *
  92
  93 dnl common/m4/gst-arch.m4
  94 dnl check CPU type
  95 AG_GST_ARCH
  96
  97 dnl Determine endianness
  98 AC_C_BIGENDIAN
  99
 100 dnl *** checks for programs ***
 101
 102 dnl find a compiler
 103 AC_PROG_CC
 104 AC_PROG_CC_STDC
 105
 106 dnl determine c++ compiler
 107 AC_PROG_CXX
 108 dnl determine if c++ is available on this system
 109 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 110
 111 dnl determine c++ preprocessor
 112 dnl FIXME: do we need this ?
 113 AC_PROG_CXXCPP
 114
 115 AS_PROG_OBJC
 116
 117 dnl check if the compiler supports '-c' and '-o' options
 118 AM_PROG_CC_C_O
 119
 120 dnl find an assembler
 121 AM_PROG_AS
 122
 123 dnl check if the compiler supports do while(0) macros
 124 AG_GST_CHECK_DOWHILE_MACROS
 125
 126 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 127 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.3])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/udp
 149 AC_CHECK_HEADERS([sys/time.h])
 150
 151 dnl used in gst/udp
 152 AC_CHECK_HEADERS([sys/socket.h])
 153
 154 dnl *** checks for types/defines ***
 155
 156 dnl Check for FIONREAD ioctl declaration.  This check is needed
 157 dnl for the UDP plugin to build on Solaris
 158 GST_CHECK_FIONREAD
 159
 160 dnl *** checks for structures ***
 161
 162 dnl *** checks for compiler characteristics ***
 163
 164 dnl check if we have GCC inline-asm
 165 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 166 if test x$HAVE_GCC_ASM = xyes ; then
 167   AC_DEFINE(HAVE_GCC_ASM, 1,
 168     [Define if compiler supports gcc inline assembly])
 169 fi
 170 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 171
 172 dnl *** checks for library functions ***
 173
 174 LIBS_SAVE=$LIBS
 175 LIBS="$LIBS $LIBM"
 176 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 177 LIBS=$LIBS_SAVE
 178
 179 dnl Check whether isinf() is defined by math.h
 180 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 181     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 182 if test "$ac_cv_have_isinf" = "yes"
 183 then
 184     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 185 fi
 186
 187 dnl Check for mmap (needed by electricfence plugin)
 188 AC_FUNC_MMAP
 189 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 190
 191 dnl Check for mmap (needed by electricfence plugin)
 192
 193 AC_CHECK_TYPE([struct ip_mreqn], [
 194               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 195               [#include <netinet/in.h>])
 196
 197 dnl *** checks for dependency libraries ***
 198
 199
 200 dnl GLib
 201 GLIB_REQ=2.31.14
 202 AG_GST_GLIB_CHECK([$GLIB_REQ])
 203
 204 dnl Orc
 205 ORC_CHECK([0.4.11])
 206
 207 dnl checks for gstreamer
 208 dnl uninstalled is selected preferentially -- see pkg-config(1)
 209 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 210 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 211 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 212 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 213 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 214 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 215
 216 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 217 if test -z $GST_TOOLS_DIR; then
 218   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 219 fi
 220 AC_SUBST(GST_TOOLS_DIR)
 221
 222 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 223 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 224
 225 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 226
 227 dnl Check for documentation xrefs
 228 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 229 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 230 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 231 AC_SUBST(GLIB_PREFIX)
 232 AC_SUBST(GST_PREFIX)
 233 AC_SUBST(GSTPB_PREFIX)
 234
 235 dnl GTK is optional and used in examples
 236 HAVE_GTK=no
 237 GTK2_REQ=2.14.0
 238 GTK3_REQ=2.91.3
 239 if test "x$BUILD_EXAMPLES" = "xyes"; then
 240   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 241   AC_ARG_WITH([gtk],
 242     AC_HELP_STRING([--with-gtk=3.0|2.0],
 243                    [which gtk+ version to compile against (default: 2.0)]),
 244     [case "$with_gtk" in
 245         2.0) GTK_REQ=$GTK2_REQ ;;
 246         3.0) GTK_REQ=$GTK3_REQ ;;
 247         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 248     esac],
 249     [with_gtk=2.0
 250      GTK_REQ=$GTK2_REQ])
 251   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 252   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 253   dnl some examples need gtk+-x11
 254   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 255   AC_SUBST(GTK_LIBS)
 256   AC_SUBST(GTK_CFLAGS)
 257 fi
 258 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 259 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 260
 261 dnl *** set variables based on configure arguments ***
 262
 263 dnl set license and copyright notice
 264 GST_LICENSE="LGPL"
 265 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 266 AC_SUBST(GST_LICENSE)
 267
 268 dnl set location of plugin directory
 269 AG_GST_SET_PLUGINDIR
 270
 271 dnl set release date/time
 272 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 273   ["${srcdir}/gst-plugins-good.doap"],
 274   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 275
 276 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 277 dnl make sure it doesn't complain about unused variables if debugging is disabled
 278 NO_WARNINGS=""
 279 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 280
 281 dnl define an ERROR_CFLAGS Makefile variable
 282 dnl -Wundef: too many broken headers
 283 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 284   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 285         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 286         -Wwrite-strings -Wold-style-definition -Waggregate-return
 287         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 288         -Wnested-externs $NO_WARNINGS])
 289 else
 290   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 291   dnl doesn't understand all warning flags that the C compiler knows about
 292   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 293   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 294         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 295         -Wwrite-strings -Wold-style-definition
 296         -Winit-self -Wmissing-include-dirs -Wno-multichar
 297         -Wnested-externs $NO_WARNINGS])
 298 fi
 299
 300 dnl define an ERROR_CXXFLAGS Makefile variable
 301 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 302         -Wmissing-declarations -Wredundant-decls
 303         -Wwrite-strings
 304         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 305         $NO_WARNINGS])
 306
 307 dnl define correct level for debugging messages
 308 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 309
 310 dnl used in examples
 311 AG_GST_DEFAULT_ELEMENTS
 312
 313 dnl *** plug-ins to include ***
 314
 315 dnl Non ported plugins (non-dependant, then dependant)
 316 dnl Make sure you have a space before and after all plugins
 317 GST_PLUGINS_NONPORTED="deinterlace \
 318  cairo cairo_gobject gdk_pixbuf \
 319  osx_video osx_audio "
 320 AC_SUBST(GST_PLUGINS_NONPORTED)
 321
 322 dnl these are all the gst plug-ins, compilable without additional libs
 323 dnl videofilter is at the top because others depend on it
 324 AG_GST_CHECK_PLUGIN(alpha)
 325 AG_GST_CHECK_PLUGIN(apetag)
 326 AG_GST_CHECK_PLUGIN(audiofx)
 327 AG_GST_CHECK_PLUGIN(audioparsers)
 328 AG_GST_CHECK_PLUGIN(auparse)
 329 AG_GST_CHECK_PLUGIN(autodetect)
 330 AG_GST_CHECK_PLUGIN(avi)
 331 AG_GST_CHECK_PLUGIN(cutter)
 332 AG_GST_CHECK_PLUGIN(debugutils)
 333 AG_GST_CHECK_PLUGIN(deinterlace)
 334 AG_GST_CHECK_PLUGIN(effectv)
 335 AG_GST_CHECK_PLUGIN(equalizer)
 336 AG_GST_CHECK_PLUGIN(flv)
 337 AG_GST_CHECK_PLUGIN(flx)
 338 AG_GST_CHECK_PLUGIN(goom)
 339 AG_GST_CHECK_PLUGIN(goom2k1)
 340 AG_GST_CHECK_PLUGIN(icydemux)
 341 AG_GST_CHECK_PLUGIN(id3demux)
 342 AG_GST_CHECK_PLUGIN(imagefreeze)
 343 AG_GST_CHECK_PLUGIN(interleave)
 344 AG_GST_CHECK_PLUGIN(isomp4)
 345 AG_GST_CHECK_PLUGIN(law)
 346 AG_GST_CHECK_PLUGIN(level)
 347 AG_GST_CHECK_PLUGIN(matroska)
 348 AG_GST_CHECK_PLUGIN(monoscope)
 349 AG_GST_CHECK_PLUGIN(multifile)
 350 AG_GST_CHECK_PLUGIN(multipart)
 351 AG_GST_CHECK_PLUGIN(replaygain)
 352 AG_GST_CHECK_PLUGIN(rtp)
 353 AG_GST_CHECK_PLUGIN(rtpmanager)
 354 AG_GST_CHECK_PLUGIN(rtsp)
 355 AG_GST_CHECK_PLUGIN(shapewipe)
 356 AG_GST_CHECK_PLUGIN(smpte)
 357 AG_GST_CHECK_PLUGIN(spectrum)
 358 AG_GST_CHECK_PLUGIN(udp)
 359 AG_GST_CHECK_PLUGIN(videobox)
 360 AG_GST_CHECK_PLUGIN(videocrop)
 361 AG_GST_CHECK_PLUGIN(videofilter)
 362 AG_GST_CHECK_PLUGIN(videomixer)
 363 AG_GST_CHECK_PLUGIN(wavenc)
 364 AG_GST_CHECK_PLUGIN(wavparse)
 365 AG_GST_CHECK_PLUGIN(y4m)
 366
 367 dnl disable experimental plug-ins
 368 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 369   AG_GST_DISABLE_PLUGIN(monoscope)
 370 fi
 371
 372 dnl *** sys plug-ins ***
 373
 374 echo
 375 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 376 echo
 377
 378 dnl DirectSound
 379 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 380 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 381   HAVE_DIRECTSOUND="no"
 382   save_CFLAGS="$CFLAGS"
 383   save_LDFLAGS="$LDFLAGS"
 384   save_LIBS="$LIBS"
 385   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 386   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 387   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 388   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 389   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 390 #include <windows.h>
 391 #include <dxerr9.h>
 392 #include <dsound.h>
 393 ]], [[
 394   DXGetErrorString9 (0);
 395   DirectSoundCreate(NULL, NULL, NULL);
 396 ]])
 397 ],
 398     [HAVE_DIRECTSOUND="yes"],
 399     [HAVE_DIRECTSOUND="no"])
 400   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 401   CFLAGS=$save_CFLAGS
 402   LDFLAGS=$save_LDFLAGS
 403   LIBS=$save_LIBS
 404
 405   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 406     dnl this is much more than we want
 407     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 408     AC_SUBST(DIRECTSOUND_CFLAGS)
 409     AC_SUBST(DIRECTSOUND_LDFLAGS)
 410     AC_SUBST(DIRECTSOUND_LIBS)
 411   fi
 412   AC_SUBST(HAVE_DIRECTSOUND)
 413 ])
 414
 415 dnl *** Win32 WaveOut ***
 416 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 417 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 418   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 419 ])
 420
 421 dnl *** OSS audio *** (Linux, *BSD)
 422 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 423 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 424  HAVE_OSS="yes"
 425 dnl Linux and newer BSD versions :
 426  AC_CHECK_HEADER(sys/soundcard.h, [
 427    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 428    ] , [
 429 dnl Some old BSD versions and also newer OpenBSD versions :
 430    AC_CHECK_HEADER(soundcard.h, [
 431      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 432      ], [
 433   dnl Some old BSD versions :
 434      AC_CHECK_HEADER(machine/soundcard.h, [
 435        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 436          [Define if OSS includes are in /machine/])
 437        ], [
 438        HAVE_OSS="no"
 439      ])
 440    ])
 441  ])
 442 ])
 443
 444 dnl *** oss4 ***
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 446 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 447   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 448   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 449       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 450       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 451 ])
 452
 453 dnl *** Sun Audio ***
 454 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 455 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 456   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 457 ])
 458
 459 dnl *** OSX Audio ***
 460 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 461 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 462   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 463 ])
 464
 465 dnl *** OS X video ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 467 HAVE_OSX_VIDEO="no"
 468 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 469   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 470 ])
 471 dnl in case header OpenGL/gl.h is found on other platforms
 472 case "$host" in
 473   *-*darwin*)
 474     dnl do nothing
 475     ;;
 476   *)
 477     HAVE_OSX_VIDEO="no"
 478     ;;
 479 esac
 480
 481
 482 dnl *** Video 4 Linux 2 ***
 483 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 484 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 486 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 487   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 488   AC_TRY_COMPILE([
 489 #include <sys/types.h>
 490 #ifdef __sun /* Solaris */
 491 #include <sys/types.h>
 492 #include <sys/videodev2.h>
 493 #else /* Linux */
 494 #include <linux/types.h>
 495 #define _LINUX_TIME_H
 496 #define __user
 497 #include <linux/videodev2.h>
 498 #endif
 499 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 500 #error too early v4l2 version or no v4l2 at all
 501 #endif
 502     ], [
 503 return 0;
 504     ], [
 505       HAVE_GST_V4L2="yes"
 506       AC_MSG_RESULT(yes)
 507     ], [
 508       HAVE_GST_V4L2="no"
 509       AC_MSG_RESULT(no)
 510
 511       HAVE_VIDEODEV=no
 512       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 513       [
 514         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 515       ])
 516
 517       if test "x$HAVE_VIDEODEV" = "xyes"; then
 518         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 519         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 520       else
 521         AC_MSG_WARN([video4linux2 was not found])
 522       fi
 523     ])
 524
 525   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 526     dnl check for missing v4l2_buffer declaration (see #135919)
 527     MISSING_DECL=0
 528     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 529     AC_TRY_COMPILE([
 530 #include <sys/types.h>
 531 #ifdef __sun /* Solaris */
 532 #include <sys/types.h>
 533 #include <sys/videodev2.h>
 534 #else /* Linux */
 535 #include <linux/types.h>
 536 #define _LINUX_TIME_H
 537 #define __user
 538 #include <linux/videodev2.h>
 539 #endif
 540     ],[
 541 struct v4l2_buffer buf;
 542 buf.index = 0;
 543 return 0;
 544     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 545     if [ test x$MISSING_DECL = x1 ]; then
 546       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 547     fi
 548
 549     dnl check for XOverlay libraries
 550     AG_GST_CHECK_XV
 551   fi
 552 ])
 553
 554 # Optional gudev for device probing
 555 AC_ARG_WITH([gudev],
 556   AC_HELP_STRING([--with-gudev],
 557     [device detection with gudev]),
 558   [],
 559   [with_gudev=check])
 560 if test x$HAVE_GST_V4L2 = xyes; then
 561   if test x$with_gudev != xno; then
 562       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 563           [ have_gudev=yes
 564             AC_DEFINE(HAVE_GUDEV, 1,
 565                [Whether gudev is available for device detection])
 566             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 567           ], [
 568           have_gudev=no
 569           ])
 570   else
 571     have_gudev=no
 572   fi
 573 fi
 574 AC_SUBST(GUDEV_CFLAGS)
 575 AC_SUBST(GUDEV_LIBS)
 576
 577 # Make libv4l2 non-automagic
 578 AC_ARG_WITH([libv4l2],
 579   AC_HELP_STRING([--with-libv4l2],
 580     [support video buffer conversion using libv4l2]),
 581   [],
 582   [with_libv4l2=check])
 583 if test x$HAVE_GST_V4L2 = xyes; then
 584   if test x$with_libv4l2 != xno; then
 585       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 586           [ have_libv4l2=yes
 587             AC_DEFINE(HAVE_LIBV4L2, 1,
 588                 [Whether libv4l2 is available for video buffer conversion])
 589           ], [
 590           have_libv4l2=no
 591           ])
 592   else
 593     have_libv4l2=no
 594   fi
 595 fi
 596
 597 dnl Check for X11
 598 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 599 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 600                   [ximagesrc], [
 601   AC_PATH_XTRA
 602
 603   dnl now try to find the HEADER
 604   ac_cflags_save="$CFLAGS"
 605   ac_cppflags_save="$CPPFLAGS"
 606   CFLAGS="$CFLAGS $X_CFLAGS"
 607   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 608   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 609
 610   if test "x$HAVE_X" = "xno"
 611   then
 612     AC_MSG_NOTICE([cannot find X11 development files])
 613   else
 614     dnl this is much more than we want
 615     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 616     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 617     dnl it does not add the libs; therefore we add them here
 618     X_LIBS="$X_LIBS -lX11"
 619     AC_SUBST(X_CFLAGS)
 620     AC_SUBST(X_LIBS)
 621
 622     dnl check for Xfixes
 623     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 624     if test "x$HAVE_XFIXES" = "xyes"
 625     then
 626         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 627     fi
 628     AC_SUBST(XFIXES_LIBS)
 629     AC_SUBST(XFIXES_CFLAGS)
 630
 631     dnl check for Xdamage
 632     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 633     if test "x$HAVE_XDAMAGE" = "xyes"
 634     then
 635         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 636     fi
 637     AC_SUBST(XDAMAGE_LIBS)
 638     AC_SUBST(XDAMAGE_CFLAGS)
 639   fi
 640   AC_SUBST(HAVE_X)
 641   CFLAGS="$ac_cflags_save"
 642   CPPFLAGS="$ac_cppflags_save"
 643 ])
 644
 645 dnl FIXME: this should be rolled into the test above, it's just an additional
 646 dnl feature of the ximagesrc plug-in
 647 dnl This is the same as in gst-plugins-base
 648 dnl check for X Shm
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 650 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 651   if test x$HAVE_X = xyes; then
 652     AC_CHECK_LIB(Xext, XShmAttach,
 653                  HAVE_XSHM="yes", HAVE_XSHM="no",
 654                  $X_LIBS)
 655     if test "x$HAVE_XSHM" = "xyes"; then
 656       XSHM_LIBS="-lXext"
 657     else
 658       dnl On AIX, it is in XextSam instead, but we still need -lXext
 659       AC_CHECK_LIB(XextSam, XShmAttach,
 660                    HAVE_XSHM="yes", HAVE_XSHM="no",
 661                    $X_LIBS)
 662       if test "x$HAVE_XSHM" = "xyes"; then
 663         XSHM_LIBS="-lXext -lXextSam"
 664       fi
 665     fi
 666   fi
 667 ], ,[
 668   AC_SUBST(HAVE_XSHM)
 669   AC_SUBST(XSHM_LIBS)
 670 ])
 671
 672 dnl for V4L2, we also need to know if we have XVIDEO
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 674 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 675                   [], [
 676   AG_GST_CHECK_XV
 677 ])
 678
 679 dnl *** ext plug-ins ***
 680 dnl keep this list sorted alphabetically !
 681
 682 if test "x$BUILD_EXTERNAL" = "xyes"; then
 683
 684 echo
 685 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 686 echo
 687
 688 dnl *** aalib ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 690 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 691   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 692   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 693 ])
 694
 695 dnl *** cairo ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 697 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 698   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 699 ])
 700
 701 dnl *** cairo-gobject ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 703 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 704   [Cairo graphics rendering gobject bindings], cairooverlay, [
 705   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 706 ])
 707
 708 dnl *** FLAC ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 710 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 711   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 712 ])
 713
 714 dnl *** GDK pixbuf ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 716 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 717   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 718 ])
 719
 720 dnl *** Jack ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 722 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 723   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 724   AC_SUBST(JACK_CFLAGS)
 725   AC_SUBST(JACK_LIBS)
 726
 727   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 728   if test x$HAVE_JACK_0_120_1 = xyes; then
 729     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 730   fi
 731   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 732   if test x$HAVE_JACK_1_9_7 = xyes; then
 733     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 734   fi
 735
 736 ])
 737
 738 dnl *** jpeg ***
 739 dnl FIXME: we could use header checks here as well IMO
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 741 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 742   AC_ARG_WITH(jpeg-mmx,
 743     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 744   OLD_LIBS="$LIBS"
 745   if test x$with_jpeg_mmx != x; then
 746     LIBS="$LIBS -L$with_jpeg_mmx"
 747   fi
 748   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 749   JPEG_LIBS="$LIBS -ljpeg-mmx"
 750   LIBS="$OLD_LIBS"
 751   if test x$HAVE_JPEG != xyes; then
 752     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 753     JPEG_LIBS="-ljpeg"
 754   fi
 755   AC_SUBST(JPEG_LIBS)
 756 ])
 757
 758 dnl *** libcaca ***
 759 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 760 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 761   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 762 ])
 763
 764 dnl *** libdv ***
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 766 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 767   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 768 ])
 769
 770 dnl *** libpng ***
 771 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 772 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 773   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 774 ])
 775
 776 dnl *** pulseaudio ***
 777 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 778 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 779
 780   dnl used in ext/pulse/pulseutil.c
 781   AC_CHECK_HEADERS([process.h])
 782
 783   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 784 ])
 785
 786 dnl *** dv1394 ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 788 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 789   dnl first test for libraw1394 >= 2.0.0
 790   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 791   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 792   dnl now see how far we got
 793   if test x$HAVE_RAW1394 = xyes && \
 794      test x$HAVE_LIBIEC61883 = xyes; then
 795        AG_GST_CHECK_LIBHEADER(AVC1394,
 796         avc1394, avc1394_send_command, $RAW1394_LIBS,
 797         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 798        AG_GST_CHECK_LIBHEADER(ROM1394,
 799         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 800         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 801        if test x$HAVE_AVC1394 = xyes && \
 802           test x$HAVE_AVC1394 = xyes && \
 803           test x$HAVE_ROM1394 = xyes; then
 804           HAVE_DV1394=yes
 805           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 806           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 807           AC_SUBST(DV1394_CFLAGS)
 808           AC_SUBST(DV1394_LIBS)
 809         fi
 810   else
 811        if test x$HAVE_RAW1394 = xno; then
 812           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 813           AG_GST_CHECK_LIBHEADER(AVC1394,
 814            avc1394, avc1394_send_command, $RAW1394_LIBS,
 815            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 816           AG_GST_CHECK_LIBHEADER(ROM1394,
 817            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 818            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 819           if test x$HAVE_RAW1394 = xyes && \
 820              test x$HAVE_AVC1394 = xyes && \
 821              test x$HAVE_ROM1394 = xyes; then
 822              HAVE_DV1394=yes
 823              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 824              DV1394_CFLAGS="$RAW1394_CFLAGS"
 825              if test x$HAVE_LIBIEC61883 = xyes; then
 826                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 827                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 828              fi
 829              AC_SUBST(DV1394_CFLAGS)
 830              AC_SUBST(DV1394_LIBS)
 831            fi
 832          fi
 833   fi
 834 ])
 835 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 836
 837 dnl *** shout2 ***
 838 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 839 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 840   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 841 ])
 842
 843 dnl *** soup ***
 844 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 845 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 846   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 847     HAVE_SOUP="yes"
 848     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 849   ],[
 850     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 851       HAVE_SOUP="no"
 852     ])
 853   ])
 854   AC_SUBST(SOUP_CFLAGS)
 855   AC_SUBST(SOUP_LIBS)
 856 ])
 857
 858 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 859 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 860 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 861 dnl   speex_jitter.h is 1.1.x only
 862 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 863 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 864   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 865   if test $HAVE_SPEEX = no
 866   then
 867     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 868       AC_CHECK_HEADER(speex/speex_jitter.h, [
 869         dnl speex 1.1.x :
 870         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 871           dnl speex 1.1.5 or + :
 872           HAVE_SPEEX="yes"
 873           SPEEX_LIBS="-lspeex"
 874           AC_SUBST(SPEEX_CFLAGS)
 875           AC_SUBST(SPEEX_LIBS)
 876         ],[
 877           HAVE_SPEEX="no"
 878         ])
 879       ],[
 880         dnl speex 1.0.x :
 881           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 882             dnl speex 1.0.4
 883             HAVE_SPEEX="yes"
 884             SPEEX_LIBS="-lspeex"
 885             AC_SUBST(SPEEX_CFLAGS)
 886             AC_SUBST(SPEEX_LIBS)
 887
 888             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 889               [defined if speex 1.0.x API detected])
 890         ],[
 891             HAVE_SPEEX="no"
 892             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 893         ], [
 894 #include <speex/speex.h>
 895         ])
 896       ])
 897     ])
 898   fi
 899 ])
 900
 901 dnl *** taglib ***
 902 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 903 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 904   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 905   if test "x$HAVE_CXX" != "xyes"; then
 906     USE_TAGLIB=false
 907     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 908   else
 909     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 910     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 911         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 912       ], [
 913         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 914     ])
 915     AC_SUBST(TAGLIB_CXXFLAGS)
 916   fi
 917 ])
 918
 919 dnl *** wavpack ***
 920 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 921 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 922   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 923     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 924       HAVE_WAVPACK=yes
 925       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 926     ],[
 927       HAVE_WAVPACK=no
 928     ])
 929   ])
 930   AC_SUBST(WAVPACK_CFLAGS)
 931   AC_SUBST(WAVPACK_LIBS)
 932 ])
 933
 934 dnl *** qtdemux & matroska prefer to have zlib ***
 935 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 936 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 937   AG_GST_CHECK_LIBHEADER(ZLIB,
 938     z, uncompress,, zlib.h, [
 939     HAVE_ZLIB="yes"
 940     ZLIB_LIBS="-lz"
 941     AC_SUBST(ZLIB_LIBS)
 942   ])
 943 ])
 944
 945 dnl *** matroska prefers to have bz2 ***
 946 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 947 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 948   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 949   AC_SUBST(BZ2_LIBS)
 950 ])
 951
 952 else
 953
 954 dnl not building plugins with external dependencies,
 955 dnl but we still need to set the conditionals
 956 AM_CONDITIONAL(USE_AALIB, false)
 957 AM_CONDITIONAL(USE_BZ2, false)
 958 AM_CONDITIONAL(USE_CAIRO, false)
 959 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 960 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 961 AM_CONDITIONAL(USE_DV1394, false)
 962 AM_CONDITIONAL(USE_FLAC, false)
 963 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 964 AM_CONDITIONAL(USE_GST_V4L2, false)
 965 AM_CONDITIONAL(USE_JACK, false)
 966 AM_CONDITIONAL(USE_JPEG, false)
 967 AM_CONDITIONAL(USE_LIBCACA, false)
 968 AM_CONDITIONAL(USE_LIBDV, false)
 969 AM_CONDITIONAL(USE_LIBIEC61883, false)
 970 AM_CONDITIONAL(USE_LIBPNG, false)
 971 AM_CONDITIONAL(USE_OSS, false)
 972 AM_CONDITIONAL(USE_OSS4, false)
 973 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 974 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 975 AM_CONDITIONAL(USE_PULSE, false)
 976 AM_CONDITIONAL(USE_SHOUT2, false)
 977 AM_CONDITIONAL(USE_SOUP, false)
 978 AM_CONDITIONAL(USE_SPEEX, false)
 979 AM_CONDITIONAL(USE_SUNAUDIO, false)
 980 AM_CONDITIONAL(USE_TAGLIB, false)
 981 AM_CONDITIONAL(USE_WAVEFORM, false)
 982 AM_CONDITIONAL(USE_WAVPACK, false)
 983 AM_CONDITIONAL(USE_X, false)
 984 AM_CONDITIONAL(USE_XSHM, false)
 985 AM_CONDITIONAL(USE_XVIDEO, false)
 986 AM_CONDITIONAL(USE_ZLIB, false)
 987
 988 fi dnl of EXT plugins
 989
 990 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 991
 992 dnl Overview:
 993 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 994 dnl GST_*:              flags shared by all built objects
 995 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 996 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 997 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 998 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 999
1000 dnl GST_OPTION_CFLAGS
1001 if test "x$USE_DEBUG" = xyes; then
1002    PROFILE_CFLAGS="-g"
1003 fi
1004 AC_SUBST(PROFILE_CFLAGS)
1005
1006 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1007   dnl Define _only_ for git (not pre-releases or releases)
1008   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1009 else
1010   DEPRECATED_CFLAGS=""
1011 fi
1012 AC_SUBST(DEPRECATED_CFLAGS)
1013
1014 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1015 dnl at make time with e.g. make ERROR_CFLAGS=""
1016 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1017 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1018 AC_SUBST(GST_OPTION_CFLAGS)
1019 AC_SUBST(GST_OPTION_CXXFLAGS)
1020
1021 dnl our libraries need to be versioned correctly
1022 AC_SUBST(GST_LT_LDFLAGS)
1023
1024 dnl FIXME: do we want to rename to GST_ALL_* ?
1025 dnl prefer internal headers to already installed ones
1026 dnl also add builddir include for enumtypes and marshal
1027 dnl add ERROR_CFLAGS, but overridable
1028 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1029 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1030 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1031 AC_SUBST(GST_CFLAGS)
1032 AC_SUBST(GST_CXXFLAGS)
1033 AC_SUBST(GST_LIBS)
1034
1035 dnl LDFLAGS really should only contain flags, not libs - they get added before
1036 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1037 GST_ALL_LDFLAGS="-no-undefined"
1038 AC_SUBST(GST_ALL_LDFLAGS)
1039
1040 dnl this really should only contain flags, not libs - they get added before
1041 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1042 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1043 AC_SUBST(GST_PLUGIN_LDFLAGS)
1044
1045 dnl *** output files ***
1046
1047 dnl keep this alphabetic per directory, please
1048 AC_CONFIG_FILES(
1049 Makefile
1050 gst/Makefile
1051 gst/alpha/Makefile
1052 gst/apetag/Makefile
1053 gst/audiofx/Makefile
1054 gst/audioparsers/Makefile
1055 gst/auparse/Makefile
1056 gst/autodetect/Makefile
1057 gst/avi/Makefile
1058 gst/cutter/Makefile
1059 gst/deinterlace/Makefile
1060 gst/debugutils/Makefile
1061 gst/effectv/Makefile
1062 gst/equalizer/Makefile
1063 gst/flv/Makefile
1064 gst/goom/Makefile
1065 gst/goom2k1/Makefile
1066 gst/id3demux/Makefile
1067 gst/icydemux/Makefile
1068 gst/imagefreeze/Makefile
1069 gst/interleave/Makefile
1070 gst/isomp4/Makefile
1071 gst/law/Makefile
1072 gst/level/Makefile
1073 gst/matroska/Makefile
1074 gst/monoscope/Makefile
1075 gst/multifile/Makefile
1076 gst/multipart/Makefile
1077 gst/replaygain/Makefile
1078 gst/rtp/Makefile
1079 gst/rtpmanager/Makefile
1080 gst/rtsp/Makefile
1081 gst/shapewipe/Makefile
1082 gst/smpte/Makefile
1083 gst/spectrum/Makefile
1084 gst/udp/Makefile
1085 gst/videobox/Makefile
1086 gst/videocrop/Makefile
1087 gst/videofilter/Makefile
1088 gst/videomixer/Makefile
1089 gst/wavenc/Makefile
1090 gst/wavparse/Makefile
1091 gst/flx/Makefile
1092 gst/y4m/Makefile
1093 ext/Makefile
1094 ext/aalib/Makefile
1095 ext/cairo/Makefile
1096 ext/dv/Makefile
1097 ext/flac/Makefile
1098 ext/gdk_pixbuf/Makefile
1099 ext/jack/Makefile
1100 ext/jpeg/Makefile
1101 ext/libcaca/Makefile
1102 ext/libpng/Makefile
1103 ext/pulse/Makefile
1104 ext/raw1394/Makefile
1105 ext/shout2/Makefile
1106 ext/soup/Makefile
1107 ext/speex/Makefile
1108 ext/taglib/Makefile
1109 ext/wavpack/Makefile
1110 sys/Makefile
1111 sys/directsound/Makefile
1112 sys/oss/Makefile
1113 sys/oss4/Makefile
1114 sys/osxaudio/Makefile
1115 sys/osxvideo/Makefile
1116 sys/sunaudio/Makefile
1117 sys/v4l2/Makefile
1118 sys/waveform/Makefile
1119 sys/ximage/Makefile
1120 po/Makefile.in
1121 tests/Makefile
1122 tests/check/Makefile
1123 tests/examples/Makefile
1124 tests/examples/audiofx/Makefile
1125 tests/examples/cairo/Makefile
1126 tests/examples/equalizer/Makefile
1127 tests/examples/jack/Makefile
1128 tests/examples/level/Makefile
1129 tests/examples/pulse/Makefile
1130 tests/examples/rtp/Makefile
1131 tests/examples/shapewipe/Makefile
1132 tests/examples/spectrum/Makefile
1133 tests/examples/v4l2/Makefile
1134 tests/files/Makefile
1135 tests/icles/Makefile
1136 common/Makefile
1137 common/m4/Makefile
1138 m4/Makefile
1139 docs/Makefile
1140 docs/plugins/Makefile
1141 docs/version.entities
1142 pkgconfig/Makefile
1143 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1144 gst-plugins-good.spec
1145 )
1146
1147 dnl Create the config.h file for Visual Studio builds
1148 dnl Beware of spaces and /'s in some of the shell variable contents.
1149 sed \
1150     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1151     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1152     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1153     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1154     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1155     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1156     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1157     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1158     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1159     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1160     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1161     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1162     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1163     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1164     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1165     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1166     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1167     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1168     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1169     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1170     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1171     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1172     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1173     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1174     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1175     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1176     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1177     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1178     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1179     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1180     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1181     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1182     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1183     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1184     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1185     config.h.in >win32/common/config.h-new
1186
1187 AC_OUTPUT
1188
1189 AG_GST_OUTPUT_PLUGINS
1190 ORC_OUTPUT
1191