configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.14.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 10, 0, 10)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.13.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127 AG_GST_ARG_WITH_PLUGINS
 128 AC_SUBST(GST_PLUGINS_SELECTED)
 129
 130 AG_GST_ARG_ENABLE_EXTERNAL
 131
 132 dnl *** checks for platform ***
 133
 134 dnl * hardware/architecture *
 135
 136 dnl common/m4/gst-arch.m4
 137 dnl check CPU type
 138 AG_GST_ARCH
 139
 140 dnl check for large file support
 141 dnl affected plugins must include config.h
 142 AC_SYS_LARGEFILE
 143
 144 dnl *** checks for programs ***
 145
 146 dnl find a compiler
 147 AC_PROG_CC
 148
 149 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 150 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 151
 152 dnl check for documentation tools
 153 GTK_DOC_CHECK([1.3])
 154 AS_PATH_PYTHON([2.1])
 155 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 156
 157 dnl *** checks for libraries ***
 158
 159 dnl For interactive UNIX (a Sun thing)
 160 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 161 AC_ISC_POSIX
 162
 163 dnl libm, for sin() etc.
 164 AC_CHECK_LIBM
 165 AC_SUBST(LIBM)
 166
 167 dnl *** checks for header files ***
 168
 169 dnl check if we have ANSI C header files
 170 AC_HEADER_STDC
 171
 172 dnl used in gst/ffmpegcolorspace/mem.c
 173 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 174 AC_CHECK_HEADERS([malloc.h])
 175
 176 dnl used in gst/subparse/gstsubparse.c
 177 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 178 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 179
 180 if test "x$HAVE_REGEX_H" = "xyes"; then
 181   ac_cppflags_save="$CPPFLAGS"
 182   CPPFLAGS="-Wall -Werror `$PKG_CONFIG --cflags libxml-2.0`"
 183   AC_COMPILE_IFELSE(
 184     AC_LANG_PROGRAM([
 185 #include <libxml/HTMLparser.h>
 186                      ],[
 187 #ifndef LIBXML_HTML_ENABLED
 188 #error libxml2 has no HTML support
 189 #endif /* LIBXML_HTML_ENABLED */
 190                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 191   CPPFLAGS="$ac_cppflags_save"
 192
 193   if test "x$HAVE_LIBXML_HTML" = "xyes"; then
 194     GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED subparse"
 195   else
 196     GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 197   fi
 198 else
 199   GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 200   HAVE_LIBXML_HTML="no"
 201 fi
 202 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 203
 204 dnl used in gst/tcp
 205 AC_CHECK_HEADERS([sys/socket.h],
 206   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 207 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 208 if test "x$HAVE_SYS_SOCKET_H" = "xyes"; then
 209   GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED tcp"
 210 else
 211   GST_PLUGINS_NO="\t[tcp]\n$GST_PLUGINS_NO"
 212 fi
 213
 214 dnl used in gst-libs/gst/rtsp
 215 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 216 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 217   WIN32_LIBS="-lws2_32"
 218   AC_SUBST(WIN32_LIBS)
 219 fi
 220
 221 dnl used in gst-libs/gst/pbutils and associated unit test
 222 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 223
 224 dnl ffmpegcolorspace includes _stdint.h
 225 dnl also, Windows does not have long long
 226 AX_CREATE_STDINT_H
 227
 228 dnl *** checks for functions ***
 229 AC_CHECK_FUNCS([localtime_r])
 230
 231 dnl *** checks for types/defines ***
 232
 233 dnl Check for FIONREAD ioctl declaration
 234 dnl used in gst/tcp
 235 GST_CHECK_FIONREAD
 236
 237 dnl *** checks for structures ***
 238
 239 dnl *** checks for compiler characteristics ***
 240
 241 dnl make sure we can use "inline" from C code
 242 AC_C_INLINE
 243
 244 dnl *** checks for library functions ***
 245
 246 dnl check for fseeko()
 247 AC_FUNC_FSEEKO
 248
 249 dnl Check for fast float to int casting as defined in C99
 250 dnl used in gst-libs/gst/floatcast/floatcast.h
 251 AC_C99_FUNC_LRINT
 252 AC_C99_FUNC_LRINTF
 253
 254 dnl Check for a way to display the function name in debug output
 255 AG_GST_CHECK_FUNCTION
 256
 257 dnl *** checks for dependency libraries ***
 258
 259 dnl GLib is required
 260 AG_GST_GLIB_CHECK([2.6])
 261
 262 dnl liboil is required
 263 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 264 if test "x$HAVE_LIBOIL" != "xyes"
 265 then
 266   AC_ERROR([liboil-0.3.8 or later is required])
 267 fi
 268
 269 dnl checks for gstreamer
 270 dnl uninstalled is selected preferentially -- see pkg-config(1)
 271 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 272 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 273 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 274 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 275 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 276 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 277
 278 dnl Check for documentation xrefs
 279 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 280 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 281 AC_SUBST(GLIB_PREFIX)
 282 AC_SUBST(GST_PREFIX)
 283
 284 dnl GTK is optional and used in examples
 285 HAVE_GTK=NO
 286 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 287 if test "x$HAVE_GTK_22" = "xyes"; then
 288   HAVE_GTK=yes
 289   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 290   AC_SUBST(GTK_VERSION)
 291   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 292   AC_SUBST(GTK_BASE_DIR)
 293 else
 294   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 295 fi
 296 if test "x$HAVE_GTK_20" = "xyes"; then
 297   HAVE_GTK=yes
 298 fi
 299 GTK_CFLAGS=$GTK2_CFLAGS
 300 GTK_LIBS=$GTK2_LIBS
 301 AC_SUBST(GTK_LIBS)
 302 AC_SUBST(GTK_CFLAGS)
 303 AC_SUBST(HAVE_GTK)
 304 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 305
 306 dnl *** set variables based on configure arguments ***
 307
 308 dnl set license and copyright notice
 309 GST_LICENSE="LGPL"
 310 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 311 AC_SUBST(GST_LICENSE)
 312
 313 dnl set location of plugin directory
 314 AG_GST_SET_PLUGINDIR
 315
 316 dnl define an ERROR_CFLAGS Makefile variable
 317 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 318
 319 dnl define correct level for debugging messages
 320 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 321
 322 dnl used in examples
 323 AG_GST_DEFAULT_ELEMENTS
 324
 325 dnl *** sys plug-ins ***
 326
 327 echo
 328 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 329 echo
 330
 331 dnl *** X11 ***
 332 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 333 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 334                   [ximagesink], [
 335   AC_PATH_XTRA
 336   ac_cflags_save="$CFLAGS"
 337   ac_cppflags_save="$CPPFLAGS"
 338   CFLAGS="$CFLAGS $X_CFLAGS"
 339   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 340
 341   dnl now try to find the HEADER
 342   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 343
 344   if test "x$HAVE_X" = "xno"
 345   then
 346     AC_MSG_NOTICE([cannot find X11 development files])
 347   else
 348     dnl this is much more than we want
 349     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 350     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 351     dnl it does not add the libs; therefore we add them here
 352     X_LIBS="$X_LIBS -lX11"
 353     AC_SUBST(X_CFLAGS)
 354     AC_SUBST(X_LIBS)
 355   fi
 356   AC_SUBST(HAVE_X)
 357   CFLAGS="$ac_cflags_save"
 358   CPPFLAGS="$ac_cppflags_save"
 359 ])
 360
 361 dnl Check for Xv extension
 362 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 363 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 364                   [xvimagesink], [
 365   AG_GST_CHECK_XV
 366 ])
 367
 368 dnl check for X Shm
 369 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 370 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 371   if test x$HAVE_X = xyes; then
 372     AC_CHECK_LIB(Xext, XShmAttach,
 373                  HAVE_XSHM="yes", HAVE_XSHM="no",
 374                  $X_LIBS)
 375     if test "x$HAVE_XSHM" = "xyes"; then
 376       XSHM_LIBS="-lXext"
 377     else
 378       dnl On AIX, it is in XextSam instead, but we still need -lXext
 379       AC_CHECK_LIB(XextSam, XShmAttach,
 380                    HAVE_XSHM="yes", HAVE_XSHM="no",
 381                    $X_LIBS)
 382       if test "x$HAVE_XSHM" = "xyes"; then
 383         XSHM_LIBS="-lXext -lXextSam"
 384       fi
 385     fi
 386   fi
 387 ], , [
 388   AC_SUBST(HAVE_XSHM)
 389   AC_SUBST(XSHM_LIBS)
 390 ])
 391
 392 dnl v4l/v4l2 checks have been moved down because they require X
 393
 394 dnl *** Video 4 Linux ***
 395 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 396 dnl renamed to GST_V4L in accordance with V4L2 below
 397 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 398 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 399   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 400 #include <sys/types.h>
 401 #define _LINUX_TIME_H
 402 #define __user
 403 #include <linux/videodev.h>
 404   ])
 405
 406   dnl we can build v4l without Xv, but then we won't have XOverlay support
 407   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 408   then
 409     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 410     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 411   fi
 412 ])
 413
 414 dnl *** ext plug-ins ***
 415 dnl keep this list sorted alphabetically !
 416
 417 if test "x$BUILD_EXTERNAL" = "xyes"; then
 418
 419 echo
 420 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 421 echo
 422
 423 dnl *** alsa ***
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 425 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 426   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 427     HAVE_ALSA="yes"
 428     AC_SUBST(ALSA_CFLAGS)
 429     AC_SUBST(ALSA_LIBS)
 430   ], [
 431     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 432   ])
 433 ])
 434
 435 dnl *** CDParanoia ***
 436 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 437 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 438   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 439                       cdda_open, -lm,
 440                       cdda_interface.h,
 441                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 442                       HEADER_DIR="no"
 443                       FOUND_CDPARANOIA="yes")
 444   if test "x$FOUND_CDPARANOIA" != "xyes";
 445   then
 446     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 447                         cdda_open, -lm,
 448                         cdda/cdda_interface.h,
 449                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 450                         HEADER_DIR="yes"
 451                         FOUND_CDPARANOIA="yes")
 452   fi
 453   if test "x$HEADER_DIR" = "xyes";
 454   then
 455     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 456                        defined if cdda headers are in a cdda/ directory)
 457   fi
 458   AC_SUBST(CDPARANOIA_LIBS)
 459 ])
 460 dnl FIXME : add second check somehow if that is necessary
 461 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 462 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 463
 464 dnl *** GNOME VFS ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 466 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 467   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 468 ])
 469
 470 dnl *** libvisual ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 472 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 473   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 474   if test $HAVE_LIBVISUAL = no
 475   then
 476     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 477   fi
 478 ])
 479
 480 dnl *** ogg ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 482 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 483   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 484   if test $HAVE_OGG = no
 485   then
 486     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 487     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 488   fi
 489 ])
 490
 491 dnl *** pango ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 493 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 494   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 495 ])
 496
 497 dnl *** theora ***
 498 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 499 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 500   dnl this check will work as long as theora uses 1.0.x or similar for the
 501   dnl first post-alpha release and not just 1.0
 502   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 503 ])
 504
 505 dnl *** vorbis ***
 506 dnl AM_PATH_VORBIS only takes two options
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 508 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 509   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 510   if test $HAVE_VORBIS = no
 511   then
 512     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 513     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 514   fi
 515 ])
 516
 517 if test "x$HAVE_VORBIS" = "xyes"; then
 518   ac_cflags_save="$CFLAGS"
 519   dnl FIXME: does this work on non-gcc? -- Company
 520   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 521   CFLAGS="-Wall -Werror"
 522   AC_COMPILE_IFELSE(
 523     AC_LANG_PROGRAM([
 524 #include <vorbis/codec.h>
 525                      ],[
 526 vorbis_dsp_state *v;
 527
 528 vorbis_synthesis_restart (v);
 529                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 530   if test "x$HAVE_VSR" = "xyes"; then
 531     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 532                        [defined if vorbis_synthesis_restart is present])
 533   fi
 534   CFLAGS="$ac_cflags_save"
 535 fi
 536
 537 else
 538
 539 dnl not building plugins with external dependencies,
 540 dnl but we still need to set the conditionals
 541 AM_CONDITIONAL(USE_ALSA, false)
 542 AM_CONDITIONAL(USE_CDPARANOIA, false)
 543 AM_CONDITIONAL(USE_GNOME_VFS, false)
 544 AM_CONDITIONAL(USE_LIBVISUAL, false)
 545 AM_CONDITIONAL(USE_OGG, false)
 546 AM_CONDITIONAL(USE_PANGO, false)
 547 AM_CONDITIONAL(USE_THEORA, false)
 548 AM_CONDITIONAL(USE_VORBIS, false)
 549
 550 fi dnl of EXT plugins
 551
 552 dnl seeking needs freetype, so check for it here
 553 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 554   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 555 ])
 556 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 557 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 558 AC_SUBST(FT2_CFLAGS)
 559 AC_SUBST(FT2_LIBS)
 560
 561 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 562
 563 dnl Overview:
 564 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 565 dnl GST_*:              flags shared by built objects to link against GStreamer
 566 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 567 dnl                          (compare to other modules) or for i18n
 568 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 569 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 570 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 571 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 572
 573 dnl GST_OPTION_CFLAGS
 574 if test "x$USE_DEBUG" = xyes; then
 575    PROFILE_CFLAGS="-g"
 576 fi
 577 AC_SUBST(PROFILE_CFLAGS)
 578
 579 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 580 AC_SUBST(DEPRECATED_CFLAGS)
 581
 582 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 583 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 584 AC_SUBST(GST_OPTION_CFLAGS)
 585
 586 dnl our libraries need to be versioned correctly
 587 AC_SUBST(GST_LT_LDFLAGS)
 588
 589 dnl GST_PLUGINS_BASE_CFLAGS
 590 dnl prefer internal headers to already installed ones
 591 dnl also add builddir include for enumtypes and marshal
 592 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 593 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 594
 595 dnl FIXME: do we want to rename to GST_ALL_* ?
 596 dnl add GST_OPTION_CFLAGS, but overridable
 597 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 598 AC_SUBST(GST_CFLAGS)
 599 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 600 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 601 AC_SUBST(GST_LIBS)
 602
 603 dnl LDFLAGS really should only contain flags, not libs - they get added before
 604 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 605 GST_ALL_LDFLAGS="-no-undefined"
 606 AC_SUBST(GST_ALL_LDFLAGS)
 607
 608 dnl GST_LIB_LDFLAGS
 609 dnl linker flags shared by all libraries
 610 dnl LDFLAGS modifier defining exported symbols from built libraries
 611 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 612 AC_SUBST(GST_LIB_LDFLAGS)
 613
 614 dnl this really should only contain flags, not libs - they get added before
 615 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 616 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 617 AC_SUBST(GST_PLUGIN_LDFLAGS)
 618
 619 dnl *** output files ***
 620
 621 AC_CONFIG_FILES(
 622 Makefile
 623 gst-plugins-base.spec
 624 gst/Makefile
 625 gst/adder/Makefile
 626 gst/audioconvert/Makefile
 627 gst/audiorate/Makefile
 628 gst/audioresample/Makefile
 629 gst/audiotestsrc/Makefile
 630 gst/ffmpegcolorspace/Makefile
 631 gst/gdp/Makefile
 632 gst/playback/Makefile
 633 gst/subparse/Makefile
 634 gst/tcp/Makefile
 635 gst/typefind/Makefile
 636 gst/videotestsrc/Makefile
 637 gst/videorate/Makefile
 638 gst/videoscale/Makefile
 639 gst/volume/Makefile
 640 sys/Makefile
 641 sys/ximage/Makefile
 642 sys/xvimage/Makefile
 643 sys/v4l/Makefile
 644 ext/Makefile
 645 ext/alsa/Makefile
 646 ext/cdparanoia/Makefile
 647 ext/gnomevfs/Makefile
 648 ext/libvisual/Makefile
 649 ext/ogg/Makefile
 650 ext/pango/Makefile
 651 ext/theora/Makefile
 652 ext/vorbis/Makefile
 653 gst-libs/Makefile
 654 gst-libs/gst/Makefile
 655 gst-libs/gst/audio/Makefile
 656 gst-libs/gst/cdda/Makefile
 657 gst-libs/gst/fft/Makefile
 658 gst-libs/gst/floatcast/Makefile
 659 gst-libs/gst/interfaces/Makefile
 660 gst-libs/gst/netbuffer/Makefile
 661 gst-libs/gst/riff/Makefile
 662 gst-libs/gst/rtp/Makefile
 663 gst-libs/gst/rtsp/Makefile
 664 gst-libs/gst/sdp/Makefile
 665 gst-libs/gst/tag/Makefile
 666 gst-libs/gst/pbutils/Makefile
 667 gst-libs/gst/video/Makefile
 668 tools/Makefile
 669 win32/common/config.h
 670 pkgconfig/Makefile
 671 pkgconfig/gstreamer-plugins-base.pc
 672 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 673 tests/Makefile
 674 tests/check/Makefile
 675 tests/examples/Makefile
 676 tests/examples/dynamic/Makefile
 677 tests/examples/seek/Makefile
 678 tests/examples/volume/Makefile
 679 tests/examples/snapshot/Makefile
 680 tests/icles/Makefile
 681 docs/Makefile
 682 docs/design/Makefile
 683 docs/libs/Makefile
 684 docs/plugins/Makefile
 685 docs/version.entities
 686 po/Makefile.in
 687 common/Makefile
 688 common/m4/Makefile
 689 m4/Makefile
 690 )
 691 AC_OUTPUT
 692
 693 AG_GST_OUTPUT_PLUGINS