configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.14.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 10, 0, 10)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.13.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127
 128 AC_ARG_WITH(plugins,
 129     AC_HELP_STRING([--with-plugins],
 130       [comma-separated list of plug-ins to compile]),
 131     [for i in `echo $withval | tr , ' '`; do
 132         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 133         then
 134             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 135         else
 136             echo "plug-in $i not recognized, ignoring..."
 137         fi
 138     done],
 139     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 140
 141 AC_SUBST(GST_PLUGINS_SELECTED)
 142
 143 dnl ext plug-ins; plug-ins that have external dependencies
 144 AG_GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 145   [HAVE_EXTERNAL=yes], enabled,
 146   [
 147     AC_MSG_NOTICE(building external plug-ins)
 148     BUILD_EXTERNAL="yes"
 149   ],[
 150     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 151     BUILD_EXTERNAL="no"
 152   ])
 153 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 154
 155 dnl *** checks for platform ***
 156
 157 dnl * hardware/architecture *
 158
 159 dnl common/m4/gst-arch.m4
 160 dnl check CPU type
 161 AG_GST_ARCH
 162
 163 dnl check for large file support
 164 dnl affected plugins must include config.h
 165 AC_SYS_LARGEFILE
 166
 167 dnl *** checks for programs ***
 168
 169 dnl find a compiler
 170 AC_PROG_CC
 171
 172 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 173 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 174
 175 dnl check for documentation tools
 176 GTK_DOC_CHECK([1.3])
 177 AS_PATH_PYTHON([2.1])
 178 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 179
 180 dnl *** checks for libraries ***
 181
 182 dnl For interactive UNIX (a Sun thing)
 183 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 184 AC_ISC_POSIX
 185
 186 dnl libm, for sin() etc.
 187 AC_CHECK_LIBM
 188 AC_SUBST(LIBM)
 189
 190 dnl *** checks for header files ***
 191
 192 dnl check if we have ANSI C header files
 193 AC_HEADER_STDC
 194
 195 dnl used in gst/ffmpegcolorspace/mem.c
 196 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 197 AC_CHECK_HEADERS([malloc.h])
 198
 199 dnl used in gst/subparse/gstsubparse.c
 200 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 201 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 202
 203 if test "x$HAVE_REGEX_H" = "xyes"; then
 204   ac_cppflags_save="$CPPFLAGS"
 205   CPPFLAGS="-Wall -Werror `$PKG_CONFIG --cflags libxml-2.0`"
 206   AC_COMPILE_IFELSE(
 207     AC_LANG_PROGRAM([
 208 #include <libxml/HTMLparser.h>
 209                      ],[
 210 #ifndef LIBXML_HTML_ENABLED
 211 #error libxml2 has no HTML support
 212 #endif /* LIBXML_HTML_ENABLED */
 213                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 214   CPPFLAGS="$ac_cppflags_save"
 215
 216   if test "x$HAVE_LIBXML_HTML" = "xyes"; then
 217     GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED subparse"
 218   else
 219     GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 220   fi
 221 else
 222   GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 223   HAVE_LIBXML_HTML="no"
 224 fi
 225 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 226
 227 dnl used in gst/tcp
 228 AC_CHECK_HEADERS([sys/socket.h],
 229   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 230 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 231 if test "x$HAVE_SYS_SOCKET_H" = "xyes"; then
 232   GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED tcp"
 233 else
 234   GST_PLUGINS_NO="\t[tcp]\n$GST_PLUGINS_NO"
 235 fi
 236
 237 dnl used in gst-libs/gst/rtsp
 238 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 239 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 240   WIN32_LIBS="-lws2_32"
 241   AC_SUBST(WIN32_LIBS)
 242 fi
 243
 244 dnl used in gst-libs/gst/pbutils and associated unit test
 245 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 246
 247 dnl ffmpegcolorspace includes _stdint.h
 248 dnl also, Windows does not have long long
 249 AX_CREATE_STDINT_H
 250
 251 dnl *** checks for functions ***
 252 AC_CHECK_FUNCS([localtime_r])
 253
 254 dnl *** checks for types/defines ***
 255
 256 dnl Check for FIONREAD ioctl declaration
 257 dnl used in gst/tcp
 258 GST_CHECK_FIONREAD
 259
 260 dnl *** checks for structures ***
 261
 262 dnl *** checks for compiler characteristics ***
 263
 264 dnl make sure we can use "inline" from C code
 265 AC_C_INLINE
 266
 267 dnl *** checks for library functions ***
 268
 269 dnl check for fseeko()
 270 AC_FUNC_FSEEKO
 271
 272 dnl Check for fast float to int casting as defined in C99
 273 dnl used in gst-libs/gst/floatcast/floatcast.h
 274 AC_C99_FUNC_LRINT
 275 AC_C99_FUNC_LRINTF
 276
 277 dnl Check for a way to display the function name in debug output
 278 AG_GST_CHECK_FUNCTION
 279
 280 dnl *** checks for dependency libraries ***
 281
 282 dnl GLib is required
 283 AG_GST_GLIB_CHECK([2.6])
 284
 285 dnl liboil is required
 286 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 287 if test "x$HAVE_LIBOIL" != "xyes"
 288 then
 289   AC_ERROR([liboil-0.3.8 or later is required])
 290 fi
 291
 292 dnl checks for gstreamer
 293 dnl uninstalled is selected preferentially -- see pkg-config(1)
 294 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 295 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 296 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 297 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 298 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 299 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 300
 301 dnl Check for documentation xrefs
 302 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 303 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 304 AC_SUBST(GLIB_PREFIX)
 305 AC_SUBST(GST_PREFIX)
 306
 307 dnl GTK is optional and used in examples
 308 HAVE_GTK=NO
 309 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 310 if test "x$HAVE_GTK_22" = "xyes"; then
 311   HAVE_GTK=yes
 312   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 313   AC_SUBST(GTK_VERSION)
 314   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 315   AC_SUBST(GTK_BASE_DIR)
 316 else
 317   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 318 fi
 319 if test "x$HAVE_GTK_20" = "xyes"; then
 320   HAVE_GTK=yes
 321 fi
 322 GTK_CFLAGS=$GTK2_CFLAGS
 323 GTK_LIBS=$GTK2_LIBS
 324 AC_SUBST(GTK_LIBS)
 325 AC_SUBST(GTK_CFLAGS)
 326 AC_SUBST(HAVE_GTK)
 327 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 328
 329 dnl *** set variables based on configure arguments ***
 330
 331 dnl set license and copyright notice
 332 GST_LICENSE="LGPL"
 333 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 334 AC_SUBST(GST_LICENSE)
 335
 336 dnl set location of plugin directory
 337 AG_GST_SET_PLUGINDIR
 338
 339 dnl define an ERROR_CFLAGS Makefile variable
 340 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 341
 342 dnl define correct level for debugging messages
 343 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 344
 345 dnl used in examples
 346 AG_GST_DEFAULT_ELEMENTS
 347
 348 dnl *** sys plug-ins ***
 349
 350 echo
 351 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 352 echo
 353
 354 dnl *** X11 ***
 355 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 356 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 357                   [ximagesink], [
 358   AC_PATH_XTRA
 359   ac_cflags_save="$CFLAGS"
 360   ac_cppflags_save="$CPPFLAGS"
 361   CFLAGS="$CFLAGS $X_CFLAGS"
 362   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 363
 364   dnl now try to find the HEADER
 365   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 366
 367   if test "x$HAVE_X" = "xno"
 368   then
 369     AC_MSG_NOTICE([cannot find X11 development files])
 370   else
 371     dnl this is much more than we want
 372     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 373     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 374     dnl it does not add the libs; therefore we add them here
 375     X_LIBS="$X_LIBS -lX11"
 376     AC_SUBST(X_CFLAGS)
 377     AC_SUBST(X_LIBS)
 378   fi
 379   AC_SUBST(HAVE_X)
 380   CFLAGS="$ac_cflags_save"
 381   CPPFLAGS="$ac_cppflags_save"
 382 ])
 383
 384 dnl Check for Xv extension
 385 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 386 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 387                   [xvimagesink], [
 388   AG_GST_CHECK_XV
 389 ])
 390
 391 dnl check for X Shm
 392 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 393 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 394   if test x$HAVE_X = xyes; then
 395     AC_CHECK_LIB(Xext, XShmAttach,
 396                  HAVE_XSHM="yes", HAVE_XSHM="no",
 397                  $X_LIBS)
 398     if test "x$HAVE_XSHM" = "xyes"; then
 399       XSHM_LIBS="-lXext"
 400     else
 401       dnl On AIX, it is in XextSam instead, but we still need -lXext
 402       AC_CHECK_LIB(XextSam, XShmAttach,
 403                    HAVE_XSHM="yes", HAVE_XSHM="no",
 404                    $X_LIBS)
 405       if test "x$HAVE_XSHM" = "xyes"; then
 406         XSHM_LIBS="-lXext -lXextSam"
 407       fi
 408     fi
 409   fi
 410 ], , [
 411   AC_SUBST(HAVE_XSHM)
 412   AC_SUBST(XSHM_LIBS)
 413 ])
 414
 415 dnl v4l/v4l2 checks have been moved down because they require X
 416
 417 dnl *** Video 4 Linux ***
 418 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 419 dnl renamed to GST_V4L in accordance with V4L2 below
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 421 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 422   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 423 #include <sys/types.h>
 424 #define _LINUX_TIME_H
 425 #define __user
 426 #include <linux/videodev.h>
 427   ])
 428
 429   dnl we can build v4l without Xv, but then we won't have XOverlay support
 430   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 431   then
 432     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 433     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 434   fi
 435 ])
 436
 437 dnl *** ext plug-ins ***
 438 dnl keep this list sorted alphabetically !
 439
 440 if test "x$BUILD_EXTERNAL" = "xyes"; then
 441
 442 echo
 443 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 444 echo
 445
 446 dnl *** alsa ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 448 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 449   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 450     HAVE_ALSA="yes"
 451     AC_SUBST(ALSA_CFLAGS)
 452     AC_SUBST(ALSA_LIBS)
 453   ], [
 454     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 455   ])
 456 ])
 457
 458 dnl *** CDParanoia ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 460 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 461   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 462                       cdda_open, -lm,
 463                       cdda_interface.h,
 464                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 465                       HEADER_DIR="no"
 466                       FOUND_CDPARANOIA="yes")
 467   if test "x$FOUND_CDPARANOIA" != "xyes";
 468   then
 469     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 470                         cdda_open, -lm,
 471                         cdda/cdda_interface.h,
 472                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 473                         HEADER_DIR="yes"
 474                         FOUND_CDPARANOIA="yes")
 475   fi
 476   if test "x$HEADER_DIR" = "xyes";
 477   then
 478     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 479                        defined if cdda headers are in a cdda/ directory)
 480   fi
 481   AC_SUBST(CDPARANOIA_LIBS)
 482 ])
 483 dnl FIXME : add second check somehow if that is necessary
 484 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 485 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 486
 487 dnl *** GNOME VFS ***
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 489 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 490   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 491 ])
 492
 493 dnl *** libvisual ***
 494 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 495 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 496   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 497   if test $HAVE_LIBVISUAL = no
 498   then
 499     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 500   fi
 501 ])
 502
 503 dnl *** ogg ***
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 505 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 506   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 507   if test $HAVE_OGG = no
 508   then
 509     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 510     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 511   fi
 512 ])
 513
 514 dnl *** pango ***
 515 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 516 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 517   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 518 ])
 519
 520 dnl *** theora ***
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 522 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 523   dnl this check will work as long as theora uses 1.0.x or similar for the
 524   dnl first post-alpha release and not just 1.0
 525   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 526 ])
 527
 528 dnl *** vorbis ***
 529 dnl AM_PATH_VORBIS only takes two options
 530 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 531 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 532   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 533   if test $HAVE_VORBIS = no
 534   then
 535     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 536     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 537   fi
 538 ])
 539
 540 if test "x$HAVE_VORBIS" = "xyes"; then
 541   ac_cflags_save="$CFLAGS"
 542   dnl FIXME: does this work on non-gcc? -- Company
 543   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 544   CFLAGS="-Wall -Werror"
 545   AC_COMPILE_IFELSE(
 546     AC_LANG_PROGRAM([
 547 #include <vorbis/codec.h>
 548                      ],[
 549 vorbis_dsp_state *v;
 550
 551 vorbis_synthesis_restart (v);
 552                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 553   if test "x$HAVE_VSR" = "xyes"; then
 554     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 555                        [defined if vorbis_synthesis_restart is present])
 556   fi
 557   CFLAGS="$ac_cflags_save"
 558 fi
 559
 560 else
 561
 562 dnl not building plugins with external dependencies,
 563 dnl but we still need to set the conditionals
 564 AM_CONDITIONAL(USE_ALSA, false)
 565 AM_CONDITIONAL(USE_CDPARANOIA, false)
 566 AM_CONDITIONAL(USE_GNOME_VFS, false)
 567 AM_CONDITIONAL(USE_LIBVISUAL, false)
 568 AM_CONDITIONAL(USE_OGG, false)
 569 AM_CONDITIONAL(USE_PANGO, false)
 570 AM_CONDITIONAL(USE_THEORA, false)
 571 AM_CONDITIONAL(USE_VORBIS, false)
 572
 573 fi dnl of EXT plugins
 574
 575 dnl seeking needs freetype, so check for it here
 576 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 577   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 578 ])
 579 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 580 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 581 AC_SUBST(FT2_CFLAGS)
 582 AC_SUBST(FT2_LIBS)
 583
 584 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 585
 586 dnl Overview:
 587 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 588 dnl GST_*:              flags shared by built objects to link against GStreamer
 589 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 590 dnl                          (compare to other modules) or for i18n
 591 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 592 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 593 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 594 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 595
 596 dnl GST_OPTION_CFLAGS
 597 if test "x$USE_DEBUG" = xyes; then
 598    PROFILE_CFLAGS="-g"
 599 fi
 600 AC_SUBST(PROFILE_CFLAGS)
 601
 602 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 603 AC_SUBST(DEPRECATED_CFLAGS)
 604
 605 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 606 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 607 AC_SUBST(GST_OPTION_CFLAGS)
 608
 609 dnl our libraries need to be versioned correctly
 610 AC_SUBST(GST_LT_LDFLAGS)
 611
 612 dnl GST_PLUGINS_BASE_CFLAGS
 613 dnl prefer internal headers to already installed ones
 614 dnl also add builddir include for enumtypes and marshal
 615 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 616 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 617
 618 dnl FIXME: do we want to rename to GST_ALL_* ?
 619 dnl add GST_OPTION_CFLAGS, but overridable
 620 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 621 AC_SUBST(GST_CFLAGS)
 622 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 623 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 624 AC_SUBST(GST_LIBS)
 625
 626 dnl LDFLAGS really should only contain flags, not libs - they get added before
 627 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 628 GST_ALL_LDFLAGS="-no-undefined"
 629 AC_SUBST(GST_ALL_LDFLAGS)
 630
 631 dnl GST_LIB_LDFLAGS
 632 dnl linker flags shared by all libraries
 633 dnl LDFLAGS modifier defining exported symbols from built libraries
 634 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 635 AC_SUBST(GST_LIB_LDFLAGS)
 636
 637 dnl this really should only contain flags, not libs - they get added before
 638 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 639 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 640 AC_SUBST(GST_PLUGIN_LDFLAGS)
 641
 642 dnl *** output files ***
 643
 644 AC_CONFIG_FILES(
 645 Makefile
 646 gst-plugins-base.spec
 647 gst/Makefile
 648 gst/adder/Makefile
 649 gst/audioconvert/Makefile
 650 gst/audiorate/Makefile
 651 gst/audioresample/Makefile
 652 gst/audiotestsrc/Makefile
 653 gst/ffmpegcolorspace/Makefile
 654 gst/gdp/Makefile
 655 gst/playback/Makefile
 656 gst/subparse/Makefile
 657 gst/tcp/Makefile
 658 gst/typefind/Makefile
 659 gst/videotestsrc/Makefile
 660 gst/videorate/Makefile
 661 gst/videoscale/Makefile
 662 gst/volume/Makefile
 663 sys/Makefile
 664 sys/ximage/Makefile
 665 sys/xvimage/Makefile
 666 sys/v4l/Makefile
 667 ext/Makefile
 668 ext/alsa/Makefile
 669 ext/cdparanoia/Makefile
 670 ext/gnomevfs/Makefile
 671 ext/libvisual/Makefile
 672 ext/ogg/Makefile
 673 ext/pango/Makefile
 674 ext/theora/Makefile
 675 ext/vorbis/Makefile
 676 gst-libs/Makefile
 677 gst-libs/gst/Makefile
 678 gst-libs/gst/audio/Makefile
 679 gst-libs/gst/cdda/Makefile
 680 gst-libs/gst/fft/Makefile
 681 gst-libs/gst/floatcast/Makefile
 682 gst-libs/gst/interfaces/Makefile
 683 gst-libs/gst/netbuffer/Makefile
 684 gst-libs/gst/riff/Makefile
 685 gst-libs/gst/rtp/Makefile
 686 gst-libs/gst/rtsp/Makefile
 687 gst-libs/gst/sdp/Makefile
 688 gst-libs/gst/tag/Makefile
 689 gst-libs/gst/pbutils/Makefile
 690 gst-libs/gst/video/Makefile
 691 tools/Makefile
 692 win32/common/config.h
 693 pkgconfig/Makefile
 694 pkgconfig/gstreamer-plugins-base.pc
 695 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 696 tests/Makefile
 697 tests/check/Makefile
 698 tests/examples/Makefile
 699 tests/examples/dynamic/Makefile
 700 tests/examples/seek/Makefile
 701 tests/examples/volume/Makefile
 702 tests/examples/snapshot/Makefile
 703 tests/icles/Makefile
 704 docs/Makefile
 705 docs/design/Makefile
 706 docs/libs/Makefile
 707 docs/plugins/Makefile
 708 docs/version.entities
 709 po/Makefile.in
 710 common/Makefile
 711 common/m4/Makefile
 712 m4/Makefile
 713 )
 714 AC_OUTPUT
 715
 716 AG_GST_OUTPUT_PLUGINS