configure.ac

   1 AC_PREREQ(2.69)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT([GStreamer RTSP Server Library], [1.7.1.1],
   6     [http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],
   7     [gst-rtsp-server])
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 dnl GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl CURRENT, REVISION, AGE
  43 dnl - library source changed -> increment REVISION
  44 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  45 dnl - interfaces added -> increment AGE
  46 dnl - interfaces removed -> AGE = 0
  47 dnl
  48 dnl Keep CURRENT as MINOR * 100 + MICRO
  49 dnl Ex : 1.0.0 => 0
  50 dnl      1.0.3 => 3
  51 dnl      1.1.0 => 100
  52 dnl      1.2.5 => 205
  53 dnl      1.10.9 (who knows) => 1009
  54 dnl
  55 dnl sets GST_LT_LDFLAGS
  56 AS_LIBTOOL(GST, 701, 0, 701)
  57
  58 dnl *** required versions of GStreamer stuff ***
  59 GST_REQ=1.7.1.1
  60 GSTPB_REQ=1.7.1.1
  61 GSTPG_REQ=1.7.1.1
  62 GSTPD_REQ=1.7.1.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71 AC_CONFIG_MACRO_DIR([m4])
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 #AM_GNU_GETTEXT_VERSION([0.17])
  76 #AM_GNU_GETTEXT([external])
  77 #AG_GST_GETTEXT([gst-rtsp-server-$GST_API_VERSION])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  83
  84 AG_GST_ARG_DEBUG
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  88 AG_GST_ARG_WITH_PACKAGE_NAME
  89 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  90
  91 AG_GST_ARG_EXAMPLES
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
  96   ["${srcdir}/gst-rtsp-server.doap"],
  97   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
  98
  99 dnl building of tests
 100 AC_ARG_ENABLE(tests,
 101   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 102   [
 103     case "${enableval}" in
 104       yes) BUILD_TESTS=yes ;;
 105       no)  BUILD_TESTS=no ;;
 106       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 107     esac
 108   ],
 109 [BUILD_TESTS=yes]) dnl Default value
 110 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 111
 112 dnl *** checks for platform ***
 113
 114 dnl * hardware/architecture *
 115
 116 dnl *** checks for programs ***
 117
 118 dnl find a compiler
 119 AC_PROG_CC
 120 AC_PROG_CC_STDC
 121
 122 dnl check if the compiler supports '-c' and '-o' options
 123 AM_PROG_CC_C_O
 124
 125 dnl find an assembler
 126 AM_PROG_AS
 127
 128 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 129 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 130
 131 dnl check for gobject-introspection
 132 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 133
 134 dnl check for documentation tools
 135 AG_GST_DOCBOOK_CHECK
 136 GTK_DOC_CHECK([1.12])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl *** checks for header files ***
 141
 142 dnl *** checks for types/defines ***
 143
 144 dnl *** checks for structures ***
 145
 146 dnl *** checks for compiler characteristics ***
 147
 148 dnl *** checks for library functions ***
 149
 150 dnl *** checks for dependancy libraries ***
 151
 152 dnl GLib is required
 153 GLIB_REQ=2.40.0
 154 AC_SUBST([GLIB_REQ])
 155 AG_GST_GLIB_CHECK([$GLIB_REQ])
 156
 157 dnl checks for gstreamer
 158 dnl uninstalled is selected preferentially -- see pkg-config(1)
 159 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], [yes])
 160
 161 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 162 if test -z $GST_TOOLS_DIR; then
 163   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 164 fi
 165 AC_SUBST(GST_TOOLS_DIR)
 166
 167 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 168 AC_SUBST(GST_PLUGINS_DIR)
 169 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 170
 171 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], [yes])
 172
 173 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], [yes])
 174 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 175 AC_SUBST(GSTPB_PLUGINS_DIR)
 176 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 177
 178 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GSTPG_REQ], [yes])
 179 GSTPG_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-good-$GST_API_VERSION --variable pluginsdir`
 180 AC_SUBST(GSTPG_PLUGINS_DIR)
 181 AC_MSG_NOTICE(Using GStreamer Good Plugins in $GSTPG_PLUGINS_DIR)
 182
 183 AG_GST_CHECK_GST_PLUGINS_BAD($GST_API_VERSION, [$GSTPD_REQ], [yes])
 184 GSTPD_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-bad-$GST_API_VERSION --variable pluginsdir`
 185 AC_SUBST(GSTPD_PLUGINS_DIR)
 186 AC_MSG_NOTICE(Using GStreamer Bad Plugins in $GSTPD_PLUGINS_DIR)
 187
 188 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 189 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 190
 191 dnl Check for -Bsymbolic-functions linker flag used to avoid
 192 dnl intra-library PLT jumps, if available.
 193 AC_ARG_ENABLE(Bsymbolic,
 194               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 195               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 196                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 197                LDFLAGS=-Wl,-Bsymbolic-functions
 198                LIBS=
 199                AC_TRY_LINK([], [return 0],
 200                            AC_MSG_RESULT(yes)
 201                            enable_Bsymbolic=yes,
 202                            AC_MSG_RESULT(no)
 203                            enable_Bsymbolic=no)
 204                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 205
 206 dnl *** set variables based on configure arguments ***
 207
 208 dnl set license and copyright notice
 209 GST_LICENSE="LGPL"
 210 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 211 AC_SUBST(GST_LICENSE)
 212
 213 dnl set location of plugin directory
 214 AG_GST_SET_PLUGINDIR
 215
 216 dnl set release date/time (and check that release version is in doap file)
 217 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 218   ["${srcdir}/gst-rtsp-server.doap"],
 219   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 220
 221 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 222 dnl make sure it doesn't complain about unused variables if debugging is disabled
 223 NO_WARNINGS=""
 224 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 225
 226 dnl define an ERROR_CFLAGS Makefile variable
 227 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 228
 229 dnl define correct level for debugging messages
 230 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 231
 232 dnl used in examples
 233 AG_GST_DEFAULT_ELEMENTS
 234
 235 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 236
 237 dnl Overview:
 238 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 239 dnl GST_*:              flags shared by built objects to link against GStreamer
 240 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 241 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 242 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 243 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 244
 245 dnl GST_OPTION_CFLAGS
 246 if test "x$USE_DEBUG" = xyes; then
 247    PROFILE_CFLAGS="-g"
 248 fi
 249 AC_SUBST(PROFILE_CFLAGS)
 250
 251 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 252 # functionality from the API that gstreamer uses
 253 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 254 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 255   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 256   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 257 else
 258   DEPRECATED_CFLAGS=""
 259 fi
 260 AC_SUBST(DEPRECATED_CFLAGS)
 261
 262 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 263 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 264 AC_SUBST(GST_OPTION_CFLAGS)
 265
 266 dnl FIXME: do we want to rename to GST_ALL_* ?
 267 dnl prefer internal headers to already installed ones
 268 dnl add GST_OPTION_CFLAGS, but overridable
 269 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 270 AC_SUBST(GST_CFLAGS)
 271 AC_SUBST(GST_LIBS)
 272
 273 dnl GST_ALL_*
 274 dnl vars common to for all internal objects (core libs, elements, applications)
 275 dnl CFLAGS:
 276 dnl - src and build dirs need to be added because every piece that gets built
 277 dnl   will need the GStreamer source and generated headers
 278 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_PLUGINS_BASE_CFLAGS $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 279 AC_SUBST([GST_ALL_CFLAGS])
 280
 281 dnl FIXME: check if LTLIBINTL is needed everywhere
 282 dnl I presume it is given that it contains the symbols that _() stuff maps to
 283 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 284 AC_SUBST([GST_ALL_LIBS])
 285
 286 dnl LDFLAGS really should only contain flags, not libs - they get added before
 287 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 288 GST_ALL_LDFLAGS="-no-undefined"
 289 if test "x${enable_Bsymbolic}" = "xyes"; then
 290   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 291 fi
 292
 293 AC_SUBST(GST_ALL_LDFLAGS)
 294
 295 dnl GST_LIB_LDFLAGS
 296 dnl linker flags shared by all libraries
 297 dnl LDFLAGS modifier defining exported symbols from built libraries
 298 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 299 AC_SUBST(GST_LIB_LDFLAGS)
 300
 301 dnl GST_OBJ_*
 302 dnl default vars for all internal objects built on libgstrtspserver
 303 dnl includes GST_ALL_*
 304 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 305 AC_SUBST([GST_OBJ_CFLAGS])
 306 GST_OBJ_LIBS="\$(top_builddir)/gst/rtsp-server/libgstrtspserver-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 307 AC_SUBST([GST_OBJ_LIBS])
 308
 309 PKG_CHECK_MODULES(LIBCGROUP, libcgroup >= 0.26, HAVE_LIBCGROUP="yes", HAVE_LIBCGROUP="no")
 310 AC_SUBST(LIBCGROUP_CFLAGS)
 311 AC_SUBST(LIBCGROUP_LIBS)
 312 AM_CONDITIONAL(HAVE_LIBCGROUP, test "x$HAVE_LIBCGROUP" = "xyes")
 313
 314 dnl this really should only contain flags, not libs - they get added before
 315 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 316
 317 dnl *** output files ***
 318
 319 dnl keep this alphabetic per directory, please
 320 AC_CONFIG_FILES([
 321 Makefile
 322 gst-rtsp.spec
 323 common/Makefile
 324 common/m4/Makefile
 325 gst/Makefile
 326 gst/rtsp-server/Makefile
 327 examples/Makefile
 328 tests/Makefile
 329 tests/check/Makefile
 330 pkgconfig/Makefile
 331 pkgconfig/gstreamer-rtsp-server.pc
 332 pkgconfig/gstreamer-rtsp-server-uninstalled.pc
 333 docs/Makefile
 334 docs/version.entities
 335 docs/libs/Makefile
 336 ])
 337 AC_OUTPUT
 338
 339 echo "
 340
 341 Configuration
 342         Version                    : ${VERSION}
 343         Source code location       : ${srcdir}
 344         Prefix                     : ${prefix}
 345         Compiler                   : ${CC}
 346         CGroups example            : ${HAVE_LIBCGROUP}
 347
 348 gst-rtsp-server configured. Type 'make' to build.
 349 "