configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.3])
 161 AS_PATH_PYTHON([2.1])
 162 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 AC_CHECK_LIBM
 168 AC_SUBST(LIBM)
 169
 170 dnl *** checks for header files ***
 171
 172 dnl check if we have ANSI C header files
 173 AC_HEADER_STDC
 174
 175 ac_cppflags_save="$CPPFLAGS"
 176 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 177 AC_COMPILE_IFELSE(
 178   AC_LANG_PROGRAM([
 179 #include <libxml/HTMLparser.h>
 180                      ],[
 181 #ifndef LIBXML_HTML_ENABLED
 182 #error libxml2 has no HTML support
 183 #endif /* LIBXML_HTML_ENABLED */
 184                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 185 CPPFLAGS="$ac_cppflags_save"
 186 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 187
 188 dnl used in gst-libs/gst/pbutils and associated unit test
 189 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 190
 191 dnl also, Windows does not have long long
 192 AX_CREATE_STDINT_H
 193
 194 dnl *** checks for functions ***
 195 AC_CHECK_FUNCS([localtime_r gmtime_r])
 196
 197 dnl *** checks for math functions ***
 198 LIBS_SAVE=$LIBS
 199 LIBS="$LIBS $LIBM"
 200 AC_CHECK_FUNCS(log2)
 201 LIBS=$LIBS_SAVE
 202
 203 dnl *** checks for types/defines ***
 204
 205 dnl *** checks for structures ***
 206
 207 dnl *** checks for compiler characteristics ***
 208
 209 dnl *** checks for library functions ***
 210
 211 dnl check for fseeko()
 212 AC_FUNC_FSEEKO
 213
 214 dnl Check for fast float to int casting as defined in C99
 215 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 216 save_libs=$LIBS
 217 LIBS="$LIBS $LIBM"
 218 AC_C99_FUNC_LRINT
 219 AC_C99_FUNC_LRINTF
 220 LIBS=$save_libs
 221
 222 dnl Check for a way to display the function name in debug output
 223 AG_GST_CHECK_FUNCTION
 224
 225 dnl *** checks for dependency libraries ***
 226
 227 dnl GLib
 228 GLIB_REQ=2.31.10
 229
 230 AG_GST_GLIB_CHECK([$GLIB_REQ])
 231
 232 dnl Check for GIO
 233 PKG_CHECK_MODULES(GIO, gio-2.0 >= $GLIB_REQ)
 234 GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 235 AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 236     [The GIO modules directory.])
 237 GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 238     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 239         [The GIO library directory.])
 240
 241 AC_SUBST(GIO_CFLAGS)
 242 AC_SUBST(GIO_LIBS)
 243 AC_SUBST(GIO_LDFLAGS)
 244
 245 ORC_CHECK([0.4.11])
 246
 247 dnl checks for gstreamer
 248 dnl uninstalled is selected preferentially -- see pkg-config(1)
 249 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 250 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 251 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 252 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 253 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 254
 255 dnl Check for documentation xrefs
 256 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 257 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 258 AC_SUBST(GLIB_PREFIX)
 259 AC_SUBST(GST_PREFIX)
 260
 261 dnl GTK is optional and only used in examples
 262 HAVE_GTK=no
 263 HAVE_GTK_X11=no
 264 GTK_REQ=3.0.0
 265 if test "x$BUILD_EXAMPLES" = "xyes"; then
 266   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 267   dnl some examples need gtk+-x11
 268   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 269   AC_SUBST(GTK_LIBS)
 270   AC_SUBST(GTK_CFLAGS)
 271 fi
 272 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 273 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 274
 275 dnl QT is optional and only used in examples
 276 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 277   HAVE_QT_GV=yes
 278   HAVE_QT=yes
 279 ], [
 280   HAVE_QT_GV=no
 281   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 282 ])
 283 if test "x$HAVE_QT" = "xyes"; then
 284   AC_MSG_CHECKING([Qt moc])
 285   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 286   AC_MSG_RESULT($QT4_MOC)
 287   AC_SUBST(QT4_MOC)
 288 fi
 289 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 290 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 291
 292 dnl chck for linux headers needed by the joystick seek example
 293 AC_COMPILE_IFELSE(
 294 [
 295   AC_LANG_PROGRAM([
 296     #include <linux/input.h>
 297     #include <linux/joystick.h>
 298   ],[
 299     struct js_event js;
 300     js.type = JS_EVENT_AXIS;
 301   ])
 302 ], [
 303   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 304 ], [
 305   HAVE_LINUX_JOYSTICK_HEADERS="no"
 306 ])
 307 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 308
 309 dnl Check for -Bsymbolic-functions linker flag used to avoid
 310 dnl intra-library PLT jumps, if available.
 311 AC_ARG_ENABLE(Bsymbolic,
 312               [AC_HELP_STRING([--disable-Bsymbolic],
 313                               [avoid linking with -Bsymbolic])],,
 314               [SAVED_LDFLAGS="${LDFLAGS}"
 315                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 316                LDFLAGS=-Wl,-Bsymbolic-functions
 317                AC_TRY_LINK([], [int main (void) { return 0; }],
 318                            AC_MSG_RESULT(yes)
 319                            enable_Bsymbolic=yes,
 320                            AC_MSG_RESULT(no)
 321                            enable_Bsymbolic=no)
 322                LDFLAGS="${SAVED_LDFLAGS}"])
 323
 324
 325 dnl *** set variables based on configure arguments ***
 326
 327 dnl set license and copyright notice
 328 GST_LICENSE="LGPL"
 329 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 330 AC_SUBST(GST_LICENSE)
 331
 332 dnl set location of plugin directory
 333 AG_GST_SET_PLUGINDIR
 334
 335 dnl set release date/time
 336 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 337   ["${srcdir}/gst-plugins-base.doap"],
 338   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 339
 340 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 341 dnl make sure it doesn't complain about unused variables if debugging is disabled
 342 NO_WARNINGS=""
 343 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 344
 345 dnl define an ERROR_CFLAGS Makefile variable
 346 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 347 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 348     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 349     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 350     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 351     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 352
 353 dnl define an ERROR_CXXFLAGS Makefile variable
 354 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 355     -Wmissing-declarations -Wredundant-decls -Wundef
 356     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 357     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 358     -Wno-multichar $NO_WARNINGS])
 359
 360 dnl define correct level for debugging messages
 361 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 362
 363 dnl used in examples
 364 AG_GST_DEFAULT_ELEMENTS
 365
 366 dnl needed for encoding-target
 367 GST_DATADIR="$GST_PREFIX/share"
 368 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 369 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 370
 371 dnl behaviour of speex based audio resampler
 372 AC_MSG_CHECKING(which audio resample format to use for integer)
 373 AC_ARG_WITH([audioresample_format],
 374         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 375         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 376 AC_MSG_RESULT($ac_cv_audioresample_format)
 377 case $ac_cv_audioresample_format in
 378   int)
 379     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 380     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 381   ;;
 382   float)
 383     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 384     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 385   ;;
 386   auto)
 387     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 388     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 389 esac
 390
 391 dnl *** plug-ins to include ***
 392
 393 dnl these are all the gst plug-ins, compilable without additional libs
 394 AG_GST_CHECK_PLUGIN(adder)
 395 AG_GST_CHECK_PLUGIN(app)
 396 AG_GST_CHECK_PLUGIN(audioconvert)
 397 AG_GST_CHECK_PLUGIN(audiorate)
 398 AG_GST_CHECK_PLUGIN(audiotestsrc)
 399 AG_GST_CHECK_PLUGIN(encoding)
 400 AG_GST_CHECK_PLUGIN(videoconvert)
 401 AG_GST_CHECK_PLUGIN(gdp)
 402 AG_GST_CHECK_PLUGIN(playback)
 403 AG_GST_CHECK_PLUGIN(audioresample)
 404 AG_GST_CHECK_PLUGIN(subparse)
 405 AG_GST_CHECK_PLUGIN(tcp)
 406 AG_GST_CHECK_PLUGIN(typefind)
 407 AG_GST_CHECK_PLUGIN(videotestsrc)
 408 AG_GST_CHECK_PLUGIN(videorate)
 409 AG_GST_CHECK_PLUGIN(videoscale)
 410 AG_GST_CHECK_PLUGIN(volume)
 411
 412 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 413 AM_CONDITIONAL(USE_XML, false)
 414 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 415
 416 dnl disable plug-ins that require libxml2's HTML support if it is not available
 417 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 418   AG_GST_DISABLE_PLUGIN(subparse)
 419 fi
 420
 421 dnl iso-codes is optional, used by libgsttag
 422 AC_ARG_ENABLE(iso-codes,
 423 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 424 [case "${enableval}" in
 425   yes) enable_iso_codes=yes ;;
 426   no)  enable_iso_codes=no ;;
 427   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 428 esac
 429 ],
 430 [enable_iso_codes=yes]) dnl Default value
 431
 432 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 433 if test "x$enable_iso_codes" = "xyes"; then
 434   AC_MSG_RESULT([yes])
 435   have_iso_codes=no
 436   AC_MSG_CHECKING([whether iso-codes are available on this system])
 437   if $PKG_CONFIG iso-codes; then
 438     AC_MSG_RESULT([yes])
 439     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 440     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 441       AC_MSG_RESULT([yes])
 442       AC_MSG_CHECKING([for iso-codes prefix])
 443       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 444       if test -d "$ISO_CODES_PREFIX"; then
 445         AC_MSG_RESULT([yes])
 446         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 447         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 448         ISO_639_DOMAIN="iso_639"
 449         AC_MSG_CHECKING([ISO_639_DOMAIN])
 450         AC_MSG_RESULT([$ISO_639_DOMAIN])
 451         have_iso_codes=yes
 452         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 453         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 454         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 455         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 456       else
 457         AC_MSG_RESULT([no])
 458       fi
 459     else
 460       AC_MSG_RESULT([no])
 461     fi
 462   else
 463     AC_MSG_RESULT([no])
 464   fi
 465   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 466 else
 467   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 468   AM_CONDITIONAL(USE_ISO_CODES, false)
 469 fi
 470
 471 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 473 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 474   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 475       HAVE_ZLIB="yes"
 476     ], [
 477       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 478         HAVE_ZLIB="yes"
 479         ZLIB_LIBS="-lz"
 480         AC_SUBST(ZLIB_LIBS)
 481       ])
 482     ])
 483 ])
 484
 485 dnl *** sys plug-ins ***
 486
 487 echo
 488 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 489 echo
 490
 491 dnl *** X11 ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 493 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 494                   [ximagesink], [
 495   AC_PATH_XTRA
 496   ac_cflags_save="$CFLAGS"
 497   ac_cppflags_save="$CPPFLAGS"
 498   CFLAGS="$CFLAGS $X_CFLAGS"
 499   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 500
 501   dnl now try to find the HEADER
 502   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 503
 504   if test "x$HAVE_X" = "xno"
 505   then
 506     AC_MSG_NOTICE([cannot find X11 development files])
 507   else
 508     dnl this is much more than we want
 509     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 510     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 511     dnl it does not add the libs; therefore we add them here
 512     X_LIBS="$X_LIBS -lX11"
 513     AC_SUBST(X_CFLAGS)
 514     AC_SUBST(X_LIBS)
 515   fi
 516   AC_SUBST(HAVE_X)
 517   CFLAGS="$ac_cflags_save"
 518   CPPFLAGS="$ac_cppflags_save"
 519 ])
 520
 521 dnl Check for Xv extension
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 523 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 524                   [xvimagesink], [
 525   AG_GST_CHECK_XV
 526 ])
 527
 528 dnl check for X Shm
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 530 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 531   if test x$HAVE_X = xyes; then
 532     AC_CHECK_LIB(Xext, XShmAttach,
 533                  HAVE_XSHM="yes", HAVE_XSHM="no",
 534                  $X_LIBS)
 535     if test "x$HAVE_XSHM" = "xyes"; then
 536       XSHM_LIBS="-lXext"
 537     else
 538       dnl On AIX, it is in XextSam instead, but we still need -lXext
 539       AC_CHECK_LIB(XextSam, XShmAttach,
 540                    HAVE_XSHM="yes", HAVE_XSHM="no",
 541                    $X_LIBS)
 542       if test "x$HAVE_XSHM" = "xyes"; then
 543         XSHM_LIBS="-lXext -lXextSam"
 544       fi
 545     fi
 546   fi
 547 ], , [
 548   AC_SUBST(HAVE_XSHM)
 549   AC_SUBST(XSHM_LIBS)
 550 ])
 551
 552 dnl *** ext plug-ins ***
 553 dnl keep this list sorted alphabetically !
 554
 555 if test "x$BUILD_EXTERNAL" = "xyes"; then
 556
 557 echo
 558 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 559 echo
 560
 561 dnl *** alsa ***
 562 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 563 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 564   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 565     HAVE_ALSA="yes"
 566     AC_SUBST(ALSA_CFLAGS)
 567     AC_SUBST(ALSA_LIBS)
 568   ], [
 569     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 570   ])
 571 ])
 572
 573 dnl *** CDParanoia ***
 574 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 575 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 576 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 577   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 578     HAVE_CDPARANOIA="yes"
 579   ], [
 580     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 581                         cdda_open, -lm,
 582                         cdda_interface.h,
 583                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 584                         HEADER_DIR="no"
 585                         FOUND_CDPARANOIA="yes")
 586     if test "x$FOUND_CDPARANOIA" != "xyes";
 587     then
 588       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 589                           cdda_open, -lm,
 590                           cdda/cdda_interface.h,
 591                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 592                           HEADER_DIR="yes"
 593                           FOUND_CDPARANOIA="yes")
 594     fi
 595     if test "x$HEADER_DIR" = "xyes";
 596     then
 597       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 598                          defined if cdda headers are in a cdda/ directory)
 599     fi
 600     if test "x$FOUND_CDPARANOIA" = "xyes";
 601     then
 602       AC_CHECK_LIB(cdda_paranoia,
 603                    paranoia_cachemodel_size,
 604                    : ,
 605                    HAVE_CDPARANOIA=no,
 606                  [-lcdda_interface])
 607     fi
 608
 609     AC_SUBST(CDPARANOIA_LIBS)
 610   ])
 611 ])
 612 dnl FIXME : add second check somehow if that is necessary
 613 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 614 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 615
 616 dnl *** ivorbis ***
 617 dnl AM_PATH_IVORBIS only takes two options
 618 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 619 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 620   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 621   if test $HAVE_IVORBIS = no
 622   then
 623     IVORBIS_LIBS=
 624     IVORBIS_CFLAGS=
 625     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 626       [IVORBIS_LIBS=-lvorbisidec
 627       HAVE_IVORBIS=yes
 628       case $host in
 629       arm-*-*)
 630         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 631       esac
 632       ],
 633       HAVE_IVORBIS=no)
 634     AC_SUBST(IVORBIS_LIBS)
 635     AC_SUBST(IVORBIS_CFLAGS)
 636   else
 637     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 638       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 639       USE_TREMOLO=no)
 640   fi
 641 ])
 642
 643 dnl *** libvisual ***
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 645 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 646   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 647   if test $HAVE_LIBVISUAL = no
 648   then
 649     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 650     if test x$HAVE_LIBVISUAL = xyes; then
 651       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 652     fi
 653   else
 654     if test x$HAVE_LIBVISUAL = xyes; then
 655       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 656     fi
 657   fi
 658   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 659   if test x$LIBVIS_PLUGINSDIR != x; then
 660     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 661         "$LIBVIS_PLUGINSDIR",
 662         [directory in which the detected libvisual's plugins are located])
 663   fi
 664 ])
 665
 666 dnl *** ogg ***
 667 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 668 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 669   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 670   if test $HAVE_OGG = no
 671   then
 672     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 673     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 674   fi
 675 ])
 676
 677 dnl *** pango ***
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 679 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 680   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 681 ])
 682
 683 dnl *** theora ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 685 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 686   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 687 ])
 688
 689 dnl *** vorbis ***
 690 dnl AM_PATH_VORBIS only takes two options
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 692 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 693   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 694   if test $HAVE_VORBIS = no
 695   then
 696     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 697     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 698   fi
 699 ])
 700
 701 if test "x$HAVE_VORBIS" = "xyes"; then
 702   ac_cflags_save="$CFLAGS"
 703   AC_COMPILE_IFELSE(
 704     AC_LANG_PROGRAM([
 705 #include <vorbis/codec.h>
 706                      ],[
 707 vorbis_dsp_state *v;
 708
 709 vorbis_synthesis_restart (v);
 710                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 711   if test "x$HAVE_VSR" = "xyes"; then
 712     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 713                        [defined if vorbis_synthesis_restart is present])
 714   fi
 715   CFLAGS="$ac_cflags_save"
 716 fi
 717
 718 else
 719
 720 dnl not building plugins with external dependencies,
 721 dnl but we still need to set the conditionals
 722 AM_CONDITIONAL(USE_ALSA, false)
 723 AM_CONDITIONAL(USE_CDPARANOIA, false)
 724 AM_CONDITIONAL(USE_GIO, false)
 725 AM_CONDITIONAL(USE_IVORBIS, false)
 726 AM_CONDITIONAL(USE_LIBVISUAL, false)
 727 AM_CONDITIONAL(USE_OGG, false)
 728 AM_CONDITIONAL(USE_PANGO, false)
 729 AM_CONDITIONAL(USE_THEORA, false)
 730 AM_CONDITIONAL(USE_VORBIS, false)
 731
 732 fi dnl of EXT plugins
 733
 734 dnl seeking needs freetype, so check for it here
 735 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 736   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 737 ])
 738 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 739 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 740 AC_SUBST(FT2_CFLAGS)
 741 AC_SUBST(FT2_LIBS)
 742
 743 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 744
 745 dnl Overview:
 746 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 747 dnl GST_*:              flags shared by built objects to link against GStreamer
 748 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 749 dnl                          (compare to other modules) or for i18n
 750 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 751 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 752 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 753 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 754
 755 dnl GST_OPTION_CFLAGS
 756 if test "x$USE_DEBUG" = xyes; then
 757    PROFILE_CFLAGS="-g"
 758 fi
 759 AC_SUBST(PROFILE_CFLAGS)
 760
 761 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 762   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 763   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 764 else
 765   DEPRECATED_CFLAGS=""
 766 fi
 767 AC_SUBST(DEPRECATED_CFLAGS)
 768
 769 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 770 dnl at make time with e.g. make ERROR_CFLAGS=""
 771 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 772 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 773 AC_SUBST(GST_OPTION_CFLAGS)
 774 AC_SUBST(GST_OPTION_CXXFLAGS)
 775
 776 dnl our libraries need to be versioned correctly
 777 AC_SUBST(GST_LT_LDFLAGS)
 778
 779 dnl GST_PLUGINS_BASE_CFLAGS
 780 dnl prefer internal headers to already installed ones
 781 dnl also add builddir include for enumtypes and marshal
 782 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 783 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 784
 785 dnl FIXME: do we want to rename to GST_ALL_* ?
 786 dnl add GST_OPTION_CFLAGS, but overridable
 787 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 788 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 789 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 790 AC_SUBST(GST_CFLAGS)
 791 AC_SUBST(GST_CXXFLAGS)
 792 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 793 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 794 AC_SUBST(GST_LIBS)
 795
 796 dnl LDFLAGS really should only contain flags, not libs - they get added before
 797 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 798 GST_ALL_LDFLAGS="-no-undefined"
 799 if test "x${enable_Bsymbolic}" = "xyes"; then
 800   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 801 fi
 802 AC_SUBST(GST_ALL_LDFLAGS)
 803
 804 dnl GST_LIB_LDFLAGS
 805 dnl linker flags shared by all libraries
 806 dnl LDFLAGS modifier defining exported symbols from built libraries
 807 dnl (export _gst_foo but not __gst_foo)
 808 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 809 AC_SUBST(GST_LIB_LDFLAGS)
 810
 811 dnl this really should only contain flags, not libs - they get added before
 812 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 813 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 814 AC_SUBST(GST_PLUGIN_LDFLAGS)
 815
 816 dnl *** output files ***
 817
 818 AC_CONFIG_FILES(
 819 Makefile
 820 gst-plugins-base.spec
 821 gst/Makefile
 822 gst/adder/Makefile
 823 gst/app/Makefile
 824 gst/audioconvert/Makefile
 825 gst/audiorate/Makefile
 826 gst/audiotestsrc/Makefile
 827 gst/encoding/Makefile
 828 gst/videoconvert/Makefile
 829 gst/gdp/Makefile
 830 gst/playback/Makefile
 831 gst/audioresample/Makefile
 832 gst/subparse/Makefile
 833 gst/tcp/Makefile
 834 gst/typefind/Makefile
 835 gst/videotestsrc/Makefile
 836 gst/videorate/Makefile
 837 gst/videoscale/Makefile
 838 gst/volume/Makefile
 839 sys/Makefile
 840 sys/ximage/Makefile
 841 sys/xvimage/Makefile
 842 ext/Makefile
 843 ext/alsa/Makefile
 844 ext/cdparanoia/Makefile
 845 ext/gio/Makefile
 846 ext/libvisual/Makefile
 847 ext/ogg/Makefile
 848 ext/pango/Makefile
 849 ext/theora/Makefile
 850 ext/vorbis/Makefile
 851 gst-libs/Makefile
 852 gst-libs/gst/Makefile
 853 gst-libs/gst/audio/Makefile
 854 gst-libs/gst/app/Makefile
 855 gst-libs/gst/fft/Makefile
 856 gst-libs/gst/interfaces/Makefile
 857 gst-libs/gst/riff/Makefile
 858 gst-libs/gst/rtp/Makefile
 859 gst-libs/gst/rtsp/Makefile
 860 gst-libs/gst/sdp/Makefile
 861 gst-libs/gst/tag/Makefile
 862 gst-libs/gst/pbutils/Makefile
 863 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 864 gst-libs/gst/video/Makefile
 865 tools/Makefile
 866 pkgconfig/Makefile
 867 pkgconfig/gstreamer-audio.pc
 868 pkgconfig/gstreamer-audio-uninstalled.pc
 869 pkgconfig/gstreamer-app.pc
 870 pkgconfig/gstreamer-app-uninstalled.pc
 871 pkgconfig/gstreamer-fft.pc
 872 pkgconfig/gstreamer-fft-uninstalled.pc
 873 pkgconfig/gstreamer-interfaces.pc
 874 pkgconfig/gstreamer-interfaces-uninstalled.pc
 875 pkgconfig/gstreamer-pbutils.pc
 876 pkgconfig/gstreamer-pbutils-uninstalled.pc
 877 pkgconfig/gstreamer-riff.pc
 878 pkgconfig/gstreamer-riff-uninstalled.pc
 879 pkgconfig/gstreamer-rtp.pc
 880 pkgconfig/gstreamer-rtp-uninstalled.pc
 881 pkgconfig/gstreamer-rtsp.pc
 882 pkgconfig/gstreamer-rtsp-uninstalled.pc
 883 pkgconfig/gstreamer-sdp.pc
 884 pkgconfig/gstreamer-sdp-uninstalled.pc
 885 pkgconfig/gstreamer-tag.pc
 886 pkgconfig/gstreamer-tag-uninstalled.pc
 887 pkgconfig/gstreamer-video.pc
 888 pkgconfig/gstreamer-video-uninstalled.pc
 889 pkgconfig/gstreamer-plugins-base.pc
 890 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 891 tests/Makefile
 892 tests/check/Makefile
 893 tests/examples/Makefile
 894 tests/examples/app/Makefile
 895 tests/examples/audio/Makefile
 896 tests/examples/dynamic/Makefile
 897 tests/examples/encoding/Makefile
 898 tests/examples/fft/Makefile
 899 tests/examples/gio/Makefile
 900 tests/examples/overlay/Makefile
 901 tests/examples/seek/Makefile
 902 tests/examples/snapshot/Makefile
 903 tests/examples/playrec/Makefile
 904 tests/files/Makefile
 905 tests/icles/Makefile
 906 tests/icles/playback/Makefile
 907 docs/Makefile
 908 docs/design/Makefile
 909 docs/libs/Makefile
 910 docs/plugins/Makefile
 911 docs/version.entities
 912 po/Makefile.in
 913 common/Makefile
 914 common/m4/Makefile
 915 m4/Makefile
 916 )
 917
 918 dnl Create the config.h file for Visual Studio builds
 919 dnl Beware of spaces and /'s in some of the shell variable contents.
 920 sed \
 921     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 922     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 923     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 924     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 925     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 926     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 927     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 928     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 929     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 930     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 931     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 932     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 933     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 934     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 935     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 936     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 937     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 938     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 939     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 940     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 941     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 942     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 943     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 944     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 945     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 946     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 947     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 948     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 949     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 950     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 951     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 952     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 953     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 954     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 955     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 956     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 957     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 958     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 959     config.h.in >win32/common/config.h-new
 960
 961
 962
 963 AC_OUTPUT
 964
 965 AG_GST_OUTPUT_PLUGINS
 966 ORC_OUTPUT
 967