configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(Gst-RTSP, 0.10.6.1,
   7     http://gstreamer.net/,
   8     gst-rtsp)
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_CVS="no", GST_CVS="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl our libraries and install dirs use major.minor as a version
  32 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  33 dnl we override it here if we need to for the release candidate of new series
  34 GST_MAJORMINOR=0.10
  35 AC_SUBST(GST_MAJORMINOR)
  36
  37 AM_PROG_LIBTOOL
  38
  39 dnl *** required versions of GStreamer stuff ***
  40 GST_REQ=0.10.29
  41 GSTPB_REQ=0.10.29
  42
  43 dnl *** autotools stuff ****
  44
  45 dnl allow for different autotools
  46 AS_AUTOTOOLS_ALTERNATE
  47
  48 dnl Add parameters for aclocal
  49 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  50
  51 dnl *** check for arguments to configure ***
  52
  53 AG_GST_ARG_DEBUG
  54 AG_GST_ARG_VALGRIND
  55 AG_GST_ARG_GCOV
  56 AG_GST_ARG_WITH_PACKAGE_NAME
  57 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  58
  59 dnl *** checks for platform ***
  60
  61 dnl * hardware/architecture *
  62
  63 dnl *** checks for programs ***
  64
  65 dnl find a compiler
  66 AC_PROG_CC
  67 AM_PROG_CC_C_O
  68
  69 dnl check for python
  70 AM_PATH_PYTHON(2.3)
  71 AM_CHECK_PYTHON_HEADERS([HAVE_PYTHON_HEADERS="yes"], [HAVE_PYTHON_HEADERS="no"])
  72
  73 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  74 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  75
  76 dnl check for documentation tools
  77 AG_GST_DOCBOOK_CHECK
  78 GTK_DOC_CHECK([1.3])
  79
  80 AC_SUBST(PYGOBJECT_REQ, 2.11.2)
  81
  82 dnl check for pygobject (optional, used in the bindings)
  83 PKG_CHECK_MODULES(PYGOBJECT, pygobject-2.0 >= $PYGOBJECT_REQ,
  84   [
  85     HAVE_PYGOBJECT="yes"
  86   ],
  87   [
  88     HAVE_PYGOBJECT="no"
  89   ])
  90 AC_SUBST(PYGOBJECT_CFLAGS)
  91
  92 dnl check for gst-python
  93 PKG_CHECK_MODULES(PYGST, gst-python-0.10,
  94   [
  95     HAVE_PYGST="yes"
  96   ],
  97   [
  98     HAVE_PYGST="no"
  99   ])
 100
 101 if test "x$HAVE_PYGST" = "xyes"; then
 102   PYGST_DEFSDIR=`pkg-config gst-python-0.10 --variable=defsdir`
 103 fi
 104 AC_SUBST(PYGST_DEFSDIR, $PYGST_DEFSDIR)
 105
 106 if test "x$HAVE_PYTHON_HEADERS" = "xyes" -a \
 107     "x$HAVE_PYGOBJECT" = "xyes" -a \
 108     "x$HAVE_PYGST" = "xyes"; then
 109   HAVE_PYTHON_BINDINGS="yes"
 110 else
 111   HAVE_PYTHON_BINDINGS="no"
 112 fi
 113
 114 AM_CONDITIONAL(WITH_PYTHON, [test "x$HAVE_PYTHON_BINDINGS" = "xyes"])
 115
 116 dnl Check for Vala
 117 AC_ARG_ENABLE([vala],
 118   AC_HELP_STRING([--enable-vala],[enable Vala bindings (default=yes)]),
 119   [case "${enableval}" in
 120     yes) enable_vala=yes ;;
 121     no)  enable_vala=no ;;
 122     *) AC_MSG_ERROR(bad value ${enableval} for --enable-vala) ;;
 123    esac
 124   ],
 125   [enable_vala=yes]) dnl Default value
 126 AM_CONDITIONAL(WITH_VALA, [test "x$enable_vala" = "xyes"])
 127
 128 dnl *** checks for libraries ***
 129
 130 dnl *** checks for header files ***
 131
 132 dnl *** checks for types/defines ***
 133
 134 dnl *** checks for structures ***
 135
 136 dnl *** checks for compiler characteristics ***
 137
 138 dnl *** checks for library functions ***
 139
 140 dnl *** checks for dependancy libraries ***
 141
 142 dnl GLib is required (GStreamer is ok with GLib-2.8, but we want at least 2.10)
 143 GLIB_REQ=2.10.0
 144 AC_SUBST([GLIB_REQ])
 145 AG_GST_GLIB_CHECK([$GLIB_REQ])
 146
 147 dnl checks for gstreamer
 148 dnl uninstalled is selected preferentially -- see pkg-config(1)
 149 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], [yes])
 150
 151 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 152 if test -z $GST_TOOLS_DIR; then
 153   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 154 fi
 155 AC_SUBST(GST_TOOLS_DIR)
 156
 157 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 158 AC_SUBST(GST_PLUGINS_DIR)
 159 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 160
 161 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], [yes])
 162
 163 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], [yes])
 164 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 165 AC_SUBST(GSTPB_PLUGINS_DIR)
 166 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 167
 168 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 169
 170 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 171 dnl check for "check", unit testing library/header
 172 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 173 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 174
 175 dnl *** set variables based on configure arguments ***
 176
 177 dnl set license and copyright notice
 178 GST_LICENSE="LGPL"
 179 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 180 AC_SUBST(GST_LICENSE)
 181
 182 dnl set location of plugin directory
 183 AG_GST_SET_PLUGINDIR
 184
 185 dnl define an ERROR_CFLAGS Makefile variable
 186 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 187
 188 dnl define correct level for debugging messages
 189 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 190
 191 dnl used in examples
 192 AG_GST_DEFAULT_ELEMENTS
 193
 194 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 195
 196 dnl Overview:
 197 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 198 dnl GST_*:              flags shared by built objects to link against GStreamer
 199 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 200 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 201 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 202 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 203
 204 dnl GST_OPTION_CFLAGS
 205 if test "x$USE_DEBUG" = xyes; then
 206    PROFILE_CFLAGS="-g"
 207 fi
 208 AC_SUBST(PROFILE_CFLAGS)
 209
 210 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 211 AC_SUBST(DEPRECATED_CFLAGS)
 212
 213 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 214 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 215 AC_SUBST(GST_OPTION_CFLAGS)
 216
 217 dnl FIXME: do we want to rename to GST_ALL_* ?
 218 dnl prefer internal headers to already installed ones
 219 dnl add GST_OPTION_CFLAGS, but overridable
 220 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 221 AC_SUBST(GST_CFLAGS)
 222 AC_SUBST(GST_LIBS)
 223
 224 dnl GST_ALL_*
 225 dnl vars common to for all internal objects (core libs, elements, applications)
 226 dnl CFLAGS:
 227 dnl - src and build dirs need to be added because every piece that gets built
 228 dnl   will need the GStreamer source and generated headers
 229 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 230 AC_SUBST([GST_ALL_CFLAGS])
 231
 232 dnl FIXME: check if LTLIBINTL is needed everywhere
 233 dnl I presume it is given that it contains the symbols that _() stuff maps to
 234 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 235 AC_SUBST([GST_ALL_LIBS])
 236
 237 dnl LDFLAGS really should only contain flags, not libs - they get added before
 238 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 239 GST_ALL_LDFLAGS="-no-undefined"
 240 AC_SUBST(GST_ALL_LDFLAGS)
 241
 242 dnl GST_OBJ_*
 243 dnl default vars for all internal objects built on libgstphonon
 244 dnl includes GST_ALL_*
 245 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 246 AC_SUBST([GST_OBJ_CFLAGS])
 247 GST_OBJ_LIBS="\$(top_builddir)/gst-phonon/libgstphonon.la \$(GST_ALL_LIBS)"
 248 AC_SUBST([GST_OBJ_LIBS])
 249
 250 dnl this really should only contain flags, not libs - they get added before
 251 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 252
 253 dnl *** output files ***
 254
 255 dnl keep this alphabetic per directory, please
 256 AC_CONFIG_FILES([
 257 Makefile
 258 gst-rtsp.spec
 259 common/Makefile
 260 common/m4/Makefile
 261 m4/Makefile
 262 gst/Makefile
 263 gst/rtsp-server/Makefile
 264 examples/Makefile
 265 bindings/Makefile
 266 bindings/python/Makefile
 267 bindings/python/codegen/Makefile
 268 bindings/vala/Makefile
 269 pkgconfig/Makefile
 270 pkgconfig/gst-rtsp-server.pc
 271 pkgconfig/gst-rtsp-server-uninstalled.pc
 272 ])
 273 AC_OUTPUT
 274
 275 echo "
 276
 277 Configuration
 278         Version                    : ${VERSION}
 279         Source code location       : ${srcdir}
 280         Prefix                     : ${prefix}
 281         Compiler                   : ${CC}
 282         Vala bindings              : ${enable_vala}
 283         Python bindings:           : ${HAVE_PYTHON_BINDINGS}
 284
 285 Gst-rtsp-server configured. Type 'make' to build.
 286 "