configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.20.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 14, 0, 14)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.19.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.11.5])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 dnl used in gst/subparse/gstsubparse.c
 158 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 159 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 160
 161 if test "x$HAVE_REGEX_H" = "xyes"; then
 162   ac_cppflags_save="$CPPFLAGS"
 163   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 164   AC_COMPILE_IFELSE(
 165     AC_LANG_PROGRAM([
 166 #include <libxml/HTMLparser.h>
 167                      ],[
 168 #ifndef LIBXML_HTML_ENABLED
 169 #error libxml2 has no HTML support
 170 #endif /* LIBXML_HTML_ENABLED */
 171                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 172   CPPFLAGS="$ac_cppflags_save"
 173 else
 174   HAVE_LIBXML_HTML="no"
 175 fi
 176 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 185 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 186   WIN32_LIBS="-lws2_32"
 187   AC_SUBST(WIN32_LIBS)
 188 fi
 189
 190 dnl check for hstrerror, for gst-libs/gst/rtsp
 191 save_libs="$LIBS"
 192 AC_CHECK_FUNC(hstrerror, ,
 193     AC_CHECK_LIB(resolv, hstrerror, ,
 194         [AC_DEFINE(NO_HSTRERROR, 1,
 195              [Define if you have no native hstrerror() function.])]))
 196 HSTRERROR_LIBS=$LIBS
 197 AC_SUBST(HSTRERROR_LIBS)
 198 LIBS="$save_libs"
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl ffmpegcolorspace includes _stdint.h
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl Check for FIONREAD ioctl declaration
 213 dnl used in gst/tcp
 214 GST_CHECK_FIONREAD
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl make sure we can use "inline" from C code
 221 AC_C_INLINE
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used in gst-libs/gst/floatcast/floatcast.h
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for dependency libraries ***
 240
 241 dnl GLib is required
 242 AG_GST_GLIB_CHECK([2.12])
 243
 244 dnl liboil is required
 245 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 246 if test "x$HAVE_LIBOIL" != "xyes"; then
 247   AC_ERROR([liboil-0.3.14 or later is required])
 248 fi
 249
 250 dnl checks for gstreamer
 251 dnl uninstalled is selected preferentially -- see pkg-config(1)
 252 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 253 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 254 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 255 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 256 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 257 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 258
 259 dnl Check for documentation xrefs
 260 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 261 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 262 AC_SUBST(GLIB_PREFIX)
 263 AC_SUBST(GST_PREFIX)
 264
 265 dnl GTK is optional and only used in examples
 266 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 267 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 268
 269 dnl *** set variables based on configure arguments ***
 270
 271 dnl set license and copyright notice
 272 GST_LICENSE="LGPL"
 273 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 274 AC_SUBST(GST_LICENSE)
 275
 276 dnl set location of plugin directory
 277 AG_GST_SET_PLUGINDIR
 278
 279 dnl define an ERROR_CFLAGS Makefile variable
 280 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 281
 282 dnl define correct level for debugging messages
 283 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 284
 285 dnl used in examples
 286 AG_GST_DEFAULT_ELEMENTS
 287
 288 dnl *** plug-ins to include ***
 289
 290 dnl these are all the gst plug-ins, compilable without additional libs
 291 AG_GST_CHECK_PLUGIN(adder)
 292 AG_GST_CHECK_PLUGIN(audioconvert)
 293 AG_GST_CHECK_PLUGIN(audiorate)
 294 AG_GST_CHECK_PLUGIN(audioresample)
 295 AG_GST_CHECK_PLUGIN(audiotestsrc)
 296 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 297 AG_GST_CHECK_PLUGIN(gdp)
 298 AG_GST_CHECK_PLUGIN(playback)
 299 AG_GST_CHECK_PLUGIN(subparse)
 300 AG_GST_CHECK_PLUGIN(tcp)
 301 AG_GST_CHECK_PLUGIN(typefind)
 302 AG_GST_CHECK_PLUGIN(videotestsrc)
 303 AG_GST_CHECK_PLUGIN(videorate)
 304 AG_GST_CHECK_PLUGIN(videoscale)
 305 AG_GST_CHECK_PLUGIN(volume)
 306
 307 dnl disable plug-ins that require libxml2's HTML support if it is not available
 308 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 309   AG_GST_DISABLE_PLUGIN(subparse)
 310 fi
 311
 312 dnl disable plug-ins that require sys/socket.h if it is not available
 313 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 314   AG_GST_DISABLE_PLUGIN(tcp)
 315 fi
 316
 317 dnl *** sys plug-ins ***
 318
 319 echo
 320 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 321 echo
 322
 323 dnl *** X11 ***
 324 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 325 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 326                   [ximagesink], [
 327   AC_PATH_XTRA
 328   ac_cflags_save="$CFLAGS"
 329   ac_cppflags_save="$CPPFLAGS"
 330   CFLAGS="$CFLAGS $X_CFLAGS"
 331   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 332
 333   dnl now try to find the HEADER
 334   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 335
 336   if test "x$HAVE_X" = "xno"
 337   then
 338     AC_MSG_NOTICE([cannot find X11 development files])
 339   else
 340     dnl this is much more than we want
 341     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 342     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 343     dnl it does not add the libs; therefore we add them here
 344     X_LIBS="$X_LIBS -lX11"
 345     AC_SUBST(X_CFLAGS)
 346     AC_SUBST(X_LIBS)
 347   fi
 348   AC_SUBST(HAVE_X)
 349   CFLAGS="$ac_cflags_save"
 350   CPPFLAGS="$ac_cppflags_save"
 351 ])
 352
 353 dnl Check for Xv extension
 354 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 355 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 356                   [xvimagesink], [
 357   AG_GST_CHECK_XV
 358 ])
 359
 360 dnl check for X Shm
 361 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 362 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 363   if test x$HAVE_X = xyes; then
 364     AC_CHECK_LIB(Xext, XShmAttach,
 365                  HAVE_XSHM="yes", HAVE_XSHM="no",
 366                  $X_LIBS)
 367     if test "x$HAVE_XSHM" = "xyes"; then
 368       XSHM_LIBS="-lXext"
 369     else
 370       dnl On AIX, it is in XextSam instead, but we still need -lXext
 371       AC_CHECK_LIB(XextSam, XShmAttach,
 372                    HAVE_XSHM="yes", HAVE_XSHM="no",
 373                    $X_LIBS)
 374       if test "x$HAVE_XSHM" = "xyes"; then
 375         XSHM_LIBS="-lXext -lXextSam"
 376       fi
 377     fi
 378   fi
 379 ], , [
 380   AC_SUBST(HAVE_XSHM)
 381   AC_SUBST(XSHM_LIBS)
 382 ])
 383
 384 dnl v4l/v4l2 checks have been moved down because they require X
 385
 386 dnl *** Video 4 Linux ***
 387 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 388 dnl renamed to GST_V4L in accordance with V4L2 below
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 390 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 391   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 392 #include <sys/types.h>
 393 #define _LINUX_TIME_H
 394 #define __user
 395 #include <linux/videodev.h>
 396   ])
 397
 398   dnl we can build v4l without Xv, but then we won't have XOverlay support
 399   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 400   then
 401     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 402     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 403   fi
 404 ])
 405
 406 dnl *** ext plug-ins ***
 407 dnl keep this list sorted alphabetically !
 408
 409 if test "x$BUILD_EXTERNAL" = "xyes"; then
 410
 411 echo
 412 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 413 echo
 414
 415 dnl *** alsa ***
 416 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 417 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 418   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 419     HAVE_ALSA="yes"
 420     AC_SUBST(ALSA_CFLAGS)
 421     AC_SUBST(ALSA_LIBS)
 422   ], [
 423     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 424   ])
 425 ])
 426
 427 dnl *** CDParanoia ***
 428 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 429 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 430   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 431                       cdda_open, -lm,
 432                       cdda_interface.h,
 433                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 434                       HEADER_DIR="no"
 435                       FOUND_CDPARANOIA="yes")
 436   if test "x$FOUND_CDPARANOIA" != "xyes";
 437   then
 438     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 439                         cdda_open, -lm,
 440                         cdda/cdda_interface.h,
 441                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 442                         HEADER_DIR="yes"
 443                         FOUND_CDPARANOIA="yes")
 444   fi
 445   if test "x$HEADER_DIR" = "xyes";
 446   then
 447     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 448                        defined if cdda headers are in a cdda/ directory)
 449   fi
 450   AC_SUBST(CDPARANOIA_LIBS)
 451 ])
 452 dnl FIXME : add second check somehow if that is necessary
 453 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 454 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 455
 456 dnl *** GNOME VFS ***
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 458 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 459   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 460 ])
 461
 462 dnl *** libgio ***
 463 USE_GIO=$BUILD_EXPERIMENTAL
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 465 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 466   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 467     HAVE_GIO="no"
 468     AC_MSG_RESULT(no)
 469   ])
 470   AC_SUBST(GIO_CFLAGS)
 471   AC_SUBST(GIO_LIBS)
 472   AC_SUBST(GIO_LDFLAGS)
 473 ])
 474
 475 dnl *** libvisual ***
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 477 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 478   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 479   if test $HAVE_LIBVISUAL = no
 480   then
 481     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 482   fi
 483 ])
 484
 485 dnl *** ogg ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 487 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 488   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 489   if test $HAVE_OGG = no
 490   then
 491     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 492     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 493   fi
 494 ])
 495
 496 dnl *** pango ***
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 498 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 499   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 500 ])
 501
 502 dnl *** theora ***
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 504 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 505   dnl this check will work as long as theora uses 1.0.x or similar for the
 506   dnl first post-alpha release and not just 1.0
 507   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 508 ])
 509
 510 dnl *** vorbis ***
 511 dnl AM_PATH_VORBIS only takes two options
 512 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 513 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 514   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 515   if test $HAVE_VORBIS = no
 516   then
 517     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 518     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 519   fi
 520 ])
 521
 522 if test "x$HAVE_VORBIS" = "xyes"; then
 523   ac_cflags_save="$CFLAGS"
 524   AC_COMPILE_IFELSE(
 525     AC_LANG_PROGRAM([
 526 #include <vorbis/codec.h>
 527                      ],[
 528 vorbis_dsp_state *v;
 529
 530 vorbis_synthesis_restart (v);
 531                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 532   if test "x$HAVE_VSR" = "xyes"; then
 533     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 534                        [defined if vorbis_synthesis_restart is present])
 535   fi
 536   CFLAGS="$ac_cflags_save"
 537 fi
 538
 539 else
 540
 541 dnl not building plugins with external dependencies,
 542 dnl but we still need to set the conditionals
 543 AM_CONDITIONAL(USE_ALSA, false)
 544 AM_CONDITIONAL(USE_CDPARANOIA, false)
 545 AM_CONDITIONAL(USE_GNOME_VFS, false)
 546 AM_CONDITIONAL(USE_GIO, false)
 547 AM_CONDITIONAL(USE_LIBVISUAL, false)
 548 AM_CONDITIONAL(USE_OGG, false)
 549 AM_CONDITIONAL(USE_PANGO, false)
 550 AM_CONDITIONAL(USE_THEORA, false)
 551 AM_CONDITIONAL(USE_VORBIS, false)
 552
 553 fi dnl of EXT plugins
 554
 555 dnl seeking needs freetype, so check for it here
 556 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 557   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 558 ])
 559 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 560 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 561 AC_SUBST(FT2_CFLAGS)
 562 AC_SUBST(FT2_LIBS)
 563
 564 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 565
 566 dnl Overview:
 567 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 568 dnl GST_*:              flags shared by built objects to link against GStreamer
 569 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 570 dnl                          (compare to other modules) or for i18n
 571 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 572 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 573 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 574 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 575
 576 dnl GST_OPTION_CFLAGS
 577 if test "x$USE_DEBUG" = xyes; then
 578    PROFILE_CFLAGS="-g"
 579 fi
 580 AC_SUBST(PROFILE_CFLAGS)
 581
 582 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 583   dnl Define _only_ during CVS (not pre-releases or releases)
 584   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 585 else
 586   DEPRECATED_CFLAGS=""
 587 fi
 588 AC_SUBST(DEPRECATED_CFLAGS)
 589
 590 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 591 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 592 AC_SUBST(GST_OPTION_CFLAGS)
 593
 594 dnl our libraries need to be versioned correctly
 595 AC_SUBST(GST_LT_LDFLAGS)
 596
 597 dnl GST_PLUGINS_BASE_CFLAGS
 598 dnl prefer internal headers to already installed ones
 599 dnl also add builddir include for enumtypes and marshal
 600 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 601 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 602
 603 dnl FIXME: do we want to rename to GST_ALL_* ?
 604 dnl add GST_OPTION_CFLAGS, but overridable
 605 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 606 AC_SUBST(GST_CFLAGS)
 607 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 608 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 609 AC_SUBST(GST_LIBS)
 610
 611 dnl LDFLAGS really should only contain flags, not libs - they get added before
 612 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 613 GST_ALL_LDFLAGS="-no-undefined"
 614 AC_SUBST(GST_ALL_LDFLAGS)
 615
 616 dnl GST_LIB_LDFLAGS
 617 dnl linker flags shared by all libraries
 618 dnl LDFLAGS modifier defining exported symbols from built libraries
 619 dnl (export _gst_foo but not __gst_foo)
 620 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 621 AC_SUBST(GST_LIB_LDFLAGS)
 622
 623 dnl this really should only contain flags, not libs - they get added before
 624 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 625 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 626 AC_SUBST(GST_PLUGIN_LDFLAGS)
 627
 628 dnl *** output files ***
 629
 630 AC_CONFIG_FILES(
 631 Makefile
 632 gst-plugins-base.spec
 633 gst/Makefile
 634 gst/adder/Makefile
 635 gst/audioconvert/Makefile
 636 gst/audiorate/Makefile
 637 gst/audioresample/Makefile
 638 gst/audiotestsrc/Makefile
 639 gst/ffmpegcolorspace/Makefile
 640 gst/gdp/Makefile
 641 gst/playback/Makefile
 642 gst/subparse/Makefile
 643 gst/tcp/Makefile
 644 gst/typefind/Makefile
 645 gst/videotestsrc/Makefile
 646 gst/videorate/Makefile
 647 gst/videoscale/Makefile
 648 gst/volume/Makefile
 649 sys/Makefile
 650 sys/ximage/Makefile
 651 sys/xvimage/Makefile
 652 sys/v4l/Makefile
 653 ext/Makefile
 654 ext/alsa/Makefile
 655 ext/cdparanoia/Makefile
 656 ext/gnomevfs/Makefile
 657 ext/gio/Makefile
 658 ext/libvisual/Makefile
 659 ext/ogg/Makefile
 660 ext/pango/Makefile
 661 ext/theora/Makefile
 662 ext/vorbis/Makefile
 663 gst-libs/Makefile
 664 gst-libs/gst/Makefile
 665 gst-libs/gst/audio/Makefile
 666 gst-libs/gst/cdda/Makefile
 667 gst-libs/gst/fft/Makefile
 668 gst-libs/gst/floatcast/Makefile
 669 gst-libs/gst/interfaces/Makefile
 670 gst-libs/gst/netbuffer/Makefile
 671 gst-libs/gst/riff/Makefile
 672 gst-libs/gst/rtp/Makefile
 673 gst-libs/gst/rtsp/Makefile
 674 gst-libs/gst/sdp/Makefile
 675 gst-libs/gst/tag/Makefile
 676 gst-libs/gst/pbutils/Makefile
 677 gst-libs/gst/video/Makefile
 678 tools/Makefile
 679 win32/common/config.h
 680 pkgconfig/Makefile
 681 pkgconfig/gstreamer-audio.pc
 682 pkgconfig/gstreamer-audio-uninstalled.pc
 683 pkgconfig/gstreamer-cdda.pc
 684 pkgconfig/gstreamer-cdda-uninstalled.pc
 685 pkgconfig/gstreamer-fft.pc
 686 pkgconfig/gstreamer-fft-uninstalled.pc
 687 pkgconfig/gstreamer-floatcast.pc
 688 pkgconfig/gstreamer-floatcast-uninstalled.pc
 689 pkgconfig/gstreamer-interfaces.pc
 690 pkgconfig/gstreamer-interfaces-uninstalled.pc
 691 pkgconfig/gstreamer-netbuffer.pc
 692 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 693 pkgconfig/gstreamer-pbutils.pc
 694 pkgconfig/gstreamer-pbutils-uninstalled.pc
 695 pkgconfig/gstreamer-riff.pc
 696 pkgconfig/gstreamer-riff-uninstalled.pc
 697 pkgconfig/gstreamer-rtp.pc
 698 pkgconfig/gstreamer-rtp-uninstalled.pc
 699 pkgconfig/gstreamer-rtsp.pc
 700 pkgconfig/gstreamer-rtsp-uninstalled.pc
 701 pkgconfig/gstreamer-sdp.pc
 702 pkgconfig/gstreamer-sdp-uninstalled.pc
 703 pkgconfig/gstreamer-tag.pc
 704 pkgconfig/gstreamer-tag-uninstalled.pc
 705 pkgconfig/gstreamer-video.pc
 706 pkgconfig/gstreamer-video-uninstalled.pc
 707 pkgconfig/gstreamer-plugins-base.pc
 708 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 709 tests/Makefile
 710 tests/check/Makefile
 711 tests/examples/Makefile
 712 tests/examples/dynamic/Makefile
 713 tests/examples/seek/Makefile
 714 tests/examples/volume/Makefile
 715 tests/examples/snapshot/Makefile
 716 tests/icles/Makefile
 717 docs/Makefile
 718 docs/design/Makefile
 719 docs/libs/Makefile
 720 docs/plugins/Makefile
 721 docs/version.entities
 722 po/Makefile.in
 723 common/Makefile
 724 common/m4/Makefile
 725 m4/Makefile
 726 )
 727 AC_OUTPUT
 728
 729 AG_GST_OUTPUT_PLUGINS