configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT([GStreamer Ugly Plug-ins],[1.7.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-ugly])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS(config.h)
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AS_LIBTOOL(GST, 700, 0, 700)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.7.0.1
  49 GSTPB_REQ=1.7.0.1
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION(0.17)
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101 AC_PROG_CC_STDC
 102
 103 dnl determine c++ compiler
 104 AC_PROG_CXX
 105 dnl determine if c++ is available on this system
 106 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 107
 108 dnl check if the compiler supports '-c' and '-o' options
 109 AM_PROG_CC_C_O
 110
 111 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 112 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 113
 114 dnl check if the compiler supports do while(0) macros
 115 AG_GST_CHECK_DOWHILE_MACROS
 116
 117 dnl check for documentation tools
 118 GTK_DOC_CHECK([1.12])
 119 AG_GST_PLUGIN_DOCS([1.12])
 120
 121 dnl *** checks for libraries ***
 122
 123 dnl check for libm, for sin()
 124 LT_LIB_M
 125 AC_SUBST(LIBM)
 126
 127 dnl *** checks for header files ***
 128
 129 dnl used by ext/a52dec
 130 AX_CREATE_STDINT_H
 131
 132 dnl Check for malloc.h
 133 AC_CHECK_HEADERS([malloc.h])
 134
 135 dnl *** checks for types/defines ***
 136
 137 dnl *** checks for structures ***
 138
 139 dnl *** checks for compiler characteristics ***
 140
 141 dnl *** checks for library functions ***
 142
 143 dnl Check for a way to display the function name in debug output
 144 AG_GST_CHECK_FUNCTION
 145
 146 dnl *** checks for dependency libraries ***
 147
 148 dnl GLib is required
 149 GLIB_REQ=2.32.0
 150 AG_GST_GLIB_CHECK([$GLIB_REQ])
 151
 152 ORC_CHECK([0.4.16])
 153
 154 dnl checks for gstreamer
 155 dnl uninstalled is selected preferentially -- see pkg-config(1)
 156 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 157 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 158 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 159 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 160 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 161
 162 dnl Check for documentation xrefs
 163 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 164 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 165 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 166 AC_SUBST(GLIB_PREFIX)
 167 AC_SUBST(GST_PREFIX)
 168 AC_SUBST(GSTPB_PREFIX)
 169
 170 dnl Needed by plugins that use g_module_*() API
 171 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 172
 173 dnl *** set variables based on configure arguments ***
 174
 175 dnl set license and copyright notice
 176 GST_LICENSE="LGPL"
 177 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 178 AC_SUBST(GST_LICENSE)
 179
 180 dnl set location of plugin directory
 181 AG_GST_SET_PLUGINDIR
 182
 183 dnl set release date/time
 184 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 185   ["${srcdir}/gst-plugins-ugly.doap"],
 186   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 187
 188 dnl build static plugins or not
 189 AC_MSG_CHECKING([whether to build static plugins or not])
 190 AC_ARG_ENABLE(
 191   static-plugins,
 192   AC_HELP_STRING(
 193     [--enable-static-plugins],
 194     [build static plugins @<:@default=no@:>@]),
 195   [AS_CASE(
 196     [$enableval], [no], [], [yes], [],
 197     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 198   [enable_static_plugins=no])
 199 AC_MSG_RESULT([$enable_static_plugins])
 200 if test "x$enable_static_plugins" = xyes; then
 201   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 202     [Define if static plugins should be built])
 203   GST_PLUGIN_LIBTOOLFLAGS=""
 204 else
 205   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 206 fi
 207 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 208 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 209
 210 dnl define an ERROR_CFLAGS Makefile variable
 211 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 212     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 213     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 214     -Winit-self -Wmissing-include-dirs -Waddress
 215     -Waggregate-return -Wno-multichar -Wnested-externs ])
 216
 217 dnl define an ERROR_CXXFLAGS Makefile variable
 218 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 219     -Wmissing-declarations -Wredundant-decls
 220     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 221     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 222     -Wno-multichar])
 223
 224 dnl define correct level for debugging messages
 225 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 226
 227 dnl used in examples
 228 AG_GST_DEFAULT_ELEMENTS
 229
 230 dnl *** plug-ins to include ***
 231
 232 dnl these are all the gst plug-ins, compilable without additional libs
 233 AG_GST_CHECK_PLUGIN(asfdemux)
 234 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 235 AG_GST_CHECK_PLUGIN(dvdsub)
 236 AG_GST_CHECK_PLUGIN(xingmux)
 237 AG_GST_CHECK_PLUGIN(realmedia)
 238
 239 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 240
 241 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 242   WIN32_LIBS="-lws2_32"
 243   AC_SUBST(WIN32_LIBS)
 244 fi
 245
 246 dnl *** ext plug-ins ***
 247 dnl keep this list sorted alphabetically !
 248
 249 if test "x$BUILD_EXTERNAL" = "xyes"; then
 250
 251 echo
 252 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 253 echo
 254
 255 dnl *** a52dec ***
 256 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 257 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 258   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 259 ])
 260
 261 dnl *** amr-nb ***
 262 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 263 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 264   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 265     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 266       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 267     fi
 268     HAVE_AMRNB="yes"
 269   ], [
 270     HAVE_AMRNB="no"
 271   ])
 272   AC_SUBST(AMRNB_CFLAGS)
 273   AC_SUBST(AMRNB_LIBS)
 274 ])
 275
 276 dnl *** amr-wb dec ***
 277 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 278 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 279   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 280     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 281       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 282     fi
 283     HAVE_AMRWB="yes"
 284   ], [
 285     HAVE_AMRWB="no"
 286   ])
 287   AC_SUBST(AMRWB_CFLAGS)
 288   AC_SUBST(AMRWB_LIBS)
 289 ])
 290
 291 dnl *** cdio ***
 292 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 293 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 294   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 295 ])
 296
 297 dnl *** dvdread ***
 298 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 299 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 300   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 301   AC_SUBST(DVDREAD_LIBS)
 302 ])
 303
 304 dnl *** lame ***
 305 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 306 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 307   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 308   [
 309     HAVE_LAME="yes"
 310     LAME_LIBS="-lmp3lame $LIBM"
 311     dnl is lame presets available
 312     LAME_CFLAGS=""
 313     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 314     ])
 315     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 316         void *ptr = &lame_set_VBR_quality
 317       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 318     ])
 319   AC_SUBST(LAME_CFLAGS)
 320   AC_SUBST(LAME_LIBS)
 321   ])
 322 ])
 323
 324 dnl *** mad ***
 325 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 326 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 327
 328   dnl check with pkg-config first
 329   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 330   MAD_LIBS="$MAD_LIBS"
 331   if test "x$HAVE_MAD" = "xno"; then
 332     dnl fall back to oldskool detection
 333     AC_CHECK_HEADER(mad.h, [
 334       AC_CHECK_LIB(mad, mad_decoder_finish,
 335         HAVE_MAD="yes" MAD_LIBS="-lmad")
 336     ])
 337   fi
 338 ])
 339 AC_SUBST(MAD_LIBS)
 340
 341 dnl *** mpeg2dec ***
 342 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 343 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 344   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 345 ])
 346
 347 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 348 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 349 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 350   GST_PATH_SIDPLAY()
 351 ])
 352
 353 dnl *** twolame ***
 354 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 355 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 356   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 357       HAVE_TWOLAME="yes"], [
 358       HAVE_TWOLAME="no"
 359   ])
 360   AC_SUBST(TWOLAME_CFLAGS)
 361   AC_SUBST(TWOLAME_LIBS)
 362 ])
 363
 364 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 365 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 366 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 367   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120)
 368 ])
 369
 370 else
 371
 372 dnl not building plugins with external dependencies,
 373 dnl but we still need to set the conditionals
 374
 375 AM_CONDITIONAL(USE_A52DEC, false)
 376 AM_CONDITIONAL(USE_AMRNB, false)
 377 AM_CONDITIONAL(USE_AMRWB, false)
 378 AM_CONDITIONAL(USE_CDIO, false)
 379 AM_CONDITIONAL(USE_DVDREAD, false)
 380 AM_CONDITIONAL(USE_LAME, false)
 381 AM_CONDITIONAL(USE_MAD, false)
 382 AM_CONDITIONAL(USE_MPEG2DEC, false)
 383 AM_CONDITIONAL(USE_SIDPLAY, false)
 384 AM_CONDITIONAL(USE_TWOLAME, false)
 385 AM_CONDITIONAL(USE_X264, false)
 386
 387 fi dnl of EXT plugins
 388
 389 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 390
 391 dnl Overview:
 392 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 393 dnl GST_*:              flags shared by built objects to link against GStreamer
 394 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 395 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 396 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 397 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 398
 399 dnl GST_OPTION_CFLAGS
 400 if test "x$USE_DEBUG" = xyes; then
 401    PROFILE_CFLAGS="-g"
 402 fi
 403 AC_SUBST(PROFILE_CFLAGS)
 404
 405 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 406   dnl Define _only_ during CVS (not pre-releases or releases)
 407   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 408 else
 409   DEPRECATED_CFLAGS=""
 410 fi
 411 AC_SUBST(DEPRECATED_CFLAGS)
 412
 413 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 414 dnl at make time with e.g. make ERROR_CFLAGS=""
 415 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 416 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 417 AC_SUBST(GST_OPTION_CFLAGS)
 418 AC_SUBST(GST_OPTION_CXXFLAGS)
 419
 420 dnl FIXME: do we want to rename to GST_ALL_* ?
 421 dnl prefer internal headers to already installed ones
 422 dnl also add builddir include for enumtypes and marshal
 423 dnl add GST_OPTION_CFLAGS, but overridable
 424 GST_CFLAGS="$GST_CFLAGS"
 425 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 426 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 427 AC_SUBST(GST_CFLAGS)
 428 AC_SUBST(GST_CXXFLAGS)
 429 AC_SUBST(GST_LIBS)
 430
 431 dnl LDFLAGS really should only contain flags, not libs - they get added before
 432 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 433 GST_ALL_LDFLAGS="-no-undefined"
 434 AC_SUBST(GST_ALL_LDFLAGS)
 435
 436 dnl this really should only contain flags, not libs - they get added before
 437 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 438 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 439 AC_SUBST(GST_PLUGIN_LDFLAGS)
 440
 441 dnl *** output files ***
 442
 443 AC_CONFIG_FILES(
 444 Makefile
 445 common/Makefile
 446 common/m4/Makefile
 447 gst-libs/Makefile
 448 gst-libs/gst/Makefile
 449 gst/Makefile
 450 gst/asfdemux/Makefile
 451 gst/dvdlpcmdec/Makefile
 452 gst/dvdsub/Makefile
 453 gst/realmedia/Makefile
 454 gst/xingmux/Makefile
 455 ext/Makefile
 456 ext/a52dec/Makefile
 457 ext/amrnb/Makefile
 458 ext/amrwbdec/Makefile
 459 ext/cdio/Makefile
 460 ext/dvdread/Makefile
 461 ext/lame/Makefile
 462 ext/mad/Makefile
 463 ext/mpeg2dec/Makefile
 464 ext/sidplay/Makefile
 465 ext/twolame/Makefile
 466 ext/x264/Makefile
 467 docs/Makefile
 468 docs/plugins/Makefile
 469 docs/version.entities
 470 tests/Makefile
 471 tests/check/Makefile
 472 m4/Makefile
 473 po/Makefile.in
 474 pkgconfig/Makefile
 475 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 476 gst-plugins-ugly.spec
 477 )
 478
 479 dnl Create the config.h file for Visual Studio builds
 480 dnl Beware of spaces and /'s in some of the shell variable contents.
 481 sed \
 482     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 483     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 484     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 485     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 486     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 487     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 488     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 489     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 490     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 491     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 492     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 493     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 494     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 495     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 496     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 497     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 498     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 499     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 500     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 501     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 502     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 503     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 504     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 505     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 506     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 507     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 508     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 509     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 510     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 511     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 512     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 513     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 514     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 515     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 516     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 517     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 518     config.h.in >win32/common/config.h-new
 519
 520 AC_OUTPUT
 521
 522 AG_GST_OUTPUT_PLUGINS
 523
 524 ORC_OUTPUT