configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.5.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl GStreamer versioning, this is mostly informational
  37 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  38 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  39 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  40 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  41 AC_SUBST(GST_VERSION_MAJOR)
  42 AC_SUBST(GST_VERSION_MINOR)
  43 AC_SUBST(GST_VERSION_MICRO)
  44 AC_SUBST(GST_VERSION_NANO)
  45
  46 dnl our libraries and install dirs use GST_API_VERSION in the filename
  47 dnl to allow side-by-side installation of different API versions
  48 GST_API_VERSION=1.0
  49 AC_SUBST(GST_API_VERSION)
  50 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  51   [GStreamer API Version])
  52
  53 dnl CURRENT, REVISION, AGE
  54 dnl - library source changed -> increment REVISION
  55 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  56 dnl - interfaces added -> increment AGE
  57 dnl - interfaces removed -> AGE = 0
  58 dnl
  59 dnl Keep CURRENT as MINOR * 100 + MICRO
  60 dnl Ex : 1.0.0 => 0
  61 dnl      1.0.3 => 3
  62 dnl      1.1.0 => 100
  63 dnl      1.2.5 => 205
  64 dnl      1.10.9 (who knows) => 1009
  65 dnl
  66 dnl sets GST_LT_LDFLAGS
  67 AS_LIBTOOL(GST, 501, 0, 501)
  68
  69 dnl *** autotools stuff ****
  70
  71 dnl allow for different autotools
  72 AS_AUTOTOOLS_ALTERNATE
  73
  74 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  75 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  76
  77 dnl set up gettext
  78 dnl the version check needs to stay here because autopoint greps for it
  79 AM_GNU_GETTEXT_VERSION([0.17])
  80 AM_GNU_GETTEXT([external])
  81 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  82
  83 dnl *** check for arguments to configure ***
  84
  85 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  86
  87 dnl subsystems - can influence other decisions so needs to be high up
  88 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  90 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 118 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 119
 120 AG_GST_ARG_DEBUG
 121 AG_GST_ARG_PROFILING
 122 AG_GST_ARG_VALGRIND
 123 AG_GST_ARG_GCOV
 124
 125 AG_GST_ARG_EXAMPLES
 126
 127 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 128 AG_GST_ARG_WITH_PACKAGE_NAME
 129 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 130
 131 AG_GST_PKG_CONFIG_PATH
 132
 133 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 134   ["${srcdir}/gstreamer.doap"],
 135   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 136
 137 dnl check for bash completion
 138 AC_ARG_WITH([bash-completion-dir],
 139     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 140         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 141     [],
 142     [with_bash_completion_dir=yes])
 143
 144 if test "x$with_bash_completion_dir" = "xyes"; then
 145     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 146         [BASH_COMPLETION_DIR="`pkg-config --variable=completionsdir bash-completion`"],
 147         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 148     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 149         [BASH_HELPERS_DIR="`pkg-config --variable=helpersdir bash-completion`"],
 150         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 151 else
 152     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 153     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 154 fi
 155
 156 AC_SUBST([BASH_COMPLETION_DIR])
 157 AC_SUBST([BASH_HELPERS_DIR])
 158 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 159
 160 dnl build static plugins or not
 161 AC_MSG_CHECKING([whether to build static plugins or not])
 162 AC_ARG_ENABLE(
 163   static-plugins,
 164   AC_HELP_STRING(
 165     [--enable-static-plugins],
 166     [build static plugins @<:@default=no@:>@]),
 167   [AS_CASE(
 168     [$enableval], [no], [], [yes], [],
 169     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 170   [enable_static_plugins=no])
 171 AC_MSG_RESULT([$enable_static_plugins])
 172 if test "x$enable_static_plugins" = xyes; then
 173   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 174     [Define if static plugins should be built])
 175   GST_PLUGIN_LIBTOOLFLAGS=""
 176 else
 177   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 178 fi
 179 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 180 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 181
 182 dnl building of tests
 183 AC_ARG_ENABLE(tests,
 184   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 185   [
 186     case "${enableval}" in
 187       yes) BUILD_TESTS=yes ;;
 188       no)  BUILD_TESTS=no ;;
 189       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 190     esac
 191   ],
 192 [BUILD_TESTS=yes]) dnl Default value
 193 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 194
 195 dnl tests known to fail
 196 AC_ARG_ENABLE(failing-tests,
 197   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 198   [
 199     case "${enableval}" in
 200       yes) BUILD_FAILING_TESTS=yes ;;
 201       no)  BUILD_FAILING_TESTS=no ;;
 202       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 203     esac
 204   ],
 205   [BUILD_FAILING_TESTS=no]) dnl Default value
 206 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 207 if test x$BUILD_FAILING_TESTS = xyes; then
 208   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 209 else
 210   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 211 fi
 212
 213 dnl building of benchmarks
 214 AC_ARG_ENABLE(benchmarks,
 215   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 216   [
 217     case "${enableval}" in
 218       yes) BUILD_BENCHMARKS=yes ;;
 219       no)  BUILD_BENCHMARKS=no ;;
 220       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 221     esac
 222   ],
 223 [BUILD_BENCHMARKS=yes]) dnl Default value
 224 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 225
 226 dnl building of tools
 227 AC_ARG_ENABLE(tools,
 228   AS_HELP_STRING([--disable-tools],[disable building tools]),
 229   [
 230     case "${enableval}" in
 231       yes) BUILD_TOOLS=yes ;;
 232       no)  BUILD_TOOLS=no ;;
 233       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 234     esac
 235   ],
 236 [BUILD_TOOLS=yes]) dnl Default value
 237 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 238
 239 dnl poison destroyed objects
 240 AC_ARG_ENABLE(poisoning,
 241   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 242   [
 243     case "${enableval}" in
 244       yes) USE_POISONING=yes ;;
 245       no)  USE_POISONING=no ;;
 246       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 247     esac
 248   ],
 249   [USE_POISONING=no]) dnl Default value
 250 if test "x$USE_POISONING" = xyes; then
 251   AC_DEFINE(USE_POISONING, 1,
 252     [Define if we should poison deallocated memory])
 253 fi
 254
 255 dnl *** checks for platform ***
 256
 257 dnl * hardware/architecture *
 258
 259 dnl common/m4/gst-arch.m4
 260 dnl check CPU type
 261 AG_GST_ARCH
 262 dnl substitution for win32/common/config.h
 263 HOST_CPU=$host_cpu
 264 AC_SUBST(HOST_CPU)
 265
 266 dnl common/m4/gst-arch.m4
 267 dnl check for unaligned access
 268 AG_GST_UNALIGNED_ACCESS
 269 dnl create a configure variable for gst/gstconfig.h
 270 if test x${as_cv_unaligned_access} = xyes ; then
 271   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 272 else
 273   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 274 fi
 275 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 276
 277 dnl check for platform specific settings
 278 AG_GST_PLATFORM
 279
 280 dnl * software *
 281
 282 dnl check for large file support
 283 dnl affected plugins must include config.h
 284 AC_SYS_LARGEFILE
 285
 286 dnl *** checks for programs ***
 287
 288 dnl find a compiler
 289 AC_PROG_CC
 290 AC_PROG_CC_STDC
 291
 292 dnl check if the compiler supports '-c' and '-o' options
 293 AM_PROG_CC_C_O
 294
 295 dnl find an assembler
 296 AM_PROG_AS
 297
 298 dnl determine if c++ is available on this system
 299 AC_PROG_CXX
 300 dnl CXX may be set to some default even if no c++ compiler is available
 301 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 302 AC_LANG_PUSH([C++])
 303 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 304 AC_LANG_POP([C++])
 305 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 306 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 307
 308 dnl Perl is used in building documentation and in the version checks
 309 AC_PATH_PROG(PERL_PATH, perl, no)
 310 if test x$PERL_PATH = xno; then
 311   AC_MSG_ERROR(Could not find perl)
 312 fi
 313
 314 dnl we require flex and bison for building the parser
 315 if test "x$GST_DISABLE_PARSE" != xyes; then
 316   AG_GST_BISON_CHECK
 317   AG_GST_FLEX_CHECK
 318 fi
 319
 320 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 321 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 322
 323 dnl check for gobject-introspection
 324 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 325
 326 dnl check for documentation tools
 327 AG_GST_DOCBOOK_CHECK
 328 GTK_DOC_CHECK([1.12])
 329 AG_GST_PLUGIN_DOCS([1.12])
 330
 331 dnl *** checks for libraries ***
 332
 333 dnl check for libm, for sin()
 334 LT_LIB_M
 335 AC_SUBST(LIBM)
 336
 337 dnl *** checks for header files ***
 338
 339 dnl check if we have ANSI C header files
 340 AC_HEADER_STDC
 341
 342 dnl Check for ucontext.h
 343 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 344
 345 dnl Check for sys/socket.h
 346 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 347 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 348
 349 dnl check for sys/times.h for tests/examples/adapter/
 350 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 351 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 352 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 353
 354 dnl Check for process.h for getpid() on win32
 355 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 356
 357 dnl Check for sys/utsname.h for uname
 358 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 359
 360 dnl Check for stdio_ext.f for __fbufsize
 361 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 362
 363 dnl check for pthreads
 364 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 365 dnl which later checks use in their test code
 366 AX_PTHREAD()
 367 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 368
 369 dnl check for sys/prctl for setting thread name on Linux
 370 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 371
 372 dnl check for pthread_setname_np(const char*)
 373 dnl which is present on OS X 10.6, iOS 3.2 and above
 374 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 375 AC_LINK_IFELSE(
 376     [AC_LANG_PROGRAM(
 377         [#include <pthread.h>],
 378         [pthread_setname_np("example")])],
 379     [AC_MSG_RESULT(yes)
 380      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 381         [Have function pthread_setname_np(const char*)])],
 382     [AC_MSG_RESULT(no)])
 383
 384 dnl check for sys/uio.h for writev()
 385 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 386
 387 dnl Check for valgrind.h
 388 dnl separate from HAVE_VALGRIND because you can have the program, but not
 389 dnl the dev package
 390 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 391
 392 dnl used in gst/gstpoll.c
 393 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 394 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 395 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 396   WIN32_LIBS="-lws2_32"
 397   AC_SUBST(WIN32_LIBS)
 398 fi
 399
 400 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 401 if test "x$BUILD_TESTS" = "xyes"; then
 402   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 403                          __gmpz_init_set_d, ,
 404                          gmp.h,
 405                          GMP_LIBS="-lgmp"
 406                          AC_SUBST(GMP_LIBS)
 407                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 408   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 409                          gsl_rng_uniform_int, -lgslcblas,
 410                          gsl/gsl_rng.h,
 411                          GSL_LIBS="-lgsl -lgslcblas"
 412                          AC_SUBST(GSL_LIBS)
 413                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 414 fi
 415
 416 dnl *** checks for types/defines ***
 417
 418 dnl *** checks for structures ***
 419
 420 dnl *** checks for compiler characteristics ***
 421
 422 dnl check if the compiler supports __uint128_t (gcc)
 423 dnl Actually check for 128-bit division, since that's what we use
 424 dnl uint128_t for.
 425 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 426     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 427       static __uint128_t v1 = 100;
 428       static __uint128_t v2 = 10;
 429       static __uint128_t u;
 430       u = v1 / v2;
 431     ]])],[
 432       gst_cv_uint128_t=yes
 433     ],[
 434       gst_cv_uint128_t=no
 435     ])
 436 )
 437 if test x$gst_cv_uint128_t = xyes; then
 438   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 439 fi
 440
 441 dnl *** checking for tm_gmtoff ***
 442 AC_MSG_CHECKING([for tm_gmtoff])
 443 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 444         #include <time.h>
 445         int main(void) {
 446           struct tm t;
 447           t.tm_gmtoff = 0;
 448           exit(0);
 449         }]])],
 450   [have_tm_gmtoff=yes
 451    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 452   [have_tm_gmtoff=no],
 453   [have_tm_gmtoff="no (cross compiling)"])
 454 AC_MSG_RESULT($have_tm_gmtoff)
 455
 456
 457 dnl *** checks for library functions ***
 458
 459 AC_CHECK_FUNCS([strcasestr])
 460
 461 AC_CHECK_FUNCS([gmtime_r])
 462 AC_CHECK_FUNCS([localtime_r])
 463 AC_CHECK_FUNCS([sigaction])
 464
 465 dnl check for fseeko()
 466 AC_FUNC_FSEEKO
 467 dnl check for ftello()
 468 AC_CHECK_FUNCS([ftello])
 469
 470 AC_CHECK_FUNCS([fgetpos])
 471 AC_CHECK_FUNCS([fsetpos])
 472
 473 dnl check for poll(), ppoll() and pselect()
 474 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 475 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 476 AC_CHECK_FUNCS([poll])
 477 AC_CHECK_FUNCS([ppoll])
 478 AC_CHECK_FUNCS([pselect])
 479
 480 dnl ****************************************
 481 dnl *** GLib POLL* compatibility defines ***
 482 dnl ****************************************
 483
 484 AC_MSG_CHECKING([for broken poll])
 485 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 486         #include <stdlib.h>
 487         #include <fcntl.h>
 488         #ifdef HAVE_SYS_POLL_H
 489         #include <sys/poll.h>
 490         #endif
 491         #ifdef HAVE_POLL_H
 492         #include <poll.h>
 493         #endif
 494         int main(void) {
 495           struct pollfd fds[1];
 496           int fd;
 497           fd = open("/dev/null", 1);
 498           fds[0].fd = fd;
 499           fds[0].events = POLLIN;
 500           fds[0].revents = 0;
 501           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 502                 exit(1);  /* Does not work for devices -- fail */
 503           }
 504           exit(0);
 505         }]])],
 506   [broken_poll=no],
 507   [broken_poll=yes
 508    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 509   [broken_poll="no (cross compiling)"])
 510 AC_MSG_RESULT($broken_poll)
 511
 512 dnl check for mmap()
 513 AC_FUNC_MMAP
 514 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 515
 516 dnl check for posix_memalign(), getpagesize()
 517 AC_CHECK_FUNCS([posix_memalign])
 518 AC_CHECK_FUNCS([getpagesize])
 519
 520 dnl Check for POSIX timers
 521 AC_CHECK_FUNCS(clock_gettime, [], [
 522   AC_CHECK_LIB(rt, clock_gettime, [
 523     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 524     LIBS="$LIBS -lrt"
 525   ], [
 526     AC_CHECK_LIB(pthread, clock_gettime, [
 527       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 528       LIBS="$LIBS -lpthread"
 529     ])
 530   ])
 531 ])
 532
 533 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 534     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 535 #include <time.h>
 536 #ifdef HAVE_UNISTD_H
 537 #include <unistd.h>
 538 #endif
 539     ]], [[
 540 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 541 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 542 #endif
 543     ]])],[
 544       gst_cv_posix_timers=yes
 545     ],[
 546       gst_cv_posix_timers=no
 547     ])
 548 )
 549
 550 if test "$gst_cv_posix_timers" = "yes"; then
 551   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 552   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 553 else
 554   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 555 fi
 556 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 557 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 558
 559 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 560     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 561 #include <time.h>
 562 #ifdef HAVE_UNISTD_H
 563 #include <unistd.h>
 564 #endif
 565     ]], [[
 566 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 567 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 568 #endif
 569     ]])],[
 570       gst_cv_monotonic_clock=yes
 571     ],[
 572       gst_cv_monotonic_clock=no
 573     ])
 574 )
 575
 576 if test "$gst_cv_monotonic_clock" = "yes"; then
 577   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 578   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 579 else
 580   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 581 fi
 582 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 583 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 584
 585 dnl Check for a way to display the function name in debug output
 586 AG_GST_CHECK_FUNCTION
 587
 588 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 589 save_cflags="$CFLAGS"
 590 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 591 AC_CHECK_LIB(dl, dladdr,
 592    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 593    LIBS="$LIBS -ldl")
 594 CFLAGS="$save_cflags"
 595
 596 dnl Check printf stuff
 597 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 598   AC_TYPE_LONG_LONG_INT
 599   AC_TYPE_UNSIGNED_LONG_LONG_INT
 600
 601   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 602     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 603   fi
 604
 605   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 606   gl_AC_HEADER_INTTYPES_H
 607
 608   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 609   gl_AC_HEADER_STDINT_H
 610
 611   AC_CHECK_TYPES(ptrdiff_t)
 612
 613   AC_TYPE_INTMAX_T
 614   AC_TYPE_SIZE_T
 615 fi
 616
 617 dnl *** checks for dependency libraries ***
 618
 619 dnl GLib
 620 GLIB_REQ=2.32.0
 621 AG_GST_GLIB_CHECK([$GLIB_REQ])
 622
 623 dnl Check for documentation xrefs
 624 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 625 AC_SUBST(GLIB_PREFIX)
 626
 627 dnl building of unit test libraries
 628 AC_ARG_ENABLE(check,
 629   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 630   [
 631     case "${enableval}" in
 632       yes) BUILD_CHECK=yes ;;
 633       no)  BUILD_CHECK=no ;;
 634       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 635     esac
 636   ], [
 637     dnl Default value
 638     case $host_os in
 639       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 640       *) BUILD_CHECK=yes ;;
 641     esac
 642 ])
 643 dnl bit of a misnomer, but keep the conditional named like this so we don't
 644 dnl have to change too much elsewhere
 645 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 646
 647 dnl configure the desired memory alignment
 648 AC_ARG_WITH([memory-alignment],
 649   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 650   [
 651     if test "x$withval" = "xyes"
 652     then
 653       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 654     else
 655       case "${withval}" in
 656         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 657         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 658         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 659       esac
 660     fi
 661   ], [
 662     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 663   ]
 664 )
 665
 666 dnl Check for -Bsymbolic-functions linker flag used to avoid
 667 dnl intra-library PLT jumps, if available.
 668 AC_ARG_ENABLE(Bsymbolic,
 669               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 670               [SAVED_LDFLAGS="${LDFLAGS}"
 671                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 672                LDFLAGS=-Wl,-Bsymbolic-functions
 673                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 674                            AC_MSG_RESULT(yes)
 675                            enable_Bsymbolic=yes],[
 676                            AC_MSG_RESULT(no)
 677                            enable_Bsymbolic=no])
 678                LDFLAGS="${SAVED_LDFLAGS}"])
 679
 680
 681 dnl *** set variables based on configure arguments
 682
 683 dnl set license and copyright notice
 684 GST_LICENSE="LGPL"
 685 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 686 AC_SUBST(GST_LICENSE)
 687
 688 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 689 AS_AC_EXPAND(LIBDIR, $libdir)
 690 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 691 AS_AC_EXPAND(DATADIR, $datadir)
 692 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 693
 694 dnl set location of plugin directory
 695 AG_GST_SET_PLUGINDIR
 696
 697 dnl make sure it doesn't complain about unused variables if debugging is disabled
 698 NO_WARNINGS=""
 699 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 700   NO_WARNINGS="-Wno-unused"
 701 fi
 702
 703 dnl define an ERROR_CFLAGS Makefile variable
 704 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 705
 706 dnl special warning flags for gst/printf
 707 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 708 AC_SUBST(PRINTF_CFLAGS)
 709
 710 dnl define correct level for debugging messages
 711 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 712
 713 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 714
 715 dnl Overview:
 716 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 717 dnl GST_ALL_*:          vars shared by all built objects
 718 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 719 dnl GST_OBJ_*:          additional vars to link to the core library
 720 dnl                     include GST_ALL_*
 721 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 722 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 723
 724 dnl GST_OPTION_CFLAGS
 725 if test "x$USE_DEBUG" = xyes; then
 726    PROFILE_CFLAGS="-g"
 727 fi
 728 AC_SUBST(PROFILE_CFLAGS)
 729
 730 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 731 # functionality from the API that gstreamer uses
 732 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 733 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 734   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 735   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 736 else
 737   DEPRECATED_CFLAGS=""
 738 fi
 739 AC_SUBST(DEPRECATED_CFLAGS)
 740
 741 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 742 dnl make DEPRECATED_CFLAGS=''
 743 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 744 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 745 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 746 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 747 AC_SUBST(GST_OPTION_CFLAGS)
 748 AC_SUBST(GST_OPTION_CXXFLAGS)
 749
 750 dnl GST_ALL_*
 751 dnl vars common to for all internal objects (core libs, elements, applications)
 752 dnl CFLAGS:
 753 dnl - src and build dirs need to be added because every piece that gets built
 754 dnl   will need the GStreamer source and generated headers
 755 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 756 dnl       from LibXML except for in the core library
 757 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 758 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 759
 760 dnl FIXME: check if LTLIBINTL is needed everywhere
 761 dnl I presume it is given that it contains the symbols that _() stuff maps to
 762 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 763
 764 dnl LDFLAGS really should only contain flags, not libs - they get added before
 765 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 766 GST_ALL_LDFLAGS="-no-undefined"
 767 if test "x${enable_Bsymbolic}" = "xyes"; then
 768   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 769 fi
 770
 771 AC_SUBST(GST_ALL_CFLAGS)
 772 AC_SUBST(GST_ALL_CXXFLAGS)
 773 AC_SUBST(GST_ALL_LIBS)
 774 AC_SUBST(GST_ALL_LDFLAGS)
 775
 776 dnl GST_LIB_LDFLAGS
 777 dnl linker flags shared by all libraries
 778 dnl LDFLAGS modifier defining exported symbols from built libraries
 779 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 780 AC_SUBST(GST_LIB_LDFLAGS)
 781
 782 dnl GST_OBJ_*
 783 dnl default vars for all internal objects built on libgstreamer
 784 dnl includes GST_ALL_*
 785 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 786 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 787 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 788 AC_SUBST(GST_OBJ_CFLAGS)
 789 AC_SUBST(GST_OBJ_CXXFLAGS)
 790 AC_SUBST(GST_OBJ_LIBS)
 791
 792 dnl GST_PLUGIN_LDFLAGS
 793 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 794 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 795 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 796
 797 dnl plugin scanner locations
 798 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 799 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 800     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 801 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 802
 803 dnl things for our internal libcheck (must be called even if building
 804 dnl libcheck is disabled because it defines conditionals)
 805 AG_GST_CHECK_CHECKS()
 806
 807 AC_CONFIG_FILES(
 808 Makefile
 809 data/Makefile
 810 gst/Makefile
 811 gst/gstconfig.h
 812 gst/gstversion.h
 813 gst/parse/Makefile
 814 gst/printf/Makefile
 815 libs/Makefile
 816 libs/gst/Makefile
 817 libs/gst/base/Makefile
 818 libs/gst/check/Makefile
 819 libs/gst/check/libcheck/Makefile
 820 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
 821 libs/gst/controller/Makefile
 822 libs/gst/helpers/Makefile
 823 libs/gst/net/Makefile
 824 plugins/Makefile
 825 plugins/elements/Makefile
 826 po/Makefile.in
 827 tests/Makefile
 828 tests/benchmarks/Makefile
 829 tests/check/Makefile
 830 tests/misc/Makefile
 831 tests/examples/Makefile
 832 tests/examples/adapter/Makefile
 833 tests/examples/controller/Makefile
 834 tests/examples/stepping/Makefile
 835 tests/examples/helloworld/Makefile
 836 tests/examples/launch/Makefile
 837 tests/examples/manual/Makefile
 838 tests/examples/memory/Makefile
 839 tests/examples/metadata/Makefile
 840 tests/examples/netclock/Makefile
 841 tests/examples/queue/Makefile
 842 tests/examples/streams/Makefile
 843 tests/examples/typefind/Makefile
 844 tools/Makefile
 845 common/Makefile
 846 common/m4/Makefile
 847 docs/Makefile
 848 docs/design/Makefile
 849 docs/faq/Makefile
 850 docs/gst/Makefile
 851 docs/gst/gstreamer.types
 852 docs/libs/Makefile
 853 docs/plugins/Makefile
 854 docs/manual/Makefile
 855 docs/pwg/Makefile
 856 docs/slides/Makefile
 857 docs/xsl/Makefile
 858 docs/version.entities
 859 m4/Makefile
 860 pkgconfig/Makefile
 861 stamp.h
 862 pkgconfig/gstreamer.pc
 863 pkgconfig/gstreamer-uninstalled.pc
 864 pkgconfig/gstreamer-base.pc
 865 pkgconfig/gstreamer-base-uninstalled.pc
 866 pkgconfig/gstreamer-check.pc
 867 pkgconfig/gstreamer-check-uninstalled.pc
 868 pkgconfig/gstreamer-controller.pc
 869 pkgconfig/gstreamer-controller-uninstalled.pc
 870 pkgconfig/gstreamer-net.pc
 871 pkgconfig/gstreamer-net-uninstalled.pc
 872 gstreamer.spec
 873 )
 874
 875 dnl Create the config.h file for Visual Studio builds
 876 dnl Beware of spaces and /'s in some of the shell variable contents.
 877 sed \
 878     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 879     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 880     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 881     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 882     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 883     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 884     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 885     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 886     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 887     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 888     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 889     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 890     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 891     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 892     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 893     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 894     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 895     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 896     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 897     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 898     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 899     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 900     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 901     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 902     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 903     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 904     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 905     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 906     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 907     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 908     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 909     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 910     config.h.in >win32/common/config.h-new
 911
 912 AC_OUTPUT
 913
 914 dnl negate for output
 915 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 916 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 917 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 918 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 919 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 920 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 921 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 922
 923 echo "
 924
 925 Configuration
 926         Version                    : ${VERSION}
 927         Source code location       : ${srcdir}
 928         Prefix                     : ${prefix}
 929         Compiler                   : ${CC}
 930         Package name               : ${GST_PACKAGE_NAME}
 931         Package origin             : ${GST_PACKAGE_ORIGIN}
 932
 933         Documentation (manuals)    : ${enable_docbook}
 934         Documentation (API)        : ${enable_gtk_doc}
 935
 936         Debug Logging              : ${enable_gst_debug}
 937         Command-line parser        : ${enable_parse}
 938         Option parsing in gst_init : ${enable_option_parsing}
 939         Tracing subsystem          : ${enable_trace}
 940         Allocation tracing         : ${enable_alloc_trace}
 941         Plugin registry            : ${enable_registry}
 942         Plugin support             : ${enable_plugin}
 943         Static plugins             : ${enable_static_plugins}
 944         Unit testing support       : ${BUILD_CHECK}
 945
 946         Debug                      : ${USE_DEBUG}
 947         Profiling                  : ${USE_PROFILING}
 948
 949         Building benchmarks        : ${BUILD_BENCHMARKS}
 950         Building examples          : ${BUILD_EXAMPLES}
 951         Building test apps         : ${BUILD_TESTS}
 952         Building tests that fail   : ${BUILD_FAILING_TESTS}
 953         Building tools             : ${BUILD_TOOLS}
 954 "