configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gstreamer, GST_VERSION, 0, 10, 0, 2,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/gst.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  31 dnl we override it here for release candidates for a new series
  32 GST_MAJORMINOR=0.10
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 2, 0, 2)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** autotools stuff ****
  46
  47 dnl allow for different autotools
  48 AS_AUTOTOOLS_ALTERNATE
  49
  50 dnl Add parameters for aclocal
  51 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  52
  53 dnl set up gettext
  54 dnl the version check needs to stay here because autopoint greps for it
  55 AM_GNU_GETTEXT_VERSION([0.11.5])
  56 AM_GNU_GETTEXT([external])
  57 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  58
  59 dnl *** check for arguments to configure ***
  60
  61 dnl subsystems - can influence other decisions so needs to be high up
  62 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  63 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  64 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  65 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  66 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  67 dnl define a substitution to use in docs/gst/gstreamer.types
  68 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  69 then
  70   GST_LOADSAVE_DOC_TYPES="%"
  71 else
  72   GST_LOADSAVE_DOC_TYPES=
  73 fi
  74 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  75 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  76 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  77 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  78 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  79 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  80 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  81 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  82 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  85 then
  86   GST_REGISTRY_DOC_TYPES="%"
  87 else
  88   GST_REGISTRY_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_REGISTRY_DOC_TYPES)
  91 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  92 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  93 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  94 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  95 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
  96 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
  97 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  98 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  99 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 100 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 101
 102 GST_ARG_DEBUG
 103 GST_ARG_PROFILING
 104 GST_ARG_VALGRIND
 105 GST_ARG_GCOV
 106
 107 GST_ARG_EXAMPLES
 108
 109 GST_ARG_WITH_PKG_CONFIG_PATH
 110 GST_ARG_WITH_PACKAGE_NAME([GStreamer])
 111 GST_ARG_WITH_PACKAGE_ORIGIN
 112
 113 dnl use a cache dir for storing element registry info.
 114 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 115
 116 AC_ARG_WITH(cachedir,
 117   AC_HELP_STRING([--with-cachedir],
 118     [specify path to use for plugin and command completion registries]),
 119   [
 120     case "${withval}" in
 121       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 122       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 123       *)   GST_CACHE_DIR="${withval}" ;;
 124     esac
 125   ],
 126   [:]) dnl Default value
 127
 128 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 129 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 130 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 131
 132 dnl building of tests
 133 AC_ARG_ENABLE(tests,
 134   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 135   [
 136     case "${enableval}" in
 137       yes) BUILD_TESTS=yes ;;
 138       no)  BUILD_TESTS=no ;;
 139       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 140     esac
 141   ],
 142 [BUILD_TESTS=yes]) dnl Default value
 143 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 144
 145 dnl tests known to fail
 146 AC_ARG_ENABLE(failing-tests,
 147   AC_HELP_STRING([--disable-failing-tests],
 148     [disable building tests known to fail]),
 149   [
 150     case "${enableval}" in
 151       yes) BUILD_FAILING_TESTS=yes ;;
 152       no)  BUILD_FAILING_TESTS=no ;;
 153       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 154     esac
 155   ],
 156   [BUILD_FAILING_TESTS=no]) dnl Default value
 157 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 158 if test x$BUILD_FAILING_TESTS = xyes; then
 159   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 160 else
 161   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 162 fi
 163
 164 dnl poison destroyed objects
 165 AC_ARG_ENABLE(poisoning,
 166   AC_HELP_STRING([--enable-poisoning],
 167     [enable poisoning of deallocated objects]),
 168   [
 169     case "${enableval}" in
 170       yes) USE_POISONING=yes ;;
 171       no)  USE_POISONING=no ;;
 172       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 173     esac
 174   ],
 175   [USE_POISONING=no]) dnl Default value
 176 if test "x$USE_POISONING" = xyes; then
 177   AC_DEFINE(USE_POISONING, 1,
 178     [Define if we should poison deallocated memory])
 179 fi
 180
 181 dnl *** checks for platform ***
 182
 183 dnl * hardware/architecture *
 184
 185 dnl common/m4/gst-arch.m4
 186 dnl check CPU type
 187 GST_ARCH
 188
 189 dnl common/m4/gst-arch.m4
 190 dnl check for unaligned access
 191 GST_UNALIGNED_ACCESS
 192 dnl create a configure variable for gst/gstconfig.h
 193 if test x${as_cv_unaligned_access} = xyes ; then
 194   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 195 else
 196   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 197 fi
 198 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 199
 200 dnl * software *
 201
 202 dnl check for large file support
 203 dnl affected plugins must include config.h
 204 AC_SYS_LARGEFILE
 205
 206 dnl HAVE_WIN32 currently means "disable POSIXisms".
 207 case "$host" in
 208   *-*-mingw*)
 209     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 210     ;;
 211   *)
 212     ;;
 213 esac
 214
 215 dnl *** checks for programs ***
 216
 217 dnl find a compiler
 218 AC_PROG_CC
 219
 220 dnl find an assembler
 221 AM_PROG_AS
 222
 223 dnl we use awk in the bison version check
 224 AC_PROG_AWK
 225
 226 dnl we require bison for building the parser
 227 dnl FIXME: check if AC_PROG_YACC is suitable here
 228 dnl FIXME: make precious
 229 AC_PATH_PROG(BISON_PATH, bison, no)
 230 if test x$BISON_PATH = xno; then
 231   AC_MSG_ERROR(Could not find bison)
 232 fi
 233
 234 dnl check bison version
 235 AC_MSG_CHECKING([bison version])
 236
 237 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 238 then
 239   AC_MSG_RESULT([ok])
 240 else
 241   AC_MSG_RESULT([too old.])
 242   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 243 fi
 244
 245 dnl we require flex for building the parser
 246 dnl FIXME: check if AC_PROG_LEX is suitable here
 247 AC_PATH_PROG(FLEX_PATH, flex, no)
 248 if test x$FLEX_PATH = xno; then
 249   AC_MSG_ERROR(Could not find flex)
 250 fi
 251
 252 dnl Perl is used in building documentation
 253 AC_PATH_PROG(PERL_PATH, perl, no)
 254 if test x$PERL_PATH = xno; then
 255   AC_MSG_ERROR(Could not find perl)
 256 fi
 257
 258 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 259 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 260
 261 dnl check for documentation tools
 262 GST_DOCBOOK_CHECK
 263 GTK_DOC_CHECK([1.3])
 264 AS_PATH_PYTHON([2.1])
 265
 266 dnl *** checks for libraries ***
 267
 268 dnl For interactive UNIX (a Sun thing)
 269 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 270 AC_ISC_POSIX
 271
 272 dnl *** checks for header files ***
 273
 274 dnl check if we have ANSI C header files
 275 AC_HEADER_STDC
 276
 277 dnl Check for ucontext.h
 278 AC_CHECK_HEADERS([ucontext.h])
 279 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 280 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 281 AC_CHECK_HEADERS([process.h])
 282
 283 dnl *** checks for types/defines ***
 284
 285 dnl *** checks for structures ***
 286
 287 dnl *** checks for compiler characteristics ***
 288
 289 dnl make sure we can use "inline" from C code
 290 AC_C_INLINE
 291
 292 OPT_CFLAGS=
 293 dnl Check for some compiler flags that optimize our code.
 294 if test "x$GCC" = xyes; then
 295   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 296 fi
 297
 298 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 299 dnl flag
 300 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 301 dnl symbolic register names in inline asm
 302 if test x$HAVE_CPU_PPC = xyes ; then
 303   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 304     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 305 fi
 306
 307 dnl *** checks for library functions ***
 308
 309 AC_CHECK_FUNCS([sigaction])
 310
 311 dnl check for fseeko()
 312 AC_FUNC_FSEEKO
 313 dnl check for ftello()
 314 AC_CHECK_FUNCS([ftello])
 315
 316 AC_CHECK_FUNCS([fgetpos])
 317 AC_CHECK_FUNCS([fsetpos])
 318
 319 dnl check for mmap()
 320 AC_FUNC_MMAP
 321 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 322
 323 dnl Check for a way to display the function name in debug output
 324 GST_CHECK_FUNCTION
 325
 326 dnl test for register_printf_function
 327 AC_CHECK_FUNC(register_printf_function,
 328   [
 329     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 330     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 331       [Defined if we have register_printf_function ()])
 332   ],
 333   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 334 )
 335 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 336
 337 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 338 save_cflags="$CFLAGS"
 339 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 340 AC_CHECK_LIB(dl, dladdr,
 341    AC_DEFINE(HAVE_DLADDR, 1,
 342              [Defined if we have dladdr ()]))
 343 CFLAGS="$save_cflags"
 344
 345 dnl *** checks for dependancy libraries ***
 346
 347 dnl GLib
 348
 349 GST_GLIB_CHECK([2.6])
 350
 351 dnl GLib 2.8 has some bug fixes that we like, so make sure our code knows
 352 AC_MSG_CHECKING([glib version >= 2.8])
 353 if pkg-config --atleast-version=2.8 glib-2.0; then
 354   AC_MSG_RESULT(yes)
 355   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 356 else
 357   AC_MSG_RESULT(no)
 358   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 359 fi
 360 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 361
 362 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 363 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 364
 365 dnl libxml 2, which is/should be optional (FIXME)
 366 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 367    test "x$GST_DISABLE_REGISTRY" = "xyes"
 368 then
 369   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 370 else
 371   dnl check for libxml2 with minimum req version
 372   GST_LIBXML2_CHECK(2.4.9)
 373 fi
 374
 375 dnl check for "check", unit testing library/header
 376 AM_PATH_CHECK(0.9.2,
 377     [
 378         HAVE_CHECK=yes
 379         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 380         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 381     ],
 382     HAVE_CHECK=no)
 383 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 384
 385 dnl *** set variables based on configure arguments
 386
 387 dnl set license and copyright notice
 388 GST_LICENSE="LGPL"
 389 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 390 AC_SUBST(GST_LICENSE)
 391
 392 dnl define LIBDIR so we can inform people where we live
 393 AS_AC_EXPAND(LIBDIR, $libdir)
 394 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 395
 396 dnl set location of plugin directory
 397 GST_SET_PLUGINDIR
 398
 399 dnl FIXME: add LIBXML_PKG here
 400 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 401 AC_SUBST(GST_PKG_DEPS)
 402
 403 dnl define an ERROR_CFLAGS Makefile variable
 404 GST_SET_ERROR_CFLAGS($GST_CVS)
 405
 406 dnl define correct level for debugging messages
 407 GST_SET_LEVEL_DEFAULT($GST_CVS)
 408
 409 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 410
 411 dnl Overview:
 412 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 413 dnl GST_ALL_*:          vars shared by all built objects
 414 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 415 dnl GST_OBJ_*:          additional vars to link to the core library
 416 dnl                     include GST_ALL_*
 417 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 418 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 419
 420 dnl GST_OPTION_CFLAGS
 421 if test "x$USE_DEBUG" = xyes; then
 422    PROFILE_CFLAGS="-g"
 423 fi
 424 AC_SUBST(PROFILE_CFLAGS)
 425
 426 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 427 AC_SUBST(DEPRECATED_CFLAGS)
 428
 429 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 430 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 431 AC_SUBST(GST_OPTION_CFLAGS)
 432
 433 dnl GST_ALL_*
 434 dnl vars common to for all internal objects (core libs, elements, applications)
 435 dnl CFLAGS:
 436 dnl - XML needs to be added because xmlPtr is used in core
 437 dnl - src and build dirs need to be added because every piece that gets built
 438 dnl   will need the GStreamer source and generated headers
 439 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 440 dnl       from LibXML except for in the core library
 441 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 442 dnl FIXME: check if LTLIBINTL is needed everywhere
 443 dnl I presume it is given that it contains the symbols that _() stuff maps to
 444 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL"
 445 dnl LDFLAGS really should only contain flags, not libs - they get added before
 446 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 447 GST_ALL_LDFLAGS="-no-undefined"
 448
 449 AC_SUBST(GST_ALL_CFLAGS)
 450 AC_SUBST(GST_ALL_LIBS)
 451 AC_SUBST(GST_ALL_LDFLAGS)
 452
 453 dnl GST_LIB_LDFLAGS
 454 dnl linker flags shared by all libraries
 455 dnl LDFLAGS modifier defining exported symbols from built libraries
 456 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 457 AC_SUBST(GST_LIB_LDFLAGS)
 458
 459 dnl GST_OBJ_*
 460 dnl default vars for all internal objects built on libgstreamer
 461 dnl includes GST_ALL_*
 462 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 463 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 464 AC_SUBST(GST_OBJ_CFLAGS)
 465 AC_SUBST(GST_OBJ_LIBS)
 466
 467 dnl GST_PLUGIN_LDFLAGS
 468 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 469 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 470 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 471
 472 dnl ##################################################
 473 dnl # deps for examples from manual                  #
 474 dnl ##################################################
 475
 476 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 477                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 478 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 479
 480 AC_CONFIG_FILES(
 481 Makefile
 482 gst/Makefile
 483 gst/gstconfig.h
 484 gst/gstversion.h
 485 gst/parse/Makefile
 486 libs/Makefile
 487 libs/gst/Makefile
 488 libs/gst/base/Makefile
 489 libs/gst/check/Makefile
 490 libs/gst/controller/Makefile
 491 libs/gst/dataprotocol/Makefile
 492 libs/gst/net/Makefile
 493 plugins/Makefile
 494 plugins/indexers/Makefile
 495 plugins/elements/Makefile
 496 po/Makefile.in
 497 tests/Makefile
 498 tests/benchmarks/Makefile
 499 tests/check/Makefile
 500 tests/misc/Makefile
 501 tests/examples/Makefile
 502 tests/examples/controller/Makefile
 503 tests/examples/helloworld/Makefile
 504 tests/examples/launch/Makefile
 505 tests/examples/metadata/Makefile
 506 tests/examples/queue/Makefile
 507 tests/examples/typefind/Makefile
 508 tests/examples/xml/Makefile
 509 tools/Makefile
 510 common/Makefile
 511 common/m4/Makefile
 512 docs/Makefile
 513 docs/faq/Makefile
 514 docs/gst/Makefile
 515 docs/gst/gstreamer.types
 516 docs/libs/Makefile
 517 docs/plugins/Makefile
 518 docs/manual/Makefile
 519 docs/pwg/Makefile
 520 docs/xsl/Makefile
 521 docs/version.entities
 522 win32/common/config.h
 523 pkgconfig/Makefile
 524 stamp.h
 525 pkgconfig/gstreamer.pc
 526 pkgconfig/gstreamer-uninstalled.pc
 527 pkgconfig/gstreamer-base.pc
 528 pkgconfig/gstreamer-base-uninstalled.pc
 529 pkgconfig/gstreamer-check.pc
 530 pkgconfig/gstreamer-check-uninstalled.pc
 531 pkgconfig/gstreamer-controller.pc
 532 pkgconfig/gstreamer-controller-uninstalled.pc
 533 pkgconfig/gstreamer-dataprotocol.pc
 534 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 535 pkgconfig/gstreamer-net.pc
 536 pkgconfig/gstreamer-net-uninstalled.pc
 537 gstreamer.spec
 538 )
 539 AC_OUTPUT