configure.ac

   1 AC_INIT
   2 AC_CONFIG_SRCDIR([gst/gstobject.h])
   3
   4 AC_CANONICAL_TARGET([])
   5
   6 AM_CONFIG_HEADER(config.h)
   7
   8 GST_VERSION_MAJOR=0
   9 GST_VERSION_MINOR=2
  10 GST_VERSION_MICRO=0
  11 GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR.$GST_VERSION_MICRO
  12
  13 PACKAGE=gstreamer
  14 VERSION=$GST_VERSION
  15
  16 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  17 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20
  21 dnl libtool
  22 GST_CURRENT=0
  23 GST_REVISION=0
  24 GST_AGE=0
  25 GST_LIBVERSION=$GST_CURRENT:$GST_REVISION:$GST_AGE
  26
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28 dnl Add parameters for aclocal
  29 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  30 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  31
  32 AC_SUBST(GST_VERSION_MAJOR)
  33 AC_SUBST(GST_VERSION_MINOR)
  34 AC_SUBST(GST_VERSION_MICRO)
  35 AC_SUBST(GST_VERSION)
  36
  37 AC_SUBST(GST_CURRENT)
  38 AC_SUBST(GST_REVISION)
  39 AC_SUBST(GST_AGE)
  40 AC_SUBST(GST_LIBVERSION)
  41
  42
  43 AM_MAINTAINER_MODE
  44
  45 AC_PROG_CC
  46 AC_PROG_CXX
  47 AC_PROG_CXXCPP
  48 AC_ISC_POSIX
  49 AC_HEADER_STDC([])
  50 AC_ARG_PROGRAM
  51
  52 dnl We disable static building for development, for time savings
  53 dnl *NOTE*: dnl this line before release, so release does static too
  54 AM_DISABLE_STATIC
  55 AC_LIBTOOL_DLOPEN
  56 AM_PROG_LIBTOOL
  57
  58 CFLAGS=""
  59
  60 dnl This is used for the -config script...
  61 builddir=`pwd`
  62 AC_SUBST(builddir)
  63
  64 dnl ##############################
  65 dnl # Do automated configuration #
  66 dnl ##############################
  67
  68 dnl Check for tools:
  69 dnl ================
  70
  71 dnl Check for nasm
  72 AC_PATH_PROG(NASM_PATH, nasm, no)
  73 AC_SUBST(NASM_PATH)
  74 if test x$NASM_PATH = xno; then
  75   AC_MSG_WARN(Couldn't find nasm)
  76   HAVE_NASM="no"
  77 else
  78   AC_DEFINE(HAVE_NASM)
  79   HAVE_NASM="yes"
  80 fi
  81
  82 dnl check for gtkdoc
  83 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkdb, true, false)
  84 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-scanobj, :, false)
  85 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-scan, :, false)
  86 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mktmpl, :, false)
  87 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkdb, :, false)
  88 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkhtml, :, false)
  89 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-fixxref, :, false)
  90
  91 dnl check for docbook tools
  92 AC_CHECK_PROG(HAVE_DB2HTML, db2html, true, false)
  93 AC_CHECK_PROG(HAVE_DB2PS, db2ps, true, false)
  94 AC_CHECK_PROG(HAVE_PS2PDF, ps2pdf, true, false)
  95
  96 dnl check for image conversion tool
  97 AC_CHECK_PROG(HAVE_FIG2DEV, fig2dev, true, false)
  98
  99 dnl The following is a hack: if fig2dev doesn't display an error message
 100 dnl for the desired type, we assume it supports it.
 101 HAVE_FIG2DEV_PNG=false
 102 if test "x$HAVE_FIG2DEV" = "xtrue" ; then
 103   fig2dev_quiet=`fig2dev -L png </dev/null 2>&1 >/dev/null`
 104   if test "x$fig2dev_quiet" = "x" ; then
 105     HAVE_FIG2DEV_PNG=true
 106   fi
 107 fi
 108 HAVE_FIG2DEV_EPS=false
 109 if test "x$HAVE_FIG2DEV" = "xtrue" ; then
 110   fig2dev_quiet=`fig2dev -L eps </dev/null 2>&1 >/dev/null`
 111   if test "x$fig2dev_quiet" = "x" ; then
 112     HAVE_FIG2DEV_EPS=true
 113   fi
 114 fi
 115
 116
 117 dnl Set up conditionals for (target) architecture:
 118 dnl ==============================================
 119
 120 dnl Determine CPU
 121 case "x${target_cpu}" in
 122   xi?86 | k?) HAVE_CPU_I386=yes
 123               AC_DEFINE(HAVE_CPU_I386)
 124               dnl FIXME could use some better detection
 125               dnl       (ie CPUID)
 126               case "x${target_cpu}" in
 127                 xi386 | xi486) ;;
 128                 *)             AC_DEFINE(HAVE_RDTSC) ;;
 129               esac ;;
 130   xpowerpc)   HAVE_CPU_PPC=yes
 131               AC_DEFINE(HAVE_CPU_PPC) ;;
 132   xalpha)     HAVE_CPU_ALPHA=yes
 133               AC_DEFINE(HAVE_CPU_ALPHA) ;;
 134   xarm*)      HAVE_CPU_ARM=yes
 135               AC_DEFINE(HAVE_CPU_ARM) ;;
 136   xsparc*)    HAVE_CPU_SPARC=yes
 137               AC_DEFINE(HAVE_CPU_SPARC) ;;
 138 esac
 139
 140 dnl Determine endianness
 141 AC_C_BIGENDIAN
 142
 143 dnl Check for MMX-capable compiler
 144 AC_MSG_CHECKING(for MMX-capable compiler)
 145 AC_TRY_RUN([
 146 #include "include/mmx.h"
 147
 148 main()
 149 { movq_r2r(mm0, mm1); return 0; }
 150 ],
 151 [
 152 HAVE_LIBMMX="yes"
 153 AC_MSG_RESULT(yes)
 154 ],
 155 HAVE_LIBMMX="no"
 156 AC_MSG_RESULT(no)
 157 ,
 158 HAVE_LIBMMX="no"
 159 AC_MSG_RESULT(no)
 160 )
 161
 162
 163
 164 dnl Check for essential libraries first:
 165 dnl ====================================
 166
 167
 168 dnl Check for glib
 169 AM_PATH_GLIB(1.2.0,,
 170             AC_MSG_ERROR(Cannot find glib: Is glib-config in path?),
 171             glib gmodule gthread)
 172 dnl Put the glib flags into $LIBS and $CFLAGS since we always use them
 173 CORE_LIBS="$GLIB_LIBS"
 174 CORE_CFLAGS="$GLIB_CFLAGS"
 175
 176
 177 dnl Check for gtk
 178 AM_PATH_GTK(1.2.0,,
 179             AC_MSG_ERROR(Cannot find gtk: Is gtk-config in path?))
 180 dnl Put the gtk flags into $LIBS and $CFLAGS since we always use them
 181 CORE_LIBS="$CORE_LIBS $GTK_LIBS"
 182 CORE_CFLAGS="$CORE_CFLAGS $GTK_CFLAGS"
 183
 184
 185 dnl Check for libxml
 186 AC_PATH_PROG(XML_CONFIG, xml-config, no)
 187 if test x$XML_CONFIG = xno; then
 188   AC_MSG_ERROR(Couldn't find xml-config)
 189 fi
 190 XML_LIBS=`xml-config --libs`
 191 XML_CFLAGS=`xml-config --cflags`
 192 AC_CHECK_LIB(xml, xmlDocGetRootElement, ,
 193   [ AC_MSG_ERROR(Need version 1.8.1 or better of libxml) ],
 194   $XML_LIBS)
 195 AC_SUBST(XML_LIBS)
 196 AC_SUBST(XML_CFLAGS)
 197 CORE_LIBS="$CORE_LIBS $XML_LIBS"
 198 CORE_CFLAGS="$CORE_CFLAGS $XML_CFLAGS"
 199
 200
 201 dnl Next, check for the optional libraries:
 202 dnl =======================================
 203
 204
 205 dnl Check for libesd
 206 esd_save_LIBS=$LIBS
 207 esd_save_CFLAGS=$CFLAGS
 208 AM_PATH_ESD(0.2.12, HAVE_LIBESD=yes, HAVE_LIBESD=no)
 209 LIBS=$esd_save_LIBS
 210 CFLAGS=$esd_save_CFLAGS
 211 AC_ARG_ENABLE(esdsink,
 212 [  --enable-esdsink          enable the building of the esdsink],
 213 [case "${enableval}" in
 214         yes) : ;;
 215         no) HAVE_LIBESD=no ;;
 216         *) AC_MSG_ERROR(bad value ${enableval} for --enable-esdsink) ;;
 217         esac],
 218 [HAVE_LIBESD=$HAVE_LIBESD])
 219
 220 dnl Check for artsc
 221 AC_PATH_PROG(ARTSC_CONFIG, artsc-config, no)
 222 if test x$ARTSC_CONFIG = xno; then
 223   AC_MSG_WARN(Couldn't find artsc-config)
 224   ARTSC_LIBS=
 225   ARTSC_CFLAGS=
 226   HAVE_ARTSC=no
 227 else
 228   ARTSC_LIBS=`artsc-config --libs`
 229   ARTSC_CFLAGS=`artsc-config --cflags`
 230   dnl AC_CHECK_HEADER uses CPPFLAGS, but not CFLAGS.
 231   dnl Assume only suitable flags result from artsc-config --cflags
 232   artsc_save_CPPFLAGS=$CPPFLAGS
 233   CPPFLAGS="$CPPFLAGS $ARTSC_CFLAGS"
 234   AC_CHECK_HEADER(artsc.h,
 235                   HAVE_ARTSC=yes,
 236                   HAVE_ARTSC=no
 237   )
 238   CPPFLAGS=$artsc_save_CPPFLAGS
 239 fi
 240 AC_SUBST(ARTSC_LIBS)
 241 AC_SUBST(ARTSC_CFLAGS)
 242 AC_ARG_ENABLE(artsd,
 243 [  --enable-artsd            enable the building of artsd plugins],
 244 [case "${enableval}" in
 245         yes) : ;;
 246         no) HAVE_ARTSC=no ;;
 247         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsd) ;;
 248         esac],
 249 [:])
 250
 251 dnl AM_PATH_XMMS(0.1.0, HAVE_LIBXMMS=yes, HAVE_LIBXMMS=no)
 252
 253
 254 dnl Check for libasound
 255 alsa_save_LIBS=$LIBS
 256 alsa_save_CFLAGS=$CFLAGS
 257 AM_PATH_ALSA(0.5.0, HAVE_LIBASOUND=yes,
 258   HAVE_LIBASOUND=no
 259   AC_MSG_WARN(
 260 ***** NOTE: These plugins won't be built: gstalsa
 261 ))
 262 if test x$HAVE_LIBASOUND = xyes;then
 263   AC_MSG_CHECKING(alsa libs == 0.5.x, not 0.9.x)
 264   AC_TRY_COMPILE([
 265 #include <sys/asoundlib.h>
 266 ], [
 267 #if !defined(SND_LIB_MINOR) && defined(SOUNDLIB_VERSION_MINOR)
 268 #define SND_LIB_MINOR SOUNDLIB_VERSION_MINOR
 269 #endif
 270
 271 void main(void) {
 272   // succeed only if it's 0.5.x
 273 #if (SND_LIB_MINOR == 5)
 274   exit(0);
 275 #else
 276 #error not 0.5.x
 277 #endif
 278
 279   exit(1);
 280 }
 281 ],AC_MSG_RESULT(0.5.x),
 282   AC_MSG_RESULT(no)
 283   AC_MSG_WARN(
 284 ***** NOTE: These plugins won't be built: gstalsa
 285 )
 286   HAVE_LIBASOUND=no)
 287 fi
 288
 289 LIBS=$alsa_save_LIBS
 290 CFLAGS=$alsa_save_CFLAGS
 291 AC_ARG_ENABLE(alsasink,
 292 [  --enable-alsasink          enable the building of the alsasink],
 293 [case "${enableval}" in
 294         yes) HAVE_LIBASOUND=$HAVE_LIBASOUND ;;
 295         no) HAVE_LIBASOUND=no ;;
 296         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsasink) ;;
 297 esac],
 298 [HAVE_LIBASOUND=$HAVE_LIBASOUND])
 299
 300 dnl Check for libaudiofile
 301 AC_PATH_PROG(AUDIOFILE_CONFIG, audiofile-config, no)
 302 if test x$AUDIOFILE_CONFIG = xno; then
 303   AC_MSG_WARN(Couldn't find audiofile-config: can't build afsink)
 304   AUDIOFILE_LIBS=
 305   HAVE_LIBAUDIOFILE=no
 306 else
 307   AUDIOFILE_LIBS=`audiofile-config --libs`
 308   HAVE_LIBAUDIOFILE=yes
 309 fi
 310 AC_SUBST(AUDIOFILE_LIBS)
 311
 312
 313 dnl Check for libgdk-pixbuf
 314 AC_PATH_PROG(GDK_PIXBUF_CONFIG, gdk-pixbuf-config, no)
 315 if test x$GDK_PIXBUF_CONFIG = xno; then
 316   AC_MSG_WARN(Couldn't find gdk-pixbuf-config)
 317   GDK_PIXBUF_LIBS=
 318   GDK_PIXBUF_CFLAGS=
 319   HAVE_GDK_PIXBUF=no
 320 else
 321   GDK_PIXBUF_LIBS=`gdk-pixbuf-config --libs`
 322   GDK_PIXBUF_CFLAGS=`gdk-pixbuf-config --cflags`
 323   HAVE_GDK_PIXBUF=yes
 324 fi
 325 AC_SUBST(GDK_PIXBUF_LIBS)
 326 AC_SUBST(GDK_PIXBUF_CFLAGS)
 327
 328
 329 dnl Check for libgnome
 330 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 331 if test x$GNOME_CONFIG = xno; then
 332   AC_MSG_WARN(Couldn't find gnome-config: can't build editor or gstplay)
 333   GNOME_LIBS=
 334   GNOME_CFLAGS=
 335   HAVE_GNOME=no
 336 else
 337   GNOME_LIBS=`gnome-config --libs gnome gnomeui`
 338   GNOME_CFLAGS=`gnome-config --cflags gnome gnomeui`
 339   GHTTP_LIBS=`gnome-config --libs gnome gnomeui`
 340   GHTTP_CFLAGS=`gnome-config --cflags gnome gnomeui`
 341   HAVE_GNOME=yes
 342 fi
 343 AC_SUBST(GNOME_LIBS)
 344 AC_SUBST(GNOME_CFLAGS)
 345 AC_SUBST(GHTTP_LIBS)
 346
 347 dnl Check for libghttp
 348 dnl FIXME: need to check for header
 349 AC_CHECK_LIB(ghttp, ghttp_request_new,
 350   [GHTTP_LIBS="-lghttp"
 351    GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 352    HAVE_LIBGHTTP=yes
 353   ],
 354   [AC_MSG_WARN(Cannot find libghttp: can't build gsthttpsrc)
 355    GHTTP_LIBS=
 356    GST_HTTPSRC_GET_TYPE=
 357    HAVE_LIBGHTTP=no
 358   ],
 359   $LIBS)
 360 AC_SUBST(GST_HTTPSRC_GET_TYPE)
 361
 362 dnl Check for libglade
 363 HAVE_LIBGLADE_GNOME="no"
 364 AC_PATH_PROG(LIBGLADE_CONFIG_PATH, libglade-config, no)
 365 if test x$LIBGLADE_CONFIG_PATH = xno; then
 366   AC_MSG_WARN(Couldn't find libglade-config - Can't build gstplay)
 367   LIBGLADE_GNOME_LIBS=
 368   LIBGLADE_GNOME_CFLAGS=
 369 else
 370   LIBGLADE_GNOME_LIBS=`libglade-config --libs gnome`
 371   LIBGLADE_GNOME_CFLAGS=`libglade-config --cflags gnome`
 372   libglade_save_CFLAGS="$CFLAGS"
 373   libglade_save_LIBS="$LIBS"
 374   CFLAGS="$CFLAGS $LIBGLADE_GNOME_CFLAGS $GTK_CFLAGS"
 375   LIBS="$LIBS $LIBGLADE_GNOME_LIBS $GTK_LIBS"
 376   AC_TRY_LINK([#include <glade/glade.h>],[glade_gnome_init();],
 377               HAVE_LIBGLADE_GNOME="yes",
 378               AC_MSG_WARN(
 379       [Couldn't find gnome libraries for libglade - Can't build gstmediaplay and gsteditor])
 380              )
 381   CFLAGS="$libglade_save_CFLAGS"
 382   LIBS="$libglade_save_LIBS"
 383 fi
 384 AC_SUBST(LIBGLADE_GNOME_LIBS)
 385 AC_SUBST(LIBGLADE_GNOME_CFLAGS)
 386
 387 dnl Check for Gnome VFS
 388 HAVE_GNOME_VFS="no"
 389 AC_MSG_CHECKING(for Gnome VFS)
 390 if gnome-config --libs vfs > /dev/null 2>&1; then
 391         HAVE_GNOME_VFS="yes"
 392         AC_MSG_RESULT(found)
 393 else
 394         AC_MSG_WARN(Did not find Gnome-VFS installed)
 395 fi
 396
 397 VFS_LIBS="`gnome-config --libs vfs`"
 398 VFS_CFLAGS="`gnome-config --cflags vfs`"
 399
 400 AC_SUBST(VFS_LIBS)
 401 AC_SUBST(VFS_CFLAGS)
 402
 403 dnl Check for atomic.h
 404 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 405 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 406 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 407 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 408 if test x$HAVE_ATOMIC_H = xyes; then
 409   AC_TRY_RUN([
 410 #include "asm/atomic.h"
 411 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 412   ],, [
 413     # Not successful
 414     if test x$HAVE_ATOMIC_H = xyes; then
 415       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 416     fi
 417     HAVE_ATOMIC_H=no
 418   ], [
 419     # Cross compiling
 420     AC_MSG_RESULT(yes)
 421     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 422   ])
 423 fi
 424
 425
 426 dnl Check for X11 extensions
 427 AC_PATH_XTRA
 428 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
 429   AC_MSG_ERROR(can not find X11)
 430 fi
 431 AC_SUBST(X_CFLAGS)
 432 AC_SUBST(X_PRE_LIBS)
 433 AC_SUBST(X_EXTRA_LIBS)
 434 AC_SUBST(X_LIBS)
 435
 436
 437 dnl Check for the Xv library
 438 xvsave_LIBS=${LIBS}
 439 AC_CHECK_LIB(Xv, XvQueryExtension, HAVE_LIBXV=yes, HAVE_LIBXV=no, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 440 LIBS=${xvsave_LIBS}
 441 AC_CHECK_HEADER(X11/extensions/Xv.h, :, HAVE_LIBXV=no)
 442 AC_CHECK_HEADER(X11/extensions/Xvlib.h, :, HAVE_LIBXV=no)
 443
 444 dnl Check for OSS audio
 445 AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS=yes, HAVE_OSS=no)
 446
 447 dnl Check for xaudio
 448 AC_CHECK_HEADER(xaudio/decoder.h,
 449   AC_DEFINE(HAVE_XAUDIO)
 450   HAVE_XAUDIO="yes",
 451   AC_MSG_WARN(
 452 ***** NOTE: These plugins won't be built: gstxa
 453 )
 454   HAVE_XAUDIO="no",
 455 )
 456
 457 dnl Check for libmad
 458 AC_MSG_CHECKING(MAD library)
 459 AC_CHECK_LIB(mad, mad_decoder_finish,
 460   HAVE_LIBMAD=yes
 461   AC_DEFINE(HAVE_LIBMAD),
 462   AC_MSG_WARN(
 463 ***** NOTE: These plugins won't be built: mad
 464 )
 465   HAVE_LIBMAD=no,
 466 )
 467
 468 dnl Check for libvorbis
 469 AC_MSG_CHECKING(Vorbis library)
 470 AC_CHECK_LIB(vorbis, ogg_sync_init,
 471   HAVE_VORBIS=yes
 472   AC_DEFINE(HAVE_VORBIS),
 473   AC_MSG_WARN(
 474 ***** NOTE: These plugins won't be built: vorbisdec vorbisenc
 475 )
 476   HAVE_VORBIS=no,
 477 )
 478
 479 dnl Check for libjpeg
 480 AC_MSG_CHECKING(libjpeg library)
 481 AC_CHECK_LIB(jpeg, jpeg_set_defaults,
 482   HAVE_LIBJPEG=yes
 483   AC_DEFINE(HAVE_LIBJPEG),
 484   AC_MSG_WARN(
 485 ***** NOTE: These plugins won't be built: jpegdec jpegenc
 486 )
 487   HAVE_LIBJPEG=no,
 488 )
 489
 490 dnl Check for libHermes
 491 AC_MSG_CHECKING(Hermes library)
 492 AC_CHECK_LIB(Hermes, Hermes_ConverterInstance,
 493   HAVE_LIBHERMES=yes
 494   AC_DEFINE(HAVE_LIBHERMES),
 495   AC_MSG_WARN(
 496 ***** NOTE: These plugins won't be built: colorspace
 497 )
 498   HAVE_LIBHERMES=no,
 499 )
 500 AC_CHECK_HEADER(Hermes/Hermes.h, :, HAVE_LIBHERMES=no)
 501
 502 dnl Check for libgsm
 503 AC_MSG_CHECKING(GSM library)
 504 AC_CHECK_LIB(gsm, gsm_create,
 505   HAVE_LIBGSM=yes
 506   AC_DEFINE(HAVE_LIBGSM),
 507   AC_MSG_WARN(
 508 ***** NOTE: These plugins won't be built: gsmdec, gsmenc
 509 )
 510   HAVE_LIBGSM=no,
 511 )
 512
 513 dnl Check for cdparanoia
 514 AC_MSG_CHECKING(CDparanoia library)
 515 HAVE_CDPARANOIA=yes
 516 AC_CHECK_LIB(cdda_interface, cdda_open, : , HAVE_CDPARANOIA=no, )
 517 AC_CHECK_HEADER(cdda_interface.h, :, HAVE_CDPARANOIA=no)
 518 AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 519 AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 520
 521 dnl Check for liblame
 522 AC_MSG_CHECKING(LAME library)
 523 AC_CHECK_LIB(mp3lame, lame_init, HAVE_LIBLAME=yes, HAVE_LIBLAME=no, )
 524 AC_CHECK_HEADER(lame/lame.h, :, HAVE_LIBLAME=no)
 525
 526 dnl Check for libshout
 527 AC_MSG_CHECKING(Shout library)
 528 AC_CHECK_LIB(shout, shout_init_connection, HAVE_LIBSHOUT=yes, HAVE_LIBSHOUT=no, )
 529 AC_CHECK_HEADER(shout/shout.h, :, HAVE_LIBSHOUT=no)
 530
 531 dnl Check for mpeg2dec
 532 AC_MSG_CHECKING(mpeg2dec library)
 533 AC_CHECK_LIB(mpeg2, mpeg2_init, HAVE_MPEG2DEC=yes, HAVE_MPEG2DEC=no, )
 534 AC_CHECK_HEADER(mpeg2dec/mpeg2.h, :, HAVE_MPEG2DEC=no)
 535
 536 dnl Check for librtp
 537 AC_MSG_CHECKING(rtp library)
 538 AC_CHECK_LIB(rtp, rtp_packet_new_take_data, HAVE_LIBRTP=yes, HAVE_LIBRTP=no, $GLIB_LIBS $GLIB_CFLAGS)
 539 AC_CHECK_HEADER(rtp/rtp-packet.h, :, HAVE_LIBRTP=no)
 540 AC_CHECK_HEADER(rtp/rtcp-packet.h, :, HAVE_LIBRTP=no)
 541 AC_CHECK_HEADER(rtp/rtp-audio.h, :, HAVE_LIBRTP=no)
 542
 543 dnl Check for arts
 544 AC_DIAGNOSE([obsolete],[instead of using `AC_LANG', `AC_DIAGNOSE([obsolete],[instead of using `AC_LANG', `AC_LANG_SAVE',
 545 and `AC_LANG_RESTORE', you should use `AC_LANG_PUSH' and `AC_LANG_POP'.])
 546 ',
 547 and `AC_LANG_POP([])', you should use `AC_LANG_PUSH' and `AC_LANG_POP'.])
 548
 549 AC_LANG_PUSH(C++)
 550 AC_MSG_CHECKING(arts library)
 551 dnl AC_CHECK_LIB(artsflow, convert_stereo_ifloat_2float, HAVE_ARTS=yes, HAVE_ARTS=no, -lmcop -lartsflow_idl)
 552 AC_CHECK_HEADER(arts/artsflow.h, HAVE_ARTS=yes, HAVE_ARTS=no)
 553 AC_LANG_POP(C++)
 554
 555 dnl Check for libraw1394
 556 AC_MSG_CHECKING(raw1394 library)
 557 AC_CHECK_LIB(raw1394, raw1394_get_handle, HAVE_RAW1394=yes, HAVE_RAW1394=no, )
 558 AC_CHECK_HEADER(libraw1394/raw1394.h, :, HAVE_RAW1394=no)
 559
 560 dnl Check for libdv
 561 AC_MSG_CHECKING(libdv)
 562 AC_CHECK_LIB(dv, dv_init, HAVE_LIBDV=yes, HAVE_LIBDV=no, -lm $GLIB_LIBS $GLIB_CFLAGS)
 563 AC_CHECK_HEADER(libdv/dv.h, :, HAVE_LIBDV=no)
 564
 565 dnl Check for aalib
 566 AC_MSG_CHECKING(aalib)
 567 AC_CHECK_LIB(aa, aa_init, HAVE_LIBAA=yes, HAVE_LIBAA=no, )
 568 AC_CHECK_HEADER(aalib.h, :, HAVE_LIBAA=no)
 569
 570 dnl Check for quicktime
 571 AC_MSG_CHECKING(openquicktime)
 572 AC_CHECK_LIB(openquicktime, quicktime_init, HAVE_LIBOPENQUICKTIME=yes, HAVE_LIBOPENQUICKTIME=no, )
 573 AC_CHECK_HEADER(openquicktime/openquicktime.h, :, HAVE_LIBOPENQUICKTIME=no)
 574
 575
 576 dnl check if css-auth.c exists (FIXME)
 577 AC_MSG_CHECKING(DVD CSS code)
 578 if test -f plugins/dvdsrc/css-auth.c
 579 then
 580   AC_MSG_RESULT(yes)
 581   HAVE_CSSAUTH="yes"
 582 else
 583   AC_MSG_RESULT(no)
 584   HAVE_CSSAUTH="no"
 585 fi
 586
 587 dnl Check for SDLlib
 588 AC_MSG_CHECKING(SDLlib)
 589 AC_CHECK_LIB(SDL, SDL_Init, HAVE_LIBSDL=yes, HAVE_LIBSDL=no, -L/usr/lib -L/usr/local/lib -lpthread)
 590 AC_CHECK_HEADER(SDL/SDL.h, :, HAVE_LIBSDL=no)
 591
 592 dnl Check for SDL
 593 HAVE_LIBSDL="no"
 594 AC_MSG_CHECKING(for SDL)
 595 if sdl-config --libs > /dev/null 2>&1; then
 596   HAVE_LIBSDL="yes"
 597   AC_MSG_RESULT(found)
 598 else
 599   AC_MSG_RESULT(not found)
 600 fi
 601
 602 SDL_LIBS="`sdl-config --libs`"
 603 SDL_CFLAGS="`sdl-config --cflags`"
 604
 605 AC_SUBST(SDL_LIBS)
 606 AC_SUBST(SDL_CFLAGS)
 607
 608 dnl Check for linux/cdrom.h
 609 AC_CHECK_HEADER(linux/cdrom.h,
 610   HAVE_LINUX_CDROM=yes, HAVE_LINUX_CDROM=no
 611 )
 612
 613 dnl Check for linux/videodev.h
 614 AC_CHECK_HEADER(linux/videodev.h,
 615   HAVE_LINUX_VIDEODEV=yes, HAVE_LINUX_VIDEODEV=no
 616 )
 617
 618
 619 dnl ######################################################################
 620 dnl # Check command line parameters, and set shell variables accordingly #
 621 dnl ######################################################################
 622
 623 AC_ARG_ENABLE(gdk-pixbuf,
 624 [  --enable-gdk-pixbuf          use gdk pixbuf, if available],
 625 [case "${enableval}" in
 626   yes) USE_GDK_PIXBUF=$HAVE_GDK_PIXBUF ;;
 627   no)  USE_GDK_PIXBUF=no ;;
 628   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdk-pixbuf) ;;
 629 esac],
 630 [USE_GDK_PIXBUF=$HAVE_GDK_PIXBUF]) dnl Default value
 631
 632 AC_ARG_ENABLE(libghttp,
 633 [  --enable-libghttp            use the ghttp library, if available],
 634 [case "${enableval}" in
 635   yes) USE_LIBGHTTP=$HAVE_LIBGHTTP ;;
 636   no)  USE_LIBGHTTP=no ;;
 637   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libghttp) ;;
 638 esac],
 639 [USE_LIBGHTTP=$HAVE_LIBGHTTP]) dnl Default value
 640
 641 AC_ARG_ENABLE(libmmx,
 642 [  --enable-libmmx              use libmmx, if available],
 643 [case "${enableval}" in
 644   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 645   no)  USE_LIBMMX=no ;;
 646   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 647 esac],
 648 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 649
 650 AC_ARG_ENABLE(atomic,
 651 [  --enable-atomic              use atomic reference counting header],
 652 [case "${enableval}" in
 653   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 654   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 655   no)  USE_ATOMIC_H=no;;
 656   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 657 esac],
 658 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 659
 660 AC_ARG_ENABLE(plugin-srcdir,
 661 [  --enable-plugin-srcdir       allow tests/demos to use non-installed plugins ],
 662 [case "${enableval}" in
 663   yes) PLUGINS_USE_SRCDIR=yes ;;
 664   no)  PLUGINS_USE_SRCDIR=no ;;
 665   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-srcdir) ;;
 666 esac],
 667 [PLUGINS_USE_SRCDIR=no]) dnl Default value
 668
 669 AC_ARG_ENABLE(debug,
 670 [  --enable-debug               compile with -g debugging info],
 671 [case "${enableval}" in
 672   yes) USE_DEBUG=yes ;;
 673   no)  USE_DEBUG=no ;;
 674   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 675 esac],
 676 [USE_DEBUG=no]) dnl Default value
 677
 678 AC_ARG_ENABLE(debug-verbose,
 679 [  --enable-debug-verbose       spews lots of useless debugging info at runtime],
 680 [case "${enableval}" in
 681   yes) USE_DEBUG_VERBOSE=yes ;;
 682   no)  USE_DEBUG_VERBOSE=no ;;
 683   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug-verbose) ;;
 684 esac],
 685 [USE_DEBUG_VERBOSE=no]) dnl Default value
 686
 687 AC_ARG_ENABLE(info,
 688 [  --enable-info                spews lots of info at runtime for plugin writers],
 689 [case "${enableval}" in
 690   yes) USE_DEBUG_INFO_VERBOSE=yes ;;
 691   no)  USE_DEBUG_INFO_VERBOSE=no ;;
 692   *) AC_MSG_ERROR(bad value ${enableval} for --enable-info) ;;
 693 esac],
 694 [USE_DEBUG_INFO_VERBOSE=no]) dnl Default value
 695
 696 AC_ARG_ENABLE(info-system,
 697 [  --disable-info-system        disables the info debugging system],
 698 [case "${enableval}" in
 699   yes) DISABLE_DEBUG_INFO=no ;;
 700   no)  DISABLE_DEBUG_INFO=yes ;;
 701   *) AC_MSG_ERROR(bad value ${enableval} for --disable-info) ;;
 702 esac],
 703 [DISABLE_DEBUG_INFO=no]) dnl Default value
 704
 705 AC_ARG_ENABLE(debug-color,
 706 [  --disable-debug-color        disables color output of DEBUG and INFO output],
 707 [case "${enableval}" in
 708   yes) DISABLE_DEBUG_COLOR=no ;;
 709   no)  DISABLE_DEBUG_COLOR=yes ;;
 710   *) AC_MSG_ERROR(bad value ${enableval} for --disable-info) ;;
 711 esac],
 712 [DISABLE_DEBUG_COLOR=no]) dnl Default value
 713
 714 AC_ARG_ENABLE(profiling,
 715 [  --enable-profiling           adds -pg to compiler commandline, for profiling],
 716 [case "${enableval}" in
 717   yes) USE_PROFILING=yes ;;
 718   no)  UES_PROFILING=no ;;
 719   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 720 esac],
 721 [USE_PROFILING=no]) dnl Default value
 722
 723 dnl Default value
 724 GST_CONFIG_DIR="/etc/gstreamer"
 725 AC_ARG_WITH(configdir,
 726 [  --with-configdir             specify path to use for configdir],
 727 [case "${withval}" in
 728   yes) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 729   no) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 730   *) GST_CONFIG_DIR="${withval}" ;;
 731 esac],
 732 [:]) dnl Default value
 733
 734 dnl Default value
 735 GST_WIN32_LIBDIR="/usr/lib/win32"
 736 AC_ARG_WITH(win32_libdir,
 737 [  --with-win32-libdir          specify location for win32 DLLs],
 738 [case "${withval}" in
 739   yes) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 740   no) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 741   *) GST_WIN32_LIBDIR="${withval}" ;;
 742 esac],
 743 [:]) dnl Default value
 744
 745 AC_ARG_ENABLE(docs-build,
 746 [  --disable-docs-build         disable all building of documentation],
 747 [case "${enableval}" in
 748   yes) BUILD_DOCS=yes ;;
 749   no)  BUILD_DOCS=no ;;
 750   *) AC_MSG_ERROR(bad value ${enableval} for --enable-docs-build) ;;
 751 esac],
 752 [BUILD_DOCS=yes]) dnl Default value
 753
 754 AC_ARG_ENABLE(plugin-docs,
 755 [  --enable-plugin-docs         enable the building of plugin documentation
 756                                (this is currently broken, so off by default)],
 757 [case "${enableval}" in
 758   yes) BUILD_PLUGIN_DOCS=yes ;;
 759   no)  BUILD_PLUGIN_DOCS=no ;;
 760   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-docs) ;;
 761 esac],
 762 [BUILD_PLUGIN_DOCS=no]) dnl Default value
 763
 764
 765
 766
 767 dnl ################################################
 768 dnl # Set defines according to variables set above #
 769 dnl ################################################
 770
 771
 772 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 773 dnl HAVE_ and it is likely to be easier to stick with the old name
 774 if test "x$USE_GDK_PIXBUF" = xyes; then
 775   AC_DEFINE(HAVE_GDK_PIXBUF)
 776 fi
 777
 778 if test "x$USE_LIBGHTTP" = xyes; then
 779   AC_DEFINE(HAVE_LIBGHTTP)
 780 fi
 781
 782 if test "x$USE_LIBMMX" = xyes; then
 783   AC_DEFINE(HAVE_LIBMMX)
 784 fi
 785
 786 if test "x$USE_ATOMIC_H" = xyes; then
 787   AC_DEFINE(HAVE_ATOMIC_H)
 788 fi
 789
 790 if test "x$PLUGINS_USE_SRCDIR" = xyes; then
 791   AC_DEFINE(PLUGINS_USE_SRCDIR)
 792 fi
 793
 794 if test "x$USE_DEBUG" = xyes; then
 795   CFLAGS="$CFLAGS -g"
 796 fi
 797
 798 if test "x$USE_DEBUG_VERBOSE" = xyes; then
 799   AC_DEFINE(GST_DEBUG_ENABLED)
 800 fi
 801
 802 if test "x$USE_DEBUG_INFO_VERBOSE" = xyes; then
 803   AC_DEFINE(GST_INFO_ENABLED_VERBOSE)
 804   AC_DEFINE(GST_INFO_ENABLED)
 805 else
 806   AC_DEFINE(GST_INFO_ENABLED)
 807 fi
 808
 809 if test "x$DISABLE_DEBUG_INFO" = xyes; then
 810   AC_DEFINE(GST_INFO_FORCE_DISABLE)
 811 fi
 812
 813 if test "x$DISABLE_DEBUG_COLOR" = xno; then
 814   AC_DEFINE(GST_DEBUG_COLOR)
 815 fi
 816
 817 if test "x$USE_PROFILING" = xyes; then
 818   CFLAGS="$CFLAGS -pg"
 819   FOMIT_FRAME_POINTER=""
 820 else
 821   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 822 fi
 823
 824 if test "x$HAVE_LIBXV" = xyes; then
 825   AC_DEFINE(HAVE_LIBXV)
 826 fi
 827
 828 if test "x$HAVE_OSS" = xyes; then
 829   AC_DEFINE(HAVE_OSS)
 830 fi
 831
 832 if test "x$HAVE_XAUDIO" = xyes; then
 833   AC_DEFINE(HAVE_XAUDIO)
 834 fi
 835
 836 if test "x$HAVE_LIBMAD" = xyes; then
 837   AC_DEFINE(HAVE_LIBMAD)
 838 fi
 839
 840 if test "x$HAVE_VORBIS" = xyes; then
 841   AC_DEFINE(HAVE_VORBIS)
 842 fi
 843
 844 if test "x$HAVE_LIBJPEG" = xyes; then
 845   AC_DEFINE(HAVE_LIBJPEG)
 846 fi
 847
 848 if test "x$HAVE_LIBSDL" = xyes; then
 849   AC_DEFINE(HAVE_LIBSDL)
 850 fi
 851
 852 if test "x$HAVE_LIBHERMES" = "xyes"; then
 853   AC_DEFINE(HAVE_LIBHERMES)
 854 fi
 855
 856 if test "x$HAVE_CSSAUTH" = xyes; then
 857   AC_DEFINE(HAVE_CSSAUTH)
 858 fi
 859
 860 if test "x$HAVE_LINUX_CDROM" = xyes; then
 861   AC_DEFINE(HAVE_LINUX_CDROM)
 862 fi
 863
 864 if test "x$HAVE_LINUX_VIDEODEV" = xyes; then
 865   AC_DEFINE(HAVE_LINUX_VIDEODEV)
 866 fi
 867
 868 if test "x$HAVE_MPEG2DEC" = xyes; then
 869   AC_DEFINE(HAVE_MPEG2DEC)
 870 fi
 871
 872 if test "x$HAVE_LIBAUDIOFILE" = xyes; then
 873   AC_DEFINE(HAVE_LIBAUDIOFILE)
 874 fi
 875
 876 if test "x$HAVE_LIBGSM" = xyes; then
 877   AC_DEFINE(HAVE_LIBGSM)
 878 fi
 879
 880 dnl #############################
 881 dnl # Set automake conditionals #
 882 dnl #############################
 883
 884 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 885 dnl HAVE_ and it is likely to be easier to stick with the old name
 886 AM_CONDITIONAL(HAVE_CPU_I386,       test "x$HAVE_CPU_I386" = "xyes")
 887 AM_CONDITIONAL(HAVE_CPU_PPC,        test "x$HAVE_CPU_PPC" = "xyes")
 888 AM_CONDITIONAL(HAVE_CPU_ALPHA,      test "x$HAVE_CPU_ALPHA" = "xyes")
 889 AM_CONDITIONAL(HAVE_CPU_ARM,        test "x$HAVE_CPU_ARM" = "xyes")
 890 AM_CONDITIONAL(HAVE_CPU_SPARC,      test "x$HAVE_CPU_SPARC" = "xyes")
 891 AM_CONDITIONAL(HAVE_GDK_PIXBUF,     test "x$USE_GDK_PIXBUF" = "xyes")
 892 AM_CONDITIONAL(HAVE_LIBGHTTP,       test "x$USE_LIBGHTTP" = "xyes")
 893 AM_CONDITIONAL(HAVE_LIBAUDIOFILE,   test "x$HAVE_LIBAUDIOFILE" = "xyes")
 894 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
 895 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 896 AM_CONDITIONAL(HAVE_OSS,            test "x$HAVE_OSS" = "xyes")
 897 AM_CONDITIONAL(HAVE_XAUDIO,         test "x$HAVE_XAUDIO" = "xyes")
 898 AM_CONDITIONAL(HAVE_LIBMAD,         test "x$HAVE_LIBMAD" = "xyes")
 899 AM_CONDITIONAL(HAVE_LINUX_CDROM,    test "x$HAVE_LINUX_CDROM" = "xyes")
 900 AM_CONDITIONAL(HAVE_LINUX_VIDEODEV, test "x$HAVE_LINUX_VIDEODEV" = "xyes")
 901 AM_CONDITIONAL(HAVE_CSSAUTH,        test "x$HAVE_CSSAUTH" = "xyes")
 902 AM_CONDITIONAL(HAVE_VORBIS,         test "x$HAVE_VORBIS" = "xyes")
 903 AM_CONDITIONAL(HAVE_LIBJPEG,        test "x$HAVE_LIBJPEG" = "xyes")
 904 AM_CONDITIONAL(HAVE_LIBSDL,         test "x$HAVE_LIBSDL" = "xyes")
 905 AM_CONDITIONAL(HAVE_LIBHERMES,      test "x$HAVE_LIBHERMES" = "xyes")
 906 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 907 AM_CONDITIONAL(HAVE_LIBGLADE_GNOME, test "x$HAVE_LIBGLADE_GNOME" = "xyes")
 908 AM_CONDITIONAL(HAVE_GNOME,          test "x$HAVE_GNOME" = "xyes")
 909 AM_CONDITIONAL(HAVE_LIBXV,          test "x$HAVE_LIBXV" = "xyes")
 910 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
 911 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
 912 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
 913 AM_CONDITIONAL(HAVE_DB2HTML,        $HAVE_DB2HTML)
 914 AM_CONDITIONAL(HAVE_DB2PS,          $HAVE_DB2PS)
 915 AM_CONDITIONAL(HAVE_PS2PDF,         $HAVE_PS2PDF)
 916 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 917 AM_CONDITIONAL(HAVE_FIG2DEV_EPS,    $HAVE_FIG2DEV_EPS)
 918 AM_CONDITIONAL(HAVE_CDPARANOIA,     test "x$HAVE_CDPARANOIA" = "xyes")
 919 AM_CONDITIONAL(HAVE_LIBLAME,        test "x$HAVE_LIBLAME" = "xyes")
 920 AM_CONDITIONAL(HAVE_LIBSHOUT,       test "x$HAVE_LIBSHOUT" = "xyes")
 921 AM_CONDITIONAL(HAVE_LIBESD,         test "x$HAVE_LIBESD" = "xyes")
 922 AM_CONDITIONAL(HAVE_ARTSC,          test "x$HAVE_ARTSC" = "xyes")
 923 AM_CONDITIONAL(HAVE_LIBASOUND,      test "x$HAVE_LIBASOUND" = "xyes")
 924 AM_CONDITIONAL(HAVE_MPEG2DEC,       test "x$HAVE_MPEG2DEC" = "xyes")
 925 AM_CONDITIONAL(HAVE_LIBXMMS,        test "x$HAVE_LIBXMMS" = "xyes")
 926 AM_CONDITIONAL(HAVE_LIBRTP,         test "x$HAVE_LIBRTP" = "xyes")
 927 AM_CONDITIONAL(HAVE_ARTS,           test "x$HAVE_ARTS" = "xyes")
 928 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 929 AM_CONDITIONAL(HAVE_LIBDV,          test "x$HAVE_LIBDV" = "xyes")
 930 AM_CONDITIONAL(HAVE_LIBAA,          test "x$HAVE_LIBAA" = "xyes")
 931 AM_CONDITIONAL(HAVE_GNOME_VFS,      test "x$HAVE_GNOME_VFS" = "xyes")
 932 AM_CONDITIONAL(HAVE_LIBOPENQUICKTIME, test "x$HAVE_LIBOPENQUICKTIME" = "xyes")
 933 AM_CONDITIONAL(HAVE_LIBGSM,         test "x$HAVE_LIBGSM" = "xyes")
 934
 935
 936 dnl ############################
 937 dnl # Set up some more defines #
 938 dnl ############################
 939
 940 dnl Set location of configuration dir.
 941 AC_DEFINE_UNQUOTED(GST_CONFIG_DIR,"$GST_CONFIG_DIR")
 942 AC_SUBST(GST_CONFIG_DIR)
 943
 944 dnl Set location of windows dll dir.
 945 AC_DEFINE_UNQUOTED(GST_WIN32_LIBDIR,"$GST_WIN32_LIBDIR")
 946 AC_SUBST(GST_WIN32_LIBDIR)
 947
 948 dnl Set location of plugin directory
 949 if test "x${prefix}" = "xNONE"; then
 950   PLUGINS_DIR=${ac_default_prefix}/lib/gst
 951 else
 952   PLUGINS_DIR=${prefix}/lib/gst
 953 fi
 954 AC_DEFINE_UNQUOTED(PLUGINS_DIR,"$PLUGINS_DIR")
 955 AC_SUBST(PLUGINS_DIR)
 956
 957 dnl Set location of uninstalled plugin directory
 958 PLUGINS_SRCDIR=`pwd`/$srcdir
 959 AC_DEFINE_UNQUOTED(PLUGINS_SRCDIR,"$PLUGINS_SRCDIR")
 960 AC_SUBST(PLUGINS_SRCDIR)
 961
 962
 963
 964 dnl ##############################
 965 dnl # Set up the defaults cflags #
 966 dnl ##############################
 967 dnl CC="kgcc"
 968 CFLAGS="$CORE_CFLAGS $CFLAGS -O6 -Wall"
 969 LIBS="$CORE_LIBS $LIBS"
 970 AC_SUBST(CORE_LIBS)
 971 AC_SUBST(CORE_CFLAGS)
 972
 973 dnl FIXME: having to AC_SUBST these is messy.  Not sure if CPPFLAGS and LDFLAGS
 974 dnl need it, either.
 975
 976 dnl Private vars for libgst only
 977 LIBGST_LIBS="$LIBS"
 978 LIBGST_CFLAGS="$CFLAGS"
 979 AC_SUBST(LIBGST_LIBS)
 980 AC_SUBST(LIBGST_CFLAGS)
 981
 982 dnl Vars for everyone else
 983 GST_LIBS="\$(top_builddir)/gst/libgst.la"
 984 GST_CFLAGS="-I\$(top_srcdir) -I\$(top_srcdir)/include"
 985 AC_SUBST(GST_LIBS)
 986 AC_SUBST(GST_CFLAGS)
 987
 988 dnl CFLAGS for everyone else
 989 CFLAGS="$CFLAGS $GST_CFLAGS"
 990 AC_SUBST(LIBS)
 991 AC_SUBST(CFLAGS)
 992
 993 dnl AC_SUBST(CPPFLAGS)
 994 dnl AC_SUBST(LDFLAGS)
 995
 996
 997 dnl #############################
 998 dnl # Configure the subpackages #
 999 dnl #############################
