configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Bad Plug-ins, 0.10.8.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-plugins-bad)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([docs/plugins/gst-plugins-bad-plugins-docs.sgml])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$GST_PLUGINS_BAD_VERSION_MAJOR.$GST_PLUGINS_BAD_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl FIXME: this macro doesn't actually work;
  40 dnl the generated libtool script has no support for the listed tags.
  41 dnl So this needs to be fixed first if we want to use this
  42 dnl AS_LIBTOOL_TAGS([CXX])
  43
  44 AC_LIBTOOL_WIN32_DLL
  45 AM_PROG_LIBTOOL
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=0.10.20
  49 GSTPB_REQ=0.10.20
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION([0.11.5])
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-bad-$GST_MAJORMINOR])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DEBUG
  68 AG_GST_ARG_PROFILING
  69 AG_GST_ARG_VALGRIND
  70 AG_GST_ARG_GCOV
  71
  72 AG_GST_ARG_EXAMPLES
  73
  74 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  75 AG_GST_ARG_WITH_PACKAGE_NAME
  76 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  77
  78 AG_GST_ARG_WITH_PLUGINS
  79
  80 AG_GST_ARG_ENABLE_EXTERNAL
  81
  82 AG_GST_ARG_ENABLE_EXPERIMENTAL
  83
  84 dnl *** checks for platform ***
  85
  86 dnl * hardware/architecture *
  87
  88 dnl common/m4/gst-arch.m4
  89 dnl check CPU type
  90 AG_GST_ARCH
  91
  92 dnl Determine endianness
  93 AC_C_BIGENDIAN
  94
  95 dnl *** checks for programs ***
  96
  97 dnl find a compiler
  98 AC_PROG_CC
  99
 100 dnl determine c++ compiler
 101 AC_PROG_CXX
 102 dnl determine if c++ is available on this system
 103 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 104
 105 AS_PROG_OBJC
 106
 107 dnl check if the compiler supports '-c' and '-o' options
 108 AM_PROG_CC_C_O
 109
 110 dnl check if the compiler supports do while(0) macros
 111 AG_GST_CHECK_DOWHILE_MACROS
 112
 113 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 114 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 115
 116 dnl check for documentation tools
 117 GTK_DOC_CHECK([1.3])
 118 AS_PATH_PYTHON([2.1])
 119 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 120
 121 dnl *** checks for libraries ***
 122
 123 dnl check for libm, for sin() etc.
 124 AC_CHECK_LIBM
 125 AC_SUBST(LIBM)
 126
 127 dnl *** checks for header files ***
 128
 129 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 130 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 131
 132 if test "x$HAVE_UNISTD_H" != "xyes"; then
 133   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 134 fi
 135
 136 dnl used by ext/dts
 137 AX_CREATE_STDINT_H
 138
 139 dnl *** checks for types/defines ***
 140
 141 dnl Check for FIONREAD ioctl declaration
 142 dnl used in gst/dccp
 143 GST_CHECK_FIONREAD
 144
 145 dnl *** checks for structures ***
 146
 147 dnl *** checks for compiler characteristics ***
 148 dnl check if we have GCC inline-asm
 149 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 150 if test x$HAVE_GCC_ASM = xyes ; then
 151   AC_DEFINE(HAVE_GCC_ASM, 1,
 152     [Define if compiler supports gcc inline assembly])
 153 fi
 154 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 155
 156 dnl *** checks for library functions ***
 157
 158 dnl *** checks for dependency libraries ***
 159
 160 dnl GLib is required
 161 AG_GST_GLIB_CHECK([2.6])
 162
 163 dnl liboil is required
 164 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 165 if test "x$HAVE_LIBOIL" != "xyes"; then
 166   AC_ERROR([liboil-0.3.8 or later is required])
 167 fi
 168
 169 dnl checks for gstreamer
 170 dnl uninstalled is selected preferentially -- see pkg-config(1)
 171 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 172 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 173 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 174 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 175 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 176 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 177 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 178
 179 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 180 AC_SUBST(GSTPB_PLUGINS_DIR)
 181 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 182
 183 dnl Check for documentation xrefs
 184 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 185 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 186 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 187 AC_SUBST(GLIB_PREFIX)
 188 AC_SUBST(GST_PREFIX)
 189 AC_SUBST(GSTPB_PREFIX)
 190
 191 dnl GTK is optional and used in examples
 192 HAVE_GTK=NO
 193 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 194 if test "x$HAVE_GTK_22" = "xyes"; then
 195   HAVE_GTK=yes
 196   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 197   AC_SUBST(GTK_VERSION)
 198   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 199   AC_SUBST(GTK_BASE_DIR)
 200   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 201   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 202   AC_SUBST(GTK_BASE_DIR)
 203 else
 204   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 205 fi
 206 if test "x$HAVE_GTK_20" = "xyes"; then
 207   HAVE_GTK=yes
 208 fi
 209 GTK_CFLAGS=$GTK2_CFLAGS
 210 GTK_LIBS=$GTK2_LIBS
 211 AC_SUBST(GTK_LIBS)
 212 AC_SUBST(GTK_CFLAGS)
 213 AC_SUBST(HAVE_GTK)
 214 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 215
 216 dnl libglade is optional and only used in examples
 217 HAVE_GLADE=NO
 218 PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0, HAVE_GLADE=yes, HAVE_GLADE=no)
 219 AC_SUBST(GLADE_LIBS)
 220 AC_SUBST(GLADE_CFLAGS)
 221 AC_SUBST(HAVE_GLADE)
 222 AM_CONDITIONAL(HAVE_GLADE, test "x$HAVE_GLADE" = "xyes")
 223
 224 dnl set license and copyright notice
 225 GST_LICENSE="LGPL"
 226 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 227 AC_SUBST(GST_LICENSE)
 228
 229 dnl set location of plugin directory
 230 AG_GST_SET_PLUGINDIR
 231
 232 dnl define an ERROR_CFLAGS Makefile variable
 233 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 234
 235 dnl define an ERROR_CXXFLAGS Makefile variable
 236 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 237
 238 dnl define correct level for debugging messages
 239 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 240
 241 dnl *** plug-ins to include ***
 242
 243 dnl these are all the gst plug-ins, compilable without additional libs
 244 AG_GST_CHECK_PLUGIN(aiffparse)
 245 AG_GST_CHECK_PLUGIN(app)
 246 AG_GST_CHECK_PLUGIN(bayer)
 247 AG_GST_CHECK_PLUGIN(cdxaparse)
 248 AG_GST_CHECK_PLUGIN(dccp)
 249 AG_GST_CHECK_PLUGIN(deinterlace)
 250 AG_GST_CHECK_PLUGIN(deinterlace2)
 251 AG_GST_CHECK_PLUGIN(dvdspu)
 252 AG_GST_CHECK_PLUGIN(festival)
 253 AG_GST_CHECK_PLUGIN(filter)
 254 AG_GST_CHECK_PLUGIN(flv)
 255 AG_GST_CHECK_PLUGIN(freeze)
 256 AG_GST_CHECK_PLUGIN(h264parse)
 257 AG_GST_CHECK_PLUGIN(librfb)
 258 AG_GST_CHECK_PLUGIN(modplug)
 259 AG_GST_CHECK_PLUGIN(mpegdemux)
 260 AG_GST_CHECK_PLUGIN(mpegtsparse)
 261 AG_GST_CHECK_PLUGIN(mpegtsmux)
 262 AG_GST_CHECK_PLUGIN(mpeg4videoparse)
 263 AG_GST_CHECK_PLUGIN(mpegvideoparse)
 264 AG_GST_CHECK_PLUGIN(mve)
 265 AG_GST_CHECK_PLUGIN(nsf)
 266 AG_GST_CHECK_PLUGIN(nuvdemux)
 267 AG_GST_CHECK_PLUGIN(pcapparse)
 268 AG_GST_CHECK_PLUGIN(rawparse)
 269 AG_GST_CHECK_PLUGIN(real)
 270 AG_GST_CHECK_PLUGIN(rtpmanager)
 271 AG_GST_CHECK_PLUGIN(scaletempo)
 272 AG_GST_CHECK_PLUGIN(sdp)
 273 AG_GST_CHECK_PLUGIN(selector)
 274 AG_GST_CHECK_PLUGIN(speed)
 275 AG_GST_CHECK_PLUGIN(speexresample)
 276 AG_GST_CHECK_PLUGIN(subenc)
 277 AG_GST_CHECK_PLUGIN(stereo)
 278 AG_GST_CHECK_PLUGIN(tta)
 279 AG_GST_CHECK_PLUGIN(videosignal)
 280 AG_GST_CHECK_PLUGIN(vmnc)
 281 AG_GST_CHECK_PLUGIN(y4m)
 282
 283 dnl *** plug-ins to exclude ***
 284
 285 dnl see if we can build C++ plug-ins
 286 if test "x$HAVE_CXX" != "xyes"; then
 287   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 288   AG_GST_DISABLE_PLUGIN(modplug)
 289 fi
 290
 291 dnl real plugin only works on i386 and x86_64 for the time being.
 292 if test "x$HAVE_CPU_I386" != "xyes" && test "x$HAVE_CPU_X86_64" != "xyes"; then
 293   AC_MSG_WARN([Not building real plugin, only works on 32bit and 64bit x86 platforms])
 294   AG_GST_DISABLE_PLUGIN(real)
 295 fi
 296
 297 dnl disable experimental plug-ins
 298 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 299   AG_GST_DISABLE_PLUGIN(deinterlace2)
 300 fi
 301
 302 dnl disable gst plugins we might not be able to build on this
 303 dnl platform: librfb (ugly but minimally invasive)
 304 dnl FIXME: maybe move to sys, or make work with winsock2
 305 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 306 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 307
 308 dnl needed for festival
 309 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 310
 311 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 312   AG_GST_DISABLE_PLUGIN(librfb)
 313 fi
 314
 315 dnl *** sys plug-ins ***
 316
 317 dnl check for QuickTime
 318 translit(dnm, m, l) AM_CONDITIONAL(USE_QUICKTIME, true)
 319 AG_GST_CHECK_FEATURE(QUICKTIME, [QuickTime wrapper], qtwrapper, [
 320   AC_CHECK_HEADER(QuickTime/Movies.h, HAVE_QUICKTIME="yes", HAVE_QUICKTIME="no")
 321 ])
 322
 323 dnl check for Video CD
 324 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 325 AG_GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 326   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 327 ])
 328
 329 dnl *** ext plug-ins ***
 330 dnl keep this list sorted alphabetically !
 331
 332 if test "x$BUILD_EXTERNAL" = "xyes"; then
 333
 334 dnl *** alsa ***
 335 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 336 AG_GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 337   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 338     HAVE_ALSA="yes"
 339     AC_SUBST(ALSA_CFLAGS)
 340     AC_SUBST(ALSA_LIBS)
 341   ], [
 342     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 343   ])
 344 ])
 345
 346 dnl *** amrwb ***
 347 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 348 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwb, [
 349   AG_GST_CHECK_LIBHEADER(AMRWB, amrwb,
 350                         GP3D_IF_decode, ,
 351                         amrwb/dec.h,
 352                         AMRWB_LIBS="-lamrwb"
 353                         AC_SUBST(AMRWB_LIBS))
 354 ])
 355
 356 dnl *** apexsink ***
 357 translit(dnm, m, l) AM_CONDITIONAL(USE_APEXSINK, true)
 358 AG_GST_CHECK_FEATURE(APEXSINK, [AirPort Express Wireless sink], apexsink, [
 359
 360   HAVE_APEXSINK="yes"
 361   # The big search for OpenSSL
 362   # copied from openssh's configure.ac
 363   AC_ARG_WITH(ssl-dir,
 364           [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 365           [
 366                   if test "x$withval" != "xno" ; then
 367                           tryssldir=$withval
 368                   fi
 369           ]
 370   )
 371
 372   AC_SEARCH_LIBS(socket, [socket])
 373   AC_SEARCH_LIBS(gethostbyname, [nsl])
 374
 375   saved_LIBS="$LIBS"
 376   saved_LDFLAGS="$LDFLAGS"
 377   saved_CPPFLAGS="$CPPFLAGS"
 378   if test "x$prefix" != "xNONE" ; then
 379           tryssldir="$tryssldir $prefix"
 380   fi
 381   AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 382           for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /usr/pkg /opt /opt/openssl ; do
 383                   CPPFLAGS="$saved_CPPFLAGS"
 384                   LDFLAGS="$saved_LDFLAGS"
 385                   LIBS="$saved_LIBS -lssl -lcrypto"
 386
 387                   # Skip directories if they don't exist
 388                   if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 389                           continue;
 390                   fi
 391                   if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 392                           # Try to use $ssldir/lib if it exists, otherwise
 393                           # $ssldir
 394                           if test -d "$ssldir/lib" ; then
 395                                   LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 396                                   if test ! -z "$need_dash_r" ; then
 397                                           LDFLAGS="-R$ssldir/lib $LDFLAGS"
 398                                   fi
 399                           else
 400                                   LDFLAGS="-L$ssldir $saved_LDFLAGS"
 401                                   if test ! -z "$need_dash_r" ; then
 402                                           LDFLAGS="-R$ssldir $LDFLAGS"
 403                                   fi
 404                           fi
 405                           # Try to use $ssldir/include if it exists, otherwise
 406                           # $ssldir
 407                           if test -d "$ssldir/include" ; then
 408                                   CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 409                           else
 410                                   CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 411                           fi
 412                   fi
 413
 414                   # Basic test to check for compatible version and correct linking
 415                   # *does not* test for RSA - that comes later.
 416                   AC_TRY_RUN(
 417                           [
 418 #include <string.h>
 419 #include <openssl/rand.h>
 420 int main(void)
 421 {
 422         char a[2048];
 423         memset(a, 0, sizeof(a));
 424         RAND_add(a, sizeof(a), sizeof(a));
 425         return(RAND_status() <= 0);
 426 }
 427                           ],
 428                           [
 429                                   found_crypto=1
 430                                   break;
 431                           ], []
 432                   )
 433
 434                   if test ! -z "$found_crypto" ; then
 435                           break;
 436                   fi
 437           done
 438
 439           if test -z "$found_crypto" ; then
 440                   HAVE_APEXSINK="no"
 441           fi
 442           if test -z "$ssldir" ; then
 443                   ssldir="(system)"
 444           fi
 445
 446           ac_cv_openssldir=$ssldir
 447   ])
 448   if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ;
 449    then
 450           dnl Need to recover ssldir - test above runs in subshell
 451           ssldir=$ac_cv_openssldir
 452           if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 453                   # Try to use $ssldir/lib if it exists, otherwise
 454                   # $ssldir
 455                   if test -d "$ssldir/lib" ; then
 456                           APEXSINK_LIBS="-L$ssldir/lib $LDFLAGS"
 457                           if test ! -z "$need_dash_r" ; then
 458                                   APEXSINK_LIBS="-R$ssldir/lib $LDFLAGS"
 459                           fi
 460                   else
 461                           APEXSINK_LDFLAGS="-L$ssldir $LDFLAGS"
 462                           if test ! -z "$need_dash_r" ; then
 463                                   APEXSINK_LIBS="-R$ssldir $LDFLAGS"
 464                           fi
 465                   fi
 466                   # Try to use $ssldir/include if it exists, otherwise
 467                   # $ssldir
 468                   if test -d "$ssldir/include" ; then
 469                           APEXSINK_CFLAGS="-I$ssldir/include $CPPFLAGS"
 470                   else
 471                           APEXSINK_CFLAGS="-I$ssldir $CPPFLAGS"
 472                   fi
 473           fi
 474   fi
 475   APEXSINK_LIBS="$APEXSINK_LIBS $LIBS"
 476   AC_SUBST(APEXSINK_LIBS)
 477   AC_SUBST(APEXSINK_CFLAGS)
 478   CPPFLAGS="$saved_CPPFLAGS"
 479   LDFLAGS="$saved_LDFLAGS"
 480   LIBS="$saved_LIBS"
 481 ])
 482
 483 dnl *** BZ2 ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 485 AG_GST_CHECK_FEATURE(BZ2, [bz2 library], bz2, [
 486   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 487   AC_SUBST(BZ2_LIBS)
 488 ])
 489
 490 #dnl *** cairo ***
 491 #translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 492 #AG_GST_CHECK_FEATURE(CAIRO, [cairo plug-in], cairo, [
 493 #  PKG_CHECK_MODULES(CAIRO, cairo >= 1.0 glitz-glx, HAVE_CAIRO=yes, [
 494 #    HAVE_CAIRO=no
 495 #    AC_MSG_RESULT(no)
 496 #  ])
 497 #  AC_SUBST(CAIRO_CFLAGS)
 498 #  AC_SUBST(CAIRO_LIBS)
 499 #])
 500
 501 dnl *** cdaudio ***
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_CDAUDIO, true)
 503 AG_GST_CHECK_FEATURE(CDAUDIO, [cdaudio], cdaudio, [
 504   AG_GST_CHECK_CONFIGPROG(CDAUDIO, libcdaudio-config)
 505   AC_SUBST(CDAUDIO_CFLAGS)
 506   AC_SUBST(CDAUDIO_LIBS)
 507 ])
 508
 509 dnl *** celt ***
 510 translit(dnm, m, l) AM_CONDITIONAL(USE_CELT, true)
 511 AG_GST_CHECK_FEATURE(CELT, [celt], celt, [
 512   PKG_CHECK_MODULES(CELT, celt >= 0.4.0, [
 513       HAVE_CELT="yes"], [
 514       HAVE_CELT="no"
 515       AC_MSG_RESULT(no)
 516   ])
 517   AC_SUBST(CELT_CFLAGS)
 518   AC_SUBST(CELT_LIBS)
 519 ])
 520
 521 dnl *** dc1394  ***
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_DC1394, true)
 523 AG_GST_CHECK_FEATURE(DC1394, [libdc1394], dc1394, [
 524    PKG_CHECK_MODULES(LIBDC1394, libdc1394-2 >= 2.0.0, [
 525         if test -z "`pkg-config --modversion libdc1394-2 | grep 2.0.0-rc`"; then
 526                 HAVE_DC1394="yes"
 527         else
 528                 HAVE_DC1394="no"
 529                 AC_MSG_RESULT(no)
 530         fi
 531    ], [
 532         HAVE_DC1394="no"
 533         AC_MSG_RESULT(no)
 534    ])
 535    AC_SUBST(LIBDC1394_CFLAGS)
 536    AC_SUBST(LIBDC1394_LIBS)
 537 ])
 538
 539
 540 dnl **** DirectFB ****
 541 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTFB, true)
 542 AG_GST_CHECK_FEATURE(DIRECTFB, [directfb], dfbvideosink , [
 543   PKG_CHECK_MODULES(DIRECTFB, directfb >= 0.9.24, HAVE_DIRECTFB="yes", [
 544     HAVE_DIRECTFB="no"
 545     AC_MSG_RESULT(no)
 546   ])
 547 ])
 548
 549 dnl **** Dirac ****
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRAC, true)
 551 AG_GST_CHECK_FEATURE(DIRAC, [dirac], dirac, [
 552   PKG_CHECK_MODULES(DIRAC, dirac >= 0.10, HAVE_DIRAC="yes", [
 553     HAVE_DIRAC="no"
 554     AC_MSG_RESULT(no)
 555   ])
 556 ])
 557
 558 dnl *** DTS ***
 559 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
 560 AG_GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
 561   HAVE_DTS="yes"
 562   AG_GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, -lm, dts.h,
 563     DTS_LIBS="-ldts_pic -lm", HAVE_DTS="no")
 564   if test $HAVE_DTS = "no"; then
 565     AG_GST_CHECK_LIBHEADER(DTS, dca, dca_init, -lm, dts.h,
 566       DTS_LIBS="-ldca -lm")
 567   fi
 568   AC_SUBST(DTS_LIBS)
 569 ])
 570
 571 dnl *** DIVX ***
 572 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 573 AG_GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 574   HAVE_DIVX=yes
 575   AC_CHECK_HEADER(encore2.h, , [
 576     AC_MSG_WARN([Divx4linux encore headers not found])
 577     HAVE_DIVX=no
 578   ])
 579   if [ test x$HAVE_DIVX = xyes ]; then
 580     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 581     AC_TRY_COMPILE([
 582 #include <encore2.h>
 583 #if ENCORE_VERSION != 20021024
 584 #error Wrong version of divx encore libraries
 585 #endif
 586     ], [
 587 return 0;
 588     ], [
 589       HAVE_DIVX=yes
 590       AC_MSG_RESULT(yes)
 591     ], [
 592       HAVE_DIVX=no
 593       AC_MSG_RESULT(no)
 594       AC_MSG_WARN([Wrong version of divx4linux installed])
 595     ])
 596   fi
 597   if [ test x$HAVE_DIVX = xyes ]; then
 598     AC_CHECK_HEADER(decore.h, , [
 599       AC_MSG_WARN([Divx4linux decoder headers not found])
 600       HAVE_DIVX=no
 601     ])
 602   fi
 603   if [ test x$HAVE_DIVX = xyes ]; then
 604     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 605     AC_TRY_COMPILE([
 606 #include <decore.h>
 607 #if DECORE_VERSION != 20021112
 608 #error Wrong version of divx decore libraries
 609 #endif
 610     ], [
 611 return 0;
 612     ], [
 613       HAVE_DIVX=yes
 614       AC_MSG_RESULT(yes)
 615     ], [
 616       HAVE_DIVX=no
 617       AC_MSG_RESULT(no)
 618       AC_MSG_WARN([Wrong version of divx4linux installed])
 619     ])
 620   fi
 621   LIBS="-lm"
 622   if test x$HAVE_DIVX = xyes; then
 623     AC_CHECK_LIB(divxencore, encore, , [
 624       AC_MSG_WARN([Divx4linux encore libs not found])
 625       HAVE_DIVX=no
 626     ])
 627   fi
 628   if test x$HAVE_DIVX = xyes; then
 629     AC_CHECK_LIB(divxdecore, decore, , [
 630       AC_MSG_WARN([Divx4linux decore libs not found])
 631       HAVE_DIVX=no
 632   ])
 633   fi
 634   if test x$HAVE_DIVX = xyes; then
 635     DIVXENC_LIBS="-ldivxencore -lm"
 636     DIVXDEC_LIBS="-ldivxdecore -lm"
 637     AC_SUBST(DIVXENC_LIBS)
 638     AC_SUBST(DIVXDEC_LIBS)
 639   fi
 640 ])
 641
 642 dnl *** dvdnav for resindvd ***
 643 USE_DVDNAV=$BUILD_EXPERIMENTAL
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 645 AG_GST_CHECK_FEATURE(DVDNAV, [dvdnav library], resindvd, [
 646   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 647   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 648   AG_GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 649   if test x"$HAVE_DVDNAV" = x"yes"; then
 650     dnl check version
 651     DVDNAV_VERSION=`dvdnav-config --version|head -n 1|sed 's/^.*) //'|sed 's/ (.*)//'`
 652     DVDNAV_MAJOR=`echo $DVDNAV_VERSION | cut -d. -f1 | sed s/[a-zA-Z\-].*//g`
 653     DVDNAV_MINOR=`echo $DVDNAV_VERSION | cut -d. -f2 | sed s/[a-zA-Z\-].*//g`
 654     DVDNAV_MICRO=`echo $DVDNAV_VERSION | cut -d. -f3 | sed s/[a-zA-Z\-].*//g`
 655     if [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 656        [[ "$DVDNAV_MINOR" -lt "1" ]]; then
 657       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 658       HAVE_DVDNAV="no"
 659     elif [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 660          [[ "$DVDNAV_MINOR" -eq "1" ]] && \
 661          [[ "$DVDNAV_MICRO" -lt "7" ]]; then
 662       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 663       HAVE_DVDNAV="no"
 664     elif [[ "$DVDNAV_MAJOR" -eq "0" ]]; then
 665       AC_DEFINE(DVDNAV_OLD, 1, [Define if an old libdvdnav is used])
 666     fi
 667   fi
 668   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 669 ])
 670
 671 dnl *** METADATA ***
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_METADATA, true)
 673 AG_GST_CHECK_FEATURE(METADATA, [METADATA muxer and demuxer], metadata, [
 674   HAVE_METADATA="no"
 675   PKG_CHECK_MODULES(EXIF, libexif >= 0.6.16, HAVE_EXIF="yes", [
 676     HAVE_EXIF="no"
 677   ])
 678   PKG_CHECK_MODULES(IPTC, libiptcdata >= 1.0.2, HAVE_IPTC="yes", [
 679     HAVE_IPTC="no"
 680   ])
 681   PKG_CHECK_MODULES(XMP, exempi-2.0, HAVE_XMP="yes", [
 682     HAVE_XMP="no"
 683   ])
 684   PKG_CHECK_MODULES(XMP_1_99_5, exempi-2.0 >= 1.99.5, XMP_CFLAGS="-DXMP_1_99_5 $XMP_CFLAGS", AC_MSG_RESULT(no))
 685   if test x$HAVE_EXIF = xyes; then
 686     METADATA_CFLAGS="-DHAVE_EXIF $EXIF_CFLAGS $METADATA_CFLAGS"
 687     METADATA_LIBS="$EXIF_LIBS $METADATA_LIBS -lm"
 688     HAVE_METADATA="yes"
 689   fi
 690   if test x$HAVE_IPTC = xyes; then
 691     METADATA_CFLAGS="-DHAVE_IPTC $IPTC_CFLAGS $METADATA_CFLAGS"
 692     METADATA_LIBS="$IPTC_LIBS $METADATA_LIBS"
 693     HAVE_METADATA="yes"
 694   fi
 695   if test x$HAVE_XMP = xyes; then
 696     METADATA_CFLAGS="-DHAVE_XMP $XMP_CFLAGS $METADATA_CFLAGS"
 697     METADATA_LIBS="$XMP_LIBS $METADATA_LIBS"
 698     HAVE_METADATA="yes"
 699   fi
 700   if test x$HAVE_METADATA = xno; then
 701     AC_MSG_WARN(no of metadata libraries (exif, iptc or xmp) found)
 702   fi
 703   dnl metadata plugin will parse whole chunks anyway
 704   HAVE_METADATA="yes"
 705   AC_SUBST(METADATA_CFLAGS)
 706   AC_SUBST(METADATA_LIBS)
 707 ])
 708
 709 dnl **** Free AAC Encoder (FAAC) ****
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 711 AG_GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 712   AG_GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h,
 713     FAAC_LIBS="-lfaac -lm")
 714   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 715   AC_SUBST(FAAC_LIBS)
 716 ])
 717
 718 dnl **** Free AAC Decoder (FAAD) ****
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 720 AG_GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 721   HAVE_FAAD="yes"
 722   AG_GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h,
 723     FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 724   if test $HAVE_FAAD = "no"; then
 725     AG_GST_CHECK_LIBHEADER(FAAD, faad, NeAACDecOpen, -lm, neaacdec.h,
 726       [ FAAD_LIBS="-lfaad -lm"
 727                 AC_DEFINE(FAAD_IS_NEAAC, 1, [Define if AAC is using new api prefix])
 728           ],
 729           HAVE_FAAD="no",)
 730   fi
 731   if test $HAVE_FAAD = "yes"; then
 732     AC_MSG_CHECKING([Checking for FAAD >= 2.0])
 733     AC_TRY_COMPILE([#include <faad.h>], [
 734         #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 735         #error Not faad2
 736         #else
 737         /* Release candidate of 2.0 is not good enough for us. This field
 738          * was added only in 2.0 final and does not exist in 2.0-RC3 */
 739         faacDecConfiguration conf; conf.dontUpSampleImplicitSBR = 1;
 740         #endif
 741     ], [
 742       HAVE_FAAD="yes"
 743       AC_MSG_RESULT(yes)
 744     ], [
 745       HAVE_FAAD="no"
 746       AC_MSG_RESULT(no)
 747     ])
 748   fi
 749   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 750   AC_SUBST(FAAD_LIBS)
 751   AC_SUBST(FAAD_IS_NEAAC)
 752 ])
 753
 754 dnl *** fbdev ***
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_FBDEV, true)
 756 AG_GST_CHECK_FEATURE(FBDEV, [linux framebuffer], fbdevsink, [
 757   if test "x$HAVE_FBDEV" != "xyes"; then
 758     AC_CHECK_HEADER([linux/fb.h], HAVE_FBDEV=yes, HAVE_FBDEV=no)
 759   fi
 760 ])
 761
 762 dnl *** gsm ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 764 AG_GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 765   AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 766   if test $HAVE_GSM != "yes"; then
 767     AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 768     if test $HAVE_GSM = "yes"; then
 769       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 770     fi
 771   fi
 772   AC_SUBST(GSM_LIBS)
 773 ])
 774
 775 dnl *** ivorbis ***
 776 dnl AM_PATH_IVORBIS only takes two options
 777 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 778 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 779   IVORBIS_LIBS=
 780   IVORBIS_CFLAGS=
 781   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 782     [IVORBIS_LIBS=-lvorbisidec
 783      HAVE_IVORBIS=yes
 784      case $host in
 785      arm-*-*)
 786        IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 787      esac
 788     ],
 789     HAVE_IVORBIS=no)
 790   AC_SUBST(IVORBIS_LIBS)
 791   AC_SUBST(IVORBIS_CFLAGS)
 792 ])
 793
 794 dnl *** Jack ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 796 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 797   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 798   AC_SUBST(JACK_CFLAGS)
 799   AC_SUBST(JACK_LIBS)
 800 ])
 801
 802 dnl *** ladspa ***
 803 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 804 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 805   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 806   save_cflags="$CFLAGS"
 807   CFLAGS="$CFLAGS -D_GNU_SOURCE"
 808
 809   AC_CHECK_LIB(dl, dlopen,
 810     LADSPA_LIBS="-ldl",
 811     HAVE_LADSPA="no")
 812   CFLAGS="$save_cflags"
 813 ])
 814 AC_SUBST(LADSPA_LIBS)
 815
 816 dnl *** libmms ***
 817 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBMMS, true)
 818 AG_GST_CHECK_FEATURE(LIBMMS, [mms protocol library], libmms, [
 819   dnl check with pkg-config first
 820   PKG_CHECK_MODULES(LIBMMS, libmms >= 0.2, HAVE_LIBMMS="yes", [
 821     HAVE_LIBMMS="no"
 822     AC_MSG_RESULT(no)
 823   ])
 824 ])
 825 AC_SUBST(LIBMMS_LIBS)
 826
 827 dnl *** mjpegtools version info ***
 828 dnl some may prefer older version (given quirks above)
 829 dnl hm, no version info seems available within mjpegtools headers
 830 dnl and API really moves along
 831 echo
 832 PKG_CHECK_EXISTS(mjpegtools >= 1.6.1.93 mjpegtools < 1.8.0, [
 833   mjpegtools_api=10601
 834 ], [
 835   PKG_CHECK_EXISTS(mjpegtools >= 1.8.0 mjpegtools < 1.9.0, [
 836     mjpegtools_api=10800
 837   ], [
 838     PKG_CHECK_MODULES(MJPEG, mjpegtools >= 1.9.0, [
 839       dnl logging API changed in release candidates
 840       OLD_CFLAGS="$CFLAGS"
 841       OLD_LIBS="$LIBS"
 842       CFLAGS="$MJPEG_CFLAGS"
 843       LIBS="$LIBS $MJPEG_LIBS -lmjpegutils -lm -lpthread"
 844       AC_CHECK_FUNC(mjpeg_loglev_t, [
 845         mjpegtools_api=10903
 846         ], [
 847         mjpegtools_api=10900
 848         ])
 849       CFLAGS="$OLD_CFLAGS"
 850       LIBS="$OLD_LIBS"
 851     ], [
 852       mjpegtools_api=0
 853     ])
 854   ])
 855 ])
 856 AC_DEFINE_UNQUOTED(GST_MJPEGTOOLS_API, $mjpegtools_api,
 857   [mjpegtools API evolution])
 858
 859 dnl *** mpeg2enc ***
 860 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
 861 AG_GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
 862   HAVE_MPEG2ENC="no"
 863   dnl we require a c++ compiler for this one
 864   if [ test x$HAVE_CXX = xyes ]; then
 865     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
 866     dnl since many distros include mjpegtools specifically without mplex
 867     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
 868     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
 869       dnl HACK because mpeg2enc 1.8.0 header files have a spurious 'include config.h'
 870       touch config.h
 871       dnl switch over to c++ to test things
 872       AC_LANG_CPLUSPLUS
 873       OLD_CPPFLAGS="$CPPFLAGS"
 874       dnl HACK as above
 875       CPPFLAGS_GOOD="$CPPFLAGS $MPEG2ENC_CFLAGS"
 876       CPPFLAGS="$CPPFLAGS_GOOD -I."
 877       dnl check headers
 878       mpeg2enc_headers_ok=no
 879       AC_CHECK_HEADER([mpeg2encoder.hh], [
 880         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
 881         OLD_LIBS="$LIBS"
 882         LIBS="$LIBS $MPEG2ENC_LIBS"
 883         AC_MSG_CHECKING([for valid mpeg2enc objects])
 884         AC_TRY_RUN([
 885           #include <mpeg2encoder.hh>
 886           #include <mpeg2encoptions.hh>
 887
 888           int
 889           main (int   argc,
 890                 char *argv[])
 891           {
 892             MPEG2EncOptions *options = new MPEG2EncOptions ();
 893             MPEG2Encoder *encoder = new MPEG2Encoder (*options);
 894             return 0;
 895           }
 896         ],[
 897           AC_MSG_RESULT(yes)
 898           dnl so far so good, let's check more things:
 899           dnl mjpegtools-1.8.0 does not install the required
 900           dnl mpeg2syntaxcodes.h header by default, and a new release
 901           dnl is not in sight, so check for this oversight in case
 902           dnl distros or folks have fixed this themselves
 903           if test "$mjpegtools_api" -ge "10800"; then
 904             AC_CHECK_HEADER([mpeg2syntaxcodes.h], [
 905                 mpeg2enc_headers_ok=yes
 906               ], [
 907                 mpeg2enc_headers_ok=no
 908               ])
 909           else
 910             mpeg2enc_headers_ok=yes
 911           fi
 912           if test "x$mpeg2enc_headers_ok" = "xyes"; then
 913             HAVE_MPEG2ENC="yes"
 914           fi
 915           CPP_FLAGS="$CPPFLAGS_GOOD"
 916           AC_SUBST(MPEG2ENC_CFLAGS)
 917           AC_SUBST(MPEG2ENC_LIBS)
 918         ], [
 919           AC_MSG_RESULT(no)
 920         ])
 921         LIBS="$OLD_LIBS"
 922       ])
 923
 924       CPPFLAGS="$OLD_CPPFLAGS"
 925       AC_LANG_C
 926     ], [
 927       HAVE_MPEG2ENC="no"
 928     ])
 929   fi
 930 ])
 931
 932 dnl *** mplex ***
 933 translit(dnm, m, l) AM_CONDITIONAL(USE_MPLEX, true)
 934 AG_GST_CHECK_FEATURE(MPLEX, [mplex], mplex, [
 935   HAVE_MPLEX="no"
 936   dnl we require a c++ compiler for this one
 937   if [ test x$HAVE_CXX = xyes ]; then
 938     dnl libmplex was first included in mjpegtools-1.6.2-rc4 (1.6.1.93)
 939     dnl since many distros include mjpegtools specifically without mplex
 940     dnl and mpeg2enc, we check for mplex on its own, too.
 941     dnl libmplex < 1.9rc? has fuzzy ABI, valgrind and other problems
 942     PKG_CHECK_MODULES(MPLEX, mjpegtools >= 1.9.0, [
 943       dnl switch over to c++ to test things
 944       AC_LANG_CPLUSPLUS
 945       OLD_CPPFLAGS="$CPPFLAGS"
 946       CPPFLAGS="$CPPFLAGS $MPLEX_CFLAGS"
 947       AC_CHECK_HEADER(interact.hpp, [
 948         MPLEX_LIBS="$MPLEX_LIBS -lmplex2 -lm"
 949         OLD_LIBS="$LIBS"
 950         LIBS="$LIBS $MPLEX_LIBS"
 951         dnl older libmplex uses off_t SegmentSize (), which leads to fuzzy ABI;
 952         dnl don't want this here
 953         AC_MSG_CHECKING([for valid mplex objects])
 954         AC_TRY_RUN([
 955
 956 #include <interact.hpp>
 957 #include <outputstrm.hpp>
 958 #include <multiplexor.hpp>
 959 int
 960 main (int   argc,
 961       char *argv[])
 962 {
 963   class TestOutputStream : public OutputStream {
 964   public:
 965     TestOutputStream () : OutputStream () { }
 966     void Write (uint8_t *a, unsigned int b) { }
 967     void NextSegment () { }
 968     uint64_t SegmentSize () { }
 969     void Close () { }
 970     int Open () { }
 971 };
 972   MultiplexJob *job = new MultiplexJob ();
 973   vector<IBitStream *> inputs;
 974   job->SetupInputStreams (inputs);
 975   TestOutputStream *out = new TestOutputStream ();
 976   Multiplexor *mux = new Multiplexor(*job, *out, NULL);
 977   return 0;
 978 }
 979         ],[
 980           HAVE_MPLEX="yes"
 981           AC_SUBST(MPLEX_CFLAGS)
 982           AC_SUBST(MPLEX_LIBS)
 983           AC_MSG_RESULT(yes)
 984         ], AC_MSG_RESULT(no))
 985         LIBS="$OLD_LIBS"
 986       ])
 987       CPPFLAGS="$OLD_CPPFLAGS"
 988       AC_LANG_C
 989     ], HAVE_MPLEX="no")
 990   fi
 991 ])
 992
 993 dnl *** musepack ***
 994 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSEPACK, true)
 995 AG_GST_CHECK_FEATURE(MUSEPACK, [musepackdec], musepack, [
 996   AC_CHECK_HEADER([mpc/mpcdec.h], [
 997     HAVE_MUSEPACK="yes"
 998     MUSEPACK_LIBS="-lmpcdec"
 999     AC_SUBST(MUSEPACK_LIBS)
1000     ], [AC_CHECK_HEADER([mpcdec/mpcdec.h], [
1001       HAVE_MUSEPACK="yes"
1002       MUSEPACK_LIBS="-lmpcdec"
1003       AC_DEFINE(MPC_IS_OLD_API, 1, [Define if the old MusePack API is used])
1004       AC_SUBST(MUSEPACK_LIBS)
1005     ], [HAVE_MUSEPACK="no"])])
1006 ])
1007
1008 dnl *** musicbrainz ***
1009 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
1010 AG_GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz tag generation], musicbrainz, [
1011   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz >= 2.1.0, HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
1012   AC_SUBST(MUSICBRAINZ_CFLAGS)
1013   AC_SUBST(MUSICBRAINZ_LIBS)
1014 ])
1015
1016 dnl *** MythTV ***
1017 translit(dnm, m, l) AM_CONDITIONAL(USE_MYTHTV, true)
1018 AG_GST_CHECK_FEATURE(MYTHTV, [MythTV client plugins], mythtvsrc, [
1019   PKG_CHECK_MODULES(GMYTH, gmyth >= 0.4 gmyth <= 0.7.99, HAVE_MYTHTV="yes", [
1020     HAVE_MYTHTV="no"
1021     AC_MSG_RESULT(no)
1022   ])
1023   AC_SUBST(GMYTH_CFLAGS)
1024   AC_SUBST(GMYTH_LIBS)
1025 ])
1026
1027 dnl *** nas ***
1028 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
1029 AG_GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
1030   HAVE_NAS="no"
1031   AG_GST_CHECK_X
1032   if test "x$HAVE_X" = "xyes"; then
1033     save_cppflags=$CFLAGS
1034     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1035     AG_GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
1036       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
1037     CPPFLAGS="$save_cppflags"
1038   fi
1039   AC_SUBST(NAS_CFLAGS)
1040   AC_SUBST(NAS_LIBS)
1041 ])
1042
1043 dnl *** neon ***
1044 translit(dnm, m, l) AM_CONDITIONAL(USE_NEON, true)
1045 AG_GST_CHECK_FEATURE(NEON, [neon http client plugins], neonhttpsrc, [
1046   PKG_CHECK_MODULES(NEON, neon >= 0.26.0  neon <= 0.28.99, HAVE_NEON="yes", [
1047     HAVE_NEON="no"
1048     AC_MSG_RESULT(no)
1049   ])
1050   AC_SUBST(NEON_CFLAGS)
1051   AC_SUBST(NEON_LIBS)
1052 ])
1053
1054 dnl *** ofa ***
1055 translit(dnm, m, l) AM_CONDITIONAL(USE_OFA, true)
1056 AG_GST_CHECK_FEATURE(OFA, [ofa plugins], ofa, [
1057   PKG_CHECK_MODULES(OFA, libofa >= 0.9.3, HAVE_OFA="yes", [
1058     HAVE_OFA="no"
1059     AC_MSG_RESULT(no)
1060   ])
1061   AC_SUBST(OFA_CFLAGS)
1062   AC_SUBST(OFA_LIBS)
1063 ])
1064
1065 dnl *** timidity ***
1066 translit(dnm, m, l) AM_CONDITIONAL(USE_TIMIDITY, true)
1067 AG_GST_CHECK_FEATURE(TIMIDITY, [timidity midi soft synth plugin], timidity, [
1068   PKG_CHECK_MODULES(TIMIDITY, libtimidity, [
1069     HAVE_TIMIDITY="yes",
1070         AC_MSG_CHECKING([for timidity.cfg])
1071         timidity_cfg=""
1072         if test -r /etc/timidity.cfg; then
1073           timidity_cfg=/etc/timidity.cfg
1074         elif test -r /etc/timidity/timidity.cfg; then
1075           timidity_cfg=/etc/timidity/timidity.cfg
1076         elif test -r /usr/share/timidity/timidity.cfg; then
1077           timidity_cfg=/usr/share/timidity/timidity.cfg
1078         elif test -r /usr/local/share/timidity/timidity.cfg; then
1079           timidity_cfg=/usr/local/share/timidity/timidity.cfg
1080         fi
1081         if test "x$timidity_cfg" != "x"; then
1082           AC_MSG_RESULT($timidity_cfg)
1083       AC_DEFINE_UNQUOTED(TIMIDITY_CFG, "$timidity_cfg", [Define location of timidity.cfg])
1084         else
1085           AC_MSG_RESULT([not found])
1086         fi
1087   ], [
1088     HAVE_TIMIDITY="no"
1089     AC_MSG_RESULT(no)
1090   ])
1091   AC_SUBST(TIMIDITY_CFLAGS)
1092   AC_SUBST(TIMIDITY_LIBS)
1093 ])
1094
1095 dnl *** wildmidi ***
1096 translit(dnm, m, l) AM_CONDITIONAL(USE_WILDMIDI, true)
1097 AG_GST_CHECK_FEATURE(WILDMIDI, [wildmidi midi soft synth plugin], wildmidi, [
1098   AC_CHECK_HEADER([wildmidi_lib.h],HAVE_WILDMIDI=yes, HAVE_WILDMIDI=no)
1099   if test "x$HAVE_WILDMIDI" = "xyes"; then
1100          WILDMIDI_CFLAGS=
1101          WILDMIDI_LIBS=-lWildMidi
1102          AC_MSG_NOTICE(compiling gstWildMidi)
1103   else
1104          WILDMIDI_CFLAGS=
1105          WILDMIDI_LIBS=
1106          AC_MSG_WARN(no WildMidi library found (libWildMidi))
1107   fi
1108   AC_SUBST(WILDMIDI_CFLAGS)
1109   AC_SUBST(WILDMIDI_LIBS)
1110 ])
1111
1112 dnl *** twolame ***
1113 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
1114 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
1115   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.0, [
1116       HAVE_TWOLAME="yes"], [
1117       HAVE_TWOLAME="no"
1118       AC_MSG_RESULT(no)
1119   ])
1120   AC_SUBST(TWOLAME_CFLAGS)
1121   AC_SUBST(TWOLAME_LIBS)
1122 ])
1123
1124 dnl *** SDL ***
1125 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
1126 AG_GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink sdlaudiosink, [
1127     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
1128 ])
1129
1130 dnl *** sndfile ***
1131 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
1132 AG_GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
1133   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.16, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
1134   AC_SUBST(SNDFILE_CFLAGS)
1135   AC_SUBST(SNDFILE_LIBS)
1136 ])
1137
1138 dnl *** soundtouch ***
1139 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUNDTOUCH, true)
1140 AG_GST_CHECK_FEATURE(SOUNDTOUCH, [soundtouch plug-in], soundtouch, [
1141   PKG_CHECK_MODULES(SOUNDTOUCH, soundtouch-1.0,
1142     HAVE_SOUNDTOUCH=yes,
1143     [PKG_CHECK_MODULES(SOUNDTOUCH, libSoundTouch,
1144       HAVE_SOUNDTOUCH=yes,
1145       HAVE_SOUNDTOUCH=no)])
1146   AC_SUBST(SOUNDTOUCH_CFLAGS)
1147   AC_SUBST(SOUNDTOUCH_LIBS)
1148   if test "x$HAVE_CXX" != "xyes"; then
1149     USE_SOUNDTOUCH=false
1150     AC_MSG_NOTICE([Not building soundtouch plugin: no C++ compiler found])
1151   fi
1152 ])
1153
1154 dnl *** spc ***
1155 translit(dnm, m, l) AM_CONDITIONAL(USE_SPC, true)
1156 AG_GST_CHECK_FEATURE(SPC, [spc decoder], spc, [
1157   AC_CHECK_HEADER(openspc.h, [
1158     AC_CHECK_LIB(openspc, OSPC_Init, [
1159       SPC_LIBS="-lopenspc"
1160       AC_SUBST(SPC_LIBS)
1161       HAVE_SPC=yes
1162     ], [
1163       HAVE_SPC=no
1164     ])
1165   ], [
1166     HAVE_SPC=no
1167   ])
1168 ])
1169
1170 dnl *** swfdec ***
1171 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
1172 AG_GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
1173   PKG_CHECK_MODULES(SWFDEC, swfdec-0.3 >= 0.3.6, HAVE_SWFDEC=yes, [
1174     HAVE_SWFDEC=no
1175     AC_MSG_RESULT(no)
1176   ])
1177   AC_SUBST(SWFDEC_CFLAGS)
1178   AC_SUBST(SWFDEC_LIBS)
1179 ])
1180
1181 dnl *** theora ***
1182 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORADEC, true)
1183 AG_GST_CHECK_FEATURE(THEORADEC, [ogg theora codec], theoraexpdec, [
1184   PKG_CHECK_MODULES(THEORADEC, theoradec, HAVE_THEORADEC="yes", [
1185     HAVE_THEORADEC="no"
1186     AC_MSG_RESULT(no)
1187   ])
1188   AC_SUBST(THEORADEC_LIBS)
1189   AC_SUBST(THEORADEC_CFLAGS)
1190 ])
1191
1192 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
1193 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
1194 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
1195   AG_GST_CHECK_LIBHEADER(X264, x264, x264_nal_encode, -lm, x264.h,
1196       AC_MSG_CHECKING([for uptodate x264 API version])
1197       dnl _stdint not yet generated, so no compiling
1198       AC_TRY_CPP([
1199         #include <x264.h>
1200         #if X264_BUILD < 55
1201         #error "x264 build too old"
1202         #endif
1203       ], [
1204         AC_MSG_RESULT(yes)
1205         X264_LIBS="$LDFLAGS -lx264 -lm"
1206         X264_CFLAGS="$CFLAGS"
1207         AC_SUBST(X264_LIBS)
1208         AC_SUBST(X264_CFLAGS)
1209       ], [
1210         AC_MSG_RESULT(no)
1211         HAVE_X264=no
1212       ]))
1213 ])
1214
1215 dnl *** XVID ***
1216 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
1217 AG_GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
1218   HAVE_XVID=no
1219   AC_CHECK_HEADER(xvid.h, [
1220     OLD_LIBS="$LIBS"
1221     LIBS="-lm"
1222     AC_CHECK_LIB(xvidcore, xvid_encore, [
1223       AC_CHECK_LIB(xvidcore, xvid_decore, [
1224         AC_CHECK_LIB(xvidcore, xvid_global, [
1225           AC_MSG_CHECKING([for uptodate XviD API version])
1226           AC_TRY_COMPILE([#include <xvid.h>], [
1227               #if XVID_API_MAJOR(XVID_API) != 4
1228               #error "Incompatible XviD API version"
1229               #endif
1230           ],[ AC_MSG_RESULT(yes)
1231             XVID_LIBS="-lxvidcore -lm"
1232             AC_SUBST(XVID_LIBS)
1233             HAVE_XVID=yes
1234           ], AC_MSG_RESULT(no) )
1235         ], )
1236       ], )
1237     ], )
1238     LIBS="$OLD_LIBS"
1239   ], )
1240 ])
1241
1242 dnl *** dvb ***
1243 translit(dnm, m, l) AM_CONDITIONAL(USE_DVB, true)
1244 AG_GST_CHECK_FEATURE(DVB, [DVB Source], dvb, [
1245   AC_MSG_CHECKING([Checking for up to date dvb installation])
1246   AC_CHECK_HEADER(linux/dvb/frontend.h, [HAVE_DVB="yes"], [HAVE_DVB="no"])
1247 ])
1248
1249 dnl *** oss4 ***
1250 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
1251 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
1252   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
1253   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
1254       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
1255       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
1256 ])
1257
1258 dnl *** wininet ***
1259 translit(dnm, m, l) AM_CONDITIONAL(USE_WININET, true)
1260 AG_GST_CHECK_FEATURE(WININET, [Windows internet library], wininet, [
1261   AC_MSG_CHECKING([Checking for windows internet support])
1262   AC_CHECK_HEADERS([windows.h wininet.h],
1263       [HAVE_WININET="yes"], [HAVE_WININET="no"])
1264 ])
1265
1266 dnl *** acm ***
1267 translit(dnm, m, l) AM_CONDITIONAL(USE_ACM, true)
1268 AG_GST_CHECK_FEATURE(ACM, [Windows ACM library], acm, [
1269   AC_MSG_CHECKING([Checking for ACM support])
1270   AC_CHECK_HEADERS([windows.h msacm.h],
1271       [HAVE_ACM="yes"], [HAVE_ACM="no"])
1272 ])
1273
1274 else
1275
1276 dnl not building plugins with external dependencies,
1277 dnl but we still need to set the conditionals
1278
1279 AM_CONDITIONAL(USE_QUICKTIME, false)
1280 AM_CONDITIONAL(USE_VCD, false)
1281 AM_CONDITIONAL(USE_ALSA, false)
1282 AM_CONDITIONAL(USE_AMRWB, false)
1283 AM_CONDITIONAL(USE_APEXSINK, false)
1284 AM_CONDITIONAL(USE_BZ2, false)
1285 AM_CONDITIONAL(USE_CDAUDIO, false)
1286 AM_CONDITIONAL(USE_CELT, false)
1287 AM_CONDITIONAL(USE_DC1394, false)
1288 AM_CONDITIONAL(USE_DIRECTFB, false)
1289 AM_CONDITIONAL(USE_DTS, false)
1290 AM_CONDITIONAL(USE_DIRAC, false)
1291 AM_CONDITIONAL(USE_DIVX, false)
1292 AM_CONDITIONAL(USE_DVB, false)
1293 AM_CONDITIONAL(USE_FAAC, false)
1294 AM_CONDITIONAL(USE_FAAD, false)
1295 AM_CONDITIONAL(USE_FBDEV, false)
1296 AM_CONDITIONAL(USE_GSM, false)
1297 AM_CONDITIONAL(USE_IVORBIS, false)
1298 AM_CONDITIONAL(USE_JACK, false)
1299 AM_CONDITIONAL(USE_LADSPA, false)
1300 AM_CONDITIONAL(USE_LIBMMS, false)
1301 AM_CONDITIONAL(USE_METADATA, false)
1302 AM_CONDITIONAL(USE_MPEG2ENC, false)
1303 AM_CONDITIONAL(USE_MPLEX, false)
1304 AM_CONDITIONAL(USE_MUSEPACK, false)
1305 AM_CONDITIONAL(USE_MUSICBRAINZ, false)
1306 AM_CONDITIONAL(USE_MYTHTV, false)
1307 AM_CONDITIONAL(USE_NAS, false)
1308 AM_CONDITIONAL(USE_NEON, false)
1309 AM_CONDITIONAL(USE_OFA, false)
1310 AM_CONDITIONAL(USE_OSS4, false)
1311 AM_CONDITIONAL(USE_TWOLAME, false)
1312 AM_CONDITIONAL(USE_SDL, false)
1313 AM_CONDITIONAL(USE_SNDFILE, false)
1314 AM_CONDITIONAL(USE_SOUNDTOUCH, false)
1315 AM_CONDITIONAL(USE_SPC, false)
1316 AM_CONDITIONAL(USE_SWFDEC, false)
1317 AM_CONDITIONAL(USE_THEORADEC, false)
1318 AM_CONDITIONAL(USE_TIMIDITY, false)
1319 AM_CONDITIONAL(USE_X264, false)
1320 AM_CONDITIONAL(USE_XVID, false)
1321 AM_CONDITIONAL(USE_WILDMIDI, false)
1322 AM_CONDITIONAL(USE_WININET, false)
1323 AM_CONDITIONAL(USE_ACM, false)
1324
1325 fi dnl of EXT plugins
1326
1327 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1328
1329 dnl Overview:
1330 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1331 dnl GST_*:              flags shared by built objects to link against GStreamer
1332 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1333 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
1334 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1335 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1336
1337 dnl GST_OPTION_CFLAGS
1338 if test "x$USE_DEBUG" = xyes; then
1339    PROFILE_CFLAGS="-g"
1340 fi
1341 AC_SUBST(PROFILE_CFLAGS)
1342
1343 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1344   dnl Define _only_ during CVS (not pre-releases or releases)
1345   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1346 else
1347   DEPRECATED_CFLAGS=""
1348 fi
1349 AC_SUBST(DEPRECATED_CFLAGS)
1350
1351 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1352 dnl at make time with e.g. make ERROR_CFLAGS=""
1353 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1354 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1355 AC_SUBST(GST_OPTION_CFLAGS)
1356 AC_SUBST(GST_OPTION_CXXFLAGS)
1357
1358 dnl FIXME: do we want to rename to GST_ALL_* ?
1359 dnl prefer internal headers to already installed ones
1360 dnl also add builddir include for enumtypes and marshal
1361 dnl add GST_OPTION_CFLAGS, but overridable
1362 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1363 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1364 AC_SUBST(GST_CFLAGS)
1365 AC_SUBST(GST_CXXFLAGS)
1366 AC_SUBST(GST_LIBS)
1367
1368 dnl LDFLAGS really should only contain flags, not libs - they get added before
1369 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1370 GST_ALL_LDFLAGS="-no-undefined"
1371 AC_SUBST(GST_ALL_LDFLAGS)
1372
1373 dnl this really should only contain flags, not libs - they get added before
1374 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1375 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1376 AC_SUBST(GST_PLUGIN_LDFLAGS)
1377
1378 dnl *** output files ***
1379
1380 dnl po/Makefile.in
1381
1382
1383 AC_CONFIG_FILES(
1384 Makefile
1385 gst-plugins-bad.spec
1386 gst/Makefile
1387 gst/aiffparse/Makefile
1388 gst/app/Makefile
1389 gst/bayer/Makefile
1390 gst/cdxaparse/Makefile
1391 gst/dccp/Makefile
1392 gst/deinterlace/Makefile
1393 gst/deinterlace2/Makefile
1394 gst/dvdspu/Makefile
1395 gst/festival/Makefile
1396 gst/filter/Makefile
1397 gst/flv/Makefile
1398 gst/freeze/Makefile
1399 gst/h264parse/Makefile
1400 gst/librfb/Makefile
1401 gst/modplug/Makefile
1402 gst/modplug/libmodplug/Makefile
1403 gst/mpegdemux/Makefile
1404 gst/mpegtsparse/Makefile
1405 gst/mpegtsmux/Makefile
1406 gst/mpegtsmux/tsmux/Makefile
1407 gst/mpeg4videoparse/Makefile
1408 gst/mpegvideoparse/Makefile
1409 gst/mve/Makefile
1410 gst/nsf/Makefile
1411 gst/nuvdemux/Makefile
1412 gst/pcapparse/Makefile
1413 gst/rawparse/Makefile
1414 gst/rtpmanager/Makefile
1415 gst/scaletempo/Makefile
1416 gst/sdp/Makefile
1417 gst/selector/Makefile
1418 gst/speed/Makefile
1419 gst/speexresample/Makefile
1420 gst/subenc/Makefile
1421 gst/stereo/Makefile
1422 gst/tta/Makefile
1423 gst/videosignal/Makefile
1424 gst/vmnc/Makefile
1425 gst/real/Makefile
1426 gst/y4m/Makefile
1427 gst-libs/Makefile
1428 gst-libs/gst/Makefile
1429 gst-libs/gst/app/Makefile
1430 gst-libs/gst/dshow/Makefile
1431 sys/Makefile
1432 sys/dshowdecwrapper/Makefile
1433 sys/acmenc/Makefile
1434 sys/dshowsrcwrapper/Makefile
1435 sys/dshowvideosink/Makefile
1436 sys/dvb/Makefile
1437 sys/fbdev/Makefile
1438 sys/oss4/Makefile
1439 sys/qtwrapper/Makefile
1440 sys/vcd/Makefile
1441 sys/wininet/Makefile
1442 sys/winks/Makefile
1443 sys/winscreencap/Makefile
1444 examples/Makefile
1445 examples/app/Makefile
1446 examples/directfb/Makefile
1447 examples/scaletempo/Makefile
1448 examples/switch/Makefile
1449 ext/amrwb/Makefile
1450 ext/alsaspdif/Makefile
1451 ext/apexsink/Makefile
1452 ext/bz2/Makefile
1453 ext/cdaudio/Makefile
1454 ext/celt/Makefile
1455 ext/dc1394/Makefile
1456 ext/dirac/Makefile
1457 ext/directfb/Makefile
1458 ext/divx/Makefile
1459 ext/dts/Makefile
1460 ext/metadata/Makefile
1461 ext/faac/Makefile
1462 ext/faad/Makefile
1463 ext/gsm/Makefile
1464 ext/ivorbis/Makefile
1465 ext/jack/Makefile
1466 ext/ladspa/Makefile
1467 ext/libmms/Makefile
1468 ext/Makefile
1469 ext/nas/Makefile
1470 ext/mpeg2enc/Makefile
1471 ext/mplex/Makefile
1472 ext/musepack/Makefile
1473 ext/musicbrainz/Makefile
1474 ext/mythtv/Makefile
1475 ext/neon/Makefile
1476 ext/ofa/Makefile
1477 ext/resindvd/Makefile
1478 ext/twolame/Makefile
1479 ext/sdl/Makefile
1480 ext/sndfile/Makefile
1481 ext/soundtouch/Makefile
1482 ext/spc/Makefile
1483 ext/swfdec/Makefile
1484 ext/theora/Makefile
1485 ext/timidity/Makefile
1486 ext/x264/Makefile
1487 ext/xvid/Makefile
1488 po/Makefile.in
1489 docs/Makefile
1490 docs/plugins/Makefile
1491 docs/version.entities
1492 common/Makefile
1493 common/m4/Makefile
1494 m4/Makefile
1495 tests/Makefile
1496 tests/check/Makefile
1497 tests/icles/Makefile
1498 win32/common/config.h
1499 )
1500 AC_OUTPUT
1501
1502 AG_GST_OUTPUT_PLUGINS