configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Bad Plug-ins, 0.10.5.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-plugins-bad)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([docs/plugins/gst-plugins-bad-plugins-docs.sgml])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$GST_PLUGINS_BAD_VERSION_MAJOR.$GST_PLUGINS_BAD_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl FIXME: this macro doesn't actually work;
  40 dnl the generated libtool script has no support for the listed tags.
  41 dnl So this needs to be fixed first if we want to use this
  42 dnl AS_LIBTOOL_TAGS([CXX])
  43
  44 AM_PROG_LIBTOOL
  45
  46 dnl *** required versions of GStreamer stuff ***
  47 dnl *** remove rtpmanager stuff below when this is updated
  48 GST_REQ=0.10.17
  49 GSTPB_REQ=0.10.17
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION([0.11.5])
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-bad-$GST_MAJORMINOR])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DEBUG
  68 AG_GST_ARG_PROFILING
  69 AG_GST_ARG_VALGRIND
  70 AG_GST_ARG_GCOV
  71
  72 AG_GST_ARG_EXAMPLES
  73
  74 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  75 AG_GST_ARG_WITH_PACKAGE_NAME
  76 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  77
  78 AG_GST_ARG_EXAMPLES
  79
  80 dnl these are all the gst plug-ins, compilable without additional libs
  81 GST_PLUGINS_ALL="\
  82   app \
  83   bayer \
  84   cdxaparse \
  85   deinterlace \
  86   dvdspu \
  87   festival \
  88   filter \
  89   flv \
  90   freeze \
  91   h264parse \
  92   interleave \
  93   librfb \
  94   modplug \
  95   mpegtsparse \
  96   mpeg4videoparse \
  97   mpegvideoparse \
  98   mve \
  99   nsf \
 100   nuvdemux \
 101   rawparse \
 102   real \
 103   replaygain \
 104   rtpmanager \
 105   sdp \
 106   selector \
 107   speexresample \
 108   speed \
 109   stereo \
 110   tta \
 111   videosignal \
 112   vmnc \
 113   y4m \
 114   "
 115
 116 AC_SUBST(GST_PLUGINS_ALL)
 117
 118 AG_GST_ARG_WITH_PLUGINS
 119
 120 AG_GST_ARG_ENABLE_EXTERNAL
 121
 122 AG_GST_ARG_ENABLE_EXPERIMENTAL
 123
 124 dnl *** checks for platform ***
 125
 126 dnl * hardware/architecture *
 127
 128 dnl common/m4/gst-arch.m4
 129 dnl check CPU type
 130 AG_GST_ARCH
 131
 132 dnl Determine endianness
 133 AC_C_BIGENDIAN
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139
 140 dnl determine c++ compiler
 141 AC_PROG_CXX
 142 dnl determine if c++ is available on this system
 143 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 144
 145 AS_PROG_OBJC
 146
 147 dnl check if the compiler supports '-c' and '-o' options
 148 AM_PROG_CC_C_O
 149
 150 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 151 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 152
 153 dnl check for documentation tools
 154 GTK_DOC_CHECK([1.3])
 155 AS_PATH_PYTHON([2.1])
 156 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 157
 158 dnl *** checks for libraries ***
 159
 160 dnl check for libm, for sin() etc.
 161 AC_CHECK_LIBM
 162 AC_SUBST(LIBM)
 163
 164 dnl *** checks for header files ***
 165
 166 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 167 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 168
 169 if test "x$HAVE_UNISTD_H" != "xyes"; then
 170   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 171 fi
 172
 173 dnl used by ext/dts
 174 AX_CREATE_STDINT_H
 175
 176 dnl *** checks for types/defines ***
 177
 178 dnl *** checks for structures ***
 179
 180 dnl *** checks for compiler characteristics ***
 181
 182 dnl *** checks for library functions ***
 183
 184 dnl *** checks for dependency libraries ***
 185
 186 dnl GLib is required
 187 AG_GST_GLIB_CHECK([2.6])
 188
 189 dnl liboil is required
 190 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 191 if test "x${HAVE_LIBOIL}" != xyes ; then
 192   AC_ERROR([liboil-0.3.8 or later is required])
 193 fi
 194
 195 dnl checks for gstreamer
 196 dnl uninstalled is selected preferentially -- see pkg-config(1)
 197 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 198 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 199 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 200 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 201 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 202 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], no)
 203 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 204
 205 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 206 AC_SUBST(GSTPB_PLUGINS_DIR)
 207 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 208
 209 dnl Check for documentation xrefs
 210 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 211 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 212 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 213 AC_SUBST(GLIB_PREFIX)
 214 AC_SUBST(GST_PREFIX)
 215 AC_SUBST(GSTPB_PREFIX)
 216
 217 dnl GTK is optional and used in examples
 218 HAVE_GTK=NO
 219 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 220 if test "x$HAVE_GTK_22" = "xyes"; then
 221   HAVE_GTK=yes
 222   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 223   AC_SUBST(GTK_VERSION)
 224   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 225   AC_SUBST(GTK_BASE_DIR)
 226   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 227   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 228   AC_SUBST(GTK_BASE_DIR)
 229 else
 230   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 231 fi
 232 if test "x$HAVE_GTK_20" = "xyes"; then
 233   HAVE_GTK=yes
 234 fi
 235 GTK_CFLAGS=$GTK2_CFLAGS
 236 GTK_LIBS=$GTK2_LIBS
 237 AC_SUBST(GTK_LIBS)
 238 AC_SUBST(GTK_CFLAGS)
 239 AC_SUBST(HAVE_GTK)
 240 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 241
 242 dnl libglade is optional and only used in examples
 243 HAVE_GLADE=NO
 244 PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0, HAVE_GLADE=yes, HAVE_GLADE=no)
 245 AC_SUBST(GLADE_LIBS)
 246 AC_SUBST(GLADE_CFLAGS)
 247 AC_SUBST(HAVE_GLADE)
 248 AM_CONDITIONAL(HAVE_GLADE, test "x$HAVE_GLADE" = "xyes")
 249
 250 dnl set license and copyright notice
 251 GST_LICENSE="LGPL"
 252 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 253 AC_SUBST(GST_LICENSE)
 254
 255 dnl set location of plugin directory
 256 AG_GST_SET_PLUGINDIR
 257
 258 dnl define an ERROR_CFLAGS Makefile variable
 259 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 260
 261 dnl define correct level for debugging messages
 262 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 263
 264 dnl *** plug-ins to exclude ***
 265
 266 dnl see if we can build C++ plug-ins
 267 if test "x$HAVE_CXX" != "xyes"; then
 268   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 269   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | sed 's/modplug//g'`
 270 fi
 271
 272 dnl real plugin only works on i386 and x86_64 for the time being.
 273 if test "x$HAVE_CPU_I386" != "xyes" && test "x$HAVE_CPU_X86_64" != "xyes"; then
 274   AC_MSG_WARN([Not building real plugin, only works on 32bit and 64bit x86 platforms])
 275   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | sed 's/real//g'`
 276 fi
 277
 278 dnl disable gst plugins we might not be able to build on this
 279 dnl platform: librfb (ugly but minimally invasive)
 280 dnl FIXME: maybe move to sys, or make work with winsock2
 281 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 282 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 283
 284 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 285   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/librfb//`
 286 fi
 287
 288 AC_SUBST(GST_PLUGINS_SELECTED)
 289
 290 dnl *** sys plug-ins ***
 291
 292 dnl OpenGL
 293 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENGL, true)
 294 AG_GST_CHECK_FEATURE(OPENGL, [Open GL], glsink, [
 295   PKG_CHECK_MODULES(GL, gl >= 7.1.0, [
 296     HAVE_OPENGL="yes"
 297     AC_SUBST(GL_CFLAGS)
 298     AC_SUBST(GL_LIBS)
 299   ],[
 300     HAVE_OPENGL=no
 301     AC_MSG_RESULT(no)
 302   ])
 303 ])
 304
 305 dnl check for QuickTime
 306 translit(dnm, m, l) AM_CONDITIONAL(USE_QUICKTIME, true)
 307 AG_GST_CHECK_FEATURE(QUICKTIME, [QuickTime wrapper], qtwrapper, [
 308   AC_CHECK_HEADER(QuickTime/Movies.h, HAVE_QUICKTIME="yes", HAVE_QUICKTIME="no")
 309 ])
 310
 311 dnl check for Video CD
 312 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 313 AG_GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 314   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 315 ])
 316
 317 dnl *** ext plug-ins ***
 318 dnl keep this list sorted alphabetically !
 319
 320 if test "x$BUILD_EXTERNAL" = "xyes"; then
 321
 322 dnl *** alsa ***
 323 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 324 AG_GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 325   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 326     HAVE_ALSA="yes"
 327     AC_SUBST(ALSA_CFLAGS)
 328     AC_SUBST(ALSA_LIBS)
 329   ], [
 330     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 331   ])
 332 ])
 333
 334 dnl *** amrwb ***
 335 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 336 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwb, [
 337   AG_GST_CHECK_LIBHEADER(AMRWB, amrwb,
 338                         GP3D_IF_decode, ,
 339                         amrwb/dec.h,
 340                         AMRWB_LIBS="-lamrwb"
 341                         AC_SUBST(AMRWB_LIBS))
 342 ])
 343
 344 dnl *** BZ2 ***
 345 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 346 AG_GST_CHECK_FEATURE(BZ2, [bz2 library], bz2, [
 347   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 348   AC_SUBST(BZ2_LIBS)
 349 ])
 350
 351 #dnl *** cairo ***
 352 #translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 353 #AG_GST_CHECK_FEATURE(CAIRO, [cairo plug-in], cairo, [
 354 #  PKG_CHECK_MODULES(CAIRO, cairo >= 1.0 glitz-glx, HAVE_CAIRO=yes, [
 355 #    HAVE_CAIRO=no
 356 #    AC_MSG_RESULT(no)
 357 #  ])
 358 #  AC_SUBST(CAIRO_CFLAGS)
 359 #  AC_SUBST(CAIRO_LIBS)
 360 #])
 361
 362 dnl *** cdaudio ***
 363 translit(dnm, m, l) AM_CONDITIONAL(USE_CDAUDIO, true)
 364 AG_GST_CHECK_FEATURE(CDAUDIO, [cdaudio], cdaudio, [
 365   AG_GST_CHECK_CONFIGPROG(CDAUDIO, libcdaudio-config)
 366   AC_SUBST(CDAUDIO_CFLAGS)
 367   AC_SUBST(CDAUDIO_LIBS)
 368 ])
 369
 370
 371 dnl *** dc1394  ***
 372 translit(dnm, m, l) AM_CONDITIONAL(USE_DC1394, true)
 373 AG_GST_CHECK_FEATURE(DC1394, [libdc1394], dc1394, [
 374    PKG_CHECK_MODULES(LIBDC1394, libdc1394-2 == 2.0.0-rc5, HAVE_DC1394="yes", [
 375         HAVE_DC1394="no"
 376         AC_MSG_RESULT(no)
 377    ])
 378    AC_SUBST(LIBDC1394_CFLAGS)
 379    AC_SUBST(LIBDC1394_LIBS)
 380 ])
 381
 382
 383 dnl **** DirectFB ****
 384 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTFB, true)
 385 AG_GST_CHECK_FEATURE(DIRECTFB, [directfb], dfbvideosink , [
 386   PKG_CHECK_MODULES(DIRECTFB, directfb >= 0.9.24, HAVE_DIRECTFB="yes", [
 387     HAVE_DIRECTFB="no"
 388     AC_MSG_RESULT(no)
 389   ])
 390 ])
 391
 392 dnl *** DTS ***
 393 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
 394 AG_GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
 395   HAVE_DTS="yes"
 396   AG_GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, -lm, dts.h,
 397     DTS_LIBS="-ldts_pic -lm", HAVE_DTS="no")
 398   if test $HAVE_DTS = "no"; then
 399     AG_GST_CHECK_LIBHEADER(DTS, dca, dca_init, -lm, dts.h,
 400       DTS_LIBS="-ldca -lm")
 401   fi
 402   AC_SUBST(DTS_LIBS)
 403 ])
 404
 405 dnl *** DIVX ***
 406 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 407 AG_GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 408   HAVE_DIVX=yes
 409   AC_CHECK_HEADER(encore2.h, , [
 410     AC_MSG_WARN([Divx4linux encore headers not found])
 411     HAVE_DIVX=no
 412   ])
 413   if [ test x$HAVE_DIVX = xyes ]; then
 414     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 415     AC_TRY_COMPILE([
 416 #include <encore2.h>
 417 #if ENCORE_VERSION != 20021024
 418 #error Wrong version of divx encore libraries
 419 #endif
 420     ], [
 421 return 0;
 422     ], [
 423       HAVE_DIVX=yes
 424       AC_MSG_RESULT(yes)
 425     ], [
 426       HAVE_DIVX=no
 427       AC_MSG_RESULT(no)
 428       AC_MSG_WARN([Wrong version of divx4linux installed])
 429     ])
 430   fi
 431   if [ test x$HAVE_DIVX = xyes ]; then
 432     AC_CHECK_HEADER(decore.h, , [
 433       AC_MSG_WARN([Divx4linux decoder headers not found])
 434       HAVE_DIVX=no
 435     ])
 436   fi
 437   if [ test x$HAVE_DIVX = xyes ]; then
 438     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 439     AC_TRY_COMPILE([
 440 #include <decore.h>
 441 #if DECORE_VERSION != 20021112
 442 #error Wrong version of divx decore libraries
 443 #endif
 444     ], [
 445 return 0;
 446     ], [
 447       HAVE_DIVX=yes
 448       AC_MSG_RESULT(yes)
 449     ], [
 450       HAVE_DIVX=no
 451       AC_MSG_RESULT(no)
 452       AC_MSG_WARN([Wrong version of divx4linux installed])
 453     ])
 454   fi
 455   LIBS="-lm"
 456   if test x$HAVE_DIVX = xyes; then
 457     AC_CHECK_LIB(divxencore, encore, , [
 458       AC_MSG_WARN([Divx4linux encore libs not found])
 459       HAVE_DIVX=no
 460     ])
 461   fi
 462   if test x$HAVE_DIVX = xyes; then
 463     AC_CHECK_LIB(divxdecore, decore, , [
 464       AC_MSG_WARN([Divx4linux decore libs not found])
 465       HAVE_DIVX=no
 466   ])
 467   fi
 468   if test x$HAVE_DIVX = xyes; then
 469     DIVXENC_LIBS="-ldivxencore -lm"
 470     DIVXDEC_LIBS="-ldivxdecore -lm"
 471     AC_SUBST(DIVXENC_LIBS)
 472     AC_SUBST(DIVXDEC_LIBS)
 473   fi
 474 ])
 475
 476 dnl *** METADATA ***
 477 translit(dnm, m, l) AM_CONDITIONAL(USE_METADATA, true)
 478 AG_GST_CHECK_FEATURE(METADATA, [METADATA muxer and demuxer], metadata, [
 479   HAVE_METADATA="no"
 480   PKG_CHECK_MODULES(EXIF, libexif >= 0.6.16, HAVE_EXIF="yes", [
 481     HAVE_EXIF="no"
 482   ])
 483   PKG_CHECK_MODULES(IPTC, libiptcdata >= 1.0.2, HAVE_IPTC="yes", [
 484     HAVE_IPTC="no"
 485   ])
 486   PKG_CHECK_MODULES(XMP, exempi-2.0, HAVE_XMP="yes", [
 487     HAVE_XMP="no"
 488   ])
 489   PKG_CHECK_MODULES(XMP_1_99_5, exempi-2.0 >= 1.99.5, XMP_CFLAGS="-DXMP_1_99_5 $XMP_CFLAGS", AC_MSG_RESULT(no))
 490   if test x$HAVE_EXIF = xyes; then
 491     METADATA_CFLAGS="-DHAVE_EXIF $EXIF_CFLAGS $METADATA_CFLAGS"
 492     METADATA_LIBS="$EXIF_LIBS $METADATA_LIBS -lm"
 493     HAVE_METADATA="yes"
 494   fi
 495   if test x$HAVE_IPTC = xyes; then
 496     METADATA_CFLAGS="-DHAVE_IPTC $IPTC_CFLAGS $METADATA_CFLAGS"
 497     METADATA_LIBS="$IPTC_LIBS $METADATA_LIBS"
 498     HAVE_METADATA="yes"
 499   fi
 500   if test x$HAVE_XMP = xyes; then
 501     METADATA_CFLAGS="-DHAVE_XMP $XMP_CFLAGS $METADATA_CFLAGS"
 502     METADATA_LIBS="$XMP_LIBS $METADATA_LIBS"
 503     HAVE_METADATA="yes"
 504   fi
 505   if test x$HAVE_METADATA = xno; then
 506     AC_MSG_WARN(no of metadata libraries (exif, iptc or xmp) found)
 507   fi
 508   dnl metadata plugin will parse whole chunks anyway
 509   HAVE_METADATA="yes"
 510   AC_SUBST(METADATA_CFLAGS)
 511   AC_SUBST(METADATA_LIBS)
 512 ])
 513
 514 dnl **** Free AAC Encoder (FAAC) ****
 515 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 516 AG_GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 517   AG_GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h,
 518     FAAC_LIBS="-lfaac -lm")
 519   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 520   AC_SUBST(FAAC_LIBS)
 521 ])
 522
 523 dnl **** Free AAC Decoder (FAAD) ****
 524 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 525 AG_GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 526   HAVE_FAAD="yes"
 527   AG_GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h,
 528     FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 529   if test $HAVE_FAAD = "no"; then
 530     AG_GST_CHECK_LIBHEADER(FAAD, faad, NeAACDecOpen, -lm, neaacdec.h,
 531       [ FAAD_LIBS="-lfaad -lm"
 532                 AC_DEFINE(FAAD_IS_NEAAC, 1, [Define if AAC is using new api prefix])
 533           ],
 534           HAVE_FAAD="no",)
 535   fi
 536   if test $HAVE_FAAD = "yes"; then
 537     AC_MSG_CHECKING([Checking for FAAD >= 2.0])
 538     AC_TRY_COMPILE([#include <faad.h>], [
 539         #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 540         #error Not faad2
 541         #else
 542         /* Release candidate of 2.0 is not good enough for us. This field
 543          * was added only in 2.0 final and does not exist in 2.0-RC3 */
 544         faacDecConfiguration conf; conf.dontUpSampleImplicitSBR = 1;
 545         #endif
 546     ], [
 547       HAVE_FAAD="yes"
 548       AC_MSG_RESULT(yes)
 549     ], [
 550       HAVE_FAAD="no"
 551       AC_MSG_RESULT(no)
 552     ])
 553   fi
 554   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 555   AC_SUBST(FAAD_LIBS)
 556   AC_SUBST(FAAD_IS_NEAAC)
 557 ])
 558
 559 dnl *** fbdev ***
 560 translit(dnm, m, l) AM_CONDITIONAL(USE_FBDEV, true)
 561 AG_GST_CHECK_FEATURE(FBDEV, [linux framebuffer], fbdevsink, [
 562   if test "x$HAVE_FBDEV" != "xyes"; then
 563     AC_CHECK_HEADER([linux/fb.h], HAVE_FBDEV=yes, HAVE_FBDEV=no)
 564   fi
 565 ])
 566
 567 dnl *** gsm ***
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 569 AG_GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 570   AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 571   if test $HAVE_GSM != "yes"; then
 572     AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 573     if test $HAVE_GSM = "yes"; then
 574       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 575     fi
 576   fi
 577   AC_SUBST(GSM_LIBS)
 578 ])
 579
 580 dnl *** ivorbis ***
 581 dnl AM_PATH_IVORBIS only takes two options
 582 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 583 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 584   IVORBIS_LIBS=
 585   IVORBIS_CFLAGS=
 586   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 587     [IVORBIS_LIBS=-lvorbisidec
 588      HAVE_IVORBIS=yes
 589      case $host in
 590      arm-*-*)
 591        IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 592      esac
 593     ],
 594     HAVE_IVORBIS=no)
 595   AC_SUBST(IVORBIS_LIBS)
 596   AC_SUBST(IVORBIS_CFLAGS)
 597 ])
 598
 599 dnl *** Jack ***
 600 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 601 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 602   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 603   AC_SUBST(JACK_CFLAGS)
 604   AC_SUBST(JACK_LIBS)
 605 ])
 606
 607 dnl *** ladspa ***
 608 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 609 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 610   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 611 ])
 612
 613 dnl *** libmms ***
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBMMS, true)
 615 AG_GST_CHECK_FEATURE(LIBMMS, [mms protocol library], libmms, [
 616   dnl check with pkg-config first
 617   PKG_CHECK_MODULES(LIBMMS, libmms >= 0.2, HAVE_LIBMMS="yes", [
 618     HAVE_LIBMMS="no"
 619     AC_MSG_RESULT(no)
 620   ])
 621 ])
 622 AC_SUBST(LIBMMS_LIBS)
 623
 624 dnl *** mjpegtools version info ***
 625 dnl some may prefer older version (given quirks above)
 626 dnl hm, no version info seems available within mjpegtools headers
 627
 628 PKG_CHECK_EXISTS(mjpegtools >= 1.9.0 mjpegtools < 1.10.0, [
 629   AC_DEFINE(GST_MJPEGTOOLS_19x, 1, [mjpegtools >= 1.9.0 is used])
 630   have_mpjegtools_19x=yes
 631   ], [
 632   have_mpjegtools_19x=no])
 633
 634 PKG_CHECK_EXISTS(mjpegtools >= 1.8.0, [
 635   AC_DEFINE(GST_MJPEGTOOLS_18x, 1, [mjpegtools >= 1.8.0 is used])
 636   have_mpjegtools_18x=yes
 637   ], [
 638   have_mpjegtools_18x=no])
 639
 640 dnl *** mpeg2enc ***
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
 642 AG_GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
 643   HAVE_MPEG2ENC="no"
 644   dnl we require a c++ compiler for this one
 645   if [ test x$HAVE_CXX = xyes ]; then
 646     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
 647     dnl since many distros include mjpegtools specifically without mplex
 648     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
 649     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
 650       dnl HACK because mpeg2enc 1.8.0 header files have a spurious 'include config.h'
 651       touch config.h
 652       dnl switch over to c++ to test things
 653       AC_LANG_CPLUSPLUS
 654       OLD_CPPFLAGS="$CPPFLAGS"
 655       dnl HACK as above
 656       CPPFLAGS_GOOD="$CPPFLAGS $MPEG2ENC_CFLAGS"
 657       CPPFLAGS="$CPPFLAGS_GOOD -I."
 658       dnl check headers
 659       mpeg2enc_headers_ok=no
 660       AC_CHECK_HEADER([mpeg2encoder.hh], [
 661         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
 662         OLD_LIBS="$LIBS"
 663         LIBS="$LIBS $MPEG2ENC_LIBS"
 664         AC_MSG_CHECKING([for valid mpeg2enc objects])
 665         AC_TRY_RUN([
 666           #include <mpeg2encoder.hh>
 667           #include <mpeg2encoptions.hh>
 668
 669           int
 670           main (int   argc,
 671                 char *argv[])
 672           {
 673             MPEG2EncOptions *options = new MPEG2EncOptions ();
 674             MPEG2Encoder *encoder = new MPEG2Encoder (*options);
 675             return 0;
 676           }
 677         ],[
 678           AC_MSG_RESULT(yes)
 679           dnl so far so good, let's check more things:
 680           dnl mjpegtools-1.8.0 does not install the required
 681           dnl mpeg2syntaxcodes.h header by default, and a new release
 682           dnl is not in sight, so check for this oversight in case
 683           dnl distros or folks have fixed this themselves
 684           if test "x$have_mpjegtools_18x" = "xyes"; then
 685             AC_CHECK_HEADER([mpeg2syntaxcodes.h], [
 686                 mpeg2enc_headers_ok=yes
 687               ], [
 688                 mpeg2enc_headers_ok=no
 689               ])
 690           else
 691             mpeg2enc_headers_ok=yes
 692           fi
 693
 694           if test "x$mpeg2enc_headers_ok" = "xyes"; then
 695             HAVE_MPEG2ENC="yes"
 696           fi
 697           CPP_FLAGS="$CPPFLAGS_GOOD"
 698           AC_SUBST(MPEG2ENC_CFLAGS)
 699           AC_SUBST(MPEG2ENC_LIBS)
 700         ], [
 701           AC_MSG_RESULT(no)
 702         ])
 703         LIBS="$OLD_LIBS"
 704       ])
 705
 706       CPPFLAGS="$OLD_CPPFLAGS"
 707       AC_LANG_C
 708     ], [
 709       HAVE_MPEG2ENC="no"
 710     ])
 711   fi
 712 ])
 713
 714 dnl *** musepack ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSEPACK, true)
 716 AG_GST_CHECK_FEATURE(MUSEPACK, [musepackdec], musepack, [
 717   AC_LANG_CPLUSPLUS
 718   AC_CHECK_HEADER([mpcdec/mpcdec.h], [
 719     HAVE_MUSEPACK="yes"
 720     MUSEPACK_LIBS="-lmpcdec"
 721     AC_SUBST(MUSEPACK_LIBS)
 722     ], [HAVE_MUSEPACK="no"])
 723   AC_LANG_C
 724 ])
 725
 726 dnl *** musicbrainz ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
 728 AG_GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz tag generation], musicbrainz, [
 729   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz >= 2.1.0, HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
 730   AC_SUBST(MUSICBRAINZ_CFLAGS)
 731   AC_SUBST(MUSICBRAINZ_LIBS)
 732 ])
 733
 734 dnl *** MythTV ***
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_MYTHTV, true)
 736 AG_GST_CHECK_FEATURE(MYTHTV, [MythTV client plugins], mythtvsrc, [
 737   PKG_CHECK_MODULES(GMYTH, gmyth >= 0.4 gmyth <= 0.4.99, HAVE_MYTHTV="yes", [
 738     HAVE_MYTHTV="no"
 739     AC_MSG_RESULT(no)
 740   ])
 741   AC_SUBST(GMYTH_CFLAGS)
 742   AC_SUBST(GMYTH_LIBS)
 743 ])
 744
 745 dnl *** nas ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
 747 AG_GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
 748   HAVE_NAS="no"
 749   if test "x$HAVE_X" = "xyes"; then
 750     save_cppflags=$CFLAGS
 751     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 752     AG_GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
 753       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
 754     CPPFLAGS="$save_cppflags"
 755   fi
 756   AC_SUBST(NAS_CFLAGS)
 757   AC_SUBST(NAS_LIBS)
 758 ])
 759
 760 dnl *** neon ***
 761 translit(dnm, m, l) AM_CONDITIONAL(USE_NEON, true)
 762 AG_GST_CHECK_FEATURE(NEON, [neon http client plugins], neonhttpsrc, [
 763   PKG_CHECK_MODULES(NEON, neon >= 0.26.0  neon <= 0.27.99, HAVE_NEON="yes", [
 764     HAVE_NEON="no"
 765     AC_MSG_RESULT(no)
 766   ])
 767   AC_SUBST(NEON_CFLAGS)
 768   AC_SUBST(NEON_LIBS)
 769 ])
 770
 771 dnl *** soup ***
 772 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 773 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 774   PKG_CHECK_MODULES(SOUP, libsoup-2.4, HAVE_SOUP="yes", [
 775     HAVE_SOUP="no"
 776     AC_MSG_RESULT(no)
 777   ])
 778   AC_SUBST(SOUP_CFLAGS)
 779   AC_SUBST(SOUP_LIBS)
 780 ])
 781
 782 dnl *** timidity ***
 783 translit(dnm, m, l) AM_CONDITIONAL(USE_TIMIDITY, true)
 784 AG_GST_CHECK_FEATURE(TIMIDITY, [timidity midi soft synth plugin], timidity, [
 785   PKG_CHECK_MODULES(TIMIDITY, libtimidity, [
 786     HAVE_TIMIDITY="yes",
 787         AC_MSG_CHECKING([for timidity.cfg])
 788         timidity_cfg=""
 789         if test -r /etc/timidity.cfg; then
 790           timidity_cfg=/etc/timidity.cfg
 791         elif test -r /etc/timidity/timidity.cfg; then
 792           timidity_cfg=/etc/timidity/timidity.cfg
 793         elif test -r /usr/share/timidity/timidity.cfg; then
 794           timidity_cfg=/usr/share/timidity/timidity.cfg
 795         elif test -r /usr/local/share/timidity/timidity.cfg; then
 796           timidity_cfg=/usr/local/share/timidity/timidity.cfg
 797         fi
 798         if test "x$timidity_cfg" != "x"; then
 799           AC_MSG_RESULT($timidity_cfg)
 800       AC_DEFINE_UNQUOTED(TIMIDITY_CFG, "$timidity_cfg", [Define location of timidity.cfg])
 801         else
 802           AC_MSG_RESULT([not found])
 803         fi
 804   ], [
 805     HAVE_TIMIDITY="no"
 806     AC_MSG_RESULT(no)
 807   ])
 808   AC_SUBST(TIMIDITY_CFLAGS)
 809   AC_SUBST(TIMIDITY_LIBS)
 810 ])
 811
 812 dnl *** wildmidi ***
 813 translit(dnm, m, l) AM_CONDITIONAL(USE_WILDMIDI, true)
 814 AG_GST_CHECK_FEATURE(WILDMIDI, [wildmidi midi soft synth plugin], wildmidi, [
 815   AC_CHECK_HEADER([wildmidi_lib.h],HAVE_WILDMIDI=yes, HAVE_WILDMIDI=no)
 816   if test "x$HAVE_WILDMIDI" = "xyes"; then
 817          WILDMIDI_CFLAGS=
 818          WILDMIDI_LIBS=-lWildMidi
 819          AC_MSG_NOTICE(compiling gstWildMidi)
 820   else
 821          WILDMIDI_CFLAGS=
 822          WILDMIDI_LIBS=
 823          AC_MSG_WARN(no WildMidi library found (libWildMidi))
 824   fi
 825   AC_SUBST(WILDMIDI_CFLAGS)
 826   AC_SUBST(WILDMIDI_LIBS)
 827 ])
 828
 829 dnl *** SDL ***
 830 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
 831 AG_GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink sdlaudiosink, [
 832     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
 833 ])
 834
 835 dnl *** sndfile ***
 836 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
 837 AG_GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
 838   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.16, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
 839   AC_SUBST(SNDFILE_CFLAGS)
 840   AC_SUBST(SNDFILE_LIBS)
 841 ])
 842
 843 dnl *** soundtouch ***
 844 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUNDTOUCH, true)
 845 AG_GST_CHECK_FEATURE(SOUNDTOUCH, [soundtouch plug-in], soundtouch, [
 846   PKG_CHECK_MODULES(SOUNDTOUCH, soundtouch-1.0,
 847     HAVE_SOUNDTOUCH=yes,
 848     [PKG_CHECK_MODULES(SOUNDTOUCH, libSoundTouch,
 849       HAVE_SOUNDTOUCH=yes,
 850       HAVE_SOUNDTOUCH=no)])
 851   AC_SUBST(SOUNDTOUCH_CFLAGS)
 852   AC_SUBST(SOUNDTOUCH_LIBS)
 853   if test "x$HAVE_CXX" != "xyes"; then
 854     USE_SOUNDTOUCH=false
 855     AC_MSG_NOTICE([Not building soundtouch plugin: no C++ compiler found])
 856   fi
 857 ])
 858
 859 dnl *** spc ***
 860 translit(dnm, m, l) AM_CONDITIONAL(USE_SPC, true)
 861 AG_GST_CHECK_FEATURE(SPC, [spc decoder], spc, [
 862   AC_CHECK_HEADER(openspc.h, [
 863     AC_CHECK_LIB(openspc, OSPC_Init, [
 864       SPC_LIBS="-lopenspc"
 865       AC_SUBST(SPC_LIBS)
 866       HAVE_SPC=yes
 867     ], [
 868       HAVE_SPC=no
 869     ])
 870   ], [
 871     HAVE_SPC=no
 872   ])
 873 ])
 874
 875 dnl *** swfdec ***
 876 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
 877 AG_GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
 878   PKG_CHECK_MODULES(SWFDEC, swfdec-0.3 >= 0.3.6, HAVE_SWFDEC=yes, [
 879     HAVE_SWFDEC=no
 880     AC_MSG_RESULT(no)
 881   ])
 882   AC_SUBST(SWFDEC_CFLAGS)
 883   AC_SUBST(SWFDEC_LIBS)
 884 ])
 885
 886 dnl *** theora ***
 887 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORADEC, true)
 888 AG_GST_CHECK_FEATURE(THEORADEC, [ogg theora codec], theoraexpdec, [
 889   PKG_CHECK_MODULES(THEORADEC, theoradec, HAVE_THEORADEC="yes", [
 890     HAVE_THEORADEC="no"
 891     AC_MSG_RESULT(no)
 892   ])
 893   AC_SUBST(THEORADEC_LIBS)
 894   AC_SUBST(THEORADEC_CFLAGS)
 895 ])
 896
 897 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 898 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 899 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 900   AG_GST_CHECK_LIBHEADER(X264, x264, x264_nal_encode, -lm, x264.h,
 901       X264_LIBS="$LDFLAGS -lx264 -lm"
 902       X264_CFLAGS="$CFLAGS"
 903       AC_SUBST(X264_LIBS)
 904       AC_SUBST(X264_CFLAGS))
 905 ])
 906
 907 dnl *** XVID ***
 908 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
 909 AG_GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
 910   HAVE_XVID=no
 911   AC_CHECK_HEADER(xvid.h, [
 912     OLD_LIBS="$LIBS"
 913     LIBS="-lm"
 914     AC_CHECK_LIB(xvidcore, xvid_encore, [
 915       AC_CHECK_LIB(xvidcore, xvid_decore, [
 916         AC_CHECK_LIB(xvidcore, xvid_global, [
 917           AC_MSG_CHECKING([for uptodate XviD API version])
 918           AC_TRY_COMPILE([#include <xvid.h>], [
 919               #if XVID_API_MAJOR(XVID_API) != 4
 920               #error "Incompatible XviD API version"
 921               #endif
 922           ],[ AC_MSG_RESULT(yes)
 923             XVID_LIBS="-lxvidcore -lm"
 924             AC_SUBST(XVID_LIBS)
 925             HAVE_XVID=yes
 926           ], AC_MSG_RESULT(no) )
 927         ], )
 928       ], )
 929     ], )
 930     LIBS="$OLD_LIBS"
 931   ], )
 932 ])
 933
 934 dnl *** dvb ***
 935 translit(dnm, m, l) AM_CONDITIONAL(USE_DVB, true)
 936 AG_GST_CHECK_FEATURE(DVB, [DVB Source], dvb, [
 937   AC_MSG_CHECKING([Checking for up to date dvb installation])
 938   AC_CHECK_HEADER(linux/dvb/frontend.h, [HAVE_DVB="yes"], [HAVE_DVB="no"])
 939 ])
 940
 941 else
 942
 943 dnl not building plugins with external dependencies,
 944 dnl but we still need to set the conditionals
 945
 946 AM_CONDITIONAL(USE_OPENGL, false)
 947 AM_CONDITIONAL(USE_QUICKTIME, false)
 948 AM_CONDITIONAL(USE_VCD, false)
 949 AM_CONDITIONAL(USE_ALSA, false)
 950 AM_CONDITIONAL(USE_AMRWB, false)
 951 AM_CONDITIONAL(USE_BZ2, false)
 952 AM_CONDITIONAL(USE_CDAUDIO, false)
 953 AM_CONDITIONAL(USE_DIRECTFB, false)
 954 AM_CONDITIONAL(USE_DTS, false)
 955 AM_CONDITIONAL(USE_DIVX, false)
 956 AM_CONDITIONAL(USE_FAAC, false)
 957 AM_CONDITIONAL(USE_FAAD, false)
 958 AM_CONDITIONAL(USE_FBDEV, false)
 959 AM_CONDITIONAL(USE_GSM, false)
 960 AM_CONDITIONAL(USE_IVORBIS, false)
 961 AM_CONDITIONAL(USE_JACK, false)
 962 AM_CONDITIONAL(USE_LADSPA, false)
 963 AM_CONDITIONAL(USE_LIBMMS, false)
 964 AM_CONDITIONAL(USE_MPEG2ENC, false)
 965 AM_CONDITIONAL(USE_MUSEPACK, false)
 966 AM_CONDITIONAL(USE_MUSICBRAINZ, false)
 967 AM_CONDITIONAL(USE_MYTHTV, false)
 968 AM_CONDITIONAL(USE_NAS, false)
 969 AM_CONDITIONAL(USE_NEON, false)
 970 AM_CONDITIONAL(USE_SOUP, false)
 971 AM_CONDITIONAL(USE_SDL, false)
 972 AM_CONDITIONAL(USE_SNDFILE, false)
 973 AM_CONDITIONAL(USE_SOUNDTOUCH, false)
 974 AM_CONDITIONAL(USE_SPC, false)
 975 AM_CONDITIONAL(USE_SWFDEC, false)
 976 AM_CONDITIONAL(USE_THEORADEC, false)
 977 AM_CONDITIONAL(USE_TIMIDITY, false)
 978 AM_CONDITIONAL(USE_X264, false)
 979 AM_CONDITIONAL(USE_XVID, false)
 980 AM_CONDITIONAL(USE_WILDMIDI, false)
 981 AM_CONDITIONAL(USE_DVB, false)
 982
 983 fi dnl of EXT plugins
 984
 985 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 986
 987 dnl Overview:
 988 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 989 dnl GST_*:              flags shared by built objects to link against GStreamer
 990 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 991 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 992 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 993 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 994
 995 dnl GST_OPTION_CFLAGS
 996 if test "x$USE_DEBUG" = xyes; then
 997    PROFILE_CFLAGS="-g"
 998 fi
 999 AC_SUBST(PROFILE_CFLAGS)
