configure.ac

   1 AC_INIT
   2 AC_CANONICAL_TARGET([])
   3
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 dnl only use Wall or Werror if compiler is gcc.
   7 if test "x$GCC" = "xyes"; then
   8    AS_VERSION(gstreamer, GST_VERSION, 0, 4, 2, 1, GST_ERROR="-Wall", GST_ERROR="-Wall -Werror")
   9 else
  10    AS_VERSION(gstreamer, GST_VERSION, 0, 4, 2, 1, GST_ERROR="", GST_ERROR="")
  11 fi
  12
  13 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  14 AM_MAINTAINER_MODE
  15 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  16 AS_LIBTOOL(GST, 0, 0, 0, yes)
  17
  18 AC_CONFIG_SRCDIR([gst/gst.c])
  19 AM_CONFIG_HEADER(config.h)
  20
  21 dnl Add parameters for aclocal
  22 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  23 ACLOCAL="$ACLOCAL -I common/m4 $ACLOCAL_FLAGS"
  24
  25 AC_PROG_CC
  26 AM_PROG_CC_STDC
  27 AM_PROG_AS
  28 AS="${CC}"
  29 AC_ISC_POSIX
  30
  31 dnl We disable static building for development, for time savings
  32 dnl *NOTE*: dnl this line before release, so release does static too
  33 dnl AM_DISABLE_STATIC
  34
  35 AC_HEADER_STDC([])
  36
  37
  38 dnl ##############################
  39 dnl # Do automated configuration #
  40 dnl ##############################
  41
  42 dnl Check for tools:
  43 dnl ================
  44
  45 dnl allow for different autotools
  46 AS_AUTOTOOLS_ALTERNATE()
  47
  48 dnl modify pkg-config path
  49 AC_ARG_WITH(pkg-config-path,
  50    AC_HELP_STRING([--with-pkg-config-path],
  51                   [colon-separated list of pkg-config(1) dirs]),
  52    [export PKG_CONFIG_PATH=${withval}])
  53
  54 GST_DOC()
  55 GST_ARCH()
  56
  57 dnl we require bison for building of some of the marshal files
  58 dnl FIXME: check if AC_PROG_YACC is suitable here
  59 AC_PATH_PROG(BISON_PATH, bison, no)
  60 if test x$BISON_PATH = xno; then
  61   AC_MSG_ERROR(Could not find bison)
  62 fi
  63
  64 dnl we require flex for building the parser
  65 dnl FIXME: check if AC_PROG_LEX is suitable here
  66 AC_PATH_PROG(FLEX_PATH, flex, no)
  67 if test x$FLEX_PATH = xno; then
  68   AC_MSG_ERROR(Could not find flex)
  69 fi
  70
  71 dnl
  72 dnl We should really use AC_SYS_LARGEFILE, but the problem is
  73 dnl many of the plugins don't include "config.h".  To assure
  74 dnl binary compatibility, it is necessary that all gstreamer
  75 dnl code be compiled with the same sizeof(off_t), so we use
  76 dnl the following crude hack.
  77 dnl
  78
  79 dnl
  80 dnl GST_CFLAGS are split up as GST_EXT_CFLAGS and GST_INT_CFLAGS
  81 dnl same for libs
  82 dnl this is so we can make GST_CFLAGS for external modules available
  83 dnl without mixing in internal (uninstalled) CFLAGS
  84 dnl
  85
  86 AC_MSG_CHECKING(for large file support)
  87 AC_TRY_RUN([
  88 #define _LARGEFILE_SOURCE
  89 #define _FILE_OFFSET_BITS 64
  90 #include <sys/types.h>
  91 int main () { return !(sizeof(off_t) == 8); }
  92 ],
  93 [
  94 AC_MSG_RESULT(yes)
  95 GST_EXT_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
  96 ],
  97 [
  98 AC_MSG_RESULT(no)
  99 ],
 100 [
 101 AC_MSG_RESULT(no)
 102 ])
 103
 104 dnl Check for essential libraries first:
 105 dnl ====================================
 106
 107 dnl === GLib 2 ===
 108 dnl Minimum required version of GLib2
 109 dnl required for compilation without warnings
 110 GLIB2_REQ="2.0.1"
 111 AC_SUBST(GLIB2_REQ)
 112
 113 dnl Check for glib2
 114 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,
 115   HAVE_GLIB2=yes,HAVE_GLIB2=no)
 116 GLIB_LIBS=$GLIB2_LIBS
 117 GLIB_CFLAGS=$GLIB2_CFLAGS
 118 AC_SUBST(GLIB_LIBS)
 119 AC_SUBST(GLIB_CFLAGS)
 120
 121 if test "x$HAVE_GLIB2" = "xno"; then
 122   AC_MSG_ERROR([GStreamer requires GLib 2.0 to compile.])
 123 fi
 124
 125 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 126 AC_SUBST(GST_PKG_DEPS)
 127
 128 dnl === libxml 2 ===
 129 dnl Minimum required version of libxml2
 130 LIBXML2_REQ="2.4.0"
 131 AC_SUBST(LIBXML2_REQ)
 132
 133 dnl check for libxml2
 134 GST_LIBXML2_CHECK()
 135
 136 dnl popt checks
 137 GST_CHECK_LIBHEADER(POPT, popt, poptStrippedArgv,, popt.h, POPT_LIBS="-lpopt",
 138   AC_MSG_ERROR([popt 1.6.1 or newer is required to build gstreamer. You can
 139                 download the latest version from
 140                 ftp://people.redhat.com/sopwith/popt/])
 141 )
 142 AC_MSG_NOTICE(Checking for POPT_TABLEEND)
 143 AC_TRY_RUN([
 144 #include <popt.h>
 145 int main ()
 146 {
 147 #ifndef POPT_TABLEEND
 148   return 1;
 149 #else
 150   return 0;
 151 #endif
 152 }
 153 ],, [
 154   dnl it failed
 155   AC_MSG_ERROR([popt 1.6.1 or newer is required to build gstreamer. You can
 156                 download the latest version from
 157                 ftp://people.redhat.com/sopwith/popt/])
 158 ])
 159
 160 dnl Check for atomic.h
 161 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 162 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 163 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 164 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 165 if test x$HAVE_ATOMIC_H = xyes; then
 166   AC_TRY_RUN([
 167 #include "asm/atomic.h"
 168 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 169   ],, [
 170     # Not successful
 171     if test x$HAVE_ATOMIC_H = xyes; then
 172       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 173     fi
 174     HAVE_ATOMIC_H=no
 175   ], [
 176     # Cross compiling
 177     AC_MSG_RESULT(yes)
 178     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 179   ])
 180 fi
 181
 182 dnl
 183 dnl Check for functions
 184 dnl
 185 AC_MSG_CHECKING(whether $GCC implements __func__)
 186 AC_CACHE_VAL(have_func,
 187 [AC_TRY_LINK([#include <stdio.h>],[printf("%s", __func__);],
 188 have_func=yes,
 189 have_func=no)])
 190 AC_MSG_RESULT($have_func)
 191 if test "$have_func" = yes; then
 192        AC_DEFINE(HAVE_FUNC,1,[defined if gcc have HAVE_FUNC)])
 193 else
 194        AC_MSG_CHECKING(whether $GCC implements __PRETTY_FUNCTION__)
 195        AC_CACHE_VAL(have_pretty_function,
 196        [AC_TRY_LINK([#include <stdio.h>],[printf("%s", __PRETTY_FUNCTION__);],
 197        have_pretty_function=yes,
 198        have_pretty_function=no)])
 199        AC_MSG_RESULT($have_pretty_function)
 200        if test "$have_pretty_function" = yes; then
 201                AC_DEFINE(HAVE_PRETTY_FUNCTION,1,[defined if gcc have HAVE_PRETTY_FUNCTION)])
 202        else
 203                AC_MSG_CHECKING(whether $GCC implements __FUNCTION__)
 204                AC_CACHE_VAL(have_function,
 205                [AC_TRY_LINK([#include <stdio.h>],[printf("%s", __FUNCTION__);],
 206                have_function=yes,
 207                have_function=no)])
 208                AC_MSG_RESULT($have_function)
 209                if test "$have_function" = yes; then
 210                        AC_DEFINE(HAVE_FUNCTION,1,[defined if gcc have HAVE_FUNCTION)])
 211                fi
 212        fi
 213 fi
 214
 215 dnl ######################################################################
 216 dnl # Check command line parameters, and set shell variables accordingly #
 217 dnl ######################################################################
 218
 219 dnl FIXME: simplify all this down using a few m4 macros
 220
 221 AC_ARG_ENABLE(libmmx,
 222 AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
 223 [case "${enableval}" in
 224   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 225   no)  USE_LIBMMX=no ;;
 226   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 227 esac],
 228 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 229
 230 AC_ARG_ENABLE(atomic,
 231 AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 232 [case "${enableval}" in
 233   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 234   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 235   no)  USE_ATOMIC_H=no;;
 236   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 237 esac],
 238 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 239
 240 AC_ARG_ENABLE(plugin-builddir,
 241 AC_HELP_STRING([--enable-plugin-builddir],[allow tests/demos to use non-installed plugins]),
 242 [case "${enableval}" in
 243   yes) PLUGINS_USE_BUILDDIR=yes ;;
 244   no)  PLUGINS_USE_BUILDDIR=no ;;
 245   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 246 esac],
 247 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 248
 249 GST_DEBUGINFO
 250
 251 AC_ARG_ENABLE(profiling,
 252 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 253 [case "${enableval}" in
 254   yes) USE_PROFILING=yes ;;
 255   no)  UES_PROFILING=no ;;
 256   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 257 esac],
 258 [USE_PROFILING=no]) dnl Default value
 259
 260 dnl set up a configuration dir
 261 GST_CONFIG_DIR=${sysconfdir}/gstreamer
 262 AC_ARG_WITH(configdir,
 263 AC_HELP_STRING([--with-configdir],[specify path to use for configuration files]),
 264 [case "${withval}" in
 265   yes) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 266   no) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 267   *) GST_CONFIG_DIR="${withval}" ;;
 268 esac],
 269 [:]) dnl Default value
 270
 271 AS_AC_EXPAND(GST_CONFIG_DIR, $GST_CONFIG_DIR)
 272 AC_MSG_NOTICE(Using $GST_CONFIG_DIR as configuration dir)
 273
 274
 275 dnl use a cache dir for storing element registry info.
 276 dnl default to building registry in the source tree if we are enabling plugin build dir
 277 if test "x$PLUGINS_USE_BUILDDIR" = "xyes"; then
 278   GST_CACHE_DIR=`pwd`
 279 else
 280   dnl ${localstatedir} points to PREFIX/var
 281   GST_CACHE_DIR=${localstatedir}/cache/gstreamer
 282 fi
 283 AC_ARG_WITH(cachedir,
 284 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 285 [case "${withval}" in
 286   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 287   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 288   *) GST_CACHE_DIR="${withval}" ;;
 289 esac],
 290 [:]) dnl Default value
 291
 292 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 293 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 294
 295
 296 dnl building of tests
 297 AC_ARG_ENABLE(tests,
 298 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 299 [case "${enableval}" in
 300   yes) BUILD_TESTS=yes ;;
 301   no)  BUILD_TESTS=no ;;
 302   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 303 esac],
 304 [BUILD_TESTS=yes]) dnl Default value
 305 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 306
 307 dnl tests known to fail
 308 AC_ARG_ENABLE(failing-tests,
 309 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 310 [case "${enableval}" in
 311   yes) BUILD_FAILING_TESTS=yes ;;
 312   no)  BUILD_FAILING_TESTS=no ;;
 313   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 314 esac],
 315 [BUILD_FAILING_TESTS=no]) dnl Default value
 316 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 317 if test x$BUILD_FAILING_TESTS = xyes; then
 318   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 319 else
 320   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 321 fi
 322
 323 AC_ARG_ENABLE(examples,
 324 AC_HELP_STRING([--disable-examples],[disable building examples]),
 325 [case "${enableval}" in
 326   yes) BUILD_EXAMPLES=yes ;;
 327   no)  BUILD_EXAMPLES=no ;;
 328   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 329 esac],
 330 [BUILD_EXAMPLES=yes]) dnl Default value
 331 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 332
 333 dnl Next, check for the optional components:
 334 dnl ========================================
 335
 336 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_LOADSAVE, true)
 337 GST_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
 338 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TYPEFIND, true)
 339 GST_SUBSYSTEM_DISABLE(TYPEFIND,[typefind plugin],)
 340 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_AUTOPLUG, true)
 341 GST_SUBSYSTEM_DISABLE(AUTOPLUG,[autoplugger subsystem])
 342 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PARSE, true)
 343 GST_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
 344 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TRACE, true)
 345 GST_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 346 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_REGISTRY, true)
 347 GST_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 348
 349 GST_EXT_CFLAGS="$GST_EXT_CFLAGS $GST_SUBSYSTEM_DISABLE_DEFINES"
 350
 351 dnl ################################################
 352 dnl # Set defines according to variables set above #
 353 dnl ################################################
 354
 355
 356 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 357 dnl HAVE_ and it is likely to be easier to stick with the old name
 358 if test "x$USE_LIBMMX" = xyes; then
 359   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 360 fi
 361
 362 if test "x$USE_ATOMIC_H" = xyes; then
 363   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 364 fi
 365
 366 dnl test if we have pthread_attr_setstack; if not use the older calls
 367 AC_CHECK_LIB(pthread, pthread_attr_setstack,
 368    AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACK, 1,
 369              [Defined if libpthread has pthread_attr_setstack ()]))
 370
 371 dnl test if we have posix_memalign; FreeBSD doesn't
 372 AC_CHECK_FUNC(posix_memalign,
 373    AC_DEFINE(HAVE_POSIX_MEMALIGN, 1,
 374              [Defined if we have posix_memalign ()]))
 375
 376 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 377   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 378 fi
 379
 380 if test "x$USE_DEBUG" = xyes; then
 381    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 382 fi
 383
 384 if test "x$USE_PROFILING" = xyes; then
 385 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 386   FOMIT_FRAME_POINTER=""
 387 else
 388   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 389 fi
 390
 391 dnl
 392 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 393 dnl
 394
 395 dnl #############################
 396 dnl # Set automake conditionals #
 397 dnl #############################
 398
 399 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 400 dnl HAVE_ and it is likely to be easier to stick with the old name
 401 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 402
 403 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 404 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 405
 406 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
 407
 408
 409 dnl ############################
 410 dnl # Set up some more defines #
 411 dnl ############################
 412
 413 dnl Set location of configuration dir.
 414 AC_DEFINE_UNQUOTED(GST_CONFIG_DIR, "$GST_CONFIG_DIR", [Define the configuration directory])
 415 AC_SUBST(GST_CONFIG_DIR)
 416
 417 dnl Set location of registry dir.
 418 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Define the registry directory])
 419 AC_SUBST(GST_CACHE_DIR)
 420
 421 dnl Set location of plugin directory
 422 if test "x${prefix}" = "xNONE"; then
 423   PLUGINS_DIR=${ac_default_prefix}/lib/gst
 424 else
 425   PLUGINS_DIR=${prefix}/lib/gst
 426 fi
 427 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 428 AC_SUBST(PLUGINS_DIR)
 429
 430 dnl Set location of uninstalled plugin directory
 431 PLUGINS_BUILDDIR=`pwd`
 432 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR, "$PLUGINS_BUILDDIR", [Define the uninstalled plugin directory])
 433 AC_SUBST(PLUGINS_BUILDDIR)
 434
 435 dnl since glib and xml are package deps, there's no need to include their cflags
 436 dnl in the pkg-config file
 437
 438 dnl for pkg-config
 439 GST_PKG_CFLAGS=$GST_EXT_CFLAGS
 440 GST_PKG_LIBS=$GST_EXT_LIBS
 441 AC_SUBST(GST_PKG_CFLAGS)
 442 AC_SUBST(GST_PKG_LIBS)
 443
 444 dnl finalize _CFLAGS and _LIBS
 445 dnl add GLIB and XML if necessary to EXT_*
 446 GST_CFLAGS="$GST_EXT_CFLAGS $XML_CFLAGS $GLIB_CFLAGS"
 447 GST_LIBS="$GST_EXT_LIBS $XML_LIBS $GLIB_LIBS -lpopt"
 448
 449 dnl Private vars for libgst only
 450 LIBGST_LIBS="$GST_LIBS"
 451 LIBGST_CFLAGS="$GST_CFLAGS -I\$(top_srcdir) $GST_ERROR"
 452 AC_SUBST(LIBGST_LIBS)
 453 AC_SUBST(LIBGST_CFLAGS)
 454
 455 dnl Vars for everyone else
 456 GST_INT_LIBS="\$(top_builddir)/gst/libgstreamer.la"
 457 GST_INT_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)/include"
 458
 459 AC_SUBST(GST_CFLAGS, "$LIBGST_CFLAGS $GST_INT_CFLAGS")
 460 AC_SUBST(GST_LIBS, "$LIBGST_LIBS $GST_INT_LIBS")
 461
 462 GST_PLUGIN_LDFLAGS='-module -avoid-version'
 463 AC_SUBST(GST_PLUGIN_LDFLAGS)
 464
 465 AC_CONFIG_SUBDIRS(libs/ext/cothreads)
 466
 467 dnl ##################################################
 468 dnl # deps for examples from manual                  #
 469 dnl ##################################################
 470
 471 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 472                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 473 AC_SUBST(LIBGNOMEUI_CFLAGS)
 474 AC_SUBST(LIBGNOMEUI_LIBS)
 475 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 476
 477 dnl ##################################################
 478 dnl # Prepare informative messages to display at end #
 479 dnl ##################################################
 480
 481 infomessages=
 482
 483 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 484   infomessages="$infomessages
 485 *** Warning: You have configured using the --enable-plugin-builddir option.
 486
 487 This option is for development purposes only: binaries built with
 488 it should be used with code in the build tree only.  To build an
 489 installable version, use ./configure without the --enable-plugin-builddir
 490 option.  Note that the autogen.sh script supplies the plugin builddir
 491 option automatically -- run ./autogen.sh --disable-plugin-buildddir to make
 492 an installable build.
 493
 494 "
 495 fi
 496
 497 dnl #########################
 498 dnl # Make the output files #
 499 dnl #########################
 500
 501 dnl libs/ext/Makefile
 502 AC_OUTPUT(
 503 Makefile
 504 include/Makefile
 505 gst/Makefile
 506 gst/gstversion.h
 507 gst/autoplug/Makefile
 508 gst/elements/Makefile
 509 gst/parse/Makefile
 510 gst/schedulers/Makefile
 511 gst/types/Makefile
 512 gst/registries/Makefile
 513 libs/Makefile
 514 libs/gst/Makefile
 515 libs/gst/bytestream/Makefile
 516 libs/gst/getbits/Makefile
 517 libs/gst/putbits/Makefile
 518 libs/gst/control/Makefile
 519 libs/ext/Makefile
 520 tests/Makefile
 521 tests/bufspeed/Makefile
 522 tests/memchunk/Makefile
 523 tests/muxing/Makefile
 524 tests/seeking/Makefile
 525 tests/sched/Makefile
 526 tests/threadstate/Makefile
 527 testsuite/Makefile
 528 testsuite/bytestream/Makefile
 529 testsuite/caps/Makefile
 530 testsuite/cleanup/Makefile
 531 testsuite/clock/Makefile
 532 testsuite/dynparams/Makefile
 533 testsuite/elements/Makefile
 534 testsuite/plugin/Makefile
 535 testsuite/refcounting/Makefile
 536 testsuite/threads/Makefile
 537 examples/Makefile
 538 examples/autoplug/Makefile
 539 examples/cutter/Makefile
 540 examples/helloworld/Makefile
 541 examples/helloworld2/Makefile
 542 examples/launch/Makefile
 543 examples/manual/Makefile
 544 examples/mixer/Makefile
 545 examples/pingpong/Makefile
 546 examples/plugins/Makefile
 547 examples/queue/Makefile
 548 examples/queue2/Makefile
 549 examples/queue3/Makefile
 550 examples/queue4/Makefile
 551 examples/thread/Makefile
 552 examples/typefind/Makefile
 553 examples/xml/Makefile
 554 tools/Makefile
 555 docs/Makefile
 556 docs/devhelp/Makefile
 557 docs/devhelp/html2xml.py
 558 docs/faq/Makefile
 559 docs/gst/Makefile
 560 docs/gst/gstreamer.types
 561 docs/libs/Makefile
 562 docs/manual/Makefile
 563 docs/pwg/Makefile
 564 docs/plugins/Makefile
 565 docs/plugins/gstreamer-plugins.types
 566 docs/xsl/Makefile
 567 stamp.h
 568 gstreamer.pc
 569 gstreamer-uninstalled.pc
 570 gstreamer.spec,
 571 echo "$infomessages", infomessages="$infomessages"
 572 )