configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.25.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.30
  56 GSTPB_REQ=0.10.30
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106 AC_PROG_CC_STDC
 107
 108 dnl determine c++ compiler
 109 AC_PROG_CXX
 110 dnl determine if c++ is available on this system
 111 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 112
 113 dnl determine c++ preprocessor
 114 dnl FIXME: do we need this ?
 115 AC_PROG_CXXCPP
 116
 117 AS_PROG_OBJC
 118
 119 dnl check if the compiler supports '-c' and '-o' options
 120 AM_PROG_CC_C_O
 121
 122 dnl find an assembler
 123 AM_PROG_AS
 124
 125 dnl check if the compiler supports do while(0) macros
 126 AG_GST_CHECK_DOWHILE_MACROS
 127
 128 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 129 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 130
 131 dnl check for gconftool-2
 132 dnl this macro defines an am conditional, so it needs to be run always
 133 AM_GCONF_SOURCE_2
 134
 135 dnl check for documentation tools
 136 GTK_DOC_CHECK([1.3])
 137 AS_PATH_PYTHON([2.1])
 138 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 139
 140 dnl *** checks for libraries ***
 141
 142 dnl check for libm, for sin()
 143 AC_CHECK_LIBM
 144 AC_SUBST(LIBM)
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/rtp/gstasteriskh263.c
 155 AC_CHECK_HEADERS([netinet/in.h])
 156 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 157 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl *** checks for types/defines ***
 163
 164 dnl Check for FIONREAD ioctl declaration.  This check is needed
 165 dnl for the UDP plugin to build on Solaris
 166 GST_CHECK_FIONREAD
 167
 168 dnl *** checks for structures ***
 169
 170 dnl *** checks for compiler characteristics ***
 171
 172 dnl check if we have GCC inline-asm
 173 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 174 if test x$HAVE_GCC_ASM = xyes ; then
 175   AC_DEFINE(HAVE_GCC_ASM, 1,
 176     [Define if compiler supports gcc inline assembly])
 177 fi
 178 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 179
 180 dnl *** checks for library functions ***
 181
 182 LIBS_SAVE=$LIBS
 183 LIBS="$LIBS $LIBM"
 184 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 185 LIBS=$LIBS_SAVE
 186
 187 dnl Check whether isinf() is defined by math.h
 188 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 190 if test "$ac_cv_have_isinf" = "yes"
 191 then
 192     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 193 fi
 194
 195 dnl Check for mmap (needed by electricfence plugin)
 196 AC_FUNC_MMAP
 197 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 198
 199 dnl Check for mmap (needed by electricfence plugin)
 200
 201 AC_CHECK_TYPE([struct ip_mreqn], [
 202               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 203               [#include <netinet/in.h>])
 204
 205 dnl *** checks for dependency libraries ***
 206
 207 dnl GLib is required
 208 AG_GST_GLIB_CHECK([2.18])
 209
 210 dnl Orc
 211 ORC_CHECK([0.4.8])
 212
 213 dnl checks for gstreamer
 214 dnl uninstalled is selected preferentially -- see pkg-config(1)
 215 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 220 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 221
 222 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 223 if test -z $GST_TOOLS_DIR; then
 224   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 225 fi
 226 AC_SUBST(GST_TOOLS_DIR)
 227
 228 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 229 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 230
 231 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 232
 233 dnl Check for documentation xrefs
 234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 235 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 236 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 237 AC_SUBST(GLIB_PREFIX)
 238 AC_SUBST(GST_PREFIX)
 239 AC_SUBST(GSTPB_PREFIX)
 240
 241 dnl GTK is optional and used in examples
 242 if test "x$BUILD_EXAMPLES" = "xyes"; then
 243   PKG_CHECK_MODULES(GTK, gtk+-3.0, HAVE_GTK=yes,
 244   [PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)])
 245   AC_SUBST(GTK_LIBS)
 246   AC_SUBST(GTK_CFLAGS)
 247 fi
 248 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 249
 250 dnl should we install schemas ?
 251 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 252 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 253   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 254   if test x$GCONFTOOL = xno; then
 255     AC_MSG_WARN(Not installing GConf schemas)
 256     HAVE_GCONFTOOL="no"
 257   else
 258     HAVE_GCONFTOOL="yes"
 259   fi
 260   AC_SUBST(HAVE_GCONFTOOL)
 261 ])
 262
 263 dnl *** set variables based on configure arguments ***
 264
 265 dnl set license and copyright notice
 266 GST_LICENSE="LGPL"
 267 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 268 AC_SUBST(GST_LICENSE)
 269
 270 dnl set location of plugin directory
 271 AG_GST_SET_PLUGINDIR
 272
 273 dnl define an ERROR_CFLAGS Makefile variable
 274 dnl -Wundef: too many broken headers
 275 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 276 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 277         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 278         -Wwrite-strings -Wold-style-definition
 279         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 280         -Wnested-externs ])
 281
 282 dnl define an ERROR_CXXFLAGS Makefile variable
 283 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 284         -Wmissing-declarations -Wredundant-decls
 285         -Wwrite-strings
 286         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 287
 288 dnl define correct level for debugging messages
 289 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 290
 291 dnl used in examples
 292 AG_GST_DEFAULT_ELEMENTS
 293
 294 dnl *** plug-ins to include ***
 295
 296 dnl these are all the gst plug-ins, compilable without additional libs
 297 dnl videofilter is at the top because others depend on it
 298 AG_GST_CHECK_PLUGIN(videofilter)
 299 AG_GST_CHECK_PLUGIN(alpha)
 300 AG_GST_CHECK_PLUGIN(apetag)
 301 AG_GST_CHECK_PLUGIN(audiofx)
 302 AG_GST_CHECK_PLUGIN(auparse)
 303 AG_GST_CHECK_PLUGIN(autodetect)
 304 AG_GST_CHECK_PLUGIN(avi)
 305 AG_GST_CHECK_PLUGIN(cutter)
 306 AG_GST_CHECK_PLUGIN(debugutils)
 307 AG_GST_CHECK_PLUGIN(deinterlace)
 308 AG_GST_CHECK_PLUGIN(effectv)
 309 AG_GST_CHECK_PLUGIN(equalizer)
 310 AG_GST_CHECK_PLUGIN(flv)
 311 AG_GST_CHECK_PLUGIN(id3demux)
 312 AG_GST_CHECK_PLUGIN(icydemux)
 313 AG_GST_CHECK_PLUGIN(interleave)
 314 AG_GST_CHECK_PLUGIN(flx)
 315 AG_GST_CHECK_PLUGIN(goom)
 316 AG_GST_CHECK_PLUGIN(goom2k1)
 317 AG_GST_CHECK_PLUGIN(imagefreeze)
 318 AG_GST_CHECK_PLUGIN(law)
 319 AG_GST_CHECK_PLUGIN(level)
 320 AG_GST_CHECK_PLUGIN(matroska)
 321 AG_GST_CHECK_PLUGIN(monoscope)
 322 AG_GST_CHECK_PLUGIN(multifile)
 323 AG_GST_CHECK_PLUGIN(multipart)
 324 AG_GST_CHECK_PLUGIN(qtdemux)
 325 AG_GST_CHECK_PLUGIN(replaygain)
 326 AG_GST_CHECK_PLUGIN(rtp)
 327 AG_GST_CHECK_PLUGIN(rtpmanager)
 328 AG_GST_CHECK_PLUGIN(rtsp)
 329 AG_GST_CHECK_PLUGIN(shapewipe)
 330 AG_GST_CHECK_PLUGIN(smpte)
 331 AG_GST_CHECK_PLUGIN(spectrum)
 332 AG_GST_CHECK_PLUGIN(udp)
 333 AG_GST_CHECK_PLUGIN(videobox)
 334 AG_GST_CHECK_PLUGIN(videocrop)
 335 AG_GST_CHECK_PLUGIN(videomixer)
 336 AG_GST_CHECK_PLUGIN(wavenc)
 337 AG_GST_CHECK_PLUGIN(wavparse)
 338 AG_GST_CHECK_PLUGIN(y4m)
 339
 340 dnl *** checks for socket and nsl libraries ***
 341 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 342
 343 dnl disable gst plugins we might not be able to build on this
 344 dnl platform: udp and rtsp (ugly but minimally invasive)
 345 dnl FIXME: maybe move to sys
 346 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 347 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 348
 349 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 350   AG_GST_DISABLE_PLUGIN(udp)
 351   AG_GST_DISABLE_PLUGIN(rtsp)
 352 fi
 353
 354 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 355   WIN32_LIBS="-lws2_32"
 356   AC_SUBST(WIN32_LIBS)
 357 fi
 358
 359 dnl disable experimental plug-ins
 360 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 361   AG_GST_DISABLE_PLUGIN(monoscope)
 362 fi
 363
 364 dnl *** sys plug-ins ***
 365
 366 echo
 367 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 368 echo
 369
 370 dnl DirectSound
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 372 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 373   HAVE_DIRECTSOUND="no"
 374   save_CFLAGS="$CFLAGS"
 375   save_LDFLAGS="$LDFLAGS"
 376   save_LIBS="$LIBS"
 377   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 378   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 379   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 380   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 381   AC_LINK_IFELSE([
 382 #include <windows.h>
 383 #include <dxerr9.h>
 384 #include <dsound.h>
 385
 386 int main ()
 387 {
 388   DXGetErrorString9 (0);
 389   DirectSoundCreate(NULL, NULL, NULL);
 390
 391   return 0;
 392 }
 393 ],
 394     [HAVE_DIRECTSOUND="yes"],
 395     [HAVE_DIRECTSOUND="no"])
 396   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 397   CFLAGS=$save_CFLAGS
 398   LDFLAGS=$save_LDFLAGS
 399   LIBS=$save_LIBS
 400
 401   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 402     dnl this is much more than we want
 403     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 404     AC_SUBST(DIRECTSOUND_CFLAGS)
 405     AC_SUBST(DIRECTSOUND_LDFLAGS)
 406     AC_SUBST(DIRECTSOUND_LIBS)
 407   fi
 408   AC_SUBST(HAVE_DIRECTSOUND)
 409 ])
 410
 411 dnl *** OSS audio *** (Linux, *BSD)
 412 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 413 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 414  HAVE_OSS="yes"
 415 dnl Linux and newer BSD versions :
 416  AC_CHECK_HEADER(sys/soundcard.h, [
 417    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 418    ] , [
 419 dnl Some old BSD versions and also newer OpenBSD versions :
 420    AC_CHECK_HEADER(soundcard.h, [
 421      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 422      ], [
 423   dnl Some old BSD versions :
 424      AC_CHECK_HEADER(machine/soundcard.h, [
 425        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 426          [Define if OSS includes are in /machine/])
 427        ], [
 428        HAVE_OSS="no"
 429      ])
 430    ])
 431  ])
 432 ])
 433
 434 dnl *** oss4 ***
 435 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 436 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 437   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 438   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 439       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 440       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 441 ])
 442
 443 dnl *** Sun Audio ***
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 445 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 446   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 447 ])
 448
 449 dnl *** OSX Audio ***
 450 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 451 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 452   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 453 ])
 454
 455 dnl *** OS X video ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 457 HAVE_OSX_VIDEO="no"
 458 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 459   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 460 ])
 461 dnl in case header OpenGL/gl.h is found on other platforms
 462 case "$host" in
 463   *-*darwin*)
 464     dnl do nothing
 465     ;;
 466   *)
 467     HAVE_OSX_VIDEO="no"
 468     ;;
 469 esac
 470
 471
 472 dnl *** Video 4 Linux 2 ***
 473 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 474 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 476 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 477   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 478   AC_TRY_COMPILE([
 479 #include <sys/types.h>
 480 #ifdef __sun /* Solaris */
 481 #include <sys/types.h>
 482 #include <sys/videodev2.h>
 483 #else /* Linux */
 484 #include <linux/types.h>
 485 #define _LINUX_TIME_H
 486 #define __user
 487 #include <linux/videodev2.h>
 488 #endif
 489 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 490 #error too early v4l2 version or no v4l2 at all
 491 #endif
 492     ], [
 493 return 0;
 494     ], [
 495       HAVE_GST_V4L2="yes"
 496       AC_MSG_RESULT(yes)
 497     ], [
 498       HAVE_GST_V4L2="no"
 499       AC_MSG_RESULT(no)
 500
 501       HAVE_VIDEODEV=no
 502       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 503       [
 504         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 505       ])
 506
 507       if test "x$HAVE_VIDEODEV" = "xyes"; then
 508         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 509         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 510       else
 511         AC_MSG_WARN([video4linux2 was not found])
 512       fi
 513     ])
 514
 515   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 516     dnl check for missing v4l2_buffer declaration (see #135919)
 517     MISSING_DECL=0
 518     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 519     AC_TRY_COMPILE([
 520 #include <sys/types.h>
 521 #ifdef __sun /* Solaris */
 522 #include <sys/types.h>
 523 #include <sys/videodev2.h>
 524 #else /* Linux */
 525 #include <linux/types.h>
 526 #define _LINUX_TIME_H
 527 #define __user
 528 #include <linux/videodev2.h>
 529 #endif
 530     ],[
 531 struct v4l2_buffer buf;
 532 buf.index = 0;
 533 return 0;
 534     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 535     if [ test x$MISSING_DECL = x1 ]; then
 536       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 537     fi
 538
 539     dnl check for XOverlay libraries
 540     AG_GST_CHECK_XV
 541   fi
 542 ])
 543
 544 # Optional gudev for device probing
 545 AC_ARG_WITH([gudev],
 546   AC_HELP_STRING([--with-gudev],
 547     [device detection with gudev]),
 548   [],
 549   [with_gudev=check])
 550 if test x$HAVE_GST_V4L2 = xyes; then
 551   if test x$with_gudev != xno; then
 552       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 553           [ have_gudev=yes
 554             AC_DEFINE(HAVE_GUDEV, 1,
 555                [Whether gudev is available for device detection])
 556             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 557           ], [
 558           have_gudev=no
 559           ])
 560   else
 561     have_gudev=no
 562   fi
 563 fi
 564 AC_SUBST(GUDEV_CFLAGS)
 565 AC_SUBST(GUDEV_LIBS)
 566
 567 # Make libv4l2 non-automagic
 568 AC_ARG_WITH([libv4l2],
 569   AC_HELP_STRING([--with-libv4l2],
 570     [support video buffer conversion using libv4l2]),
 571   [],
 572   [with_libv4l2=check])
 573 if test x$HAVE_GST_V4L2 = xyes; then
 574   if test x$with_libv4l2 != xno; then
 575       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 576           [ have_libv4l2=yes
 577             AC_DEFINE(HAVE_LIBV4L2, 1,
 578                 [Whether libv4l2 is available for video buffer conversion])
 579           ], [
 580           have_libv4l2=no
 581           ])
 582   else
 583     have_libv4l2=no
 584   fi
 585 fi
 586
 587 dnl Check for X11
 588 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 589 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 590                   [ximagesrc], [
 591   AC_PATH_XTRA
 592
 593   dnl now try to find the HEADER
 594   ac_cflags_save="$CFLAGS"
 595   ac_cppflags_save="$CPPFLAGS"
 596   CFLAGS="$CFLAGS $X_CFLAGS"
 597   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 598   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 599
 600   if test "x$HAVE_X" = "xno"
 601   then
 602     AC_MSG_NOTICE([cannot find X11 development files])
 603   else
 604     dnl this is much more than we want
 605     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 606     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 607     dnl it does not add the libs; therefore we add them here
 608     X_LIBS="$X_LIBS -lX11"
 609     AC_SUBST(X_CFLAGS)
 610     AC_SUBST(X_LIBS)
 611
 612     dnl check for Xfixes
 613     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 614     if test "x$HAVE_XFIXES" = "xyes"
 615     then
 616         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 617     fi
 618     AC_SUBST(XFIXES_LIBS)
 619     AC_SUBST(XFIXES_CFLAGS)
 620
 621     dnl check for Xdamage
 622     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 623     if test "x$HAVE_XDAMAGE" = "xyes"
 624     then
 625         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 626     fi
 627     AC_SUBST(XDAMAGE_LIBS)
 628     AC_SUBST(XDAMAGE_CFLAGS)
 629   fi
 630   AC_SUBST(HAVE_X)
 631   CFLAGS="$ac_cflags_save"
 632   CPPFLAGS="$ac_cppflags_save"
 633 ])
 634
 635 dnl FIXME: this should be rolled into the test above, it's just an additional
 636 dnl feature of the ximagesrc plug-in
 637 dnl This is the same as in gst-plugins-base
 638 dnl check for X Shm
 639 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 640 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 641   if test x$HAVE_X = xyes; then
 642     AC_CHECK_LIB(Xext, XShmAttach,
 643                  HAVE_XSHM="yes", HAVE_XSHM="no",
 644                  $X_LIBS)
 645     if test "x$HAVE_XSHM" = "xyes"; then
 646       XSHM_LIBS="-lXext"
 647     else
 648       dnl On AIX, it is in XextSam instead, but we still need -lXext
 649       AC_CHECK_LIB(XextSam, XShmAttach,
 650                    HAVE_XSHM="yes", HAVE_XSHM="no",
 651                    $X_LIBS)
 652       if test "x$HAVE_XSHM" = "xyes"; then
 653         XSHM_LIBS="-lXext -lXextSam"
 654       fi
 655     fi
 656   fi
 657 ], ,[
 658   AC_SUBST(HAVE_XSHM)
 659   AC_SUBST(XSHM_LIBS)
 660 ])
 661
 662 dnl for V4L2, we also need to know if we have XVIDEO
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 664 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 665                   [], [
 666   AG_GST_CHECK_XV
 667 ])
 668
 669 dnl *** ext plug-ins ***
 670 dnl keep this list sorted alphabetically !
 671
 672 if test "x$BUILD_EXTERNAL" = "xyes"; then
 673
 674 echo
 675 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 676 echo
 677
 678 dnl *** aalib ***
 679 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 680 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 681   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 682   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 683 ])
 684
 685 dnl *** annodex ***
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 687 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 688   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 689 ])
 690
 691 dnl *** cairo ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 693 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 694   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 695 ])
 696
 697 dnl **** ESound ****
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 699 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 700   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 701   if test $HAVE_ESD = no
 702   then
 703     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 704     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 705   fi
 706 ])
 707
 708 dnl *** FLAC ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 710 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 711   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 712 ])
 713
 714 dnl *** GConf ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 716 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 717   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 718 ])
 719
 720 dnl *** GDK pixbuf ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 722 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 723   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 724 ])
 725
 726 dnl *** HAL ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 728 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 729   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 730 ])
 731
 732 dnl *** jpeg ***
 733 dnl FIXME: we could use header checks here as well IMO
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 735 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 736   AC_ARG_WITH(jpeg-mmx,
 737     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 738   OLD_LIBS="$LIBS"
 739   if test x$with_jpeg_mmx != x; then
 740     LIBS="$LIBS -L$with_jpeg_mmx"
 741   fi
 742   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 743   JPEG_LIBS="$LIBS -ljpeg-mmx"
 744   LIBS="$OLD_LIBS"
 745   if test x$HAVE_JPEG != xyes; then
 746     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 747     JPEG_LIBS="-ljpeg"
 748   fi
 749   AC_SUBST(JPEG_LIBS)
 750 ])
 751
 752 dnl *** libcaca ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 754 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 755   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 756   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 757   if test "x$HAVE_LIBCACA" != "xyes"; then
 758     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 759     dnl see if it compilation works too, might not if we are cross-compiling
 760     if test "x$HAVE_LIBCACA" = "xyes"; then
 761       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 762                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 763     fi
 764   fi
 765 ])
 766
 767 dnl *** libdv ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 769 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 770   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 771 ])
 772
 773 dnl *** libpng ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 775 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 776   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 777 ])
 778
 779 dnl *** pulseaudio ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 781 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 782
 783   dnl used in ext/pulse/pulseutil.c
 784   AC_CHECK_HEADERS([process.h])
 785
 786   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 787   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 788   if test x$HAVE_PULSE_0_9_11 = xyes; then
 789     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 790   fi
 791   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 792   if test x$HAVE_PULSE_0_9_12 = xyes; then
 793     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 794   fi
 795   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 796   if test x$HAVE_PULSE_0_9_13 = xyes; then
 797     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 798   fi
 799   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 800   if test x$HAVE_PULSE_0_9_15 = xyes; then
 801     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 802   fi
 803   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 804   if test x$HAVE_PULSE_0_9_16 = xyes; then
 805     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 806   fi
 807   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 808   if test x$HAVE_PULSE_0_9_20 = xyes; then
 809     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 810   fi
 811 ])
 812
 813 dnl *** dv1394 ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 815 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 816   dnl first test for libraw1394 >= 2.0.0
 817   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 818   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 819   dnl now see how far we got
 820   if test x$HAVE_RAW1394 = xyes && \
 821      test x$HAVE_LIBIEC61883 = xyes; then
 822        AG_GST_CHECK_LIBHEADER(AVC1394,
 823         avc1394, avc1394_send_command, $RAW1394_LIBS,
 824         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 825        AG_GST_CHECK_LIBHEADER(ROM1394,
 826         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 827         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 828        if test x$HAVE_AVC1394 = xyes && \
 829           test x$HAVE_AVC1394 = xyes && \
 830           test x$HAVE_ROM1394 = xyes; then
 831           HAVE_DV1394=yes
 832           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 833           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 834           AC_SUBST(DV1394_CFLAGS)
 835           AC_SUBST(DV1394_LIBS)
 836         fi
 837   else
 838        if test x$HAVE_RAW1394 = xno; then
 839           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 840           AG_GST_CHECK_LIBHEADER(AVC1394,
 841            avc1394, avc1394_send_command, $RAW1394_LIBS,
 842            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 843           AG_GST_CHECK_LIBHEADER(ROM1394,
 844            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 845            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 846           if test x$HAVE_RAW1394 = xyes && \
 847              test x$HAVE_AVC1394 = xyes && \
 848              test x$HAVE_ROM1394 = xyes; then
 849              HAVE_DV1394=yes
 850              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 851              DV1394_CFLAGS="$RAW1394_CFLAGS"
 852              if test x$HAVE_LIBIEC61883 = xyes; then
 853                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 854                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 855              fi
 856              AC_SUBST(DV1394_CFLAGS)
 857              AC_SUBST(DV1394_LIBS)
 858            fi
 859          fi
 860   fi
 861 ])
 862
 863 dnl *** shout2 ***
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 865 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 866   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 867   if test $HAVE_SHOUT2 = no
 868   then
 869     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 870     AC_SUBST(SHOUT2_CFLAGS)
 871     AC_SUBST(SHOUT2_LIBS)
 872   fi
 873 ])
 874
 875 dnl *** soup ***
 876 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 877 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 878   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 879     HAVE_SOUP="yes"
 880     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 881   ],[
 882     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 883       HAVE_SOUP="no"
 884       AC_MSG_RESULT(no)
 885     ])
 886   ])
 887   AC_SUBST(SOUP_CFLAGS)
 888   AC_SUBST(SOUP_LIBS)
 889 ])
 890
 891 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 892 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 893 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 894 dnl   speex_jitter.h is 1.1.x only
 895 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 896 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 897   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 898   if test $HAVE_SPEEX = no
 899   then
 900     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 901       AC_CHECK_HEADER(speex/speex_jitter.h, [
 902         dnl speex 1.1.x :
 903         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 904           dnl speex 1.1.5 or + :
 905           HAVE_SPEEX="yes"
 906           SPEEX_LIBS="-lspeex"
 907           AC_SUBST(SPEEX_CFLAGS)
 908           AC_SUBST(SPEEX_LIBS)
 909         ],[
 910           HAVE_SPEEX="no"
 911         ])
 912       ],[
 913         dnl speex 1.0.x :
 914           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 915             dnl speex 1.0.4
 916             HAVE_SPEEX="yes"
 917             SPEEX_LIBS="-lspeex"
 918             AC_SUBST(SPEEX_CFLAGS)
 919             AC_SUBST(SPEEX_LIBS)
 920
 921             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 922               [defined if speex 1.0.x API detected])
 923         ],[
 924             HAVE_SPEEX="no"
 925             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 926         ], [
 927 #include <speex/speex.h>
 928         ])
 929       ])
 930     ])
 931   fi
 932 ])
 933
 934 dnl *** taglib ***
 935 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 936 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 937   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 938   if test "x$HAVE_CXX" != "xyes"; then
 939     USE_TAGLIB=false
 940     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 941   else
 942     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 943     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 944         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 945       ], [
 946         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 947     ])
 948     AC_SUBST(TAGLIB_CXXFLAGS)
 949   fi
 950 ])
 951
 952 dnl *** wavpack ***
 953 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 954 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 955   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 956     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 957       HAVE_WAVPACK=yes
 958       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 959     ],[
 960       HAVE_WAVPACK=no
 961       AC_MSG_RESULT(no)
 962     ])
 963   ])
 964   AC_SUBST(WAVPACK_CFLAGS)
 965   AC_SUBST(WAVPACK_LIBS)
 966 ])
 967
 968 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 969 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 970 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 971   AG_GST_CHECK_LIBHEADER(ZLIB,
 972     z, uncompress,, zlib.h, [
 973     HAVE_ZLIB="yes"
 974     ZLIB_LIBS="-lz"
 975     AC_SUBST(ZLIB_LIBS)
 976   ])
 977 ])
 978
 979 dnl *** matroska prefers to have bz2 ***
 980 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 981 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 982   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 983   AC_SUBST(BZ2_LIBS)
 984 ])
 985
 986 else
 987
 988 dnl not building plugins with external dependencies,
 989 dnl but we still need to set the conditionals
 990 AM_CONDITIONAL(USE_AALIB, false)
 991 AM_CONDITIONAL(USE_ANNODEX, false)
 992 AM_CONDITIONAL(USE_BZ2, false)
 993 AM_CONDITIONAL(USE_CAIRO, false)
 994 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 995 AM_CONDITIONAL(USE_DV1394, false)
 996 AM_CONDITIONAL(USE_ESD, false)
 997 AM_CONDITIONAL(USE_FLAC, false)
 998 AM_CONDITIONAL(USE_GCONF, false)
 999 AM_CONDITIONAL(USE_GCONFTOOL, false)
