configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/udp
 153 AC_CHECK_HEADERS([sys/time.h])
 154
 155 dnl *** checks for types/defines ***
 156
 157 dnl Check for FIONREAD ioctl declaration.  This check is needed
 158 dnl for the UDP plugin to build on Solaris
 159 GST_CHECK_FIONREAD
 160
 161 dnl *** checks for structures ***
 162
 163 dnl *** checks for compiler characteristics ***
 164
 165 dnl check if we have GCC inline-asm
 166 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 167 if test x$HAVE_GCC_ASM = xyes ; then
 168   AC_DEFINE(HAVE_GCC_ASM, 1,
 169     [Define if compiler supports gcc inline assembly])
 170 fi
 171 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 172
 173 dnl *** checks for library functions ***
 174
 175 LIBS_SAVE=$LIBS
 176 LIBS="$LIBS $LIBM"
 177 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 178 LIBS=$LIBS_SAVE
 179
 180 dnl Check whether isinf() is defined by math.h
 181 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 182     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 183 if test "$ac_cv_have_isinf" = "yes"
 184 then
 185     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 186 fi
 187
 188 dnl Check for mmap (needed by electricfence plugin)
 189 AC_FUNC_MMAP
 190 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193
 194 AC_CHECK_TYPE([struct ip_mreqn], [
 195               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 196               [#include <netinet/in.h>])
 197
 198 dnl *** checks for dependency libraries ***
 199
 200 dnl GLib is required
 201 AG_GST_GLIB_CHECK([2.24])
 202
 203 dnl Check for GIO
 204 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 205 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 206   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.31.10)
 207   GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 208   AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 209       [The GIO modules directory.])
 210   GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 211       AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 212           [The GIO library directory.])
 213
 214   AC_SUBST(GIO_CFLAGS)
 215   AC_SUBST(GIO_LIBS)
 216   AC_SUBST(GIO_LDFLAGS)
 217 ])
 218
 219 dnl Orc
 220 ORC_CHECK([0.4.11])
 221
 222 dnl checks for gstreamer
 223 dnl uninstalled is selected preferentially -- see pkg-config(1)
 224 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 225 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 226 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 227 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 228 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 229 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 230
 231 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 232 if test -z $GST_TOOLS_DIR; then
 233   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 234 fi
 235 AC_SUBST(GST_TOOLS_DIR)
 236
 237 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 238 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 239
 240 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 241
 242 dnl Check for documentation xrefs
 243 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 244 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 245 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 246 AC_SUBST(GLIB_PREFIX)
 247 AC_SUBST(GST_PREFIX)
 248 AC_SUBST(GSTPB_PREFIX)
 249
 250 dnl GTK is optional and used in examples
 251 HAVE_GTK=no
 252 GTK2_REQ=2.14.0
 253 GTK3_REQ=2.91.3
 254 if test "x$BUILD_EXAMPLES" = "xyes"; then
 255   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 256   AC_ARG_WITH([gtk],
 257     AC_HELP_STRING([--with-gtk=3.0|2.0],
 258                    [which gtk+ version to compile against (default: 2.0)]),
 259     [case "$with_gtk" in
 260         2.0) GTK_REQ=$GTK2_REQ ;;
 261         3.0) GTK_REQ=$GTK3_REQ ;;
 262         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 263     esac],
 264     [with_gtk=2.0
 265      GTK_REQ=$GTK2_REQ])
 266   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 267   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 268   dnl some examples need gtk+-x11
 269   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 270   AC_SUBST(GTK_LIBS)
 271   AC_SUBST(GTK_CFLAGS)
 272 fi
 273 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 274 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 275
 276 dnl *** set variables based on configure arguments ***
 277
 278 dnl set license and copyright notice
 279 GST_LICENSE="LGPL"
 280 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 281 AC_SUBST(GST_LICENSE)
 282
 283 dnl set location of plugin directory
 284 AG_GST_SET_PLUGINDIR
 285
 286 dnl set release date/time
 287 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 288   ["${srcdir}/gst-plugins-good.doap"],
 289   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 290
 291 dnl define an ERROR_CFLAGS Makefile variable
 292 dnl -Wundef: too many broken headers
 293 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 294   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 295         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 296         -Wwrite-strings -Wold-style-definition -Waggregate-return
 297         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 298         -Wnested-externs ])
 299 else
 300   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 301   dnl doesn't understand all warning flags that the C compiler knows about
 302   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 303   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 304         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 305         -Wwrite-strings -Wold-style-definition
 306         -Winit-self -Wmissing-include-dirs -Wno-multichar
 307         -Wnested-externs ])
 308 fi
 309
 310 dnl define an ERROR_CXXFLAGS Makefile variable
 311 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 312         -Wmissing-declarations -Wredundant-decls
 313         -Wwrite-strings
 314         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 315
 316 dnl define correct level for debugging messages
 317 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 318
 319 dnl used in examples
 320 AG_GST_DEFAULT_ELEMENTS
 321
 322 dnl *** plug-ins to include ***
 323
 324 dnl Non ported plugins (non-dependant, then dependant)
 325 dnl Make sure you have a space before and after all plugins
 326 GST_PLUGINS_NONPORTED="deinterlace interleave flx goom2k1 \
 327  imagefreeze interleave monoscope smpte \
 328  videobox videomixer \
 329  cairo cairo_gobject dv1394 gdk_pixbuf libdv libpng \
 330  oss oss4 shout2 \
 331  taglib wavpack \
 332  osx_video osx_audio "
 333 AC_SUBST(GST_PLUGINS_NONPORTED)
 334
 335 dnl these are all the gst plug-ins, compilable without additional libs
 336 dnl videofilter is at the top because others depend on it
 337 AG_GST_CHECK_PLUGIN(alpha)
 338 AG_GST_CHECK_PLUGIN(apetag)
 339 AG_GST_CHECK_PLUGIN(audiofx)
 340 AG_GST_CHECK_PLUGIN(audioparsers)
 341 AG_GST_CHECK_PLUGIN(auparse)
 342 AG_GST_CHECK_PLUGIN(autodetect)
 343 AG_GST_CHECK_PLUGIN(avi)
 344 AG_GST_CHECK_PLUGIN(cutter)
 345 AG_GST_CHECK_PLUGIN(debugutils)
 346 AG_GST_CHECK_PLUGIN(deinterlace)
 347 AG_GST_CHECK_PLUGIN(effectv)
 348 AG_GST_CHECK_PLUGIN(equalizer)
 349 AG_GST_CHECK_PLUGIN(flv)
 350 AG_GST_CHECK_PLUGIN(flx)
 351 AG_GST_CHECK_PLUGIN(goom)
 352 AG_GST_CHECK_PLUGIN(goom2k1)
 353 AG_GST_CHECK_PLUGIN(icydemux)
 354 AG_GST_CHECK_PLUGIN(id3demux)
 355 AG_GST_CHECK_PLUGIN(imagefreeze)
 356 AG_GST_CHECK_PLUGIN(interleave)
 357 AG_GST_CHECK_PLUGIN(isomp4)
 358 AG_GST_CHECK_PLUGIN(law)
 359 AG_GST_CHECK_PLUGIN(level)
 360 AG_GST_CHECK_PLUGIN(matroska)
 361 AG_GST_CHECK_PLUGIN(monoscope)
 362 AG_GST_CHECK_PLUGIN(multifile)
 363 AG_GST_CHECK_PLUGIN(multipart)
 364 AG_GST_CHECK_PLUGIN(replaygain)
 365 AG_GST_CHECK_PLUGIN(rtp)
 366 AG_GST_CHECK_PLUGIN(rtpmanager)
 367 AG_GST_CHECK_PLUGIN(rtsp)
 368 AG_GST_CHECK_PLUGIN(shapewipe)
 369 AG_GST_CHECK_PLUGIN(smpte)
 370 AG_GST_CHECK_PLUGIN(spectrum)
 371 AG_GST_CHECK_PLUGIN(udp)
 372 AG_GST_CHECK_PLUGIN(videobox)
 373 AG_GST_CHECK_PLUGIN(videocrop)
 374 AG_GST_CHECK_PLUGIN(videofilter)
 375 AG_GST_CHECK_PLUGIN(videomixer)
 376 AG_GST_CHECK_PLUGIN(wavenc)
 377 AG_GST_CHECK_PLUGIN(wavparse)
 378 AG_GST_CHECK_PLUGIN(y4m)
 379
 380 dnl disable experimental plug-ins
 381 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 382   AG_GST_DISABLE_PLUGIN(monoscope)
 383 fi
 384
 385 dnl *** sys plug-ins ***
 386
 387 echo
 388 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 389 echo
 390
 391 dnl DirectSound
 392 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 393 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 394   HAVE_DIRECTSOUND="no"
 395   save_CFLAGS="$CFLAGS"
 396   save_LDFLAGS="$LDFLAGS"
 397   save_LIBS="$LIBS"
 398   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 399   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 400   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 401   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 402   AC_LINK_IFELSE([
 403 #include <windows.h>
 404 #include <dxerr9.h>
 405 #include <dsound.h>
 406
 407 int main ()
 408 {
 409   DXGetErrorString9 (0);
 410   DirectSoundCreate(NULL, NULL, NULL);
 411
 412   return 0;
 413 }
 414 ],
 415     [HAVE_DIRECTSOUND="yes"],
 416     [HAVE_DIRECTSOUND="no"])
 417   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 418   CFLAGS=$save_CFLAGS
 419   LDFLAGS=$save_LDFLAGS
 420   LIBS=$save_LIBS
 421
 422   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 423     dnl this is much more than we want
 424     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 425     AC_SUBST(DIRECTSOUND_CFLAGS)
 426     AC_SUBST(DIRECTSOUND_LDFLAGS)
 427     AC_SUBST(DIRECTSOUND_LIBS)
 428   fi
 429   AC_SUBST(HAVE_DIRECTSOUND)
 430 ])
 431
 432 dnl *** Win32 WaveOut ***
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 434 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 435   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 436 ])
 437
 438 dnl *** OSS audio *** (Linux, *BSD)
 439 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 440 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 441  HAVE_OSS="yes"
 442 dnl Linux and newer BSD versions :
 443  AC_CHECK_HEADER(sys/soundcard.h, [
 444    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 445    ] , [
 446 dnl Some old BSD versions and also newer OpenBSD versions :
 447    AC_CHECK_HEADER(soundcard.h, [
 448      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 449      ], [
 450   dnl Some old BSD versions :
 451      AC_CHECK_HEADER(machine/soundcard.h, [
 452        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 453          [Define if OSS includes are in /machine/])
 454        ], [
 455        HAVE_OSS="no"
 456      ])
 457    ])
 458  ])
 459 ])
 460
 461 dnl *** oss4 ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 463 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 464   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 465   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 466       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 467       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 468 ])
 469
 470 dnl *** Sun Audio ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 472 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 473   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 474 ])
 475
 476 dnl *** OSX Audio ***
 477 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 478 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 479   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 480 ])
 481
 482 dnl *** OS X video ***
 483 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 484 HAVE_OSX_VIDEO="no"
 485 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 486   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 487 ])
 488 dnl in case header OpenGL/gl.h is found on other platforms
 489 case "$host" in
 490   *-*darwin*)
 491     dnl do nothing
 492     ;;
 493   *)
 494     HAVE_OSX_VIDEO="no"
 495     ;;
 496 esac
 497
 498
 499 dnl *** Video 4 Linux 2 ***
 500 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 501 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 503 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 504   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 505   AC_TRY_COMPILE([
 506 #include <sys/types.h>
 507 #ifdef __sun /* Solaris */
 508 #include <sys/types.h>
 509 #include <sys/videodev2.h>
 510 #else /* Linux */
 511 #include <linux/types.h>
 512 #define _LINUX_TIME_H
 513 #define __user
 514 #include <linux/videodev2.h>
 515 #endif
 516 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 517 #error too early v4l2 version or no v4l2 at all
 518 #endif
 519     ], [
 520 return 0;
 521     ], [
 522       HAVE_GST_V4L2="yes"
 523       AC_MSG_RESULT(yes)
 524     ], [
 525       HAVE_GST_V4L2="no"
 526       AC_MSG_RESULT(no)
 527
 528       HAVE_VIDEODEV=no
 529       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 530       [
 531         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 532       ])
 533
 534       if test "x$HAVE_VIDEODEV" = "xyes"; then
 535         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 536         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 537       else
 538         AC_MSG_WARN([video4linux2 was not found])
 539       fi
 540     ])
 541
 542   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 543     dnl check for missing v4l2_buffer declaration (see #135919)
 544     MISSING_DECL=0
 545     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 546     AC_TRY_COMPILE([
 547 #include <sys/types.h>
 548 #ifdef __sun /* Solaris */
 549 #include <sys/types.h>
 550 #include <sys/videodev2.h>
 551 #else /* Linux */
 552 #include <linux/types.h>
 553 #define _LINUX_TIME_H
 554 #define __user
 555 #include <linux/videodev2.h>
 556 #endif
 557     ],[
 558 struct v4l2_buffer buf;
 559 buf.index = 0;
 560 return 0;
 561     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 562     if [ test x$MISSING_DECL = x1 ]; then
 563       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 564     fi
 565
 566     dnl check for XOverlay libraries
 567     AG_GST_CHECK_XV
 568   fi
 569 ])
 570
 571 # Optional gudev for device probing
 572 AC_ARG_WITH([gudev],
 573   AC_HELP_STRING([--with-gudev],
 574     [device detection with gudev]),
 575   [],
 576   [with_gudev=check])
 577 if test x$HAVE_GST_V4L2 = xyes; then
 578   if test x$with_gudev != xno; then
 579       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 580           [ have_gudev=yes
 581             AC_DEFINE(HAVE_GUDEV, 1,
 582                [Whether gudev is available for device detection])
 583             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 584           ], [
 585           have_gudev=no
 586           ])
 587   else
 588     have_gudev=no
 589   fi
 590 fi
 591 AC_SUBST(GUDEV_CFLAGS)
 592 AC_SUBST(GUDEV_LIBS)
 593
 594 # Make libv4l2 non-automagic
 595 AC_ARG_WITH([libv4l2],
 596   AC_HELP_STRING([--with-libv4l2],
 597     [support video buffer conversion using libv4l2]),
 598   [],
 599   [with_libv4l2=check])
 600 if test x$HAVE_GST_V4L2 = xyes; then
 601   if test x$with_libv4l2 != xno; then
 602       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 603           [ have_libv4l2=yes
 604             AC_DEFINE(HAVE_LIBV4L2, 1,
 605                 [Whether libv4l2 is available for video buffer conversion])
 606           ], [
 607           have_libv4l2=no
 608           ])
 609   else
 610     have_libv4l2=no
 611   fi
 612 fi
 613
 614 dnl Check for X11
 615 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 616 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 617                   [ximagesrc], [
 618   AC_PATH_XTRA
 619
 620   dnl now try to find the HEADER
 621   ac_cflags_save="$CFLAGS"
 622   ac_cppflags_save="$CPPFLAGS"
 623   CFLAGS="$CFLAGS $X_CFLAGS"
 624   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 625   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 626
 627   if test "x$HAVE_X" = "xno"
 628   then
 629     AC_MSG_NOTICE([cannot find X11 development files])
 630   else
 631     dnl this is much more than we want
 632     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 633     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 634     dnl it does not add the libs; therefore we add them here
 635     X_LIBS="$X_LIBS -lX11"
 636     AC_SUBST(X_CFLAGS)
 637     AC_SUBST(X_LIBS)
 638
 639     dnl check for Xfixes
 640     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 641     if test "x$HAVE_XFIXES" = "xyes"
 642     then
 643         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 644     fi
 645     AC_SUBST(XFIXES_LIBS)
 646     AC_SUBST(XFIXES_CFLAGS)
 647
 648     dnl check for Xdamage
 649     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 650     if test "x$HAVE_XDAMAGE" = "xyes"
 651     then
 652         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 653     fi
 654     AC_SUBST(XDAMAGE_LIBS)
 655     AC_SUBST(XDAMAGE_CFLAGS)
 656   fi
 657   AC_SUBST(HAVE_X)
 658   CFLAGS="$ac_cflags_save"
 659   CPPFLAGS="$ac_cppflags_save"
 660 ])
 661
 662 dnl FIXME: this should be rolled into the test above, it's just an additional
 663 dnl feature of the ximagesrc plug-in
 664 dnl This is the same as in gst-plugins-base
 665 dnl check for X Shm
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 667 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 668   if test x$HAVE_X = xyes; then
 669     AC_CHECK_LIB(Xext, XShmAttach,
 670                  HAVE_XSHM="yes", HAVE_XSHM="no",
 671                  $X_LIBS)
 672     if test "x$HAVE_XSHM" = "xyes"; then
 673       XSHM_LIBS="-lXext"
 674     else
 675       dnl On AIX, it is in XextSam instead, but we still need -lXext
 676       AC_CHECK_LIB(XextSam, XShmAttach,
 677                    HAVE_XSHM="yes", HAVE_XSHM="no",
 678                    $X_LIBS)
 679       if test "x$HAVE_XSHM" = "xyes"; then
 680         XSHM_LIBS="-lXext -lXextSam"
 681       fi
 682     fi
 683   fi
 684 ], ,[
 685   AC_SUBST(HAVE_XSHM)
 686   AC_SUBST(XSHM_LIBS)
 687 ])
 688
 689 dnl for V4L2, we also need to know if we have XVIDEO
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 691 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 692                   [], [
 693   AG_GST_CHECK_XV
 694 ])
 695
 696 dnl *** ext plug-ins ***
 697 dnl keep this list sorted alphabetically !
 698
 699 if test "x$BUILD_EXTERNAL" = "xyes"; then
 700
 701 echo
 702 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 703 echo
 704
 705 dnl *** aalib ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 707 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 708   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 709   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 710 ])
 711
 712 dnl *** annodex ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 714 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 715   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 716 ])
 717
 718 dnl *** cairo ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 720 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 721   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 722 ])
 723
 724 dnl *** cairo-gobject ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 726 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 727   [Cairo graphics rendering gobject bindings], cairooverlay, [
 728   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 729 ])
 730
 731 dnl *** FLAC ***
 732 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 733 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 734   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 735 ])
 736
 737 dnl *** GDK pixbuf ***
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 739 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 740   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 741 ])
 742
 743 dnl *** Jack ***
 744 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 745 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 746   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 747   AC_SUBST(JACK_CFLAGS)
 748   AC_SUBST(JACK_LIBS)
 749
 750   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 751   if test x$HAVE_JACK_0_120_1 = xyes; then
 752     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 753   fi
 754   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 755   if test x$HAVE_JACK_1_9_7 = xyes; then
 756     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 757   fi
 758
 759 ])
 760
 761 dnl *** jpeg ***
 762 dnl FIXME: we could use header checks here as well IMO
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 764 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 765   AC_ARG_WITH(jpeg-mmx,
 766     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 767   OLD_LIBS="$LIBS"
 768   if test x$with_jpeg_mmx != x; then
 769     LIBS="$LIBS -L$with_jpeg_mmx"
 770   fi
 771   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 772   JPEG_LIBS="$LIBS -ljpeg-mmx"
 773   LIBS="$OLD_LIBS"
 774   if test x$HAVE_JPEG != xyes; then
 775     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 776     JPEG_LIBS="-ljpeg"
 777   fi
 778   AC_SUBST(JPEG_LIBS)
 779 ])
 780
 781 dnl *** libcaca ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 783 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 784   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 785 ])
 786
 787 dnl *** libdv ***
 788 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 789 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 790   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 791 ])
 792
 793 dnl *** libpng ***
 794 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 795 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 796   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 797 ])
 798
 799 dnl *** pulseaudio ***
 800 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 801 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 802
 803   dnl used in ext/pulse/pulseutil.c
 804   AC_CHECK_HEADERS([process.h])
 805
 806   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 807 ])
 808
 809 dnl *** dv1394 ***
 810 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 811 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 812   dnl first test for libraw1394 >= 2.0.0
 813   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 814   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 815   dnl now see how far we got
 816   if test x$HAVE_RAW1394 = xyes && \
 817      test x$HAVE_LIBIEC61883 = xyes; then
 818        AG_GST_CHECK_LIBHEADER(AVC1394,
 819         avc1394, avc1394_send_command, $RAW1394_LIBS,
 820         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 821        AG_GST_CHECK_LIBHEADER(ROM1394,
 822         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 823         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 824        if test x$HAVE_AVC1394 = xyes && \
 825           test x$HAVE_AVC1394 = xyes && \
 826           test x$HAVE_ROM1394 = xyes; then
 827           HAVE_DV1394=yes
 828           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 829           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 830           AC_SUBST(DV1394_CFLAGS)
 831           AC_SUBST(DV1394_LIBS)
 832         fi
 833   else
 834        if test x$HAVE_RAW1394 = xno; then
 835           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 836           AG_GST_CHECK_LIBHEADER(AVC1394,
 837            avc1394, avc1394_send_command, $RAW1394_LIBS,
 838            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 839           AG_GST_CHECK_LIBHEADER(ROM1394,
 840            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 841            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 842           if test x$HAVE_RAW1394 = xyes && \
 843              test x$HAVE_AVC1394 = xyes && \
 844              test x$HAVE_ROM1394 = xyes; then
 845              HAVE_DV1394=yes
 846              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 847              DV1394_CFLAGS="$RAW1394_CFLAGS"
 848              if test x$HAVE_LIBIEC61883 = xyes; then
 849                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 850                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 851              fi
 852              AC_SUBST(DV1394_CFLAGS)
 853              AC_SUBST(DV1394_LIBS)
 854            fi
 855          fi
 856   fi
 857 ])
 858 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 859
 860 dnl *** shout2 ***
 861 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 862 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 863   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 864 ])
 865
 866 dnl *** soup ***
 867 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 868 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 869   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 870     HAVE_SOUP="yes"
 871     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 872   ],[
 873     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 874       HAVE_SOUP="no"
 875     ])
 876   ])
 877   AC_SUBST(SOUP_CFLAGS)
 878   AC_SUBST(SOUP_LIBS)
 879 ])
 880
 881 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 882 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 883 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 884 dnl   speex_jitter.h is 1.1.x only
 885 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 886 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 887   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 888   if test $HAVE_SPEEX = no
 889   then
 890     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 891       AC_CHECK_HEADER(speex/speex_jitter.h, [
 892         dnl speex 1.1.x :
 893         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 894           dnl speex 1.1.5 or + :
 895           HAVE_SPEEX="yes"
 896           SPEEX_LIBS="-lspeex"
 897           AC_SUBST(SPEEX_CFLAGS)
 898           AC_SUBST(SPEEX_LIBS)
 899         ],[
 900           HAVE_SPEEX="no"
 901         ])
 902       ],[
 903         dnl speex 1.0.x :
 904           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 905             dnl speex 1.0.4
 906             HAVE_SPEEX="yes"
 907             SPEEX_LIBS="-lspeex"
 908             AC_SUBST(SPEEX_CFLAGS)
 909             AC_SUBST(SPEEX_LIBS)
 910
 911             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 912               [defined if speex 1.0.x API detected])
 913         ],[
 914             HAVE_SPEEX="no"
 915             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 916         ], [
 917 #include <speex/speex.h>
 918         ])
 919       ])
 920     ])
 921   fi
 922 ])
 923
 924 dnl *** taglib ***
 925 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 926 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 927   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 928   if test "x$HAVE_CXX" != "xyes"; then
 929     USE_TAGLIB=false
 930     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 931   else
 932     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 933     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 934         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 935       ], [
 936         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 937     ])
 938     AC_SUBST(TAGLIB_CXXFLAGS)
 939   fi
 940 ])
 941
 942 dnl *** wavpack ***
 943 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 944 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 945   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 946     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 947       HAVE_WAVPACK=yes
 948       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 949     ],[
 950       HAVE_WAVPACK=no
 951     ])
 952   ])
 953   AC_SUBST(WAVPACK_CFLAGS)
 954   AC_SUBST(WAVPACK_LIBS)
 955 ])
 956
 957 dnl *** qtdemux & matroska prefer to have zlib ***
 958 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 959 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 960   AG_GST_CHECK_LIBHEADER(ZLIB,
 961     z, uncompress,, zlib.h, [
 962     HAVE_ZLIB="yes"
 963     ZLIB_LIBS="-lz"
 964     AC_SUBST(ZLIB_LIBS)
 965   ])
 966 ])
 967
 968 dnl *** matroska prefers to have bz2 ***
 969 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 970 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 971   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 972   AC_SUBST(BZ2_LIBS)
 973 ])
 974
 975 else
 976
 977 dnl not building plugins with external dependencies,
 978 dnl but we still need to set the conditionals
 979 AM_CONDITIONAL(USE_AALIB, false)
 980 AM_CONDITIONAL(USE_ANNODEX, false)
 981 AM_CONDITIONAL(USE_BZ2, false)
 982 AM_CONDITIONAL(USE_CAIRO, false)
 983 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 984 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 985 AM_CONDITIONAL(USE_DV1394, false)
 986 AM_CONDITIONAL(USE_FLAC, false)
 987 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 988 AM_CONDITIONAL(USE_GST_V4L2, false)
 989 AM_CONDITIONAL(USE_JACK, false)
 990 AM_CONDITIONAL(USE_JPEG, false)
 991 AM_CONDITIONAL(USE_LIBCACA, false)
 992 AM_CONDITIONAL(USE_LIBDV, false)
 993 AM_CONDITIONAL(USE_LIBIEC61883, false)
 994 AM_CONDITIONAL(USE_LIBPNG, false)
 995 AM_CONDITIONAL(USE_OSS, false)
 996 AM_CONDITIONAL(USE_OSS4, false)
 997 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 998 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 999 AM_CONDITIONAL(USE_PULSE, false)
