configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.13.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1301, 0, 1301)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.13.1.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl checks for gstreamer
 284 dnl uninstalled is selected preferentially -- see pkg-config(1)
 285 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 286 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 288 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 289 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 290 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 291
 292 dnl Check for documentation xrefs
 293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 294 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 295 AC_SUBST(GLIB_PREFIX)
 296 AC_SUBST(GST_PREFIX)
 297
 298 dnl check for libdrm
 299 PKG_CHECK_MODULES(DRM, libdrm >= 2.4.55, HAVE_DRM=yes, HAVE_DRM=no)
 300
 301 AG_GST_GL_CHECKS
 302
 303 dnl check for gudev
 304 PKG_CHECK_MODULES(G_UDEV, gudev-1.0 , [
 305         AC_DEFINE([HAVE_GUDEV], 1, [Define if gudev is installed])
 306         HAVE_GUDEV="yes" ],
 307         [HAVE_GUDEV="no"])
 308
 309 dnl GTK is optional and only used in examples
 310 HAVE_GTK=no
 311 HAVE_GTK_X11=no
 312 HAVE_GDK_PIXBUF=no
 313 GTK_REQ=3.10
 314 if test "x$BUILD_EXAMPLES" = "xyes"; then
 315   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 316   dnl some examples need gtk+-x11
 317   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 318   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 319   AC_SUBST(GTK_LIBS)
 320   AC_SUBST(GTK_CFLAGS)
 321
 322   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 323   AC_SUBST(GDK_PIXBUF_LIBS)
 324   AC_SUBST(GDK_PIXBUF_CFLAGS)
 325 fi
 326 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 327 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 328 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 329 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 330
 331 HAVE_QT=no
 332 HAVE_QT_MOC=no
 333 dnl QT is optional and only used in examples
 334 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 335   HAVE_QT=yes
 336 ], [
 337   HAVE_QT=no
 338 ])
 339 if test "x$HAVE_QT" = "xyes"; then
 340   AC_CHECK_TOOL(QT_MOC, moc)
 341   AC_MSG_CHECKING([for Qt5 moc])
 342   mocversion=`$QT_MOC -v 2>&1`
 343   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 344   if test x"$mocversiongrep" != x"$mocversion"; then
 345     AC_MSG_RESULT([no])
 346     # moc was not the qt5 one, try with moc-qt5
 347     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 348     AC_MSG_CHECKING([for Qt5 moc-qt5])
 349     mocversion=`$QT_MOC -v 2>&1`
 350     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 351     if test x"$mocversiongrep" != x"$mocversion"; then
 352       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 353       AC_MSG_CHECKING([for qtchooser])
 354       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 355       mocversion=`$qt5tooldir/moc -v 2>&1`
 356       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 357       if test x"$mocversiongrep" != x"$mocversion"; then
 358         # no valid moc found
 359         QT_MOC="no"
 360       else
 361         QT_MOC=$qt5tooldir/moc
 362       fi
 363     else
 364       QT_MOC=$QT_MOC
 365     fi
 366   fi
 367   AC_SUBST(QT_MOC)
 368   AC_MSG_RESULT([$QT_MOC])
 369 fi
 370 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 371 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 372
 373 dnl Check for OpenGL example dependencies (clutter, sdl, etc.)
 374 AG_GST_GL_EXAMPLES_CHECKS
 375
 376 dnl chck for linux headers needed by the joystick seek example
 377 AC_COMPILE_IFELSE(
 378 [
 379   AC_LANG_PROGRAM([
 380     #include <linux/input.h>
 381     #include <linux/joystick.h>
 382   ],[
 383     struct js_event js;
 384     js.type = JS_EVENT_AXIS;
 385   ])
 386 ], [
 387   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 388 ], [
 389   HAVE_LINUX_JOYSTICK_HEADERS="no"
 390 ])
 391 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 392
 393 dnl Check for -Bsymbolic-functions linker flag used to avoid
 394 dnl intra-library PLT jumps, if available.
 395 AC_ARG_ENABLE(Bsymbolic,
 396               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 397               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 398                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 399                LDFLAGS=-Wl,-Bsymbolic-functions
 400                LIBS=
 401                AC_TRY_LINK([], [return 0],
 402                            AC_MSG_RESULT(yes)
 403                            enable_Bsymbolic=yes,
 404                            AC_MSG_RESULT(no)
 405                            enable_Bsymbolic=no)
 406                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 407
 408
 409 dnl *** set variables based on configure arguments ***
 410
 411 dnl set license and copyright notice
 412 GST_LICENSE="LGPL"
 413 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 414 AC_SUBST(GST_LICENSE)
 415
 416 dnl set location of plugin directory
 417 AG_GST_SET_PLUGINDIR
 418
 419 dnl set release date/time
 420 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 421   ["${srcdir}/gst-plugins-base.doap"],
 422   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 423
 424 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 425 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 426 if test x$enable_static = xyes -a x$enable_shared = xno; then
 427   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 428 fi
 429
 430 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 431 dnl make sure it doesn't complain about unused variables if debugging is disabled
 432 NO_WARNINGS=""
 433 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 434
 435 dnl define an ERROR_CFLAGS Makefile variable
 436 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 437 dnl -Waggregate-return - xcb_intern_atom() returns an aggregate value
 438 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 439     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 440     -Wwrite-strings  -Wformat-nonliteral -Wformat-security
 441     -Winit-self -Wmissing-include-dirs -Waddress
 442     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 443
 444 dnl define an ERROR_CXXFLAGS Makefile variable
 445 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 446     -Wmissing-declarations -Wredundant-decls -Wundef
 447     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 448     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 449     -Wno-multichar $NO_WARNINGS])
 450
 451 dnl define correct level for debugging messages
 452 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 453
 454 dnl used in examples
 455 AG_GST_DEFAULT_ELEMENTS
 456
 457 dnl needed for encoding-target
 458 GST_DATADIR="$GST_PREFIX/share"
 459 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 460 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 461
 462 dnl behaviour of speex based audio resampler
 463 AC_MSG_CHECKING(which audio resample format to use for integer)
 464 AC_ARG_WITH([audioresample_format],
 465         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 466         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 467 AC_MSG_RESULT($ac_cv_audioresample_format)
 468 case $ac_cv_audioresample_format in
 469   int)
 470     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 471     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 472   ;;
 473   float)
 474     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 475     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 476   ;;
 477   auto)
 478     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 479     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 480 esac
 481
 482 dnl Check for mmap (needed by allocators library)
 483 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 484
 485 dnl *** plug-ins to include ***
 486
 487 dnl these are all the gst plug-ins, compilable without additional libs
 488 AG_GST_CHECK_PLUGIN(adder)
 489 AG_GST_CHECK_PLUGIN(app)
 490 AG_GST_CHECK_PLUGIN(audioconvert)
 491 AG_GST_CHECK_PLUGIN(audiomixer)
 492 AG_GST_CHECK_PLUGIN(audiorate)
 493 AG_GST_CHECK_PLUGIN(audiotestsrc)
 494 AG_GST_CHECK_PLUGIN(encoding)
 495 AG_GST_CHECK_PLUGIN(videoconvert)
 496 AG_GST_CHECK_PLUGIN(gio)
 497 AG_GST_CHECK_PLUGIN(playback)
 498 AG_GST_CHECK_PLUGIN(audioresample)
 499 AG_GST_CHECK_PLUGIN(rawparse)
 500 AG_GST_CHECK_PLUGIN(subparse)
 501 AG_GST_CHECK_PLUGIN(tcp)
 502 AG_GST_CHECK_PLUGIN(typefind)
 503 AG_GST_CHECK_PLUGIN(videotestsrc)
 504 AG_GST_CHECK_PLUGIN(videorate)
 505 AG_GST_CHECK_PLUGIN(videoscale)
 506 AG_GST_CHECK_PLUGIN(volume)
 507
 508 dnl iso-codes is optional, used by libgsttag
 509 AC_ARG_ENABLE(iso-codes,
 510 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 511 [case "${enableval}" in
 512   yes) enable_iso_codes=yes ;;
 513   no)  enable_iso_codes=no ;;
 514   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 515 esac
 516 ],
 517 [enable_iso_codes=yes]) dnl Default value
 518
 519 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 520 if test "x$enable_iso_codes" = "xyes"; then
 521   AC_MSG_RESULT([yes])
 522   have_iso_codes=no
 523   AC_MSG_CHECKING([whether iso-codes are available on this system])
 524   if $PKG_CONFIG iso-codes; then
 525     AC_MSG_RESULT([yes])
 526     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 527     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 528       AC_MSG_RESULT([yes])
 529       AC_MSG_CHECKING([for iso-codes prefix])
 530       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 531       if test -d "$ISO_CODES_PREFIX"; then
 532         AC_MSG_RESULT([yes])
 533         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 534         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 535         ISO_639_DOMAIN="iso_639"
 536         AC_MSG_CHECKING([ISO_639_DOMAIN])
 537         AC_MSG_RESULT([$ISO_639_DOMAIN])
 538         have_iso_codes=yes
 539         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 540         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 541         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 542         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 543       else
 544         AC_MSG_RESULT([no])
 545       fi
 546     else
 547       AC_MSG_RESULT([no])
 548     fi
 549   else
 550     AC_MSG_RESULT([no])
 551   fi
 552   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 553 else
 554   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 555   AM_CONDITIONAL(USE_ISO_CODES, false)
 556 fi
 557
 558 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 559 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 560 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 561   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 562       HAVE_ZLIB="yes"
 563     ], [
 564       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 565         HAVE_ZLIB="yes"
 566         ZLIB_LIBS="-lz"
 567         AC_SUBST(ZLIB_LIBS)
 568       ])
 569     ])
 570 ])
 571
 572 dnl *** sys plug-ins ***
 573
 574 echo
 575 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 576 echo
 577
 578 dnl *** X11 ***
 579 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 580 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 581                   [ximagesink], [
 582   AG_GST_PKG_CHECK_MODULES(X, x11)
 583 ])
 584
 585 dnl Check for Xv extension
 586 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 587 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 588                   [xvimagesink], [
 589   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 590 ])
 591
 592 dnl check for X Shm
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 594 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 595   if test x$HAVE_X = xyes; then
 596     PKG_CHECK_MODULES(XSHM, xext, [
 597       AC_CHECK_LIB(Xext, XShmAttach, [
 598         HAVE_XSHM="yes"
 599       ], [
 600         HAVE_XSHM="no"
 601         XSHM_LIBS=""
 602       ], [ $X_LIBS ])
 603     ], [
 604       HAVE_XSHM="no"
 605     ])
 606   fi
 607 ], , [
 608   AC_SUBST(HAVE_XSHM)
 609   AC_SUBST(XSHM_LIBS)
 610 ])
 611
 612 dnl *** ext plug-ins ***
 613 dnl keep this list sorted alphabetically !
 614
 615 if test "x$BUILD_EXTERNAL" = "xyes"; then
 616
 617 echo
 618 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 619 echo
 620
 621 dnl *** alsa ***
 622 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 623 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 624   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 625     HAVE_ALSA="yes"
 626     AC_SUBST(ALSA_CFLAGS)
 627     AC_SUBST(ALSA_LIBS)
 628   ], [
 629     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 630   ])
 631 ])
 632
 633 dnl *** CDParanoia ***
 634 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 635 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 636 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 637   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 638     HAVE_CDPARANOIA="yes"
 639   ], [
 640     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 641                         cdda_open, -lm,
 642                         cdda_interface.h,
 643                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 644                         HEADER_DIR="no"
 645                         FOUND_CDPARANOIA="yes")
 646     if test "x$FOUND_CDPARANOIA" != "xyes";
 647     then
 648       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 649                           cdda_open, -lm,
 650                           cdda/cdda_interface.h,
 651                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 652                           HEADER_DIR="yes"
 653                           FOUND_CDPARANOIA="yes")
 654     fi
 655     if test "x$HEADER_DIR" = "xyes";
 656     then
 657       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 658                          defined if cdda headers are in a cdda/ directory)
 659     fi
 660     if test "x$FOUND_CDPARANOIA" = "xyes";
 661     then
 662       AC_CHECK_LIB(cdda_paranoia,
 663                    paranoia_cachemodel_size,
 664                    : ,
 665                    HAVE_CDPARANOIA=no,
 666                  [-lcdda_interface])
 667     fi
 668
 669     AC_SUBST(CDPARANOIA_LIBS)
 670   ])
 671 ])
 672 dnl FIXME : add second check somehow if that is necessary
 673 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 674 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 675
 676 dnl *** gl ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_GL, true)
 678 AG_GST_CHECK_FEATURE(GL, [gl elements], gl, [
 679   HAVE_GL="no"
 680
 681   if test x"$USE_OPENGL" = x"yes" -o x"$USE_GLES2" = x"yes"; then
 682     HAVE_GL="yes"
 683     AG_GST_GL_PLUGIN_CHECKS
 684   fi
 685 ])
 686
 687 dnl *** ivorbis ***
 688 dnl AM_PATH_IVORBIS only takes two options
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 690 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 691   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 692   if test $HAVE_IVORBIS = no
 693   then
 694     IVORBIS_LIBS=
 695     IVORBIS_CFLAGS=
 696     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 697       [IVORBIS_LIBS=-lvorbisidec
 698       HAVE_IVORBIS=yes
 699       case $host in
 700       arm-*-*)
 701         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 702       esac
 703       ],
 704       HAVE_IVORBIS=no)
 705     AC_SUBST(IVORBIS_LIBS)
 706     AC_SUBST(IVORBIS_CFLAGS)
 707   else
 708     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 709       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 710       USE_TREMOLO=no)
 711   fi
 712 ])
 713
 714 dnl *** libvisual ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 716 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 717   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 718   if test x$HAVE_LIBVISUAL = xyes; then
 719     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 720   fi
 721   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 722   if test x$LIBVIS_PLUGINSDIR != x; then
 723     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 724         "$LIBVIS_PLUGINSDIR",
 725         [directory in which the detected libvisual's plugins are located])
 726   fi
 727 ])
 728
 729 dnl *** ogg ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 731 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 732   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 733 ])
 734
 735 dnl *** Opus ***
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 737 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 738   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 739           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 740           HAVE_OPUS="yes"
 741   ], [
 742           HAVE_OPUS="no"
 743   ])
 744   AC_SUBST(OPUS_CFLAGS)
 745   AC_SUBST(OPUS_LIBS)
 746 ])
 747
 748 dnl *** pango ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 750 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 751   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 752 ])
 753
 754 dnl *** theora ***
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 756 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 757   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 758 ])
 759
 760 dnl *** vorbis ***
 761 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 762 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 763   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 764 ])
 765
 766 if test "x$HAVE_VORBIS" = "xyes"; then
 767   ac_cflags_save="$CFLAGS"
 768   AC_COMPILE_IFELSE([
 769     AC_LANG_PROGRAM([[
 770 #include <vorbis/codec.h>
 771                      ]],[[
 772 vorbis_dsp_state *v;
 773
 774 vorbis_synthesis_restart (v);
 775                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 776   if test "x$HAVE_VSR" = "xyes"; then
 777     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 778                        [defined if vorbis_synthesis_restart is present])
 779   fi
 780   CFLAGS="$ac_cflags_save"
 781 fi
 782
 783 else
 784
 785 dnl not building plugins with external dependencies,
 786 dnl but we still need to set the conditionals
 787 AM_CONDITIONAL(USE_ALSA, false)
 788 AM_CONDITIONAL(USE_CDPARANOIA, false)
 789 AM_CONDITIONAL(USE_GL, false)
 790 AM_CONDITIONAL(USE_IVORBIS, false)
 791 AM_CONDITIONAL(USE_LIBVISUAL, false)
 792 AM_CONDITIONAL(USE_OGG, false)
 793 AM_CONDITIONAL(USE_OPUS, false)
 794 AM_CONDITIONAL(USE_PANGO, false)
 795 AM_CONDITIONAL(USE_THEORA, false)
 796 AM_CONDITIONAL(USE_VORBIS, false)
 797
 798 fi dnl of EXT plugins
 799
 800 AM_CONDITIONAL(HAVE_GRAPHENE, test "x$HAVE_GRAPHENE" = "xyes")
 801 AM_CONDITIONAL(HAVE_PNG, test "x$HAVE_PNG" = "xyes")
 802 AM_CONDITIONAL(HAVE_JPEG, test "x$HAVE_JPEG" = "xyes")
 803
 804 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 805 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 806     HAVE_GIO_UNIX_2_0="yes",
 807     HAVE_GIO_UNIX_2_0="no")
 808 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 809
 810 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 811
 812 dnl Overview:
 813 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 814 dnl GST_*:              flags shared by built objects to link against GStreamer
 815 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 816 dnl                          (compare to other modules) or for i18n
 817 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 818 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 819 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 820 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 821
 822 dnl GST_OPTION_CFLAGS
 823 if test "x$USE_DEBUG" = xyes; then
 824    PROFILE_CFLAGS="-g"
 825 fi
 826 AC_SUBST(PROFILE_CFLAGS)
 827
 828 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 829   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 830   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 831 else
 832   DEPRECATED_CFLAGS=""
 833 fi
 834 AC_SUBST(DEPRECATED_CFLAGS)
 835
 836 VISIBILITY_CFLAGS=""
 837 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 838 AC_SUBST(VISIBILITY_CFLAGS)
 839
 840 VISIBILITY_CXXFLAGS=""
 841 if test "x$HAVE_CXX" = "xyes"; then
 842   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 843 fi
 844 AC_SUBST(VISIBILITY_CXXFLAGS)
 845
 846 dnl disable strict aliasing
 847 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 848 AC_SUBST(EXTRA_CFLAGS)
 849
 850 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 851 dnl at make time with e.g. make ERROR_CFLAGS=""
 852 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 853 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 854 AC_SUBST(GST_OPTION_CFLAGS)
 855 AC_SUBST(GST_OPTION_CXXFLAGS)
 856
 857 dnl our libraries need to be versioned correctly
 858 AC_SUBST(GST_LT_LDFLAGS)
 859
 860 dnl GST_PLUGINS_BASE_CFLAGS
 861 dnl prefer internal headers to already installed ones
 862 dnl also add builddir include for enumtypes and marshal
 863 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 864 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 865
 866 dnl FIXME: do we want to rename to GST_ALL_* ?
 867 dnl add GST_OPTION_CFLAGS, but overridable
 868 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 869 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 870 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 871 AC_SUBST(GST_CFLAGS)
 872 AC_SUBST(GST_CXXFLAGS)
 873 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 874 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 875 AC_SUBST(GST_LIBS)
 876
 877 dnl LDFLAGS really should only contain flags, not libs - they get added before
 878 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 879 GST_ALL_LDFLAGS="-no-undefined"
 880 if test "x${enable_Bsymbolic}" = "xyes"; then
 881   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 882 fi
 883 AC_SUBST(GST_ALL_LDFLAGS)
 884
 885 dnl GST_LIB_LDFLAGS
 886 dnl linker flags shared by all libraries
 887 dnl LDFLAGS modifier defining exported symbols from built libraries
 888 dnl (export _gst_foo but not __gst_foo)
 889 GST_LIB_LDFLAGS=""
 890 AC_SUBST(GST_LIB_LDFLAGS)
 891
 892 dnl this really should only contain flags, not libs - they get added before
 893 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 894 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 895 AC_SUBST(GST_PLUGIN_LDFLAGS)
 896
 897 dnl *** output files ***
 898
 899 $MKDIR_P tests/check/orc
 900
 901 AC_CONFIG_FILES(
 902 Makefile
 903 gst/Makefile
 904 gst/adder/Makefile
 905 gst/app/Makefile
 906 gst/audioconvert/Makefile
 907 gst/audiomixer/Makefile
 908 gst/audiorate/Makefile
 909 gst/audioresample/Makefile
 910 gst/audiotestsrc/Makefile
 911 gst/encoding/Makefile
 912 gst/videoconvert/Makefile
 913 gst/gio/Makefile
 914 gst/pbtypes/Makefile
 915 gst/playback/Makefile
 916 gst/rawparse/Makefile
 917 gst/subparse/Makefile
 918 gst/tcp/Makefile
 919 gst/typefind/Makefile
 920 gst/videotestsrc/Makefile
 921 gst/videorate/Makefile
 922 gst/videoscale/Makefile
 923 gst/volume/Makefile
 924 sys/Makefile
 925 sys/ximage/Makefile
 926 sys/xvimage/Makefile
 927 ext/Makefile
 928 ext/alsa/Makefile
 929 ext/cdparanoia/Makefile
 930 ext/gl/Makefile
 931 ext/libvisual/Makefile
 932 ext/ogg/Makefile
 933 ext/opus/Makefile
 934 ext/pango/Makefile
 935 ext/theora/Makefile
 936 ext/vorbis/Makefile
 937 gst-libs/Makefile
 938 gst-libs/gst/Makefile
 939 gst-libs/gst/allocators/Makefile
 940 gst-libs/gst/audio/Makefile
 941 gst-libs/gst/app/Makefile
 942 gst-libs/gst/fft/Makefile
 943 gst-libs/gst/gl/Makefile
 944 gst-libs/gst/gl/android/Makefile
 945 gst-libs/gst/gl/cocoa/Makefile
 946 gst-libs/gst/gl/dispmanx/Makefile
 947 gst-libs/gst/gl/glprototypes/Makefile
 948 gst-libs/gst/gl/eagl/Makefile
 949 gst-libs/gst/gl/egl/Makefile
 950 gst-libs/gst/gl/wayland/Makefile
 951 gst-libs/gst/gl/win32/Makefile
 952 gst-libs/gst/gl/x11/Makefile
 953 gst-libs/gst/gl/viv-fb/Makefile
 954 gst-libs/gst/gl/gbm/Makefile
 955 gst-libs/gst/riff/Makefile
 956 gst-libs/gst/rtp/Makefile
 957 gst-libs/gst/rtsp/Makefile
 958 gst-libs/gst/sdp/Makefile
 959 gst-libs/gst/tag/Makefile
 960 gst-libs/gst/pbutils/Makefile
 961 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 962 gst-libs/gst/video/Makefile
 963 tools/Makefile
 964 pkgconfig/Makefile
 965 pkgconfig/gstreamer-allocators.pc
 966 pkgconfig/gstreamer-allocators-uninstalled.pc
 967 pkgconfig/gstreamer-audio.pc
 968 pkgconfig/gstreamer-audio-uninstalled.pc
 969 pkgconfig/gstreamer-app.pc
 970 pkgconfig/gstreamer-app-uninstalled.pc
 971 pkgconfig/gstreamer-fft.pc
 972 pkgconfig/gstreamer-fft-uninstalled.pc
 973 pkgconfig/gstreamer-pbutils.pc
 974 pkgconfig/gstreamer-pbutils-uninstalled.pc
 975 pkgconfig/gstreamer-riff.pc
 976 pkgconfig/gstreamer-riff-uninstalled.pc
 977 pkgconfig/gstreamer-rtp.pc
 978 pkgconfig/gstreamer-rtp-uninstalled.pc
 979 pkgconfig/gstreamer-rtsp.pc
 980 pkgconfig/gstreamer-rtsp-uninstalled.pc
 981 pkgconfig/gstreamer-sdp.pc
 982 pkgconfig/gstreamer-sdp-uninstalled.pc
 983 pkgconfig/gstreamer-tag.pc
 984 pkgconfig/gstreamer-tag-uninstalled.pc
 985 pkgconfig/gstreamer-video.pc
 986 pkgconfig/gstreamer-video-uninstalled.pc
 987 pkgconfig/gstreamer-gl.pc
 988 pkgconfig/gstreamer-gl-uninstalled.pc
 989 pkgconfig/gstreamer-plugins-base.pc
 990 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 991 tests/Makefile
 992 tests/check/Makefile
 993 tests/examples/Makefile
 994 tests/examples/app/Makefile
 995 tests/examples/audio/Makefile
 996 tests/examples/decodebin_next/Makefile
 997 tests/examples/dynamic/Makefile
 998 tests/examples/encoding/Makefile
 999 tests/examples/fft/Makefile
1000 tests/examples/gio/Makefile
1001 tests/examples/gl/Makefile
1002 tests/examples/gl/generic/Makefile
1003 tests/examples/gl/generic/cube/Makefile
1004 tests/examples/gl/generic/doublecube/Makefile
1005 tests/examples/gl/generic/recordgraphic/Makefile
1006 tests/examples/gl/generic/cubeyuv/Makefile
1007 tests/examples/gl/qt/Makefile
1008 tests/examples/gl/gtk/Makefile
1009 tests/examples/gl/gtk/fxtest/Makefile
1010 tests/examples/gl/gtk/3dvideo/Makefile
1011 tests/examples/gl/gtk/switchvideooverlay/Makefile
1012 tests/examples/gl/gtk/filternovideooverlay/Makefile
1013 tests/examples/gl/gtk/filtervideooverlay/Makefile
1014 tests/examples/gl/cocoa/Makefile
1015 tests/examples/gl/sdl/Makefile
1016 tests/examples/gl/clutter/Makefile
1017 tests/examples/overlay/Makefile
1018 tests/examples/seek/Makefile
1019 tests/examples/snapshot/Makefile
1020 tests/examples/playback/Makefile
1021 tests/examples/playrec/Makefile
1022 tests/files/Makefile
1023 tests/icles/Makefile
1024 tests/icles/playback/Makefile
1025 docs/Makefile
1026 docs/libs/Makefile
1027 docs/plugins/Makefile
1028 docs/version.entities
1029 po/Makefile.in
1030 common/Makefile
1031 common/m4/Makefile
1032 m4/Makefile
1033 )
1034 AC_OUTPUT
1035
1036 AG_GST_OUTPUT_PLUGINS
1037 ORC_OUTPUT
1038