1000
1001 dnl AC_CONFIG_SUBDIRS(gist)
1002 dnl AC_CONFIG_SUBDIRS(plugins/mp3decode/xing/libxing)
1003
1004
1005 dnl #########################
1006 dnl # Make the output files #
1007 dnl #########################
1008
1009 AC_OUTPUT(
1010 Makefile
1011 include/Makefile
1012 include/wine/Makefile
1013 gst/Makefile
1014 gst/gstversion.h
1015 gst/types/Makefile
1016 gst/elements/Makefile
1017 gst/autoplug/Makefile
1018 libs/Makefile
1019 libs/riff/Makefile
1020 libs/colorspace/Makefile
1021 libs/videoscale/Makefile
1022 libs/getbits/Makefile
1023 libs/putbits/Makefile
1024 libs/winloader/Makefile
1025 libs/idct/Makefile
1026 plugins/Makefile
1027 plugins/aasink/Makefile
1028 plugins/alsa/Makefile
1029 plugins/au/Makefile
1030 plugins/audiofile/Makefile
1031 plugins/audioscale/Makefile
1032 plugins/avi/Makefile
1033 plugins/avi/wincodec/Makefile
1034 plugins/flx/Makefile
1035 plugins/jpeg/Makefile
1036 plugins/mp3decode/Makefile
1037 plugins/mp3decode/types/Makefile
1038 plugins/mp3decode/xa/Makefile
1039 plugins/mp3decode/mpg123/Makefile
1040 plugins/mp3decode/mad/Makefile
1041 plugins/mp3decode/parse/Makefile
1042 plugins/mp3encode/Makefile
1043 plugins/mp3encode/lame/Makefile
1044 plugins/mpeg2/Makefile
1045 plugins/mpeg2/parse/Makefile
1046 plugins/mpeg2/ac3parse/Makefile
1047 plugins/mpeg2/ac3dec/Makefile
1048 plugins/mpeg2/video/Makefile
1049 plugins/mpeg2/mpeg2enc/Makefile
1050 plugins/mpeg2/mpeg2dec/Makefile
1051 plugins/mpeg2/subtitles/Makefile
1052 plugins/mpeg2/videoparse/Makefile
1053 plugins/mpeg2/mpegtypes/Makefile
1054 plugins/mpeg1/Makefile
1055 plugins/mpeg1/mpegtypes/Makefile
1056 plugins/mpeg1/mpeg_play/Makefile
1057 plugins/mpeg1/mpegaudio/Makefile
1058 plugins/mpeg1/parse/Makefile
1059 plugins/mpeg1/system_encode/Makefile
1060 plugins/mpeg1/mpeg1encoder/Makefile
1061 plugins/mpeg1video/Makefile
1062 plugins/mpeg1video/parse/Makefile
1063 plugins/oss/Makefile
1064 plugins/rtp/Makefile
1065 plugins/rtp/rtpsend/Makefile
1066 plugins/mulaw/Makefile
1067 plugins/alaw/Makefile
1068 plugins/filters/Makefile
1069 plugins/filters/smooth/Makefile
1070 plugins/filters/median/Makefile
1071 plugins/filters/ladspa/Makefile
1072 plugins/filters/stereo2mono/Makefile
1073 plugins/filters/mono2stereo/Makefile
1074 plugins/filters/intfloatconvert/Makefile
1075 plugins/filters/passthrough/Makefile
1076 plugins/filters/adder/Makefile
1077 plugins/filters/colorspace/Makefile
1078 plugins/filters/volenv/Makefile
1079 plugins/filters/level/Makefile
1080 plugins/gnomevfs/Makefile
1081 plugins/icecast/Makefile
1082 plugins/icecast/icecastsend/Makefile
1083 plugins/effects/Makefile
1084 plugins/effects/stereo/Makefile
1085 plugins/effects/volume/Makefile
1086 plugins/visualization/Makefile
1087 plugins/visualization/spectrum/Makefile
1088 plugins/visualization/vumeter/Makefile
1089 plugins/visualization/synaesthesia/Makefile
1090 plugins/visualization/smoothwave/Makefile
1091 plugins/videoscale/Makefile
1092 plugins/xvideosink/Makefile
1093 plugins/wav/Makefile
1094 plugins/dvdsrc/Makefile
1095 plugins/vcdsrc/Makefile
1096 plugins/rtjpeg/Makefile
1097 plugins/vorbis/Makefile
1098 plugins/capture/Makefile
1099 plugins/capture/v4l/Makefile
1100 plugins/cdparanoia/Makefile
1101 plugins/esd/Makefile
1102 plugins/esd/esdsink/Makefile
1103 plugins/artsd/Makefile
1104 plugins/quicktime/Makefile
1105 plugins/xmms/Makefile
1106 plugins/arts/Makefile
1107 plugins/gsm/Makefile
1108 plugins/1394/Makefile
1109 plugins/sdlsink/Makefile
1110 plugins/dv/Makefile
1111 gstplay/Makefile
1112 dnl components/bonobo-gstmediaplay/Makefile
1113 test/Makefile
1114 test/xml/Makefile
1115 test/bindings/Makefile
1116 tests/Makefile
1117 tests/sched/Makefile
1118 tests/eos/Makefile
1119 testsuite/Makefile
1120 testsuite/capsnego/Makefile
1121 testsuite/refcounting/Makefile
1122 tests/nego/Makefile
1123 examples/Makefile
1124 examples/autoplug/Makefile
1125 examples/helloworld/Makefile
1126 examples/helloworld2/Makefile
1127 examples/launch/Makefile
1128 examples/queue/Makefile
1129 examples/queue2/Makefile
1130 examples/queue3/Makefile
1131 examples/queue4/Makefile
1132 examples/thread/Makefile
1133 examples/mixer/Makefile
1134 examples/launch/Makefile
1135 examples/xml/Makefile
1136 examples/plugins/Makefile
1137 examples/typefind/Makefile
1138 examples/mixer/Makefile
1139 editor/Makefile
1140 editor/pixmaps/Makefile
1141 tools/Makefile
1142 docs/Makefile
1143 docs/gst/Makefile
1144 docs/gst/gstreamer.types
1145 docs/libs/Makefile
1146 docs/plugins/Makefile
1147 docs/plugins/gstreamer-plugins.types
1148 docs/manual/Makefile
1149 docs/fwg/Makefile
1150 debian/Makefile
1151 stamp.h
1152 gstreamer-config
1153 gstreamer.pc
1154 gstreamer-uninstalled.pc
1155 gstreamer.spec,
1156 chmod +x gstreamer-config
1157 )