1000 AM_CONDITIONAL(USE_SHOUT2, false)
1001 AM_CONDITIONAL(USE_SOUP, false)
1002 AM_CONDITIONAL(USE_SPEEX, false)
1003 AM_CONDITIONAL(USE_SUNAUDIO, false)
1004 AM_CONDITIONAL(USE_TAGLIB, false)
1005 AM_CONDITIONAL(USE_WAVEFORM, false)
1006 AM_CONDITIONAL(USE_WAVPACK, false)
1007 AM_CONDITIONAL(USE_X, false)
1008 AM_CONDITIONAL(USE_XSHM, false)
1009 AM_CONDITIONAL(USE_XVIDEO, false)
1010 AM_CONDITIONAL(USE_ZLIB, false)
1011
1012 fi dnl of EXT plugins
1013
1014 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1015
1016 dnl Overview:
1017 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1018 dnl GST_*:              flags shared by all built objects
1019 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1020 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1021 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1022 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1023
1024 dnl GST_OPTION_CFLAGS
1025 if test "x$USE_DEBUG" = xyes; then
1026    PROFILE_CFLAGS="-g"
1027 fi
1028 AC_SUBST(PROFILE_CFLAGS)
1029
1030 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1031   dnl Define _only_ for git (not pre-releases or releases)
1032   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1033 else
1034   DEPRECATED_CFLAGS=""
1035 fi
1036 AC_SUBST(DEPRECATED_CFLAGS)
1037
1038 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1039 dnl at make time with e.g. make ERROR_CFLAGS=""
1040 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1041 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1042 AC_SUBST(GST_OPTION_CFLAGS)
1043 AC_SUBST(GST_OPTION_CXXFLAGS)
1044
1045 dnl our libraries need to be versioned correctly
1046 AC_SUBST(GST_LT_LDFLAGS)
1047
1048 dnl FIXME: do we want to rename to GST_ALL_* ?
1049 dnl prefer internal headers to already installed ones
1050 dnl also add builddir include for enumtypes and marshal
1051 dnl add ERROR_CFLAGS, but overridable
1052 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1053 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1054 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1055 AC_SUBST(GST_CFLAGS)
1056 AC_SUBST(GST_CXXFLAGS)
1057 AC_SUBST(GST_LIBS)
1058
1059 dnl LDFLAGS really should only contain flags, not libs - they get added before
1060 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1061 GST_ALL_LDFLAGS="-no-undefined"
1062 AC_SUBST(GST_ALL_LDFLAGS)
1063
1064 dnl this really should only contain flags, not libs - they get added before
1065 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1066 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1067 AC_SUBST(GST_PLUGIN_LDFLAGS)
1068
1069 dnl *** output files ***
1070
1071 dnl keep this alphabetic per directory, please
1072 AC_CONFIG_FILES(
1073 Makefile
1074 gst/Makefile
1075 gst/alpha/Makefile
1076 gst/apetag/Makefile
1077 gst/audiofx/Makefile
1078 gst/audioparsers/Makefile
1079 gst/auparse/Makefile
1080 gst/autodetect/Makefile
1081 gst/avi/Makefile
1082 gst/cutter/Makefile
1083 gst/deinterlace/Makefile
1084 gst/debugutils/Makefile
1085 gst/effectv/Makefile
1086 gst/equalizer/Makefile
1087 gst/flv/Makefile
1088 gst/goom/Makefile
1089 gst/goom2k1/Makefile
1090 gst/id3demux/Makefile
1091 gst/icydemux/Makefile
1092 gst/imagefreeze/Makefile
1093 gst/interleave/Makefile
1094 gst/isomp4/Makefile
1095 gst/law/Makefile
1096 gst/level/Makefile
1097 gst/matroska/Makefile
1098 gst/monoscope/Makefile
1099 gst/multifile/Makefile
1100 gst/multipart/Makefile
1101 gst/replaygain/Makefile
1102 gst/rtp/Makefile
1103 gst/rtpmanager/Makefile
1104 gst/rtsp/Makefile
1105 gst/shapewipe/Makefile
1106 gst/smpte/Makefile
1107 gst/spectrum/Makefile
1108 gst/udp/Makefile
1109 gst/videobox/Makefile
1110 gst/videocrop/Makefile
1111 gst/videofilter/Makefile
1112 gst/videomixer/Makefile
1113 gst/wavenc/Makefile
1114 gst/wavparse/Makefile
1115 gst/flx/Makefile
1116 gst/y4m/Makefile
1117 ext/Makefile
1118 ext/aalib/Makefile
1119 ext/annodex/Makefile
1120 ext/cairo/Makefile
1121 ext/dv/Makefile
1122 ext/flac/Makefile
1123 ext/gdk_pixbuf/Makefile
1124 ext/jack/Makefile
1125 ext/jpeg/Makefile
1126 ext/libcaca/Makefile
1127 ext/libpng/Makefile
1128 ext/pulse/Makefile
1129 ext/raw1394/Makefile
1130 ext/shout2/Makefile
1131 ext/soup/Makefile
1132 ext/speex/Makefile
1133 ext/taglib/Makefile
1134 ext/wavpack/Makefile
1135 sys/Makefile
1136 sys/directsound/Makefile
1137 sys/oss/Makefile
1138 sys/oss4/Makefile
1139 sys/osxaudio/Makefile
1140 sys/osxvideo/Makefile
1141 sys/sunaudio/Makefile
1142 sys/v4l2/Makefile
1143 sys/waveform/Makefile
1144 sys/ximage/Makefile
1145 po/Makefile.in
1146 tests/Makefile
1147 tests/check/Makefile
1148 tests/examples/Makefile
1149 tests/examples/audiofx/Makefile
1150 tests/examples/cairo/Makefile
1151 tests/examples/equalizer/Makefile
1152 tests/examples/jack/Makefile
1153 tests/examples/level/Makefile
1154 tests/examples/pulse/Makefile
1155 tests/examples/rtp/Makefile
1156 tests/examples/shapewipe/Makefile
1157 tests/examples/spectrum/Makefile
1158 tests/examples/v4l2/Makefile
1159 tests/files/Makefile
1160 tests/icles/Makefile
1161 common/Makefile
1162 common/m4/Makefile
1163 m4/Makefile
1164 docs/Makefile
1165 docs/plugins/Makefile
1166 docs/version.entities
1167 pkgconfig/Makefile
1168 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1169 gst-plugins-good.spec
1170 )
1171
1172 dnl Create the config.h file for Visual Studio builds
1173 dnl Beware of spaces and /'s in some of the shell variable contents.
1174 sed \
1175     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1176     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1177     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1178     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1179     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1180     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1181     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1182     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1183     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1184     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1185     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1186     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1187     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1188     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1189     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1190     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1191     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1192     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1193     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1194     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1195     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1196     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1197     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1198     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1199     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1200     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1201     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1202     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1203     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1204     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1205     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1206     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1207     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1208     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1209     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1210     config.h.in >win32/common/config.h-new
1211
1212 AC_OUTPUT
1213
1214 AG_GST_OUTPUT_PLUGINS
1215 ORC_OUTPUT
1216