configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.9.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 901, 0, 901)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  93 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  94 if test "x$GST_DISABLE_PARSE" = xyes; then
  95   AC_DEFINE(GST_DISABLE_PARSE, 1,
  96     [Define if pipeline parsing code is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  99 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 100 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 101   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 102     [Define if option parsing is disabled])
 103 fi
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[historic tracing subsystem])
 105 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 106 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 107 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 108 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 109 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 110 dnl define a substitution to use in docs/gst/gstreamer.types
 111 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 112 then
 113   GST_REGISTRY_DOC_TYPES="%"
 114 else
 115   GST_REGISTRY_DOC_TYPES=
 116 fi
 117 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 118 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 119 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 120
 121 AG_GST_ARG_DEBUG
 122 AG_GST_ARG_PROFILING
 123 AG_GST_ARG_VALGRIND
 124 AG_GST_ARG_GCOV
 125
 126 AG_GST_ARG_EXAMPLES
 127
 128 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 129 AG_GST_ARG_WITH_PACKAGE_NAME
 130 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 131
 132 AG_GST_PKG_CONFIG_PATH
 133
 134 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 135   ["${srcdir}/gstreamer.doap"],
 136   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 137
 138 dnl check for bash completion
 139 AC_ARG_WITH([bash-completion-dir],
 140     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 141         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 142     [],
 143     [with_bash_completion_dir=yes])
 144
 145 if test "x$with_bash_completion_dir" = "xyes"
 146 then
 147     extra_args=
 148
 149     if test "x$prefix" != "xNONE"
 150     then
 151         extra_args="--define-variable=prefix=\"$prefix\""
 152     fi
 153
 154     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 155         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 156         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 157     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 158         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 159         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 160 else
 161     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 162     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 163 fi
 164
 165 AC_SUBST([BASH_COMPLETION_DIR])
 166 AC_SUBST([BASH_HELPERS_DIR])
 167 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 168
 169 dnl build static plugins or not
 170 AC_MSG_CHECKING([whether to build static plugins or not])
 171 AC_ARG_ENABLE(
 172   static-plugins,
 173   AC_HELP_STRING(
 174     [--enable-static-plugins],
 175     [build static plugins @<:@default=no@:>@]),
 176   [AS_CASE(
 177     [$enableval], [no], [], [yes], [],
 178     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 179   [enable_static_plugins=no])
 180 AC_MSG_RESULT([$enable_static_plugins])
 181 if test "x$enable_static_plugins" = xyes; then
 182   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 183     [Define if static plugins should be built])
 184   GST_PLUGIN_LIBTOOLFLAGS=""
 185 else
 186   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 187 fi
 188 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 189 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 190
 191 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 192 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 193 if test x$enable_static = xyes -a x$enable_shared = xno; then
 194   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 195 fi
 196
 197 dnl building of tests
 198 AC_ARG_ENABLE(tests,
 199   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 200   [
 201     case "${enableval}" in
 202       yes) BUILD_TESTS=yes ;;
 203       no)  BUILD_TESTS=no ;;
 204       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 205     esac
 206   ],
 207 [BUILD_TESTS=yes]) dnl Default value
 208 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 209
 210 dnl tests known to fail
 211 AC_ARG_ENABLE(failing-tests,
 212   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 213   [
 214     case "${enableval}" in
 215       yes) BUILD_FAILING_TESTS=yes ;;
 216       no)  BUILD_FAILING_TESTS=no ;;
 217       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 218     esac
 219   ],
 220   [BUILD_FAILING_TESTS=no]) dnl Default value
 221 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 222 if test x$BUILD_FAILING_TESTS = xyes; then
 223   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 224 else
 225   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 226 fi
 227
 228 dnl building of benchmarks
 229 AC_ARG_ENABLE(benchmarks,
 230   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 231   [
 232     case "${enableval}" in
 233       yes) BUILD_BENCHMARKS=yes ;;
 234       no)  BUILD_BENCHMARKS=no ;;
 235       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 236     esac
 237   ],
 238 [BUILD_BENCHMARKS=yes]) dnl Default value
 239 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 240
 241 dnl building of tools
 242 AC_ARG_ENABLE(tools,
 243   AS_HELP_STRING([--disable-tools],[disable building tools]),
 244   [
 245     case "${enableval}" in
 246       yes) BUILD_TOOLS=yes ;;
 247       no)  BUILD_TOOLS=no ;;
 248       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 249     esac
 250   ],
 251 [BUILD_TOOLS=yes]) dnl Default value
 252 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 253
 254 dnl poison destroyed objects
 255 AC_ARG_ENABLE(poisoning,
 256   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 257   [
 258     case "${enableval}" in
 259       yes) USE_POISONING=yes ;;
 260       no)  USE_POISONING=no ;;
 261       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 262     esac
 263   ],
 264   [USE_POISONING=no]) dnl Default value
 265 if test "x$USE_POISONING" = xyes; then
 266   AC_DEFINE(USE_POISONING, 1,
 267     [Define if we should poison deallocated memory])
 268 fi
 269
 270 dnl PTP support parts
 271 AC_MSG_CHECKING([whether PTP support can be enabled])
 272 case "$host_os" in
 273   *android*)
 274     dnl Can't run on Android because of permissions
 275     HAVE_PTP=no
 276     ;;
 277   mingw*|pw32*|cygwin*)
 278     dnl Not ported to Windows yet
 279     HAVE_PTP=no
 280     ;;
 281   darwin*)
 282     dnl Can't run on iOS because of permissions
 283     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 284     ;;
 285   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 286     HAVE_PTP=yes
 287     ;;
 288   *)
 289     HAVE_PTP=no
 290     ;;
 291 esac
 292 AC_MSG_RESULT([$HAVE_PTP])
 293
 294 dnl user/group to change to in gst-ptp-helper
 295 AC_ARG_WITH([ptp-helper-setuid-user],
 296   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 297   [
 298     if test "x$withval" != "x"
 299     then
 300       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 301     fi
 302   ], []
 303 )
 304
 305 dnl group/group to change to in gst-ptp-helper
 306 AC_ARG_WITH([ptp-helper-setuid-group],
 307   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 308   [
 309     if test "x$withval" != "x"
 310     then
 311       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 312     fi
 313   ], []
 314 )
 315
 316 AC_ARG_WITH(
 317   ptp-helper-permissions,
 318   AC_HELP_STRING(
 319     [--with-ptp-helper-permissions],
 320     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 321     [],
 322     [with_ptp_helper_permissions=auto])
 323
 324 gst_ptp_have_cap=no
 325 AG_GST_CHECK_LIBHEADER(CAP, cap,
 326                        cap_init, ,
 327                        sys/capability.h,
 328                        CAP_LIBS="-lcap"
 329                        AC_SUBST(CAP_LIBS)
 330                        gst_ptp_have_cap=yes)
 331
 332 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 333
 334 if test "x$HAVE_PTP" = "xyes"; then
 335 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 336
 337 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 338 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 339     [[
 340         #include <sys/ioctl.h>
 341         #include <net/if.h>
 342     ]],
 343     [[
 344         struct ifreq ifr;
 345         struct ifconf ifc;
 346         ioctl(0, SIOCGIFCONF, &ifc);
 347         ioctl(0, SIOCGIFFLAGS, &ifr);
 348         ioctl(0, SIOCGIFHWADDR, &ifr);
 349         int dummy = ifr.ifr_hwaddr.sa_data[0];
 350     ]])], [
 351         AC_MSG_RESULT(yes)
 352         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 353     ], [
 354         AC_MSG_RESULT(no)
 355 ])
 356
 357 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 358 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 359     [[
 360         #include <ifaddrs.h>
 361         #include <net/if.h>
 362         #include <net/if_dl.h>
 363     ]],
 364     [[
 365         struct ifaddrs *ifaddr;
 366         getifaddrs(&ifaddr);
 367         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 368     ]])], [
 369         AC_MSG_RESULT(yes)
 370         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 371     ], [
 372         AC_MSG_RESULT(no)
 373     ])
 374
 375 AC_MSG_CHECKING([how to install gst-ptp-helper])
 376 if test "x$with_ptp_helper_permissions" = "xauto"; then
 377     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 378         with_ptp_helper_permissions="capabilities"
 379     else
 380         with_ptp_helper_permissions="setuid-root"
 381     fi
 382 fi
 383 AC_MSG_RESULT([$with_ptp_helper_permissions])
 384
 385 case "$with_ptp_helper_permissions" in
 386   none)
 387     ;;
 388   setuid-root)
 389      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 390         [Use setuid-root for permissions in PTP helper])
 391     ;;
 392   capabilities)
 393      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 394         [Use capabilities for permissions in PTP helper])
 395     ;;
 396   *)
 397     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 398     ;;
 399 esac
 400
 401 fi
 402
 403 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 404 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 405 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 406
 407 dnl *** checks for platform ***
 408
 409 dnl * hardware/architecture *
 410
 411 dnl common/m4/gst-arch.m4
 412 dnl check CPU type
 413 AG_GST_ARCH
 414 dnl substitution for win32/common/config.h
 415 HOST_CPU=$host_cpu
 416 AC_SUBST(HOST_CPU)
 417
 418 dnl common/m4/gst-arch.m4
 419 dnl check for unaligned access
 420 AG_GST_UNALIGNED_ACCESS
 421 dnl create a configure variable for gst/gstconfig.h
 422 if test x${as_cv_unaligned_access} = xyes ; then
 423   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 424 else
 425   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 426 fi
 427 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 428
 429 dnl check for platform specific settings
 430 AG_GST_PLATFORM
 431
 432 dnl * software *
 433
 434 dnl check for large file support
 435 dnl affected plugins must include config.h
 436 AC_SYS_LARGEFILE
 437
 438 dnl *** checks for programs ***
 439
 440 dnl find a compiler
 441 AC_PROG_CC
 442 AC_PROG_CC_STDC
 443
 444 dnl check if the compiler supports '-c' and '-o' options
 445 AM_PROG_CC_C_O
 446
 447 dnl find an assembler
 448 AM_PROG_AS
 449
 450 dnl determine if c++ is available on this system
 451 AC_PROG_CXX
 452 dnl CXX may be set to some default even if no c++ compiler is available
 453 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 454 AC_LANG_PUSH([C++])
 455 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 456 AC_LANG_POP([C++])
 457 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 458 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 459
 460 dnl Perl is used in building documentation and in the version checks
 461 AC_PATH_PROG(PERL_PATH, perl, no)
 462 if test x$PERL_PATH = xno; then
 463   AC_MSG_ERROR(Could not find perl)
 464 fi
 465
 466 dnl we require flex and bison for building the parser
 467 if test "x$GST_DISABLE_PARSE" != xyes; then
 468   AG_GST_BISON_CHECK
 469   AG_GST_FLEX_CHECK
 470 fi
 471
 472 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 473 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 474
 475 dnl check for gobject-introspection
 476 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 477
 478 dnl check for documentation tools
 479 AG_GST_DOCBOOK_CHECK
 480 GTK_DOC_CHECK([1.12])
 481 AG_GST_PLUGIN_DOCS([1.12])
 482
 483 dnl *** checks for libraries ***
 484
 485 dnl check for libm, for sin()
 486 LT_LIB_M
 487 AC_SUBST(LIBM)
 488
 489 dnl *** checks for header files ***
 490
 491 dnl check if we have ANSI C header files
 492 AC_HEADER_STDC
 493
 494 dnl Check for ucontext.h
 495 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 496
 497 dnl Check for sys/socket.h
 498 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 499 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 500
 501 dnl check for sys/times.h for tests/examples/adapter/
 502 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 503 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 504 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 505
 506 dnl Check for process.h for getpid() on win32
 507 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 508
 509 dnl Check for sys/utsname.h for uname
 510 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 511
 512 dnl Check for stdio_ext.f for __fbufsize
 513 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 514
 515 dnl check for pthreads
 516 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 517 dnl which later checks use in their test code
 518 AX_PTHREAD()
 519 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 520
 521 dnl check for sys/prctl for setting thread name on Linux
 522 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 523
 524 dnl check for pthread_setname_np(const char*)
 525 dnl which is present on OS X 10.6, iOS 3.2 and above
 526 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 527 AC_LINK_IFELSE(
 528     [AC_LANG_PROGRAM(
 529         [#include <pthread.h>],
 530         [pthread_setname_np("example")])],
 531     [AC_MSG_RESULT(yes)
 532      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 533         [Have function pthread_setname_np(const char*)])],
 534     [AC_MSG_RESULT(no)])
 535
 536 dnl check for sys/uio.h for writev()
 537 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 538
 539 dnl Check for valgrind.h
 540 dnl separate from HAVE_VALGRIND because you can have the program, but not
 541 dnl the dev package
 542 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 543
 544 dnl used in gst/gstpoll.c
 545 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 546 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 547 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 548   WIN32_LIBS="-lws2_32"
 549   AC_SUBST(WIN32_LIBS)
 550 fi
 551
 552 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 553 if test "x$BUILD_TESTS" = "xyes"; then
 554   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 555                          __gmpz_init_set_d, ,
 556                          gmp.h,
 557                          GMP_LIBS="-lgmp"
 558                          AC_SUBST(GMP_LIBS)
 559                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 560   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 561                          gsl_rng_uniform_int, -lgslcblas,
 562                          gsl/gsl_rng.h,
 563                          GSL_LIBS="-lgsl -lgslcblas"
 564                          AC_SUBST(GSL_LIBS)
 565                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 566 fi
 567
 568 dnl *** checks for types/defines ***
 569
 570 dnl *** checks for structures ***
 571
 572 dnl *** checks for compiler characteristics ***
 573
 574 dnl check if the compiler supports __uint128_t (gcc)
 575 dnl Actually check for 128-bit division, since that's what we use
 576 dnl uint128_t for.
 577 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 578     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 579       static __uint128_t v1 = 100;
 580       static __uint128_t v2 = 10;
 581       static __uint128_t u;
 582       u = v1 / v2;
 583     ]])],[
 584       gst_cv_uint128_t=yes
 585     ],[
 586       gst_cv_uint128_t=no
 587     ])
 588 )
 589 if test x$gst_cv_uint128_t = xyes; then
 590   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 591 fi
 592
 593 dnl *** checking for tm_gmtoff ***
 594 AC_MSG_CHECKING([for tm_gmtoff])
 595 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 596         #include <time.h>
 597         int main(void) {
 598           struct tm t;
 599           t.tm_gmtoff = 0;
 600           exit(0);
 601         }]])],
 602   [have_tm_gmtoff=yes
 603    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 604   [have_tm_gmtoff=no],
 605   [have_tm_gmtoff="no (cross compiling)"])
 606 AC_MSG_RESULT($have_tm_gmtoff)
 607
 608
 609 dnl *** checks for library functions ***
 610
 611 AC_CHECK_FUNCS([strcasestr])
 612
 613 AC_CHECK_FUNCS([gmtime_r])
 614 AC_CHECK_FUNCS([localtime_r])
 615 AC_CHECK_FUNCS([sigaction])
 616 AC_CHECK_FUNCS([getrusage])
 617 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 618 AC_CHECK_HEADERS([sys/resource.h])
 619
 620 dnl check for fseeko()
 621 AC_FUNC_FSEEKO
 622 dnl check for ftello()
 623 AC_CHECK_FUNCS([ftello])
 624
 625 AC_CHECK_FUNCS([fgetpos])
 626 AC_CHECK_FUNCS([fsetpos])
 627
 628 dnl check for poll(), ppoll() and pselect()
 629 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 630 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 631 AC_CHECK_FUNCS([poll])
 632 AC_CHECK_FUNCS([ppoll])
 633 AC_CHECK_FUNCS([pselect])
 634
 635 dnl check for socketpair()
 636 AC_CHECK_FUNC(socketpair, [], [
 637   AC_CHECK_LIB(socket, socketpair, [
 638     SOCKET_LIBS="-lsocket"
 639     AC_SUBST(SOCKET_LIBS)
 640   ])
 641 ])
 642
 643 dnl ****************************************
 644 dnl *** GLib POLL* compatibility defines ***
 645 dnl ****************************************
 646
 647 AC_MSG_CHECKING([for broken poll])
 648 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 649         #include <stdlib.h>
 650         #include <fcntl.h>
 651         #ifdef HAVE_SYS_POLL_H
 652         #include <sys/poll.h>
 653         #endif
 654         #ifdef HAVE_POLL_H
 655         #include <poll.h>
 656         #endif
 657         int main(void) {
 658           struct pollfd fds[1];
 659           int fd;
 660           fd = open("/dev/null", 1);
 661           fds[0].fd = fd;
 662           fds[0].events = POLLIN;
 663           fds[0].revents = 0;
 664           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 665                 exit(1);  /* Does not work for devices -- fail */
 666           }
 667           exit(0);
 668         }]])],
 669   [broken_poll=no],
 670   [broken_poll=yes
 671    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 672   [broken_poll="no (cross compiling)"])
 673 AC_MSG_RESULT($broken_poll)
 674
 675 dnl check for mmap()
 676 AC_FUNC_MMAP
 677 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 678
 679 dnl check for posix_memalign(), getpagesize()
 680 AC_CHECK_FUNCS([posix_memalign])
 681 AC_CHECK_FUNCS([getpagesize])
 682
 683 dnl Check for POSIX timers
 684 AC_CHECK_FUNCS(clock_gettime, [], [
 685   AC_CHECK_LIB(rt, clock_gettime, [
 686     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 687     LIBS="$LIBS -lrt"
 688   ], [
 689     AC_CHECK_LIB(pthread, clock_gettime, [
 690       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 691       LIBS="$LIBS -lpthread"
 692     ])
 693   ])
 694 ])
 695
 696 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 697     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 698 #include <time.h>
 699 #ifdef HAVE_UNISTD_H
 700 #include <unistd.h>
 701 #endif
 702     ]], [[
 703 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 704 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 705 #endif
 706     ]])],[
 707       gst_cv_posix_timers=yes
 708     ],[
 709       gst_cv_posix_timers=no
 710     ])
 711 )
 712
 713 if test "$gst_cv_posix_timers" = "yes"; then
 714   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 715   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 716 else
 717   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 718 fi
 719 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 720 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 721
 722 dnl Check for posix signals
 723 AC_CHECK_FUNC(signal, [
 724   AC_CHECK_HEADERS([signal.h], [
 725     AC_DEFINE(HAVE_POSIX_SIGNALS,1,[Have posix signals])
 726   ], [], [])
 727 ])
 728
 729 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 730     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 731 #include <time.h>
 732 #ifdef HAVE_UNISTD_H
 733 #include <unistd.h>
 734 #endif
 735     ]], [[
 736 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 737 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 738 #endif
 739     ]])],[
 740       gst_cv_monotonic_clock=yes
 741     ],[
 742       gst_cv_monotonic_clock=no
 743     ])
 744 )
 745
 746 if test "$gst_cv_monotonic_clock" = "yes"; then
 747   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 748   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 749 else
 750   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 751 fi
 752 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 753 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 754
 755 dnl Check for a way to display the function name in debug output
 756 AG_GST_CHECK_FUNCTION
 757
 758 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 759 save_cflags="$CFLAGS"
 760 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 761 AC_CHECK_LIB(dl, dladdr,
 762    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 763    LIBS="$LIBS -ldl")
 764 CFLAGS="$save_cflags"
 765
 766 dnl Check printf stuff
 767 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 768   AC_TYPE_LONG_LONG_INT
 769   AC_TYPE_UNSIGNED_LONG_LONG_INT
 770
 771   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 772     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 773   fi
 774
 775   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 776   gl_AC_HEADER_INTTYPES_H
 777
 778   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 779   gl_AC_HEADER_STDINT_H
 780
 781   AC_CHECK_TYPES(ptrdiff_t)
 782
 783   AC_TYPE_INTMAX_T
 784   AC_TYPE_SIZE_T
 785 fi
 786
 787 dnl *** checks for dependency libraries ***
 788
 789 dnl GLib
 790 GLIB_REQ=2.40.0
 791 AG_GST_GLIB_CHECK([$GLIB_REQ])
 792
 793 dnl Check for documentation xrefs
 794 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 795 AC_SUBST(GLIB_PREFIX)
 796
 797 dnl GTK is optional and only used in examples
 798 HAVE_GTK=no
 799 GTK_REQ=3.10
 800 if test "x$BUILD_EXAMPLES" = "xyes"; then
 801   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 802   AC_SUBST(GTK_LIBS)
 803   AC_SUBST(GTK_CFLAGS)
 804 fi
 805 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 806
 807 dnl building of unit test libraries
 808 AC_ARG_ENABLE(check,
 809   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 810   [
 811     case "${enableval}" in
 812       yes) BUILD_CHECK=yes ;;
 813       no)  BUILD_CHECK=no ;;
 814       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 815     esac
 816   ], [
 817     dnl Default value
 818     case $host_os in
 819       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 820       *) BUILD_CHECK=yes ;;
 821     esac
 822 ])
 823 dnl bit of a misnomer, but keep the conditional named like this so we don't
 824 dnl have to change too much elsewhere
 825 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 826
 827 dnl configure the desired memory alignment
 828 AC_ARG_WITH([memory-alignment],
 829   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 830   [
 831     if test "x$withval" = "xyes"
 832     then
 833       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 834     else
 835       case "${withval}" in
 836         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 837         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 838         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 839       esac
 840     fi
 841   ], [
 842     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 843   ]
 844 )
 845
 846 dnl Check for -Bsymbolic-functions linker flag used to avoid
 847 dnl intra-library PLT jumps, if available.
 848 AC_ARG_ENABLE(Bsymbolic,
 849               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 850               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 851                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 852                LDFLAGS=-Wl,-Bsymbolic-functions
 853                LIBS=
 854                AC_TRY_LINK([], [return 0],
 855                            AC_MSG_RESULT(yes)
 856                            enable_Bsymbolic=yes,
 857                            AC_MSG_RESULT(no)
 858                            enable_Bsymbolic=no)
 859                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 860
 861
 862 dnl *** set variables based on configure arguments
 863
 864 dnl set license and copyright notice
 865 GST_LICENSE="LGPL"
 866 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 867 AC_SUBST(GST_LICENSE)
 868
 869 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 870 AS_AC_EXPAND(LIBDIR, $libdir)
 871 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 872 AS_AC_EXPAND(DATADIR, $datadir)
 873 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 874
 875 dnl set location of plugin directory
 876 AG_GST_SET_PLUGINDIR
 877
 878 dnl make sure it doesn't complain about unused variables if debugging is disabled
 879 NO_WARNINGS=""
 880 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 881   NO_WARNINGS="-Wno-unused"
 882 fi
 883
 884 dnl define an ERROR_CFLAGS Makefile variable
 885 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 886
 887 dnl special warning flags for gst/printf
 888 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 889 AC_SUBST(PRINTF_CFLAGS)
 890
 891 dnl define correct level for debugging messages
 892 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 893
 894 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 895
 896 dnl Overview:
 897 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 898 dnl GST_ALL_*:          vars shared by all built objects
 899 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 900 dnl GST_OBJ_*:          additional vars to link to the core library
 901 dnl                     include GST_ALL_*
 902 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 903 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 904
 905 dnl GST_OPTION_CFLAGS
 906 if test "x$USE_DEBUG" = xyes; then
 907    PROFILE_CFLAGS="-g"
 908 fi
 909 AC_SUBST(PROFILE_CFLAGS)
 910
 911 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 912 # functionality from the API that gstreamer uses
 913 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 914 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 915   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 916   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 917 else
 918   DEPRECATED_CFLAGS=""
 919 fi
 920 AC_SUBST(DEPRECATED_CFLAGS)
 921
 922 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 923 dnl make DEPRECATED_CFLAGS=''
 924 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 925 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 926 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 927 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 928 AC_SUBST(GST_OPTION_CFLAGS)
 929 AC_SUBST(GST_OPTION_CXXFLAGS)
 930
 931 dnl GST_ALL_*
 932 dnl vars common to for all internal objects (core libs, elements, applications)
 933 dnl CFLAGS:
 934 dnl - src and build dirs need to be added because every piece that gets built
 935 dnl   will need the GStreamer source and generated headers
 936 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 937 dnl       from LibXML except for in the core library
 938 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 939 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 940
 941 dnl FIXME: check if LTLIBINTL is needed everywhere
 942 dnl I presume it is given that it contains the symbols that _() stuff maps to
 943 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 944
 945 dnl LDFLAGS really should only contain flags, not libs - they get added before
 946 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 947 GST_ALL_LDFLAGS="-no-undefined"
 948 if test "x${enable_Bsymbolic}" = "xyes"; then
 949   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 950 fi
 951
 952 AC_SUBST(GST_ALL_CFLAGS)
 953 AC_SUBST(GST_ALL_CXXFLAGS)
 954 AC_SUBST(GST_ALL_LIBS)
 955 AC_SUBST(GST_ALL_LDFLAGS)
 956
 957 dnl GST_LIB_LDFLAGS
 958 dnl linker flags shared by all libraries
 959 dnl LDFLAGS modifier defining exported symbols from built libraries
 960 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 961 AC_SUBST(GST_LIB_LDFLAGS)
 962
 963 dnl GST_OBJ_*
 964 dnl default vars for all internal objects built on libgstreamer
 965 dnl includes GST_ALL_*
 966 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
 967 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
 968 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 969 AC_SUBST(GST_OBJ_CFLAGS)
 970 AC_SUBST(GST_OBJ_CXXFLAGS)
 971 AC_SUBST(GST_OBJ_LIBS)
 972
 973 dnl GST_PLUGIN_LDFLAGS
 974 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 975 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 976 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 977
 978 dnl plugin scanner locations
 979 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 980 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 981     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 982 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 983
 984 dnl ptp helper locations
 985 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
 986 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
 987     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
 988 AC_SUBST(GST_PTP_HELPER_INSTALLED)
 989
 990 dnl things for our internal libcheck (must be called even if building
 991 dnl libcheck is disabled because it defines conditionals)
 992 AG_GST_CHECK_CHECKS
 993
 994 AC_CONFIG_FILES(
 995 Makefile
 996 data/Makefile
 997 gst/Makefile
 998 gst/gstconfig.h
 999 gst/gstversion.h
1000 gst/parse/Makefile
1001 gst/printf/Makefile
1002 libs/Makefile
1003 libs/gst/Makefile
1004 libs/gst/base/Makefile
1005 libs/gst/check/Makefile
1006 libs/gst/check/libcheck/Makefile
1007 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1008 libs/gst/controller/Makefile
1009 libs/gst/helpers/Makefile
1010 libs/gst/net/Makefile
1011 plugins/Makefile
1012 plugins/elements/Makefile
1013 plugins/tracers/Makefile
1014 po/Makefile.in
1015 tests/Makefile
1016 tests/benchmarks/Makefile
1017 tests/check/Makefile
1018 tests/misc/Makefile
1019 tests/examples/Makefile
1020 tests/examples/adapter/Makefile
1021 tests/examples/controller/Makefile
1022 tests/examples/stepping/Makefile
1023 tests/examples/helloworld/Makefile
1024 tests/examples/manual/Makefile
1025 tests/examples/memory/Makefile
1026 tests/examples/netclock/Makefile
1027 tests/examples/ptp/Makefile
1028 tests/examples/streamiddemux/Makefile
1029 tests/examples/streams/Makefile
1030 tools/Makefile
1031 common/Makefile
1032 common/m4/Makefile
1033 docs/Makefile
1034 docs/design/Makefile
1035 docs/faq/Makefile
1036 docs/gst/Makefile
1037 docs/gst/gstreamer.types
1038 docs/libs/Makefile
1039 docs/plugins/Makefile
1040 docs/manual/Makefile
1041 docs/pwg/Makefile
1042 docs/slides/Makefile
1043 docs/xsl/Makefile
1044 docs/version.entities
1045 m4/Makefile
1046 pkgconfig/Makefile
1047 stamp.h
1048 pkgconfig/gstreamer.pc
1049 pkgconfig/gstreamer-uninstalled.pc
1050 pkgconfig/gstreamer-base.pc
1051 pkgconfig/gstreamer-base-uninstalled.pc
1052 pkgconfig/gstreamer-check.pc
1053 pkgconfig/gstreamer-check-uninstalled.pc
1054 pkgconfig/gstreamer-controller.pc
1055 pkgconfig/gstreamer-controller-uninstalled.pc
1056 pkgconfig/gstreamer-net.pc
1057 pkgconfig/gstreamer-net-uninstalled.pc
1058 gstreamer.spec
1059 )
1060
1061 dnl Create the config.h file for Visual Studio builds
1062 dnl Beware of spaces and /'s in some of the shell variable contents.
1063 sed \
1064     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1065     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1066     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1067     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1068     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1069     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1070     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1071     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1072     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1073     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1074     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1075     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1076     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1077     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1078     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1079     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1080     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1081     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1082     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1083     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1084     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
1085     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1086     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1087     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
1088     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1089     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
1090     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1091     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1092     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1093     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
1094     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
1095     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1096     config.h.in >win32/common/config.h-new
1097
1098 AC_OUTPUT
1099
1100 dnl negate for output
1101 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1102 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1103 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1104 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1105 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
1106 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
1107 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1108 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1109
1110 echo "
1111
1112 Configuration
1113         Version                    : ${VERSION}
1114         Source code location       : ${srcdir}
1115         Prefix                     : ${prefix}
1116         Compiler                   : ${CC}
1117         Package name               : ${GST_PACKAGE_NAME}
1118         Package origin             : ${GST_PACKAGE_ORIGIN}
1119
1120         Documentation (manuals)    : ${enable_docbook}
1121         Documentation (API)        : ${enable_gtk_doc}
1122
1123         Debug logging              : ${enable_gst_debug}
1124         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1125         Command-line parser        : ${enable_parse}
1126         Option parsing in gst_init : ${enable_option_parsing}
1127         Historic tracing subsystem : ${enable_trace}
1128         Allocation tracing         : ${enable_alloc_trace}
1129         Plugin registry            : ${enable_registry}
1130         Plugin support             : ${enable_plugin}
1131         Static plugins             : ${enable_static_plugins}
1132         Unit testing support       : ${BUILD_CHECK}
1133         PTP clock support          : ${HAVE_PTP}
1134
1135         Debug                      : ${USE_DEBUG}
1136         Profiling                  : ${USE_PROFILING}
1137
1138         Building benchmarks        : ${BUILD_BENCHMARKS}
1139         Building examples          : ${BUILD_EXAMPLES}
1140         Building test apps         : ${BUILD_TESTS}
1141         Building tests that fail   : ${BUILD_FAILING_TESTS}
1142         Building tools             : ${BUILD_TOOLS}
1143 "