configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Ugly Plug-ins, 0.10.19.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-ugly)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER(config.h)
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS([CXX])
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.36
  56 GSTPB_REQ=0.10.36
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION(0.17)
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-ugly-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 119 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 dnl check for documentation tools
 125 GTK_DOC_CHECK([1.3])
 126 AS_PATH_PYTHON([2.1])
 127 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 128
 129 dnl *** checks for libraries ***
 130
 131 dnl check for libm, for sin()
 132 AC_CHECK_LIBM
 133 AC_SUBST(LIBM)
 134
 135 dnl *** checks for header files ***
 136
 137 dnl used by ext/a52dec
 138 AX_CREATE_STDINT_H
 139
 140 dnl Check for malloc.h
 141 AC_CHECK_HEADERS([malloc.h])
 142
 143 dnl *** checks for types/defines ***
 144
 145 dnl *** checks for structures ***
 146
 147 dnl *** checks for compiler characteristics ***
 148
 149 dnl *** checks for library functions ***
 150
 151 dnl Check for a way to display the function name in debug output
 152 AG_GST_CHECK_FUNCTION
 153
 154 dnl *** checks for dependency libraries ***
 155
 156 dnl GLib is required
 157 AG_GST_GLIB_CHECK([2.20])
 158 ORC_CHECK([0.4.6])
 159
 160 dnl checks for gstreamer
 161 dnl uninstalled is selected preferentially -- see pkg-config(1)
 162 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 163 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 164 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 165 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 166 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 167
 168 dnl Check for documentation xrefs
 169 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 170 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 171 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 172 AC_SUBST(GLIB_PREFIX)
 173 AC_SUBST(GST_PREFIX)
 174 AC_SUBST(GSTPB_PREFIX)
 175
 176 dnl *** set variables based on configure arguments ***
 177
 178 dnl set license and copyright notice
 179 GST_LICENSE="LGPL"
 180 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 181 AC_SUBST(GST_LICENSE)
 182
 183 dnl set location of plugin directory
 184 AG_GST_SET_PLUGINDIR
 185
 186 dnl set release date/time
 187 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 188   ["${srcdir}/gst-plugins-ugly.doap"],
 189   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 190
 191 dnl define an ERROR_CFLAGS Makefile variable
 192 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 193     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 194     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 195     -Winit-self -Wmissing-include-dirs -Waddress
 196     -Waggregate-return -Wno-multichar -Wnested-externs ])
 197
 198 dnl define an ERROR_CXXFLAGS Makefile variable
 199 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 200     -Wmissing-declarations -Wredundant-decls
 201     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 202     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 203     -Wno-multichar])
 204
 205 dnl define correct level for debugging messages
 206 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 207
 208 dnl used in examples
 209 AG_GST_DEFAULT_ELEMENTS
 210
 211 dnl *** plug-ins to include ***
 212
 213 dnl these are all the gst plug-ins, compilable without additional libs
 214 AG_GST_CHECK_PLUGIN(asfdemux)
 215 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 216 AG_GST_CHECK_PLUGIN(dvdsub)
 217 AG_GST_CHECK_PLUGIN(iec958)
 218 AG_GST_CHECK_PLUGIN(mpegaudioparse)
 219 AG_GST_CHECK_PLUGIN(mpegstream)
 220 AG_GST_CHECK_PLUGIN(realmedia)
 221 AG_GST_CHECK_PLUGIN(synaesthesia)
 222
 223 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 224
 225 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 226   WIN32_LIBS="-lws2_32"
 227   AC_SUBST(WIN32_LIBS)
 228 fi
 229
 230 dnl disable experimental plug-ins
 231 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 232   AG_GST_DISABLE_PLUGIN(synaesthesia)
 233 fi
 234
 235 dnl *** ext plug-ins ***
 236 dnl keep this list sorted alphabetically !
 237
 238 if test "x$BUILD_EXTERNAL" = "xyes"; then
 239
 240 echo
 241 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 242 echo
 243
 244 dnl *** a52dec ***
 245 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 246 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 247   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 248 ])
 249
 250 dnl *** amr-nb ***
 251 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 252 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 253   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 254     HAVE_AMRNB="yes"
 255   ], [
 256     HAVE_AMRNB="no"
 257   ])
 258   AC_SUBST(AMRNB_CFLAGS)
 259   AC_SUBST(AMRNB_LIBS)
 260 ])
 261
 262 dnl *** amr-wb dec ***
 263 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 264 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 265   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 266     HAVE_AMRWB="yes"
 267   ], [
 268     HAVE_AMRWB="no"
 269   ])
 270   AC_SUBST(AMRWB_CFLAGS)
 271   AC_SUBST(AMRWB_LIBS)
 272 ])
 273
 274 dnl *** cdio ***
 275 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 276 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 277   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 278 ])
 279
 280 dnl *** dvdread ***
 281 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 282 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 283   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 284   AC_SUBST(DVDREAD_LIBS)
 285 ])
 286
 287 dnl *** lame ***
 288 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 289 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 290   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 291   [
 292     HAVE_LAME="yes"
 293     LAME_LIBS="-lmp3lame $LIBM"
 294     dnl is lame presets available
 295     LAME_CFLAGS=""
 296     AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
 297       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 298       [LAME_CFLAGS=""]
 299     )
 300     AC_TRY_COMPILE([#include <lame/lame.h>], [
 301         void *ptr = &lame_set_VBR_quality
 302       ],
 303       [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
 304       [LAME_CFLAGS="$LAME_CFLAGS"]
 305     )
 306   AC_SUBST(LAME_CFLAGS)
 307   AC_SUBST(LAME_LIBS)
 308   ])
 309 ])
 310
 311 dnl *** mad ***
 312 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 313 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 314
 315   dnl check with pkg-config first
 316   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 317   MAD_LIBS="$MAD_LIBS"
 318   if test "x$HAVE_MAD" = "xno"; then
 319     dnl fall back to oldskool detection
 320     AC_CHECK_HEADER(mad.h, [
 321       AC_CHECK_LIB(mad, mad_decoder_finish,
 322         HAVE_MAD="yes" MAD_LIBS="-lmad")
 323     ])
 324   fi
 325 ])
 326 AC_SUBST(MAD_LIBS)
 327
 328 dnl *** mpeg2dec ***
 329 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 330 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 331   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 332 ])
 333
 334 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 335 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 336 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 337   GST_PATH_SIDPLAY()
 338 ])
 339
 340 dnl *** twolame ***
 341 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 342 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 343   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 344       HAVE_TWOLAME="yes"], [
 345       HAVE_TWOLAME="no"
 346   ])
 347   AC_SUBST(TWOLAME_CFLAGS)
 348   AC_SUBST(TWOLAME_LIBS)
 349 ])
 350
 351 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 352 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 353 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 354   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.55.0)
 355 ])
 356
 357 else
 358
 359 dnl not building plugins with external dependencies,
 360 dnl but we still need to set the conditionals
 361
 362 AM_CONDITIONAL(USE_A52DEC, false)
 363 AM_CONDITIONAL(USE_AMRNB, false)
 364 AM_CONDITIONAL(USE_AMRWB, false)
 365 AM_CONDITIONAL(USE_CDIO, false)
 366 AM_CONDITIONAL(USE_DVDREAD, false)
 367 AM_CONDITIONAL(USE_LAME, false)
 368 AM_CONDITIONAL(USE_MAD, false)
 369 AM_CONDITIONAL(USE_MPEG2DEC, false)
 370 AM_CONDITIONAL(USE_SIDPLAY, false)
 371 AM_CONDITIONAL(USE_TWOLAME, false)
 372 AM_CONDITIONAL(USE_X264, false)
 373
 374 fi dnl of EXT plugins
 375
 376 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 377
 378 dnl Overview:
 379 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 380 dnl GST_*:              flags shared by built objects to link against GStreamer
 381 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 382 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 383 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 384 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 385
 386 dnl GST_OPTION_CFLAGS
 387 if test "x$USE_DEBUG" = xyes; then
 388    PROFILE_CFLAGS="-g"
 389 fi
 390 AC_SUBST(PROFILE_CFLAGS)
 391
 392 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 393   dnl Define _only_ during CVS (not pre-releases or releases)
 394   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 395 else
 396   DEPRECATED_CFLAGS=""
 397 fi
 398 AC_SUBST(DEPRECATED_CFLAGS)
 399
 400 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 401 dnl at make time with e.g. make ERROR_CFLAGS=""
 402 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 403 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 404 AC_SUBST(GST_OPTION_CFLAGS)
 405 AC_SUBST(GST_OPTION_CXXFLAGS)
 406
 407 dnl FIXME: do we want to rename to GST_ALL_* ?
 408 dnl prefer internal headers to already installed ones
 409 dnl also add builddir include for enumtypes and marshal
 410 dnl add GST_OPTION_CFLAGS, but overridable
 411 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 412 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 413 AC_SUBST(GST_CFLAGS)
 414 AC_SUBST(GST_CXXFLAGS)
 415 AC_SUBST(GST_LIBS)
 416
 417 dnl LDFLAGS really should only contain flags, not libs - they get added before
 418 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 419 GST_ALL_LDFLAGS="-no-undefined"
 420 AC_SUBST(GST_ALL_LDFLAGS)
 421
 422 dnl this really should only contain flags, not libs - they get added before
 423 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 424 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 425 AC_SUBST(GST_PLUGIN_LDFLAGS)
 426
 427 dnl *** output files ***
 428
 429 AC_CONFIG_FILES(
 430 Makefile
 431 common/Makefile
 432 common/m4/Makefile
 433 gst-libs/Makefile
 434 gst-libs/gst/Makefile
 435 gst/Makefile
 436 gst/asfdemux/Makefile
 437 gst/dvdlpcmdec/Makefile
 438 gst/dvdsub/Makefile
 439 gst/iec958/Makefile
 440 gst/mpegaudioparse/Makefile
 441 gst/mpegstream/Makefile
 442 gst/realmedia/Makefile
 443 gst/synaesthesia/Makefile
 444 ext/Makefile
 445 ext/a52dec/Makefile
 446 ext/amrnb/Makefile
 447 ext/amrwbdec/Makefile
 448 ext/cdio/Makefile
 449 ext/dvdread/Makefile
 450 ext/lame/Makefile
 451 ext/mad/Makefile
 452 ext/mpeg2dec/Makefile
 453 ext/sidplay/Makefile
 454 ext/twolame/Makefile
 455 ext/x264/Makefile
 456 docs/Makefile
 457 docs/plugins/Makefile
 458 docs/version.entities
 459 tests/Makefile
 460 tests/check/Makefile
 461 m4/Makefile
 462 po/Makefile.in
 463 pkgconfig/Makefile
 464 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 465 gst-plugins-ugly.spec
 466 )
 467
 468 dnl Create the config.h file for Visual Studio builds
 469 dnl Beware of spaces and /'s in some of the shell variable contents.
 470 sed \
 471     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 472     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 473     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 474     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 475     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 476     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 477     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 478     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 479     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 480     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 481     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 482     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 483     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 484     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 485     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 486     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 487     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 488     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 489     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 490     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 491     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 492     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 493     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 494     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 495     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 496     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 497     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 498     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 499     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 500     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 501     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 502     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 503     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 504     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 505     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 506     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 507     config.h.in >win32/common/config.h-new
 508
 509 AC_OUTPUT
 510
 511 AG_GST_OUTPUT_PLUGINS
 512
 513 ORC_OUTPUT