configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer FFMpeg, 0.10.5.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-ffmpeg)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/ffmpeg/gstffmpeg.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 AC_LIBTOOL_WIN32_DLL
  40 AM_PROG_LIBTOOL
  41
  42 dnl *** required versions of GStreamer stuff ***
  43 GST_REQ=0.10.13
  44 LIBOIL_MAJORMINOR=0.3
  45 LIBOIL_REQ=0.3.6
  46
  47 dnl *** autotools stuff ****
  48
  49 dnl allow for different autotools
  50 AS_AUTOTOOLS_ALTERNATE
  51
  52 dnl Add parameters for aclocal
  53 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  54
  55 dnl *** check for arguments to configure ***
  56
  57 AG_GST_ARG_WITH_PACKAGE_NAME
  58 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  59 AG_GST_ARG_VALGRIND
  60
  61 dnl *** checks for platform ***
  62
  63 dnl * hardware/architecture *
  64
  65 dnl common/m4/gst-arch.m4
  66 dnl check CPU type
  67 AG_GST_ARCH
  68
  69 dnl *** checks for programs ***
  70
  71 dnl find a compiler
  72 AC_PROG_CC
  73
  74 # FIXME: are these two lines needed ?
  75 AM_PROG_CC_STDC
  76 AS="${CC}"
  77
  78 dnl check if the compiler supports '-c' and '-o' options
  79 AM_PROG_CC_C_O
  80
  81 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  82 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  83
  84 dnl check for documentation tools
  85 AG_GST_DOCBOOK_CHECK
  86 GTK_DOC_CHECK([1.3])
  87 AS_PATH_PYTHON([2.1])
  88 AG_GST_PLUGIN_DOCS([1.3],[2.1])
  89
  90 dnl *** checks for libraries ***
  91
  92 dnl check for libm, for sin()
  93 AC_CHECK_LIBM
  94 AC_SUBST(LIBM)
  95
  96 dnl *** checks for header files ***
  97
  98 dnl check if we have ANSI C header files
  99 AC_HEADER_STDC
 100
 101 dnl *** checks for types/defines ***
 102
 103 dnl *** checks for structures ***
 104
 105 dnl *** checks for compiler characteristics ***
 106
 107 dnl *** checks for library functions ***
 108
 109 dnl *** checks for dependancy libraries ***
 110
 111 dnl checks for gstreamer
 112 dnl uninstalled is selected preferentially -- see pkg-config(1)
 113 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 114 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 115 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GST_REQ])
 116 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 117 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 118
 119 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 120 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 121
 122 dnl liboil is required for cpu detection for libpostproc
 123 dnl FIXME : In theory we should be able to compile libpostproc with cpudetect
 124 dnl capabilities, which would enable us to get rid of this
 125 PKG_CHECK_MODULES(LIBOIL, liboil-$LIBOIL_MAJORMINOR >= $LIBOIL_REQ, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 126 if test "x$HAVE_LIBOIL" != "xyes"
 127 then
 128   AC_MSG_ERROR([liboil-$LIBOIL_REQ or later is required])
 129   AC_ERROR
 130 fi
 131
 132 AC_SUBST(LIBOIL_CFLAGS)
 133 AC_SUBST(LIBOIL_LIBS)
 134
 135 dnl *** set variables based on configure arguments ***
 136
 137 dnl set location of plugin directory
 138 AG_GST_SET_PLUGINDIR
 139
 140 dnl define an ERROR_CFLAGS Makefile variable
 141 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 142
 143 dnl define correct level for debugging messages
 144 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 145
 146 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 147
 148 dnl Overview:
 149 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 150 dnl GST_*:              flags shared by built objects to link against GStreamer
 151 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 152 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 153 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 154 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 155
 156 dnl GST_OPTION_CFLAGS
 157 if test "x$USE_DEBUG" = xyes; then
 158    PROFILE_CFLAGS="-g"
 159 fi
 160 AC_SUBST(PROFILE_CFLAGS)
 161
 162 if test "x$GST_CVS" = "xyes"; then
 163   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 164 else
 165   DEPRECATED_CFLAGS=""
 166 fi
 167 AC_SUBST(DEPRECATED_CFLAGS)
 168
 169 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 170 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 171
 172 AC_SUBST(GST_OPTION_CFLAGS)
 173
 174 dnl FIXME: do we want to rename to GST_ALL_* ?
 175 dnl prefer internal headers to already installed ones
 176 dnl also add builddir include for enumtypes and marshal
 177 dnl add GST_OPTION_CFLAGS, but overridable
 178 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 179 AC_SUBST(GST_CFLAGS)
 180 AC_SUBST(GST_LIBS)
 181
 182 GST_ALL_LDFLAGS="-no-undefined"
 183 AC_SUBST(GST_ALL_LDFLAGS)
 184
 185 dnl this really should only contain flags, not libs - they get added before
 186 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 187 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 188 AC_SUBST(GST_PLUGIN_LDFLAGS)
 189
 190 dnl Add MacOSX specific flags
 191 AC_CANONICAL_HOST
 192 case $host_os in
 193      darwin*)
 194         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 195         ;;
 196      *)
 197         DARWIN_LDFLAGS=""
 198         ;;
 199 esac
 200 AC_SUBST(DARWIN_LDFLAGS)
 201
 202 dnl *** Check for bz2
 203 AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzlibVersion, , bzlib.h,, AC_ERROR([libz2 is required]))
 204
 205 dnl *** configure external libs ***
 206
 207 HAVE_FFMPEG_UNINSTALLED=1
 208
 209 AC_ARG_WITH(system-ffmpeg,
 210             [AC_HELP_STRING([--with-system-ffmpeg], [use system FFmpeg libraries])])
 211
 212 if test "x$with_system_ffmpeg" = "xyes"; then
 213   PKG_CHECK_MODULES(FFMPEG, libavutil libavcodec libavformat)
 214   PKG_CHECK_MODULES(POSTPROC, libavcodec libpostproc)
 215   saved_CPPFLAGS="$CPPFLAGS"
 216   CPPFLAGS="$CPPFLAGS $FFMPEG_CFLAGS"
 217   AC_CHECK_HEADERS([avi.h])
 218   CPPFLAGS="$saved_CPPFLAGS"
 219   AC_DEFINE([FFMPEG_SOURCE], ["system install"], [Describes where the FFmpeg libraries come from.])
 220   HAVE_FFMPEG_UNINSTALLED=0
 221   AC_MSG_NOTICE([Using system-installed FFMpeg code])
 222   AC_MSG_WARN([
 223   ======================================================================
 224    WARNING: you have chosen to build gst-ffmpeg against a random
 225    external version of ffmpeg instead of building it against the tested
 226    internal ffmpeg snapshot that is included with gst-ffmpeg.
 227
 228    This is a very bad idea.  So bad in fact that words cannot express
 229    just how bad it is.  Suffice to say that it is BAD.
 230
 231    The GStreamer developers cannot and will not support a gst-ffmpeg
 232    built this way.  Any bug reports that indicate there is an external
 233    version of ffmpeg involved will be closed immediately without further
 234    investigation.
 235
 236    The reason such a setup can't be supported is that the ffmpeg API
 237    and ABI is in constant flux, yet there aren't any official releases
 238    of the ffmpeg library to develop against.  This makes it impossible
 239    to guarantee that gst-ffmpeg will work reliably, or even compile,
 240    with a randomly picked version ffmpeg.  Even if gst-ffmpeg compiles
 241    and superficially appears to work fine against your chosen external
 242    ffmpeg version, that might just not be the case on other systems, or
 243    even the same system at a later time, or when using decoders,
 244    encoders, demuxers or muxers that have not been tested.
 245
 246    Please do not create or distribute binary packages of gst-ffmpeg
 247    that link against an external ffmpeg. Thank you!
 248   ======================================================================
 249   ])
 250
 251   dnl No, this is not too extreme, we want people to see and read the above
 252   sleep 15
 253 else
 254
 255   source "$srcdir/ffmpegrev"
 256
 257   AC_MSG_NOTICE([Using ffmpeg revision $FFMPEG_REVISION])
 258
 259   dnl libgstffmpeg.la: include dirs
 260   FFMPEG_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/ffmpeg/libavformat \
 261                  -I \$(top_srcdir)/gst-libs/ext/ffmpeg/libavutil \
 262                  -I \$(top_srcdir)/gst-libs/ext/ffmpeg/libavcodec \
 263                  -I \$(top_srcdir)/gst-libs/ext/ffmpeg \
 264                  -Wno-deprecated-declarations"
 265
 266   dnl libgstffmpeg.la: libs to statically link to
 267   FFMPEG_LIBS="\$(top_builddir)/gst-libs/ext/ffmpeg/libavformat/libavformat.a \
 268                \$(top_builddir)/gst-libs/ext/ffmpeg/libavcodec/libavcodec.a \
 269                \$(top_builddir)/gst-libs/ext/ffmpeg/libavutil/libavutil.a"
 270   dnl
 271   POSTPROC_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/ffmpeg/libpostproc    \
 272                    -I \$(top_srcdir)/gst-libs/ext/ffmpeg/libavutil      \
 273                    -I \$(top_srcdir)/gst-libs/ext/ffmpeg/libavcodec     \
 274                    -I \$(top_srcdir)/gst-libs/ext/ffmpeg        \
 275                    -Wno-deprecated-declarations"
 276
 277   dnl libgstpostproc.la: libs to statically link to
 278   POSTPROC_LIBS="\$(top_builddir)/gst-libs/ext/ffmpeg/libpostproc/libpostproc.a \
 279                  \$(top_builddir)/gst-libs/ext/ffmpeg/libavutil/libavutil.a"
 280
 281   FFMPEG_SUBDIRS=gst-libs
 282   AC_DEFINE(HAVE_AVI_H)
 283   AC_DEFINE([FFMPEG_SOURCE], ["local snapshot"], [Describes where the FFmpeg libraries come from.])
 284   # Enable shared and static so that we get .a files, but with PIC code.
 285   ac_configure_args="$ac_configure_args --disable-vhook --disable-ffserver --disable-ffplay --enable-postproc --enable-gpl --enable-static --enable-shared --disable-encoder=flac --disable-decoder=cavs --disable-protocols --disable-devices --disable-network"
 286   case $host_os in
 287     # Unfortunately, in Mac OS 10.5 the current rev of ffmpeg builds
 288     # some non-PIC code into the .a file. See
 289     # http://trac.macosforge.org/projects/macports/ticket/13725 for more
 290     # info.
 291     darwin*)
 292       ac_configure_args="$ac_configure_args --disable-mmx --disable-altivec"
 293       ;;
 294     *)
 295       ;;
 296   esac
 297   AC_SUBST(FFMPEG_CO_DIR)
 298   AC_SUBST(FFMPEG_SVN)
 299   AC_SUBST(FFMPEG_REVISION)
 300   AC_CONFIG_SUBDIRS(gst-libs/ext/ffmpeg)
 301   AC_MSG_NOTICE([Using included FFMpeg code])
 302 fi
 303
 304 AC_SUBST(FFMPEG_CFLAGS)
 305 AC_SUBST(FFMPEG_LIBS)
 306 AC_SUBST(FFMPEG_SUBDIRS)
 307 AC_SUBST(POSTPROC_CFLAGS)
 308 AC_SUBST(POSTPROC_LIBS)
 309
 310 if test x$HAVE_FFMPEG_UNINSTALLED = x1; then
 311   AC_DEFINE(HAVE_FFMPEG_UNINSTALLED, [], [Defined if building against uninstalled FFmpeg source])
 312 fi
 313 AM_CONDITIONAL(HAVE_FFMPEG_UNINSTALLED, test x$HAVE_FFMPEG_UNINSTALLED = x1)
 314
 315 AC_CONFIG_FILES(
 316 Makefile
 317 gst-ffmpeg.spec
 318 ext/Makefile
 319 ext/ffmpeg/Makefile
 320 ext/libpostproc/Makefile
 321 gst-libs/Makefile
 322 gst-libs/ext/Makefile
 323 docs/Makefile
 324 docs/version.entities
 325 common/Makefile
 326 common/m4/Makefile
 327 tests/Makefile
 328 tests/check/Makefile
 329 )
 330 AC_OUTPUT
 331