configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT([GStreamer Ugly Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-ugly])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER(config.h)
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AS_LIBTOOL(GST, 2, 0, 2)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.1.0
  49 GSTPB_REQ=1.1.0
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION(0.17)
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101 AC_PROG_CC_STDC
 102
 103 dnl determine c++ compiler
 104 AC_PROG_CXX
 105 dnl determine if c++ is available on this system
 106 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 107
 108 dnl check if the compiler supports '-c' and '-o' options
 109 AM_PROG_CC_C_O
 110
 111 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 112 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 113
 114 dnl check if the compiler supports do while(0) macros
 115 AG_GST_CHECK_DOWHILE_MACROS
 116
 117 dnl check for documentation tools
 118 GTK_DOC_CHECK([1.12])
 119 AG_GST_PLUGIN_DOCS([1.12])
 120
 121 dnl *** checks for libraries ***
 122
 123 dnl check for libm, for sin()
 124 LT_LIB_M
 125 AC_SUBST(LIBM)
 126
 127 dnl *** checks for header files ***
 128
 129 dnl used by ext/a52dec
 130 AX_CREATE_STDINT_H
 131
 132 dnl Check for malloc.h
 133 AC_CHECK_HEADERS([malloc.h])
 134
 135 dnl *** checks for types/defines ***
 136
 137 dnl *** checks for structures ***
 138
 139 dnl *** checks for compiler characteristics ***
 140
 141 dnl *** checks for library functions ***
 142
 143 dnl Check for a way to display the function name in debug output
 144 AG_GST_CHECK_FUNCTION
 145
 146 dnl *** checks for dependency libraries ***
 147
 148 dnl GLib is required
 149 GLIB_REQ=2.32.0
 150 AG_GST_GLIB_CHECK([$GLIB_REQ])
 151
 152 ORC_CHECK([0.4.16])
 153
 154 dnl checks for gstreamer
 155 dnl uninstalled is selected preferentially -- see pkg-config(1)
 156 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 157 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 158 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 159 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 160 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 161
 162 dnl Check for documentation xrefs
 163 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 164 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 165 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 166 AC_SUBST(GLIB_PREFIX)
 167 AC_SUBST(GST_PREFIX)
 168 AC_SUBST(GSTPB_PREFIX)
 169
 170 dnl *** set variables based on configure arguments ***
 171
 172 dnl set license and copyright notice
 173 GST_LICENSE="LGPL"
 174 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 175 AC_SUBST(GST_LICENSE)
 176
 177 dnl set location of plugin directory
 178 AG_GST_SET_PLUGINDIR
 179
 180 dnl set release date/time
 181 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 182   ["${srcdir}/gst-plugins-ugly.doap"],
 183   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 184
 185 dnl define an ERROR_CFLAGS Makefile variable
 186 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 187     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 188     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 189     -Winit-self -Wmissing-include-dirs -Waddress
 190     -Waggregate-return -Wno-multichar -Wnested-externs ])
 191
 192 dnl define an ERROR_CXXFLAGS Makefile variable
 193 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 194     -Wmissing-declarations -Wredundant-decls
 195     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 196     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 197     -Wno-multichar])
 198
 199 dnl define correct level for debugging messages
 200 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 201
 202 dnl used in examples
 203 AG_GST_DEFAULT_ELEMENTS
 204
 205 dnl *** plug-ins to include ***
 206
 207 dnl Non ported plugins (non-dependant, then dependant)
 208 dnl Make sure you have a space before and after all plugins
 209 GST_PLUGINS_NONPORTED=" "
 210 AC_SUBST(GST_PLUGINS_NONPORTED)
 211
 212 dnl these are all the gst plug-ins, compilable without additional libs
 213 AG_GST_CHECK_PLUGIN(asfdemux)
 214 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 215 AG_GST_CHECK_PLUGIN(dvdsub)
 216 AG_GST_CHECK_PLUGIN(xingmux)
 217 AG_GST_CHECK_PLUGIN(realmedia)
 218
 219 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 220
 221 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 222   WIN32_LIBS="-lws2_32"
 223   AC_SUBST(WIN32_LIBS)
 224 fi
 225
 226 dnl *** ext plug-ins ***
 227 dnl keep this list sorted alphabetically !
 228
 229 if test "x$BUILD_EXTERNAL" = "xyes"; then
 230
 231 echo
 232 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 233 echo
 234
 235 dnl *** a52dec ***
 236 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 237 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 238   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 239 ])
 240
 241 dnl *** amr-nb ***
 242 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 243 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 244   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 245     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 246       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 247     fi
 248     HAVE_AMRNB="yes"
 249   ], [
 250     HAVE_AMRNB="no"
 251   ])
 252   AC_SUBST(AMRNB_CFLAGS)
 253   AC_SUBST(AMRNB_LIBS)
 254 ])
 255
 256 dnl *** amr-wb dec ***
 257 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 258 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 259   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 260     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 261       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 262     fi
 263     HAVE_AMRWB="yes"
 264   ], [
 265     HAVE_AMRWB="no"
 266   ])
 267   AC_SUBST(AMRWB_CFLAGS)
 268   AC_SUBST(AMRWB_LIBS)
 269 ])
 270
 271 dnl *** cdio ***
 272 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 273 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 274   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 275 ])
 276
 277 dnl *** dvdread ***
 278 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 279 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 280   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 281   AC_SUBST(DVDREAD_LIBS)
 282 ])
 283
 284 dnl *** lame ***
 285 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 286 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 287   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 288   [
 289     HAVE_LAME="yes"
 290     LAME_LIBS="-lmp3lame $LIBM"
 291     dnl is lame presets available
 292     LAME_CFLAGS=""
 293     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 294     ])
 295     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 296         void *ptr = &lame_set_VBR_quality
 297       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 298     ])
 299   AC_SUBST(LAME_CFLAGS)
 300   AC_SUBST(LAME_LIBS)
 301   ])
 302 ])
 303
 304 dnl *** mad ***
 305 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 306 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 307
 308   dnl check with pkg-config first
 309   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 310   MAD_LIBS="$MAD_LIBS"
 311   if test "x$HAVE_MAD" = "xno"; then
 312     dnl fall back to oldskool detection
 313     AC_CHECK_HEADER(mad.h, [
 314       AC_CHECK_LIB(mad, mad_decoder_finish,
 315         HAVE_MAD="yes" MAD_LIBS="-lmad")
 316     ])
 317   fi
 318 ])
 319 AC_SUBST(MAD_LIBS)
 320
 321 dnl *** mpeg2dec ***
 322 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 323 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 324   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 325 ])
 326
 327 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 328 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 329 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 330   GST_PATH_SIDPLAY()
 331 ])
 332
 333 dnl *** twolame ***
 334 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 335 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 336   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 337       HAVE_TWOLAME="yes"], [
 338       HAVE_TWOLAME="no"
 339   ])
 340   AC_SUBST(TWOLAME_CFLAGS)
 341   AC_SUBST(TWOLAME_LIBS)
 342 ])
 343
 344 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 345 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 346 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 347   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120.0)
 348 ])
 349
 350 else
 351
 352 dnl not building plugins with external dependencies,
 353 dnl but we still need to set the conditionals
 354
 355 AM_CONDITIONAL(USE_A52DEC, false)
 356 AM_CONDITIONAL(USE_AMRNB, false)
 357 AM_CONDITIONAL(USE_AMRWB, false)
 358 AM_CONDITIONAL(USE_CDIO, false)
 359 AM_CONDITIONAL(USE_DVDREAD, false)
 360 AM_CONDITIONAL(USE_LAME, false)
 361 AM_CONDITIONAL(USE_MAD, false)
 362 AM_CONDITIONAL(USE_MPEG2DEC, false)
 363 AM_CONDITIONAL(USE_SIDPLAY, false)
 364 AM_CONDITIONAL(USE_TWOLAME, false)
 365 AM_CONDITIONAL(USE_X264, false)
 366
 367 fi dnl of EXT plugins
 368
 369 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 370
 371 dnl Overview:
 372 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 373 dnl GST_*:              flags shared by built objects to link against GStreamer
 374 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 375 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 376 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 377 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 378
 379 dnl GST_OPTION_CFLAGS
 380 if test "x$USE_DEBUG" = xyes; then
 381    PROFILE_CFLAGS="-g"
 382 fi
 383 AC_SUBST(PROFILE_CFLAGS)
 384
 385 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 386   dnl Define _only_ during CVS (not pre-releases or releases)
 387   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 388 else
 389   DEPRECATED_CFLAGS=""
 390 fi
 391 AC_SUBST(DEPRECATED_CFLAGS)
 392
 393 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 394 dnl at make time with e.g. make ERROR_CFLAGS=""
 395 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 396 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 397 AC_SUBST(GST_OPTION_CFLAGS)
 398 AC_SUBST(GST_OPTION_CXXFLAGS)
 399
 400 dnl FIXME: do we want to rename to GST_ALL_* ?
 401 dnl prefer internal headers to already installed ones
 402 dnl also add builddir include for enumtypes and marshal
 403 dnl add GST_OPTION_CFLAGS, but overridable
 404 GST_CFLAGS="$GST_CFLAGS"
 405 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 406 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 407 AC_SUBST(GST_CFLAGS)
 408 AC_SUBST(GST_CXXFLAGS)
 409 AC_SUBST(GST_LIBS)
 410
 411 dnl LDFLAGS really should only contain flags, not libs - they get added before
 412 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 413 GST_ALL_LDFLAGS="-no-undefined"
 414 AC_SUBST(GST_ALL_LDFLAGS)
 415
 416 dnl this really should only contain flags, not libs - they get added before
 417 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 418 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 419 AC_SUBST(GST_PLUGIN_LDFLAGS)
 420
 421 dnl *** output files ***
 422
 423 AC_CONFIG_FILES(
 424 Makefile
 425 common/Makefile
 426 common/m4/Makefile
 427 gst-libs/Makefile
 428 gst-libs/gst/Makefile
 429 gst/Makefile
 430 gst/asfdemux/Makefile
 431 gst/dvdlpcmdec/Makefile
 432 gst/dvdsub/Makefile
 433 gst/realmedia/Makefile
 434 gst/xingmux/Makefile
 435 ext/Makefile
 436 ext/a52dec/Makefile
 437 ext/amrnb/Makefile
 438 ext/amrwbdec/Makefile
 439 ext/cdio/Makefile
 440 ext/dvdread/Makefile
 441 ext/lame/Makefile
 442 ext/mad/Makefile
 443 ext/mpeg2dec/Makefile
 444 ext/sidplay/Makefile
 445 ext/twolame/Makefile
 446 ext/x264/Makefile
 447 docs/Makefile
 448 docs/plugins/Makefile
 449 docs/version.entities
 450 tests/Makefile
 451 tests/check/Makefile
 452 m4/Makefile
 453 po/Makefile.in
 454 pkgconfig/Makefile
 455 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 456 gst-plugins-ugly.spec
 457 )
 458
 459 dnl Create the config.h file for Visual Studio builds
 460 dnl Beware of spaces and /'s in some of the shell variable contents.
 461 sed \
 462     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 463     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 464     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 465     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 466     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 467     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 468     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 469     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 470     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 471     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 472     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 473     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 474     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 475     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 476     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 477     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 478     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 479     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 480     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 481     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 482     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 483     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 484     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 485     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 486     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 487     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 488     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 489     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 490     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 491     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 492     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 493     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 494     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 495     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 496     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 497     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 498     config.h.in >win32/common/config.h-new
 499
 500 AC_OUTPUT
 501
 502 AG_GST_OUTPUT_PLUGINS
 503
 504 ORC_OUTPUT