configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.5.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 501, 0, 501)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84
  85 dnl subsystems - can influence other decisions so needs to be high up
  86 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  87 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  88 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  90 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  91 if test "x$GST_DISABLE_PARSE" = xyes; then
  92   AC_DEFINE(GST_DISABLE_PARSE, 1,
  93     [Define if pipeline parsing code is disabled])
  94 fi
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  96 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  97 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  98   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  99     [Define if option parsing is disabled])
 100 fi
 101 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 102 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 104 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 106 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 107 dnl define a substitution to use in docs/gst/gstreamer.types
 108 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 109 then
 110   GST_REGISTRY_DOC_TYPES="%"
 111 else
 112   GST_REGISTRY_DOC_TYPES=
 113 fi
 114 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 115 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 116 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 117
 118 AG_GST_ARG_DEBUG
 119 AG_GST_ARG_PROFILING
 120 AG_GST_ARG_VALGRIND
 121 AG_GST_ARG_GCOV
 122
 123 AG_GST_ARG_EXAMPLES
 124
 125 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 126 AG_GST_ARG_WITH_PACKAGE_NAME
 127 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 128
 129 AG_GST_PKG_CONFIG_PATH
 130
 131 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 132   ["${srcdir}/gstreamer.doap"],
 133   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 134
 135 dnl check for bash completion
 136 AC_ARG_WITH([bash-completion-dir],
 137     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 138         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 139     [],
 140     [with_bash_completion_dir=yes])
 141
 142 if test "x$with_bash_completion_dir" = "xyes"
 143 then
 144     extra_args=
 145
 146     if test "x$prefix" != "xNONE"
 147     then
 148         extra_args="--define-variable=prefix=\"$prefix\""
 149     fi
 150
 151     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 152         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 153         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 154     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 155         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 156         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 157 else
 158     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 159     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 160 fi
 161
 162 AC_SUBST([BASH_COMPLETION_DIR])
 163 AC_SUBST([BASH_HELPERS_DIR])
 164 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 165
 166 dnl build static plugins or not
 167 AC_MSG_CHECKING([whether to build static plugins or not])
 168 AC_ARG_ENABLE(
 169   static-plugins,
 170   AC_HELP_STRING(
 171     [--enable-static-plugins],
 172     [build static plugins @<:@default=no@:>@]),
 173   [AS_CASE(
 174     [$enableval], [no], [], [yes], [],
 175     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 176   [enable_static_plugins=no])
 177 AC_MSG_RESULT([$enable_static_plugins])
 178 if test "x$enable_static_plugins" = xyes; then
 179   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 180     [Define if static plugins should be built])
 181   GST_PLUGIN_LIBTOOLFLAGS=""
 182 else
 183   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 184 fi
 185 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 186 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 187
 188 dnl building of tests
 189 AC_ARG_ENABLE(tests,
 190   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 191   [
 192     case "${enableval}" in
 193       yes) BUILD_TESTS=yes ;;
 194       no)  BUILD_TESTS=no ;;
 195       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 196     esac
 197   ],
 198 [BUILD_TESTS=yes]) dnl Default value
 199 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 200
 201 dnl tests known to fail
 202 AC_ARG_ENABLE(failing-tests,
 203   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 204   [
 205     case "${enableval}" in
 206       yes) BUILD_FAILING_TESTS=yes ;;
 207       no)  BUILD_FAILING_TESTS=no ;;
 208       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 209     esac
 210   ],
 211   [BUILD_FAILING_TESTS=no]) dnl Default value
 212 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 213 if test x$BUILD_FAILING_TESTS = xyes; then
 214   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 215 else
 216   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 217 fi
 218
 219 dnl building of benchmarks
 220 AC_ARG_ENABLE(benchmarks,
 221   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 222   [
 223     case "${enableval}" in
 224       yes) BUILD_BENCHMARKS=yes ;;
 225       no)  BUILD_BENCHMARKS=no ;;
 226       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 227     esac
 228   ],
 229 [BUILD_BENCHMARKS=yes]) dnl Default value
 230 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 231
 232 dnl building of tools
 233 AC_ARG_ENABLE(tools,
 234   AS_HELP_STRING([--disable-tools],[disable building tools]),
 235   [
 236     case "${enableval}" in
 237       yes) BUILD_TOOLS=yes ;;
 238       no)  BUILD_TOOLS=no ;;
 239       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 240     esac
 241   ],
 242 [BUILD_TOOLS=yes]) dnl Default value
 243 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 244
 245 dnl poison destroyed objects
 246 AC_ARG_ENABLE(poisoning,
 247   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 248   [
 249     case "${enableval}" in
 250       yes) USE_POISONING=yes ;;
 251       no)  USE_POISONING=no ;;
 252       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 253     esac
 254   ],
 255   [USE_POISONING=no]) dnl Default value
 256 if test "x$USE_POISONING" = xyes; then
 257   AC_DEFINE(USE_POISONING, 1,
 258     [Define if we should poison deallocated memory])
 259 fi
 260
 261 dnl *** checks for platform ***
 262
 263 dnl * hardware/architecture *
 264
 265 dnl common/m4/gst-arch.m4
 266 dnl check CPU type
 267 AG_GST_ARCH
 268 dnl substitution for win32/common/config.h
 269 HOST_CPU=$host_cpu
 270 AC_SUBST(HOST_CPU)
 271
 272 dnl common/m4/gst-arch.m4
 273 dnl check for unaligned access
 274 AG_GST_UNALIGNED_ACCESS
 275 dnl create a configure variable for gst/gstconfig.h
 276 if test x${as_cv_unaligned_access} = xyes ; then
 277   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 278 else
 279   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 280 fi
 281 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 282
 283 dnl check for platform specific settings
 284 AG_GST_PLATFORM
 285
 286 dnl * software *
 287
 288 dnl check for large file support
 289 dnl affected plugins must include config.h
 290 AC_SYS_LARGEFILE
 291
 292 dnl *** checks for programs ***
 293
 294 dnl find a compiler
 295 AC_PROG_CC
 296 AC_PROG_CC_STDC
 297
 298 dnl check if the compiler supports '-c' and '-o' options
 299 AM_PROG_CC_C_O
 300
 301 dnl find an assembler
 302 AM_PROG_AS
 303
 304 dnl determine if c++ is available on this system
 305 AC_PROG_CXX
 306 dnl CXX may be set to some default even if no c++ compiler is available
 307 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 308 AC_LANG_PUSH([C++])
 309 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 310 AC_LANG_POP([C++])
 311 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 312 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 313
 314 dnl Perl is used in building documentation and in the version checks
 315 AC_PATH_PROG(PERL_PATH, perl, no)
 316 if test x$PERL_PATH = xno; then
 317   AC_MSG_ERROR(Could not find perl)
 318 fi
 319
 320 dnl we require flex and bison for building the parser
 321 if test "x$GST_DISABLE_PARSE" != xyes; then
 322   AG_GST_BISON_CHECK
 323   AG_GST_FLEX_CHECK
 324 fi
 325
 326 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 327 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 328
 329 dnl check for gobject-introspection
 330 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 331
 332 dnl check for documentation tools
 333 AG_GST_DOCBOOK_CHECK
 334 GTK_DOC_CHECK([1.12])
 335 AG_GST_PLUGIN_DOCS([1.12])
 336
 337 dnl *** checks for libraries ***
 338
 339 dnl check for libm, for sin()
 340 LT_LIB_M
 341 AC_SUBST(LIBM)
 342
 343 dnl *** checks for header files ***
 344
 345 dnl check if we have ANSI C header files
 346 AC_HEADER_STDC
 347
 348 dnl Check for ucontext.h
 349 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 350
 351 dnl Check for sys/socket.h
 352 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 353 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 354
 355 dnl check for sys/times.h for tests/examples/adapter/
 356 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 357 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 358 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 359
 360 dnl Check for process.h for getpid() on win32
 361 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 362
 363 dnl Check for sys/utsname.h for uname
 364 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 365
 366 dnl Check for stdio_ext.f for __fbufsize
 367 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 368
 369 dnl check for pthreads
 370 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 371 dnl which later checks use in their test code
 372 AX_PTHREAD()
 373 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 374
 375 dnl check for sys/prctl for setting thread name on Linux
 376 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 377
 378 dnl check for pthread_setname_np(const char*)
 379 dnl which is present on OS X 10.6, iOS 3.2 and above
 380 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 381 AC_LINK_IFELSE(
 382     [AC_LANG_PROGRAM(
 383         [#include <pthread.h>],
 384         [pthread_setname_np("example")])],
 385     [AC_MSG_RESULT(yes)
 386      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 387         [Have function pthread_setname_np(const char*)])],
 388     [AC_MSG_RESULT(no)])
 389
 390 dnl check for sys/uio.h for writev()
 391 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 392
 393 dnl Check for valgrind.h
 394 dnl separate from HAVE_VALGRIND because you can have the program, but not
 395 dnl the dev package
 396 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 397
 398 dnl used in gst/gstpoll.c
 399 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 400 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 401 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 402   WIN32_LIBS="-lws2_32"
 403   AC_SUBST(WIN32_LIBS)
 404 fi
 405
 406 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 407 if test "x$BUILD_TESTS" = "xyes"; then
 408   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 409                          __gmpz_init_set_d, ,
 410                          gmp.h,
 411                          GMP_LIBS="-lgmp"
 412                          AC_SUBST(GMP_LIBS)
 413                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 414   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 415                          gsl_rng_uniform_int, -lgslcblas,
 416                          gsl/gsl_rng.h,
 417                          GSL_LIBS="-lgsl -lgslcblas"
 418                          AC_SUBST(GSL_LIBS)
 419                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 420 fi
 421
 422 dnl *** checks for types/defines ***
 423
 424 dnl *** checks for structures ***
 425
 426 dnl *** checks for compiler characteristics ***
 427
 428 dnl check if the compiler supports __uint128_t (gcc)
 429 dnl Actually check for 128-bit division, since that's what we use
 430 dnl uint128_t for.
 431 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 432     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 433       static __uint128_t v1 = 100;
 434       static __uint128_t v2 = 10;
 435       static __uint128_t u;
 436       u = v1 / v2;
 437     ]])],[
 438       gst_cv_uint128_t=yes
 439     ],[
 440       gst_cv_uint128_t=no
 441     ])
 442 )
 443 if test x$gst_cv_uint128_t = xyes; then
 444   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 445 fi
 446
 447 dnl *** checking for tm_gmtoff ***
 448 AC_MSG_CHECKING([for tm_gmtoff])
 449 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 450         #include <time.h>
 451         int main(void) {
 452           struct tm t;
 453           t.tm_gmtoff = 0;
 454           exit(0);
 455         }]])],
 456   [have_tm_gmtoff=yes
 457    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 458   [have_tm_gmtoff=no],
 459   [have_tm_gmtoff="no (cross compiling)"])
 460 AC_MSG_RESULT($have_tm_gmtoff)
 461
 462
 463 dnl *** checks for library functions ***
 464
 465 AC_CHECK_FUNCS([strcasestr])
 466
 467 AC_CHECK_FUNCS([gmtime_r])
 468 AC_CHECK_FUNCS([localtime_r])
 469 AC_CHECK_FUNCS([sigaction])
 470
 471 dnl check for fseeko()
 472 AC_FUNC_FSEEKO
 473 dnl check for ftello()
 474 AC_CHECK_FUNCS([ftello])
 475
 476 AC_CHECK_FUNCS([fgetpos])
 477 AC_CHECK_FUNCS([fsetpos])
 478
 479 dnl check for poll(), ppoll() and pselect()
 480 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 481 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 482 AC_CHECK_FUNCS([poll])
 483 AC_CHECK_FUNCS([ppoll])
 484 AC_CHECK_FUNCS([pselect])
 485
 486 dnl ****************************************
 487 dnl *** GLib POLL* compatibility defines ***
 488 dnl ****************************************
 489
 490 AC_MSG_CHECKING([for broken poll])
 491 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 492         #include <stdlib.h>
 493         #include <fcntl.h>
 494         #ifdef HAVE_SYS_POLL_H
 495         #include <sys/poll.h>
 496         #endif
 497         #ifdef HAVE_POLL_H
 498         #include <poll.h>
 499         #endif
 500         int main(void) {
 501           struct pollfd fds[1];
 502           int fd;
 503           fd = open("/dev/null", 1);
 504           fds[0].fd = fd;
 505           fds[0].events = POLLIN;
 506           fds[0].revents = 0;
 507           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 508                 exit(1);  /* Does not work for devices -- fail */
 509           }
 510           exit(0);
 511         }]])],
 512   [broken_poll=no],
 513   [broken_poll=yes
 514    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 515   [broken_poll="no (cross compiling)"])
 516 AC_MSG_RESULT($broken_poll)
 517
 518 dnl check for mmap()
 519 AC_FUNC_MMAP
 520 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 521
 522 dnl check for posix_memalign(), getpagesize()
 523 AC_CHECK_FUNCS([posix_memalign])
 524 AC_CHECK_FUNCS([getpagesize])
 525
 526 dnl Check for POSIX timers
 527 AC_CHECK_FUNCS(clock_gettime, [], [
 528   AC_CHECK_LIB(rt, clock_gettime, [
 529     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 530     LIBS="$LIBS -lrt"
 531   ], [
 532     AC_CHECK_LIB(pthread, clock_gettime, [
 533       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 534       LIBS="$LIBS -lpthread"
 535     ])
 536   ])
 537 ])
 538
 539 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 540     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 541 #include <time.h>
 542 #ifdef HAVE_UNISTD_H
 543 #include <unistd.h>
 544 #endif
 545     ]], [[
 546 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 547 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 548 #endif
 549     ]])],[
 550       gst_cv_posix_timers=yes
 551     ],[
 552       gst_cv_posix_timers=no
 553     ])
 554 )
 555
 556 if test "$gst_cv_posix_timers" = "yes"; then
 557   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 558   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 559 else
 560   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 561 fi
 562 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 563 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 564
 565 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 566     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 567 #include <time.h>
 568 #ifdef HAVE_UNISTD_H
 569 #include <unistd.h>
 570 #endif
 571     ]], [[
 572 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 573 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 574 #endif
 575     ]])],[
 576       gst_cv_monotonic_clock=yes
 577     ],[
 578       gst_cv_monotonic_clock=no
 579     ])
 580 )
 581
 582 if test "$gst_cv_monotonic_clock" = "yes"; then
 583   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 584   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 585 else
 586   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 587 fi
 588 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 589 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 590
 591 dnl Check for a way to display the function name in debug output
 592 AG_GST_CHECK_FUNCTION
 593
 594 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 595 save_cflags="$CFLAGS"
 596 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 597 AC_CHECK_LIB(dl, dladdr,
 598    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 599    LIBS="$LIBS -ldl")
 600 CFLAGS="$save_cflags"
 601
 602 dnl Check printf stuff
 603 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 604   AC_TYPE_LONG_LONG_INT
 605   AC_TYPE_UNSIGNED_LONG_LONG_INT
 606
 607   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 608     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 609   fi
 610
 611   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 612   gl_AC_HEADER_INTTYPES_H
 613
 614   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 615   gl_AC_HEADER_STDINT_H
 616
 617   AC_CHECK_TYPES(ptrdiff_t)
 618
 619   AC_TYPE_INTMAX_T
 620   AC_TYPE_SIZE_T
 621 fi
 622
 623 dnl *** checks for dependency libraries ***
 624
 625 dnl GLib
 626 GLIB_REQ=2.32.0
 627 AG_GST_GLIB_CHECK([$GLIB_REQ])
 628
 629 dnl Check for documentation xrefs
 630 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 631 AC_SUBST(GLIB_PREFIX)
 632
 633 dnl building of unit test libraries
 634 AC_ARG_ENABLE(check,
 635   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 636   [
 637     case "${enableval}" in
 638       yes) BUILD_CHECK=yes ;;
 639       no)  BUILD_CHECK=no ;;
 640       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 641     esac
 642   ], [
 643     dnl Default value
 644     case $host_os in
 645       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 646       *) BUILD_CHECK=yes ;;
 647     esac
 648 ])
 649 dnl bit of a misnomer, but keep the conditional named like this so we don't
 650 dnl have to change too much elsewhere
 651 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 652
 653 dnl configure the desired memory alignment
 654 AC_ARG_WITH([memory-alignment],
 655   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 656   [
 657     if test "x$withval" = "xyes"
 658     then
 659       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 660     else
 661       case "${withval}" in
 662         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 663         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 664         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 665       esac
 666     fi
 667   ], [
 668     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 669   ]
 670 )
 671
 672 dnl Check for -Bsymbolic-functions linker flag used to avoid
 673 dnl intra-library PLT jumps, if available.
 674 AC_ARG_ENABLE(Bsymbolic,
 675               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 676               [SAVED_LDFLAGS="${LDFLAGS}"
 677                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 678                LDFLAGS=-Wl,-Bsymbolic-functions
 679                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 680                            AC_MSG_RESULT(yes)
 681                            enable_Bsymbolic=yes],[
 682                            AC_MSG_RESULT(no)
 683                            enable_Bsymbolic=no])
 684                LDFLAGS="${SAVED_LDFLAGS}"])
 685
 686
 687 dnl *** set variables based on configure arguments
 688
 689 dnl set license and copyright notice
 690 GST_LICENSE="LGPL"
 691 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 692 AC_SUBST(GST_LICENSE)
 693
 694 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 695 AS_AC_EXPAND(LIBDIR, $libdir)
 696 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 697 AS_AC_EXPAND(DATADIR, $datadir)
 698 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 699
 700 dnl set location of plugin directory
 701 AG_GST_SET_PLUGINDIR
 702
 703 dnl make sure it doesn't complain about unused variables if debugging is disabled
 704 NO_WARNINGS=""
 705 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 706   NO_WARNINGS="-Wno-unused"
 707 fi
 708
 709 dnl define an ERROR_CFLAGS Makefile variable
 710 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 711
 712 dnl special warning flags for gst/printf
 713 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 714 AC_SUBST(PRINTF_CFLAGS)
 715
 716 dnl define correct level for debugging messages
 717 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 718
 719 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 720
 721 dnl Overview:
 722 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 723 dnl GST_ALL_*:          vars shared by all built objects
 724 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 725 dnl GST_OBJ_*:          additional vars to link to the core library
 726 dnl                     include GST_ALL_*
 727 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 728 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 729
 730 dnl GST_OPTION_CFLAGS
 731 if test "x$USE_DEBUG" = xyes; then
 732    PROFILE_CFLAGS="-g"
 733 fi
 734 AC_SUBST(PROFILE_CFLAGS)
 735
 736 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 737 # functionality from the API that gstreamer uses
 738 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 739 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 740   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 741   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 742 else
 743   DEPRECATED_CFLAGS=""
 744 fi
 745 AC_SUBST(DEPRECATED_CFLAGS)
 746
 747 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 748 dnl make DEPRECATED_CFLAGS=''
 749 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 750 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 751 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 752 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 753 AC_SUBST(GST_OPTION_CFLAGS)
 754 AC_SUBST(GST_OPTION_CXXFLAGS)
 755
 756 dnl GST_ALL_*
 757 dnl vars common to for all internal objects (core libs, elements, applications)
 758 dnl CFLAGS:
 759 dnl - src and build dirs need to be added because every piece that gets built
 760 dnl   will need the GStreamer source and generated headers
 761 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 762 dnl       from LibXML except for in the core library
 763 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 764 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 765
 766 dnl FIXME: check if LTLIBINTL is needed everywhere
 767 dnl I presume it is given that it contains the symbols that _() stuff maps to
 768 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 769
 770 dnl LDFLAGS really should only contain flags, not libs - they get added before
 771 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 772 GST_ALL_LDFLAGS="-no-undefined"
 773 if test "x${enable_Bsymbolic}" = "xyes"; then
 774   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 775 fi
 776
 777 AC_SUBST(GST_ALL_CFLAGS)
 778 AC_SUBST(GST_ALL_CXXFLAGS)
 779 AC_SUBST(GST_ALL_LIBS)
 780 AC_SUBST(GST_ALL_LDFLAGS)
 781
 782 dnl GST_LIB_LDFLAGS
 783 dnl linker flags shared by all libraries
 784 dnl LDFLAGS modifier defining exported symbols from built libraries
 785 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 786 AC_SUBST(GST_LIB_LDFLAGS)
 787
 788 dnl GST_OBJ_*
 789 dnl default vars for all internal objects built on libgstreamer
 790 dnl includes GST_ALL_*
 791 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 792 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 793 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 794 AC_SUBST(GST_OBJ_CFLAGS)
 795 AC_SUBST(GST_OBJ_CXXFLAGS)
 796 AC_SUBST(GST_OBJ_LIBS)
 797
 798 dnl GST_PLUGIN_LDFLAGS
 799 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 800 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 801 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 802
 803 dnl plugin scanner locations
 804 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 805 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 806     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 807 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 808
 809 dnl things for our internal libcheck (must be called even if building
 810 dnl libcheck is disabled because it defines conditionals)
 811 AG_GST_CHECK_CHECKS()
 812
 813 AC_CONFIG_FILES(
 814 Makefile
 815 data/Makefile
 816 gst/Makefile
 817 gst/gstconfig.h
 818 gst/gstversion.h
 819 gst/parse/Makefile
 820 gst/printf/Makefile
 821 libs/Makefile
 822 libs/gst/Makefile
 823 libs/gst/base/Makefile
 824 libs/gst/check/Makefile
 825 libs/gst/check/libcheck/Makefile
 826 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
 827 libs/gst/controller/Makefile
 828 libs/gst/helpers/Makefile
 829 libs/gst/net/Makefile
 830 plugins/Makefile
 831 plugins/elements/Makefile
 832 po/Makefile.in
 833 tests/Makefile
 834 tests/benchmarks/Makefile
 835 tests/check/Makefile
 836 tests/misc/Makefile
 837 tests/examples/Makefile
 838 tests/examples/adapter/Makefile
 839 tests/examples/controller/Makefile
 840 tests/examples/stepping/Makefile
 841 tests/examples/helloworld/Makefile
 842 tests/examples/manual/Makefile
 843 tests/examples/memory/Makefile
 844 tests/examples/netclock/Makefile
 845 tests/examples/streamiddemux/Makefile
 846 tests/examples/streams/Makefile
 847 tools/Makefile
 848 common/Makefile
 849 common/m4/Makefile
 850 docs/Makefile
 851 docs/design/Makefile
 852 docs/faq/Makefile
 853 docs/gst/Makefile
 854 docs/gst/gstreamer.types
 855 docs/libs/Makefile
 856 docs/plugins/Makefile
 857 docs/manual/Makefile
 858 docs/pwg/Makefile
 859 docs/slides/Makefile
 860 docs/xsl/Makefile
 861 docs/version.entities
 862 m4/Makefile
 863 pkgconfig/Makefile
 864 stamp.h
 865 pkgconfig/gstreamer.pc
 866 pkgconfig/gstreamer-uninstalled.pc
 867 pkgconfig/gstreamer-base.pc
 868 pkgconfig/gstreamer-base-uninstalled.pc
 869 pkgconfig/gstreamer-check.pc
 870 pkgconfig/gstreamer-check-uninstalled.pc
 871 pkgconfig/gstreamer-controller.pc
 872 pkgconfig/gstreamer-controller-uninstalled.pc
 873 pkgconfig/gstreamer-net.pc
 874 pkgconfig/gstreamer-net-uninstalled.pc
 875 gstreamer.spec
 876 )
 877
 878 dnl Create the config.h file for Visual Studio builds
 879 dnl Beware of spaces and /'s in some of the shell variable contents.
 880 sed \
 881     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 882     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 883     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 884     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 885     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 886     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 887     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 888     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 889     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 890     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 891     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 892     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 893     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 894     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 895     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 896     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 897     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 898     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 899     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 900     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 901     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 902     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 903     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 904     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 905     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 906     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 907     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 908     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 909     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 910     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 911     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 912     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 913     config.h.in >win32/common/config.h-new
 914
 915 AC_OUTPUT
 916
 917 dnl negate for output
 918 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 919 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 920 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 921 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 922 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 923 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 924 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 925
 926 echo "
 927
 928 Configuration
 929         Version                    : ${VERSION}
 930         Source code location       : ${srcdir}
 931         Prefix                     : ${prefix}
 932         Compiler                   : ${CC}
 933         Package name               : ${GST_PACKAGE_NAME}
 934         Package origin             : ${GST_PACKAGE_ORIGIN}
 935
 936         Documentation (manuals)    : ${enable_docbook}
 937         Documentation (API)        : ${enable_gtk_doc}
 938
 939         Debug Logging              : ${enable_gst_debug}
 940         Command-line parser        : ${enable_parse}
 941         Option parsing in gst_init : ${enable_option_parsing}
 942         Tracing subsystem          : ${enable_trace}
 943         Allocation tracing         : ${enable_alloc_trace}
 944         Plugin registry            : ${enable_registry}
 945         Plugin support             : ${enable_plugin}
 946         Static plugins             : ${enable_static_plugins}
 947         Unit testing support       : ${BUILD_CHECK}
 948
 949         Debug                      : ${USE_DEBUG}
 950         Profiling                  : ${USE_PROFILING}
 951
 952         Building benchmarks        : ${BUILD_BENCHMARKS}
 953         Building examples          : ${BUILD_EXAMPLES}
 954         Building test apps         : ${BUILD_TESTS}
 955         Building tests that fail   : ${BUILD_FAILING_TESTS}
 956         Building tools             : ${BUILD_TOOLS}
 957 "