1000 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1001 AM_CONDITIONAL(USE_GST_V4L2, false)
1002 AM_CONDITIONAL(USE_HAL, false)
1003 AM_CONDITIONAL(USE_JPEG, false)
1004 AM_CONDITIONAL(USE_LIBCACA, false)
1005 AM_CONDITIONAL(USE_LIBDV, false)
1006 AM_CONDITIONAL(USE_LIBPNG, false)
1007 AM_CONDITIONAL(USE_OSS, false)
1008 AM_CONDITIONAL(USE_OSS4, false)
1009 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1010 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1011 AM_CONDITIONAL(USE_PULSE, false)
1012 AM_CONDITIONAL(USE_SHOUT2, false)
1013 AM_CONDITIONAL(USE_SOUP, false)
1014 AM_CONDITIONAL(USE_SPEEX, false)
1015 AM_CONDITIONAL(USE_SUNAUDIO, false)
1016 AM_CONDITIONAL(USE_TAGLIB, false)
1017 AM_CONDITIONAL(USE_WAVPACK, false)
1018 AM_CONDITIONAL(USE_X, false)
1019 AM_CONDITIONAL(USE_XSHM, false)
1020 AM_CONDITIONAL(USE_XVIDEO, false)
1021 AM_CONDITIONAL(USE_ZLIB, false)
1022
1023 fi dnl of EXT plugins
1024
1025 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1026
1027 dnl Overview:
1028 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1029 dnl GST_*:              flags shared by all built objects
1030 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1031 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1032 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1033 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1034
1035 dnl GST_OPTION_CFLAGS
1036 if test "x$USE_DEBUG" = xyes; then
1037    PROFILE_CFLAGS="-g"
1038 fi
1039 AC_SUBST(PROFILE_CFLAGS)
1040
1041 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1042   dnl Define _only_ for git (not pre-releases or releases)
1043   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1044 else
1045   DEPRECATED_CFLAGS=""
1046 fi
1047 AC_SUBST(DEPRECATED_CFLAGS)
1048
1049 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1050 dnl at make time with e.g. make ERROR_CFLAGS=""
1051 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1052 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1053 AC_SUBST(GST_OPTION_CFLAGS)
1054 AC_SUBST(GST_OPTION_CXXFLAGS)
1055
1056 dnl our libraries need to be versioned correctly
1057 AC_SUBST(GST_LT_LDFLAGS)
1058
1059 dnl FIXME: do we want to rename to GST_ALL_* ?
1060 dnl prefer internal headers to already installed ones
1061 dnl also add builddir include for enumtypes and marshal
1062 dnl add ERROR_CFLAGS, but overridable
1063 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1064 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1065 AC_SUBST(GST_CFLAGS)
1066 AC_SUBST(GST_CXXFLAGS)
1067 AC_SUBST(GST_LIBS)
1068
1069 dnl LDFLAGS really should only contain flags, not libs - they get added before
1070 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1071 GST_ALL_LDFLAGS="-no-undefined"
1072 AC_SUBST(GST_ALL_LDFLAGS)
1073
1074 dnl this really should only contain flags, not libs - they get added before
1075 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1076 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1077 AC_SUBST(GST_PLUGIN_LDFLAGS)
1078
1079 dnl *** output files ***
1080
1081 dnl keep this alphabetic per directory, please
1082 AC_CONFIG_FILES(
1083 Makefile
1084 gst/Makefile
1085 gst/alpha/Makefile
1086 gst/apetag/Makefile
1087 gst/audiofx/Makefile
1088 gst/auparse/Makefile
1089 gst/autodetect/Makefile
1090 gst/avi/Makefile
1091 gst/cutter/Makefile
1092 gst/deinterlace/Makefile
1093 gst/debugutils/Makefile
1094 gst/effectv/Makefile
1095 gst/equalizer/Makefile
1096 gst/flv/Makefile
1097 gst/id3demux/Makefile
1098 gst/icydemux/Makefile
1099 gst/imagefreeze/Makefile
1100 gst/interleave/Makefile
1101 gst/goom/Makefile
1102 gst/goom2k1/Makefile
1103 gst/law/Makefile
1104 gst/level/Makefile
1105 gst/matroska/Makefile
1106 gst/monoscope/Makefile
1107 gst/multifile/Makefile
1108 gst/multipart/Makefile
1109 gst/qtdemux/Makefile
1110 gst/replaygain/Makefile
1111 gst/rtp/Makefile
1112 gst/rtpmanager/Makefile
1113 gst/rtsp/Makefile
1114 gst/shapewipe/Makefile
1115 gst/smpte/Makefile
1116 gst/spectrum/Makefile
1117 gst/udp/Makefile
1118 gst/videobox/Makefile
1119 gst/videocrop/Makefile
1120 gst/videofilter/Makefile
1121 gst/videomixer/Makefile
1122 gst/wavenc/Makefile
1123 gst/wavparse/Makefile
1124 gst/flx/Makefile
1125 gst/y4m/Makefile
1126 ext/jpeg/Makefile
1127 ext/Makefile
1128 ext/aalib/Makefile
1129 ext/annodex/Makefile
1130 ext/cairo/Makefile
1131 ext/dv/Makefile
1132 ext/esd/Makefile
1133 ext/flac/Makefile
1134 ext/gconf/Makefile
1135 ext/gdk_pixbuf/Makefile
1136 ext/hal/Makefile
1137 ext/libcaca/Makefile
1138 ext/libpng/Makefile
1139 ext/pulse/Makefile
1140 ext/raw1394/Makefile
1141 ext/shout2/Makefile
1142 ext/soup/Makefile
1143 ext/speex/Makefile
1144 ext/taglib/Makefile
1145 ext/wavpack/Makefile
1146 sys/Makefile
1147 sys/directsound/Makefile
1148 sys/oss/Makefile
1149 sys/oss4/Makefile
1150 sys/osxaudio/Makefile
1151 sys/osxvideo/Makefile
1152 sys/sunaudio/Makefile
1153 sys/v4l2/Makefile
1154 sys/waveform/Makefile
1155 sys/ximage/Makefile
1156 po/Makefile.in
1157 tests/Makefile
1158 tests/check/Makefile
1159 tests/examples/Makefile
1160 tests/examples/audiofx/Makefile
1161 tests/examples/equalizer/Makefile
1162 tests/examples/level/Makefile
1163 tests/examples/rtp/Makefile
1164 tests/examples/shapewipe/Makefile
1165 tests/examples/spectrum/Makefile
1166 tests/examples/v4l2/Makefile
1167 tests/files/Makefile
1168 tests/icles/Makefile
1169 gconf/Makefile
1170 gconf/gstreamer.schemas
1171 common/Makefile
1172 common/m4/Makefile
1173 m4/Makefile
1174 docs/Makefile
1175 docs/plugins/Makefile
1176 docs/version.entities
1177 pkgconfig/Makefile
1178 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1179 gst-plugins-good.spec
1180 )
1181
1182 dnl Create the config.h file for Visual Studio builds
1183 dnl Beware of spaces and /'s in some of the shell variable contents.
1184 sed \
1185     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1186     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1187     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1188     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1189     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1190     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1191     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1192     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1193     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1194     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1195     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1196     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1197     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1198     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1199     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1200     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1201     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1202     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1203     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1204     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1205     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1206     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1207     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1208     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1209     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1210     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1211     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1212     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1213     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1214     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1215     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1216     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1217     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1218     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1219     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1220     config.h.in >win32/common/config.h-new
1221
1222 AC_OUTPUT
1223
1224 AG_GST_OUTPUT_PLUGINS
1225 ORC_OUTPUT
1226