1000
1001 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1002   dnl Define _only_ during CVS (not pre-releases or releases)
1003   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1004 else
1005   DEPRECATED_CFLAGS=""
1006 fi
1007 AC_SUBST(DEPRECATED_CFLAGS)
1008
1009 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
1010 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1011 AC_SUBST(GST_OPTION_CFLAGS)
1012
1013 dnl FIXME: do we want to rename to GST_ALL_* ?
1014 dnl prefer internal headers to already installed ones
1015 dnl also add builddir include for enumtypes and marshal
1016 dnl add GST_OPTION_CFLAGS, but overridable
1017 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1018 AC_SUBST(GST_CFLAGS)
1019 AC_SUBST(GST_LIBS)
1020
1021 dnl LDFLAGS really should only contain flags, not libs - they get added before
1022 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1023 GST_ALL_LDFLAGS="-no-undefined"
1024 AC_SUBST(GST_ALL_LDFLAGS)
1025
1026 dnl this really should only contain flags, not libs - they get added before
1027 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1028 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1029 AC_SUBST(GST_PLUGIN_LDFLAGS)
1030
1031 dnl *** output files ***
1032
1033 dnl po/Makefile.in
1034
1035
1036 AC_CONFIG_FILES(
1037 Makefile
1038 gst-plugins-bad.spec
1039 gst/Makefile
1040 gst/app/Makefile
1041 gst/bayer/Makefile
1042 gst/cdxaparse/Makefile
1043 gst/deinterlace/Makefile
1044 gst/dvdspu/Makefile
1045 gst/festival/Makefile
1046 gst/filter/Makefile
1047 gst/flv/Makefile
1048 gst/freeze/Makefile
1049 gst/h264parse/Makefile
1050 gst/interleave/Makefile
1051 gst/librfb/Makefile
1052 gst/modplug/Makefile
1053 gst/modplug/libmodplug/Makefile
1054 gst/mpegtsparse/Makefile
1055 gst/mpeg4videoparse/Makefile
1056 gst/mpegvideoparse/Makefile
1057 gst/mve/Makefile
1058 gst/nsf/Makefile
1059 gst/nuvdemux/Makefile
1060 gst/rawparse/Makefile
1061 gst/replaygain/Makefile
1062 gst/rtpmanager/Makefile
1063 gst/sdp/Makefile
1064 gst/selector/Makefile
1065 gst/speed/Makefile
1066 gst/speexresample/Makefile
1067 gst/stereo/Makefile
1068 gst/tta/Makefile
1069 gst/videosignal/Makefile
1070 gst/vmnc/Makefile
1071 gst/real/Makefile
1072 gst/y4m/Makefile
1073 gst-libs/Makefile
1074 gst-libs/gst/Makefile
1075 gst-libs/gst/app/Makefile
1076 sys/Makefile
1077 sys/fbdev/Makefile
1078 sys/glsink/Makefile
1079 sys/dvb/Makefile
1080 sys/qtwrapper/Makefile
1081 sys/vcd/Makefile
1082 examples/Makefile
1083 examples/app/Makefile
1084 examples/directfb/Makefile
1085 examples/switch/Makefile
1086 ext/amrwb/Makefile
1087 ext/alsaspdif/Makefile
1088 ext/bz2/Makefile
1089 ext/cdaudio/Makefile
1090 ext/dc1394/Makefile
1091 ext/directfb/Makefile
1092 ext/divx/Makefile
1093 ext/dts/Makefile
1094 ext/metadata/Makefile
1095 ext/faac/Makefile
1096 ext/faad/Makefile
1097 ext/gsm/Makefile
1098 ext/ivorbis/Makefile
1099 ext/jack/Makefile
1100 ext/ladspa/Makefile
1101 ext/libmms/Makefile
1102 ext/Makefile
1103 ext/nas/Makefile
1104 ext/mpeg2enc/Makefile
1105 ext/musepack/Makefile
1106 ext/musicbrainz/Makefile
1107 ext/mythtv/Makefile
1108 ext/neon/Makefile
1109 ext/soup/Makefile
1110 ext/sdl/Makefile
1111 ext/sndfile/Makefile
1112 ext/soundtouch/Makefile
1113 ext/spc/Makefile
1114 ext/swfdec/Makefile
1115 ext/theora/Makefile
1116 ext/timidity/Makefile
1117 ext/x264/Makefile
1118 ext/xvid/Makefile
1119 po/Makefile.in
1120 docs/Makefile
1121 docs/plugins/Makefile
1122 docs/version.entities
1123 common/Makefile
1124 common/m4/Makefile
1125 m4/Makefile
1126 tests/Makefile
1127 tests/check/Makefile
1128 tests/icles/Makefile
1129 win32/common/config.h
1130 )
1131 AC_OUTPUT
1132
1133 AG_GST_OUTPUT_PLUGINS