configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT([GStreamer Ugly Plug-ins],[1.7.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-ugly])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS(config.h)
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AS_LIBTOOL(GST, 700, 0, 700)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.7.0.1
  49 GSTPB_REQ=1.7.0.1
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION(0.17)
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  68 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl check if the compiler supports '-c' and '-o' options
 110 AM_PROG_CC_C_O
 111
 112 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 113 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 114
 115 dnl check if the compiler supports do while(0) macros
 116 AG_GST_CHECK_DOWHILE_MACROS
 117
 118 dnl check for documentation tools
 119 GTK_DOC_CHECK([1.12])
 120 AG_GST_PLUGIN_DOCS([1.12])
 121
 122 dnl *** checks for libraries ***
 123
 124 dnl check for libm, for sin()
 125 LT_LIB_M
 126 AC_SUBST(LIBM)
 127
 128 dnl *** checks for header files ***
 129
 130 dnl used by ext/a52dec
 131 AX_CREATE_STDINT_H
 132
 133 dnl Check for malloc.h
 134 AC_CHECK_HEADERS([malloc.h])
 135
 136 dnl *** checks for types/defines ***
 137
 138 dnl *** checks for structures ***
 139
 140 dnl *** checks for compiler characteristics ***
 141
 142 dnl *** checks for library functions ***
 143
 144 dnl Check for a way to display the function name in debug output
 145 AG_GST_CHECK_FUNCTION
 146
 147 dnl *** checks for dependency libraries ***
 148
 149 dnl GLib is required
 150 GLIB_REQ=2.40.0
 151 AG_GST_GLIB_CHECK([$GLIB_REQ])
 152
 153 ORC_CHECK([0.4.16])
 154
 155 dnl checks for gstreamer
 156 dnl uninstalled is selected preferentially -- see pkg-config(1)
 157 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 158 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 159 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 160 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 161 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 162
 163 dnl Check for documentation xrefs
 164 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 165 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 166 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 167 AC_SUBST(GLIB_PREFIX)
 168 AC_SUBST(GST_PREFIX)
 169 AC_SUBST(GSTPB_PREFIX)
 170
 171 dnl Needed by plugins that use g_module_*() API
 172 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 173
 174 dnl *** set variables based on configure arguments ***
 175
 176 dnl set license and copyright notice
 177 GST_LICENSE="LGPL"
 178 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 179 AC_SUBST(GST_LICENSE)
 180
 181 dnl set location of plugin directory
 182 AG_GST_SET_PLUGINDIR
 183
 184 dnl set release date/time
 185 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 186   ["${srcdir}/gst-plugins-ugly.doap"],
 187   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 188
 189 dnl build static plugins or not
 190 AC_MSG_CHECKING([whether to build static plugins or not])
 191 AC_ARG_ENABLE(
 192   static-plugins,
 193   AC_HELP_STRING(
 194     [--enable-static-plugins],
 195     [build static plugins @<:@default=no@:>@]),
 196   [AS_CASE(
 197     [$enableval], [no], [], [yes], [],
 198     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 199   [enable_static_plugins=no])
 200 AC_MSG_RESULT([$enable_static_plugins])
 201 if test "x$enable_static_plugins" = xyes; then
 202   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 203     [Define if static plugins should be built])
 204   GST_PLUGIN_LIBTOOLFLAGS=""
 205 else
 206   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 207 fi
 208 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 209 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 210
 211 dnl define an ERROR_CFLAGS Makefile variable
 212 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 213     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 214     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 215     -Winit-self -Wmissing-include-dirs -Waddress
 216     -Waggregate-return -Wno-multichar -Wnested-externs ])
 217
 218 dnl define an ERROR_CXXFLAGS Makefile variable
 219 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 220     -Wmissing-declarations -Wredundant-decls
 221     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 222     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 223     -Wno-multichar])
 224
 225 dnl define correct level for debugging messages
 226 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 227
 228 dnl used in examples
 229 AG_GST_DEFAULT_ELEMENTS
 230
 231 dnl *** plug-ins to include ***
 232
 233 dnl these are all the gst plug-ins, compilable without additional libs
 234 AG_GST_CHECK_PLUGIN(asfdemux)
 235 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 236 AG_GST_CHECK_PLUGIN(dvdsub)
 237 AG_GST_CHECK_PLUGIN(xingmux)
 238 AG_GST_CHECK_PLUGIN(realmedia)
 239
 240 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 241
 242 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 243   WIN32_LIBS="-lws2_32"
 244   AC_SUBST(WIN32_LIBS)
 245 fi
 246
 247 dnl *** ext plug-ins ***
 248 dnl keep this list sorted alphabetically !
 249
 250 if test "x$BUILD_EXTERNAL" = "xyes"; then
 251
 252 echo
 253 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 254 echo
 255
 256 dnl *** a52dec ***
 257 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 258 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 259   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 260 ])
 261
 262 dnl *** amr-nb ***
 263 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 264 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 265   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 266     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 267       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 268     fi
 269     HAVE_AMRNB="yes"
 270   ], [
 271     HAVE_AMRNB="no"
 272   ])
 273   AC_SUBST(AMRNB_CFLAGS)
 274   AC_SUBST(AMRNB_LIBS)
 275 ])
 276
 277 dnl *** amr-wb dec ***
 278 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 279 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 280   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 281     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 282       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 283     fi
 284     HAVE_AMRWB="yes"
 285   ], [
 286     HAVE_AMRWB="no"
 287   ])
 288   AC_SUBST(AMRWB_CFLAGS)
 289   AC_SUBST(AMRWB_LIBS)
 290 ])
 291
 292 dnl *** cdio ***
 293 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 294 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 295   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 296 ])
 297
 298 dnl *** dvdread ***
 299 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 300 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 301   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 302   AC_SUBST(DVDREAD_LIBS)
 303 ])
 304
 305 dnl *** lame ***
 306 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 307 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 308   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 309   [
 310     HAVE_LAME="yes"
 311     LAME_LIBS="-lmp3lame $LIBM"
 312     dnl is lame presets available
 313     LAME_CFLAGS=""
 314     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 315     ])
 316     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 317         void *ptr = &lame_set_VBR_quality
 318       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 319     ])
 320   AC_SUBST(LAME_CFLAGS)
 321   AC_SUBST(LAME_LIBS)
 322   ])
 323 ])
 324
 325 dnl *** mad ***
 326 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 327 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 328
 329   dnl check with pkg-config first
 330   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 331   MAD_LIBS="$MAD_LIBS"
 332   if test "x$HAVE_MAD" = "xno"; then
 333     dnl fall back to oldskool detection
 334     AC_CHECK_HEADER(mad.h, [
 335       AC_CHECK_LIB(mad, mad_decoder_finish,
 336         HAVE_MAD="yes" MAD_LIBS="-lmad")
 337     ])
 338   fi
 339 ])
 340 AC_SUBST(MAD_LIBS)
 341
 342 dnl *** mpeg2dec ***
 343 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 344 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 345   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 346 ])
 347
 348 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 350 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 351   GST_PATH_SIDPLAY()
 352 ])
 353
 354 dnl *** twolame ***
 355 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 356 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 357   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 358       HAVE_TWOLAME="yes"], [
 359       HAVE_TWOLAME="no"
 360   ])
 361   AC_SUBST(TWOLAME_CFLAGS)
 362   AC_SUBST(TWOLAME_LIBS)
 363 ])
 364
 365 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 366 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 367 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 368   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120)
 369 ])
 370
 371 else
 372
 373 dnl not building plugins with external dependencies,
 374 dnl but we still need to set the conditionals
 375
 376 AM_CONDITIONAL(USE_A52DEC, false)
 377 AM_CONDITIONAL(USE_AMRNB, false)
 378 AM_CONDITIONAL(USE_AMRWB, false)
 379 AM_CONDITIONAL(USE_CDIO, false)
 380 AM_CONDITIONAL(USE_DVDREAD, false)
 381 AM_CONDITIONAL(USE_LAME, false)
 382 AM_CONDITIONAL(USE_MAD, false)
 383 AM_CONDITIONAL(USE_MPEG2DEC, false)
 384 AM_CONDITIONAL(USE_SIDPLAY, false)
 385 AM_CONDITIONAL(USE_TWOLAME, false)
 386 AM_CONDITIONAL(USE_X264, false)
 387
 388 fi dnl of EXT plugins
 389
 390 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 391
 392 dnl Overview:
 393 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 394 dnl GST_*:              flags shared by built objects to link against GStreamer
 395 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 396 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 397 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 398 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 399
 400 dnl GST_OPTION_CFLAGS
 401 if test "x$USE_DEBUG" = xyes; then
 402    PROFILE_CFLAGS="-g"
 403 fi
 404 AC_SUBST(PROFILE_CFLAGS)
 405
 406 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 407   dnl Define _only_ during CVS (not pre-releases or releases)
 408   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 409 else
 410   DEPRECATED_CFLAGS=""
 411 fi
 412 AC_SUBST(DEPRECATED_CFLAGS)
 413
 414 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 415 dnl at make time with e.g. make ERROR_CFLAGS=""
 416 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 417 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 418 AC_SUBST(GST_OPTION_CFLAGS)
 419 AC_SUBST(GST_OPTION_CXXFLAGS)
 420
 421 dnl FIXME: do we want to rename to GST_ALL_* ?
 422 dnl prefer internal headers to already installed ones
 423 dnl also add builddir include for enumtypes and marshal
 424 dnl add GST_OPTION_CFLAGS, but overridable
 425 GST_CFLAGS="$GST_CFLAGS"
 426 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 427 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 428 AC_SUBST(GST_CFLAGS)
 429 AC_SUBST(GST_CXXFLAGS)
 430 AC_SUBST(GST_LIBS)
 431
 432 dnl LDFLAGS really should only contain flags, not libs - they get added before
 433 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 434 GST_ALL_LDFLAGS="-no-undefined"
 435 AC_SUBST(GST_ALL_LDFLAGS)
 436
 437 dnl this really should only contain flags, not libs - they get added before
 438 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 439 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 440 AC_SUBST(GST_PLUGIN_LDFLAGS)
 441
 442 dnl *** output files ***
 443
 444 AC_CONFIG_FILES(
 445 Makefile
 446 common/Makefile
 447 common/m4/Makefile
 448 gst-libs/Makefile
 449 gst-libs/gst/Makefile
 450 gst/Makefile
 451 gst/asfdemux/Makefile
 452 gst/dvdlpcmdec/Makefile
 453 gst/dvdsub/Makefile
 454 gst/realmedia/Makefile
 455 gst/xingmux/Makefile
 456 ext/Makefile
 457 ext/a52dec/Makefile
 458 ext/amrnb/Makefile
 459 ext/amrwbdec/Makefile
 460 ext/cdio/Makefile
 461 ext/dvdread/Makefile
 462 ext/lame/Makefile
 463 ext/mad/Makefile
 464 ext/mpeg2dec/Makefile
 465 ext/sidplay/Makefile
 466 ext/twolame/Makefile
 467 ext/x264/Makefile
 468 docs/Makefile
 469 docs/plugins/Makefile
 470 docs/version.entities
 471 tests/Makefile
 472 tests/check/Makefile
 473 m4/Makefile
 474 po/Makefile.in
 475 pkgconfig/Makefile
 476 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 477 gst-plugins-ugly.spec
 478 )
 479
 480 dnl Create the config.h file for Visual Studio builds
 481 dnl Beware of spaces and /'s in some of the shell variable contents.
 482 sed \
 483     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 484     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 485     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 486     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 487     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 488     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 489     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 490     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 491     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 492     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 493     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 494     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 495     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 496     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 497     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 498     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 499     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 500     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 501     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 502     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 503     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 504     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 505     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 506     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 507     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 508     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 509     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 510     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 511     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 512     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 513     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 514     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 515     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 516     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 517     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 518     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 519     config.h.in >win32/common/config.h-new
 520
 521 AC_OUTPUT
 522
 523 AG_GST_OUTPUT_PLUGINS
 524
 525 ORC_OUTPUT