configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [11])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # Configure defaults
  13 m4_define([default_glapi],              [any])
  14
  15 # gstreamer-vaapi library (libtool) version number
  16 m4_define([gst_vaapi_lt_current],       [6])
  17 m4_define([gst0_vaapi_lt_current_bias], [0])
  18 m4_define([gst1_vaapi_lt_current_bias], [2])
  19 m4_define([gst2_vaapi_lt_current_bias], [4])
  20 m4_define([gst4_vaapi_lt_current_bias], [5])
  21 m4_define([gst6_vaapi_lt_current_bias], [6])
  22 m4_define([gst_vaapi_lt_revision],      [0])
  23 m4_define([gst_vaapi_lt_age],           [0])
  24
  25 # glib version number
  26 m4_define([glib_version], [2.28])
  27
  28 # gstreamer version number
  29 m4_define([gst_api_version],            [autodetect])
  30 m4_define([gst1_version],               [1.0.0])
  31 m4_define([gst1_plugins_base_version],  [1.0.0])
  32 m4_define([gst1_plugins_bad_version],   [1.0.0])
  33 m4_define([gst12_version],              [1.1.90])
  34 m4_define([gst12_plugins_base_version], [1.1.0])
  35 m4_define([gst12_plugins_bad_version],  [1.1.0])
  36 m4_define([gst14_version],              [1.2.90])
  37 m4_define([gst14_plugins_base_version], [1.3.0])
  38 m4_define([gst14_plugins_bad_version],  [1.3.0])
  39 m4_define([gst16_version],              [1.5.0])
  40 m4_define([gst16_plugins_base_version], [1.5.0])
  41 m4_define([gst16_plugins_bad_version],  [1.5.0])
  42
  43 # Wayland minimum version number
  44 m4_define([wayland_api_version], [1.0.0])
  45
  46 # VA-API minimum version number
  47 m4_define([va_api_version],     [0.30.4])
  48 m4_define([va_api_enc_version], [0.34.0])
  49 m4_define([va_api_drm_version], [0.33.0])
  50 m4_define([va_api_x11_version], [0.31.0])
  51 m4_define([va_api_wld_version], [0.33.0])
  52
  53 # libva package version number
  54 m4_define([libva_enc_package_version], [1.2.0])
  55 m4_define([libva_drm_package_version], [1.1.0])
  56 m4_define([libva_x11_package_version], [1.0.3])
  57 m4_define([libva_wld_package_version], [1.1.0])
  58
  59 # gtk-doc version number
  60 # XXX: introspection annotations require gtk-doc >= 1.12
  61 m4_define([gtkdoc_version], [1.9])
  62
  63 AC_PREREQ([2.66])
  64 AC_INIT([gst_vaapi], [gst_vaapi_version],
  65     [gwenole.beauchesne@intel.com],
  66     [gstreamer-vaapi])
  67
  68 AC_CONFIG_HEADERS([config.h])
  69 AC_CONFIG_SRCDIR([Makefile.am])
  70 AC_CONFIG_MACRO_DIR([m4])
  71 AC_CONFIG_AUX_DIR([build-aux])
  72
  73 AC_CANONICAL_TARGET
  74
  75 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  76
  77 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  78 AC_SUBST(TODAY)
  79
  80 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  81 AC_SUBST(LIBVA_PACKAGE_VERSION)
  82
  83 WAYLAND_API_VERSION=wayland_api_version
  84 AC_SUBST(WAYLAND_API_VERSION)
  85
  86 dnl Use pretty build output with automake >= 1.11
  87 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  88   AM_DEFAULT_VERBOSITY=1
  89   AC_SUBST(AM_DEFAULT_VERBOSITY)
  90 ])
  91
  92 dnl Check for tools
  93 AC_PROG_CC
  94 AM_PROG_CC_C_O
  95
  96 AC_ARG_VAR([GIT], [Path to git program, if any])
  97 AC_PATH_PROG([GIT], [git])
  98 AM_CONDITIONAL([HAVE_GIT], [test -n "$GIT"])
  99
 100 AC_ARG_VAR([YASM], [Path to yasm program, if any])
 101 AC_PATH_PROG([YASM], [yasm])
 102 if test -z "$YASM" -a "$enable_builtin_libvpx" = "yes"; then
 103     AC_MSG_ERROR([yasm is needed to build libvpx sources])
 104 fi
 105
 106 dnl Initialize libtool
 107 LT_PREREQ([2.2])
 108 LT_INIT
 109
 110 AC_ARG_ENABLE(builtin_videoparsers,
 111     AS_HELP_STRING([--enable-builtin-videoparsers],
 112                    [enable built-in videoparsers @<:@default=yes@:>@]),
 113     [], [enable_builtin_videoparsers="yes"])
 114
 115 AC_ARG_ENABLE(builtin_codecparsers,
 116     AS_HELP_STRING([--enable-builtin-codecparsers],
 117                    [enable built-in codecparsers @<:@default=yes@:>@]),
 118     [], [enable_builtin_codecparsers="yes"])
 119
 120 AC_ARG_ENABLE(builtin_libvpx,
 121     AS_HELP_STRING([--enable-builtin-libvpx],
 122                    [enable built-in libvpx @<:@default=yes@:>@]),
 123     [], [enable_builtin_libvpx="yes"])
 124
 125 AC_ARG_ENABLE([encoders],
 126     AS_HELP_STRING([--enable-encoders],
 127                    [enable video encoders @<:@default=yes@:>@]),
 128     [], [enable_encoders="yes"])
 129
 130 AC_ARG_ENABLE(drm,
 131     AS_HELP_STRING([--enable-drm],
 132                    [enable DRM backend @<:@default=yes@:>@]),
 133     [], [enable_drm="yes"])
 134
 135 AC_ARG_ENABLE(x11,
 136     AS_HELP_STRING([--enable-x11],
 137                    [enable X11 output @<:@default=yes@:>@]),
 138     [], [enable_x11="yes"])
 139
 140 AC_ARG_ENABLE(glx,
 141     AS_HELP_STRING([--enable-glx],
 142                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 143     [], [enable_glx="yes"])
 144
 145 AC_ARG_ENABLE(wayland,
 146     AC_HELP_STRING([--enable-wayland],
 147                    [enable Wayland output @<:@default=yes@:>@]),
 148     [], [enable_wayland="yes"])
 149
 150 AC_ARG_ENABLE([egl],
 151     AS_HELP_STRING([--enable-egl],
 152         [enable EGL output @<:@default=yes@:>@]),
 153     [], [enable_egl="yes"])
 154
 155 AC_ARG_WITH([glapi],
 156     AS_HELP_STRING([--with-glapi=APIs],
 157         [build with the specified OpenGL APIs @<:@default=default_glapi@:>@]),
 158     [GLAPI="$with_glapi"], [GLAPI=default_glapi])
 159
 160 dnl Check for basic libraries
 161 AC_CHECK_LIB(m, tan)
 162
 163 dnl Check for Gtk doc
 164 GTKDOC_VERSION=gtkdoc_version
 165 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 166 m4_ifdef([GTK_DOC_CHECK], [
 167 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 168 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 169 AC_SUBST(GTKDOC_VERSION)
 170
 171 dnl Check for GLib
 172 GLIB_VERSION_REQUIRED=glib_version
 173 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 174 AC_SUBST(GLIB_VERSION_REQUIRED)
 175
 176 dnl Check to see if dlopen is in default libraries (like Solaris, which
 177 dnl has it in libc), or if libdl is needed to get it.
 178 AC_CHECK_FUNC([dlopen], [], [
 179     AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 180 AC_SUBST([DLOPEN_LIBS])
 181
 182 dnl ---------------------------------------------------------------------------
 183 dnl -- GStreamer                                                             --
 184 dnl ---------------------------------------------------------------------------
 185 AC_MSG_CHECKING([for GStreamer API version])
 186 if $PKG_CONFIG --exists "gstreamer-1.0"; then
 187     gst_version=`$PKG_CONFIG --modversion "gstreamer-1.0"`
 188     gst_major_version=`echo "$gst_version" | cut -d'.' -f1`
 189     gst_minor_version=`echo "$gst_version" | cut -d'.' -f2`
 190     GST_API_VERSION="${gst_major_version}.${gst_minor_version}"
 191     GST_PKG_VERSION="1.0"
 192 fi
 193 if test -z "$GST_PKG_VERSION"; then
 194     AC_MSG_ERROR([gstreamer-$GST_PKG_VERSION was not found])
 195 fi
 196 AC_MSG_RESULT([$GST_API_VERSION])
 197
 198 AC_DEFINE_UNQUOTED([GST_API_VERSION_S], ["$GST_API_VERSION"],
 199     [Defined to the string representation of GStreamer version])
 200
 201 dnl Versions for GStreamer and plugins-base
 202 case $GST_API_VERSION in
 203 1.0)
 204     GST_VERSION_REQUIRED=gst1_version
 205     GST_PLUGINS_BASE_VERSION_REQUIRED=gst1_plugins_base_version
 206     GST_PLUGINS_BAD_VERSION_REQUIRED=gst1_plugins_bad_version
 207     ;;
 208 1.2)
 209     GST_VERSION_REQUIRED=gst12_version
 210     GST_PLUGINS_BASE_VERSION_REQUIRED=gst12_plugins_base_version
 211     GST_PLUGINS_BAD_VERSION_REQUIRED=gst12_plugins_bad_version
 212     ;;
 213 1.4)
 214     GST_VERSION_REQUIRED=gst14_version
 215     GST_PLUGINS_BASE_VERSION_REQUIRED=gst14_plugins_base_version
 216     GST_PLUGINS_BAD_VERSION_REQUIRED=gst14_plugins_bad_version
 217     ;;
 218 1.[[5-6]])
 219     GST_VERSION_REQUIRED=gst16_version
 220     GST_PLUGINS_BASE_VERSION_REQUIRED=gst16_plugins_base_version
 221     GST_PLUGINS_BAD_VERSION_REQUIRED=gst16_plugins_bad_version
 222     ;;
 223 *)
 224     AC_MSG_ERROR([unsupported GStreamer API version $GST_API_VERSION])
 225     ;;
 226 esac
 227 AC_SUBST(GST_API_VERSION)
 228 AC_SUBST(GST_VERSION_REQUIRED)
 229 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 230 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 231
 232 USE_GST_API_1_0p="no"
 233 USE_GST_API_1_2p="no"
 234 USE_GST_API_1_4p="no"
 235 AS_VERSION_COMPARE([$GST_API_VERSION], [1.0],
 236     [], [USE_GST_API_1_0p="yes"], [USE_GST_API_1_0p="yes"])
 237 AS_VERSION_COMPARE([$GST_API_VERSION], [1.2],
 238     [], [USE_GST_API_1_2p="yes"], [USE_GST_API_1_2p="yes"])
 239 AS_VERSION_COMPARE([$GST_API_VERSION], [1.4],
 240     [], [USE_GST_API_1_4p="yes"], [USE_GST_API_1_4p="yes"])
 241 AM_CONDITIONAL([USE_GST_API_1_0p], [test "$USE_GST_API_1_0p" = "yes"])
 242 AM_CONDITIONAL([USE_GST_API_1_2p], [test "$USE_GST_API_1_2p" = "yes"])
 243 AM_CONDITIONAL([USE_GST_API_1_4p], [test "$USE_GST_API_1_4p" = "yes"])
 244
 245 AC_SUBST([GST_PKG_VERSION])
 246
 247 AC_DEFINE_UNQUOTED([GST_PKG_VERSION_S], ["$GST_PKG_VERSION"],
 248     [Defined to the string representation of GStreamer API version])
 249
 250 dnl Validate certain features
 251 if test "$GST_API_VERSION" = "1.0"; then
 252     AC_MSG_WARN([support for GStreamer 1.0 is obsolete, and will be removed])
 253 fi
 254
 255 dnl GStreamer Core
 256 PKG_CHECK_MODULES([GST],
 257     [gstreamer-$GST_PKG_VERSION >= $GST_VERSION_REQUIRED])
 258 PKG_CHECK_MODULES([GST_BASE],
 259     [gstreamer-base-$GST_PKG_VERSION >= $GST_VERSION_REQUIRED])
 260
 261 dnl GStreamer -base plugins
 262 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 263     [gstreamer-plugins-base-$GST_PKG_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 264 if test "$GST_API_VERSION" = "0.10"; then
 265 PKG_CHECK_MODULES([GST_INTERFACES],
 266     [gstreamer-interfaces-$GST_PKG_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 267 fi
 268
 269 dnl ... gst_dmabuf_memory_get_fd (gstreamer-allocators)
 270 PKG_CHECK_MODULES([GST_ALLOCATORS],
 271     [gstreamer-allocators-$GST_PKG_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 272
 273 dnl ... GstVideoOverlayComposition (gstreamer-video)
 274 PKG_CHECK_MODULES([GST_VIDEO],
 275     [gstreamer-video-$GST_PKG_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 276
 277 dnl GStreamer -bad plugins (deprecated in GStreamer v1.2)
 278 if test "$USE_GST_API_1_2p" != "yes" && test "$USE_GST_API_1_4p" != "yes"; then
 279 PKG_CHECK_MODULES([GST_BASEVIDEO],
 280     [gstreamer-basevideo-$GST_PKG_VERSION >= $GST_PLUGINS_BAD_VERSION_REQUIRED])
 281 fi
 282
 283 dnl ... bitstream parsers
 284 if test "$enable_builtin_codecparsers" = "yes"; then
 285     ac_cv_have_gst_mpeg2_parser="no"
 286     ac_cv_have_gst_h264_parser="no"
 287     ac_cv_have_gst_jpeg_parser="no"
 288     ac_cv_have_gst_vp8_parser="no"
 289 else
 290 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 291     [gstreamer-codecparsers-$GST_PKG_VERSION >= $GST_PLUGINS_BAD_VERSION_REQUIRED])
 292 fi
 293
 294 dnl ... MPEG-2 parser, with the required extensions
 295 AC_CACHE_CHECK([for MPEG-2 parser],
 296     ac_cv_have_gst_mpeg2_parser, [
 297     saved_CPPFLAGS="$CPPFLAGS"
 298     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 299     saved_LIBS="$LIBS"
 300     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 301     AC_COMPILE_IFELSE(
 302         [AC_LANG_PROGRAM(
 303             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 304             [[GstMpegVideoSequenceHdr seq_hdr;
 305               GstMpegVideoSequenceExt seq_ext;
 306               GstMpegVideoSequenceDisplayExt seq_dpy;
 307               GstMpegVideoSliceHdr slice_hdr;
 308               GstMpegVideoPacket packet;
 309               gst_mpeg_video_packet_parse_slice_header(&packet, &slice_hdr,
 310                   &seq_hdr, NULL);
 311               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 312                   &seq_ext, &seq_dpy);]])],
 313         [ac_cv_have_gst_mpeg2_parser="yes"],
 314         [ac_cv_have_gst_mpeg2_parser="no"]
 315     )
 316     CPPFLAGS="$saved_CPPFLAGS"
 317     LIBS="$saved_LIBS"
 318 ])
 319 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 320     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 321
 322 dnl ... H.264 parser, with the required extensions
 323 AC_CACHE_CHECK([for H.264 parser],
 324     ac_cv_have_gst_h264_parser, [
 325     saved_CPPFLAGS="$CPPFLAGS"
 326     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 327     saved_LIBS="$LIBS"
 328     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 329     AC_COMPILE_IFELSE(
 330         [AC_LANG_PROGRAM(
 331             [[#include <gst/codecparsers/gsth264parser.h>]],
 332             [[GstH264SliceHdr slice_hdr;
 333               GstH264VUIParams vui_params;
 334               GstH264Profile profile = GST_H264_PROFILE_HIGH;
 335               slice_hdr.n_emulation_prevention_bytes = 0;
 336               vui_params.par_n = 0;
 337               vui_params.par_d = 0;]])],
 338         [ac_cv_have_gst_h264_parser="yes"],
 339         [ac_cv_have_gst_h264_parser="no"]
 340     )
 341     CPPFLAGS="$saved_CPPFLAGS"
 342     LIBS="$saved_LIBS"
 343 ])
 344 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 345     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 346
 347 dnl ... JPEG parser, not upstream yet
 348 AC_CACHE_CHECK([for JPEG parser],
 349     ac_cv_have_gst_jpeg_parser, [
 350     saved_CPPFLAGS="$CPPFLAGS"
 351     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 352     saved_LIBS="$LIBS"
 353     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 354     AC_COMPILE_IFELSE(
 355         [AC_LANG_PROGRAM(
 356             [[#include <gst/codecparsers/gstjpegparser.h>]],
 357             [[GstJpegImage jpeg_image;]])],
 358         [ac_cv_have_gst_jpeg_parser="yes"],
 359         [ac_cv_have_gst_jpeg_parser="no"]
 360     )
 361     CPPFLAGS="$saved_CPPFLAGS"
 362     LIBS="$saved_LIBS"
 363 ])
 364 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 365     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 366
 367 dnl ... VP8 parser, not upstream yet
 368 if test "$enable_builtin_libvpx" = "yes"; then
 369     ac_cv_have_gst_vp8_parser="no"
 370 fi
 371 AC_CACHE_CHECK([for VP8 parser],
 372     ac_cv_have_gst_vp8_parser, [
 373     saved_CPPFLAGS="$CPPFLAGS"
 374     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 375     saved_LIBS="$LIBS"
 376     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 377     AC_COMPILE_IFELSE(
 378         [AC_LANG_PROGRAM(
 379             [[#include <gst/codecparsers/gstvp8parser.h>]],
 380             [[GstVp8FrameHdr frame_hdr;]])],
 381         [ac_cv_have_gst_vp8_parser="yes"],
 382         [ac_cv_have_gst_vp8_parser="no"]
 383     )
 384     CPPFLAGS="$saved_CPPFLAGS"
 385     LIBS="$saved_LIBS"
 386 ])
 387 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_VP8],
 388     [test "$ac_cv_have_gst_vp8_parser" != "yes"])
 389 AM_CONDITIONAL([USE_BUILTIN_LIBVPX], [test "$enable_builtin_libvpx" = "yes"])
 390
 391 dnl ... video parsers
 392 AM_CONDITIONAL([USE_LOCAL_VIDEO_PARSERS],
 393     [test "$enable_builtin_videoparsers" = "yes"])
 394
 395 dnl ... opengl helper libraries
 396 HAVE_GSTGL=0
 397 if test "$enable_glx" = "yes" -o "$enable_egl" = "yes"; then
 398     PKG_CHECK_MODULES([GST_GL],
 399         [gstreamer-gl-$GST_PKG_VERSION >= $GST_PLUGINS_BAD_VERSION_REQUIRED],
 400         [HAVE_GSTGL=1], [HAVE_GSTGL=0])
 401 fi
 402
 403 if test $HAVE_GSTGL -eq 1; then
 404     AC_CACHE_CHECK([for GStreamer OpenGL helper libraries],
 405         [ac_cv_have_gst_gl_helpers], [
 406         saved_CPPFLAGS="$CPPFLAGS"
 407         CPPFLAGS="$CPPFLAGS $GST_GL_CFLAGS"
 408         saved_LIBS="$LIBS"
 409         LIBS="$saved_LIBS"
 410         AC_CHECK_HEADERS([gst/gl/gl.h], [:], [HAVE_GSTGL=0])
 411         AC_COMPILE_IFELSE(
 412             [AC_LANG_PROGRAM(
 413                 [[#include <gst/gl/gl.h>]],
 414                 [[GstGLContext gl_context;]])],
 415             [ac_cv_have_gst_gl_helpers="yes"],
 416             [ac_cv_have_gst_gl_helpers="no" HAVE_GSTGL=0]
 417         )
 418         CPPFLAGS="$saved_CPPFLAGS"
 419         LIBS="$saved_LIBS"
 420     ])
 421 fi
 422 AM_CONDITIONAL([USE_GST_GL_HELPERS], [test $HAVE_GSTGL -eq 1])
 423
 424 AC_DEFINE_UNQUOTED([USE_GST_GL_HELPERS], [$HAVE_GSTGL],
 425     [Defined to 1 if GStreamer OpenGL helper libraries are available])
 426
 427 if test "$enable_egl" = "yes" -a $HAVE_GSTGL -ne 1; then
 428     AC_MSG_WARN([GStreamer/GL helper libraries not found, disabling EGL support])
 429     enable_egl="no"
 430 fi
 431
 432 case $GST_API_VERSION in
 433 1.0)    lt_bias=gst1_vaapi_lt_current_bias;;
 434 1.2)    lt_bias=gst2_vaapi_lt_current_bias;;
 435 1.4) lt_bias=gst4_vaapi_lt_current_bias;;
 436 1.[[5-6]])    lt_bias=gst6_vaapi_lt_current_bias;;
 437 esac
 438 GST_VAAPI_MAJOR_VERSION=`expr gst_vaapi_lt_current - "$lt_bias"`
 439 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
 440
 441 AC_DEFINE_UNQUOTED([GST_VAAPI_MAJOR_VERSION_S], ["$GST_VAAPI_MAJOR_VERSION"],
 442     [Defined to the string representation of gstreamer-vaapi major version])
 443
 444 dnl GST_VAAPI_LT_LDFLAGS:
 445 GST_VAAPI_LT_CURRENT="$GST_VAAPI_MAJOR_VERSION"
 446 GST_VAAPI_LT_REV=gst_vaapi_lt_revision
 447 GST_VAAPI_LT_AGE=gst_vaapi_lt_age
 448 GST_VAAPI_LT_VERSION="$GST_VAAPI_LT_CURRENT:$GST_VAAPI_LT_REV:$GST_VAAPI_LT_AGE"
 449 GST_VAAPI_LT_LDFLAGS="-version-info $GST_VAAPI_LT_VERSION"
 450 AC_SUBST(GST_VAAPI_LT_VERSION)
 451 AC_SUBST(GST_VAAPI_LT_LDFLAGS)
 452
 453 dnl GST_ALL_LDFLAGS:
 454 dnl LDFLAGS really should only contain flags, not libs - they get added before
 455 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 456 GST_ALL_LDFLAGS="-no-undefined"
 457 AC_SUBST(GST_ALL_LDFLAGS)
 458
 459 dnl GST_PLUGIN_LDFLAGS:
 460 dnl this really should only contain flags, not libs - they get added before
 461 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 462 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 463 AC_SUBST(GST_PLUGIN_LDFLAGS)
 464
 465 dnl Check for the GStreamer plugins directory
 466 AC_ARG_VAR([GST_PLUGIN_PATH_1_0], [installation path for gstreamer-vaapi plugin elements for GStreamer 1.0])
 467 AC_MSG_CHECKING([for GStreamer plugins directory])
 468 if test -d "$GST_PLUGIN_PATH_1_0"; then
 469     GST_PLUGINS_DIR="$GST_PLUGIN_PATH_1_0"
 470 else
 471     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_PKG_VERSION --variable pluginsdir`
 472     if test -z "$GST_PLUGINS_DIR"; then
 473         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_PKG_VERSION"
 474     fi
 475 fi
 476 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 477 plugindir="$GST_PLUGINS_DIR"
 478 AC_SUBST(plugindir)
 479
 480 dnl ---------------------------------------------------------------------------
 481 dnl -- Renderers                                                             --
 482 dnl ---------------------------------------------------------------------------
 483
 484 dnl Check for DRM/libudev
 485 USE_DRM=0
 486 if test "$enable_drm" = "yes"; then
 487     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 488     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 489
 490     if test $USE_DRM -eq 1; then
 491         saved_CPPFLAGS="$CPPFLAGS"
 492         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 493         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 494         CPPFLAGS="$saved_CPPFLAGS"
 495     fi
 496 fi
 497
 498 dnl Check for X11
 499 USE_X11=0
 500 if test "$enable_x11" = "yes"; then
 501     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 502     if test $USE_X11 -eq 1; then
 503         saved_CPPFLAGS="$CPPFLAGS"
 504         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 505         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 506         CPPFLAGS="$saved_CPPFLAGS"
 507     fi
 508 fi
 509
 510 dnl Check for XKB library
 511 HAVE_XKBLIB=0
 512 if test $USE_X11 -eq 1; then
 513     AC_CHECK_HEADERS([X11/XKBlib.h], [HAVE_XKBLIB=1], [:])
 514 fi
 515 if test $HAVE_XKBLIB -eq 1; then
 516     AC_DEFINE_UNQUOTED([HAVE_XKBLIB], 1,
 517         [Defined to 1 if the XKB extension exists.])
 518 fi
 519
 520 dnl Check for XRandR
 521 HAVE_XRANDR=0
 522 if test $USE_X11 -eq 1; then
 523     HAVE_XRANDR=1
 524     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 525     if test $HAVE_XRANDR -eq 1; then
 526         saved_CPPFLAGS="$CPPFLAGS"
 527         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 528         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 529         CPPFLAGS="$saved_CPPFLAGS"
 530     fi
 531 fi
 532 if test $HAVE_XRANDR -eq 1; then
 533     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 534         [Defined to 1 if the XRandR extension exists.])
 535 fi
 536
 537 dnl Check for XRender
 538 HAVE_XRENDER=0
 539 if test $USE_X11 -eq 1; then
 540     HAVE_XRENDER=1
 541     PKG_CHECK_MODULES([XRENDER], [xrender], [:], [HAVE_XRENDER=0])
 542     if test $HAVE_XRENDER -eq 1; then
 543         saved_CPPFLAGS="$CPPFLAGS"
 544         CPPFLAGS="$CPPFLAGS $XRENDER_CFLAGS"
 545         AC_CHECK_HEADERS([X11/extensions/Xrender.h], [:], [HAVE_XRENDER=0])
 546         CPPFLAGS="$saved_CPPFLAGS"
 547     fi
 548 fi
 549 if test $HAVE_XRENDER -eq 1; then
 550     AC_DEFINE_UNQUOTED([HAVE_XRENDER], [1],
 551         [Defined to 1 if the XRender extension exists.])
 552 fi
 553
 554 dnl OpenGL
 555 enable_opengl="no"
 556 if test "$enable_glx" = "yes"; then
 557     enable_opengl="yes"
 558 fi
 559 if test "$enable_egl" = "yes"; then
 560     enable_opengl="yes"
 561 fi
 562 GLES_VERSION_MASK=0
 563
 564 HAVE_GL=0
 565 if test "$enable_opengl" = "yes"; then
 566 case ",$GLAPI," in
 567 (*,any,*|*,gl,*)
 568     HAVE_GL=1
 569     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 570     saved_CPPFLAGS="$CPPFLAGS"
 571     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 572     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 573 #ifdef HAVE_GL_GL_H
 574 # include <GL/gl.h>
 575 #endif
 576     ])
 577     CPPFLAGS="$saved_CPPFLAGS"
 578     ;;
 579 esac
 580 fi
 581 GLES_VERSION_MASK=`expr $GLES_VERSION_MASK "+" $HAVE_GL "*" 1`
 582
 583 dnl OpenGL|ESv2
 584 HAVE_GLESv2=0
 585 if test "$enable_opengl" = "yes"; then
 586 case ",$GLAPI," in
 587 (*,any,*|*,gles2,*)
 588     HAVE_GLESv2=1
 589     PKG_CHECK_MODULES([GLES2], [glesv2], [:], [HAVE_GLESv2=0])
 590     saved_CPPFLAGS="$CPPFLAGS"
 591     CPPFLAGS="$CPPFLAGS $GLES2_CFLAGS"
 592     AC_CHECK_HEADERS([GLES2/gl2.h GLES2/gl2ext.h], [:],
 593         [HAVE_GLESv2=0], [
 594 #ifdef HAVE_GLES2_GL2_H
 595 # include <GLES2/gl2.h>
 596 #endif
 597     ])
 598     CPPFLAGS="$saved_CPPFLAGS"
 599     ;;
 600 esac
 601 fi
 602 GLES_VERSION_MASK=`expr $GLES_VERSION_MASK "+" $HAVE_GLESv2 "*" 4`
 603
 604 dnl OpenGL|ESv3
 605 HAVE_GLESv3=0
 606 if test "$enable_opengl" = "yes"; then
 607 case ",$GLAPI," in
 608 (*,any,*|*,gles3,*)
 609     HAVE_GLESv3=1
 610     PKG_CHECK_MODULES([GLES3], [glesv2], [:], [HAVE_GLESv3=0])
 611     saved_CPPFLAGS="$CPPFLAGS"
 612     CPPFLAGS="$CPPFLAGS $GLES3_CFLAGS"
 613     AC_CHECK_HEADERS([GLES3/gl3.h GLES3/gl3ext.h GLES2/gl2ext.h], [:],
 614         [HAVE_GLESv3=0], [
 615 #ifdef HAVE_GLES3_GL3_H
 616 # include <GLES3/gl3.h>
 617 #endif
 618     ])
 619     CPPFLAGS="$saved_CPPFLAGS"
 620     ;;
 621 esac
 622 fi
 623 GLES_VERSION_MASK=`expr $GLES_VERSION_MASK "+" $HAVE_GLESv3 "*" 8`
 624
 625 dnl ... GLX
 626 USE_GLX=0
 627 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 628     USE_GLX=1
 629     saved_CPPFLAGS="$CPPFLAGS"
 630     saved_LIBS="$LIBS"
 631     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 632     LIBS="$LIBS $GL_LIBS"
 633     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 634 #ifdef HAVE_GL_GL_H
 635 # include <GL/gl.h>
 636 #endif
 637     ])
 638     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 639     CPPFLAGS="$saved_CPPFLAGS"
 640     LIBS="$saved_LIBS"
 641 fi
 642
 643 dnl ... EGL
 644 USE_EGL=0
 645 if test "$enable_egl" = "yes" -a $GLES_VERSION_MASK -ne 0; then
 646     USE_EGL=1
 647     PKG_CHECK_MODULES([EGL], [egl], [:], [USE_EGL=0])
 648     saved_CPPFLAGS="$CPPFLAGS"
 649     saved_LIBS="$LIBS"
 650     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL=0])
 651     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL=0])
 652     CPPFLAGS="$saved_CPPFLAGS"
 653     LIBS="$saved_LIBS"
 654 fi
 655
 656 dnl Check for Wayland
 657 USE_WAYLAND=0
 658 if test "$enable_wayland" = "yes"; then
 659     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 660         [USE_WAYLAND=1], [USE_WAYLAND=0])
 661
 662     if test $USE_WAYLAND -eq 1; then
 663         saved_CPPFLAGS="$CPPFLAGS"
 664         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 665         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 666         CPPFLAGS="$saved_CPPFLAGS"
 667     fi
 668 fi
 669
 670 dnl ---------------------------------------------------------------------------
 671 dnl -- VA-API                                                                --
 672 dnl ---------------------------------------------------------------------------
 673
 674 dnl Core API
 675 LIBVA_PKGNAME="libva"
 676 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 677 AC_SUBST(LIBVA_PKGNAME)
 678
 679 VA_VERSION=`$PKG_CONFIG --modversion libva`
 680 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 681 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 682 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 683 VA_VERSION_STR="$VA_VERSION"
 684
 685 dnl VA/DRM API
 686 HAVE_VA_DRM=0
 687 if test $USE_DRM -eq 1; then
 688     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 689         [HAVE_VA_DRM=1], [USE_DRM=0])
 690
 691     if test $HAVE_VA_DRM -eq 1; then
 692         saved_CPPFLAGS="$CPPFLAGS"
 693         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 694         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 695         CPPFLAGS="$saved_CPPFLAGS"
 696     fi
 697 fi
 698
 699 dnl VA/X11 API
 700 HAVE_VA_X11=0
 701 LIBVA_X11_PKGNAME="libva-x11"
 702 if test $USE_X11 -eq 1; then
 703     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 704         [HAVE_VA_X11=1], [USE_X11=0])
 705 fi
 706 AC_SUBST(LIBVA_X11_PKGNAME)
 707
 708 dnl Check for va_dec_jpeg.h header
 709 saved_CPPFLAGS="$CPPFLAGS"
 710 CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 711 AC_CHECK_HEADERS([va/va_dec_jpeg.h], [], [], [#include <va/va.h>])
 712 CPPFLAGS="$saved_CPPFLAGS"
 713
 714 dnl Check for JPEG decoding API (0.32.1+)
 715 USE_JPEG_DECODER=0
 716 AC_CACHE_CHECK([for JPEG decoding API],
 717     ac_cv_have_jpeg_decoding_api, [
 718     saved_CPPFLAGS="$CPPFLAGS"
 719     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 720     saved_LIBS="$LIBS"
 721     LIBS="$LIBS $LIBVA_LIBS"
 722     AC_COMPILE_IFELSE(
 723         [AC_LANG_PROGRAM(
 724             [[#include <va/va.h>
 725               #ifdef HAVE_VA_VA_DEC_JPEG_H
 726               #include <va/va_dec_jpeg.h>
 727               #endif
 728             ]],
 729             [[VAPictureParameterBufferJPEGBaseline pic_param;
 730               VASliceParameterBufferJPEGBaseline slice_param;
 731               VAHuffmanTableBufferJPEGBaseline huffman_table;
 732               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 733         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 734         [ac_cv_have_jpeg_decoding_api="no"]
 735     )
 736     CPPFLAGS="$saved_CPPFLAGS"
 737     LIBS="$saved_LIBS"
 738 ])
 739
 740 dnl Check for va_dec_vp8.h header
 741 saved_CPPFLAGS="$CPPFLAGS"
 742 CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 743 AC_CHECK_HEADERS([va/va_dec_vp8.h], [], [], [#include <va/va.h>])
 744 CPPFLAGS="$saved_CPPFLAGS"
 745
 746 dnl Check for VP8 decoding API (0.34+)
 747 USE_VP8_DECODER=0
 748 AC_CACHE_CHECK([for VP8 decoding API],
 749     ac_cv_have_vp8_decoding_api, [
 750     saved_CPPFLAGS="$CPPFLAGS"
 751     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 752     saved_LIBS="$LIBS"
 753     LIBS="$LIBS $LIBVA_LIBS"
 754     AC_COMPILE_IFELSE(
 755         [AC_LANG_PROGRAM(
 756             [[#include <va/va.h>
 757               #ifdef HAVE_VA_VA_DEC_VP8_H
 758               #include <va/va_dec_vp8.h>
 759               #endif
 760             ]],
 761             [[VAPictureParameterBufferVP8 pic_param;
 762               VASliceParameterBufferVP8 slice_param;
 763               VAProbabilityDataBufferVP8 prob_data;
 764               VAIQMatrixBufferVP8 iq_matrix;
 765               slice_param.slice_data_offset = 0;
 766               slice_param.slice_data_flag = 0;]])],
 767         [ac_cv_have_vp8_decoding_api="yes" USE_VP8_DECODER=1],
 768         [ac_cv_have_vp8_decoding_api="no"]
 769     )
 770     CPPFLAGS="$saved_CPPFLAGS"
 771     LIBS="$saved_LIBS"
 772 ])
 773
 774
 775 dnl Check for vpp (video post-processing) support
 776 USE_VA_VPP=0
 777 AC_CACHE_CHECK([for video post-postprocessing API],
 778     ac_cv_have_va_vpp_api, [
 779     saved_CPPFLAGS="$CPPFLAGS"
 780     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 781     saved_LIBS="$LIBS"
 782     LIBS="$LIBS $LIBVA_LIBS"
 783     AC_COMPILE_IFELSE(
 784         [AC_LANG_PROGRAM(
 785             [[#include <va/va.h>
 786               #include <va/va_vpp.h>]],
 787             [[VADisplay va_dpy;
 788               VAContextID vpp_ctx;
 789               VAProcFilterType filters[VAProcFilterCount];
 790               unsigned int num_filters = VAProcFilterCount;
 791               vaQueryVideoProcFilters(va_dpy, vpp_ctx, filters, &num_filters);
 792               ]])],
 793         [ac_cv_have_va_vpp_api="yes" USE_VA_VPP=1],
 794         [ac_cv_have_va_vpp_api="no"]
 795     )
 796     CPPFLAGS="$saved_CPPFLAGS"
 797     LIBS="$saved_LIBS"
 798 ])
 799
 800 dnl Check for encoding support
 801 USE_ENCODERS=0
 802 USE_JPEG_ENCODER=0
 803 USE_VP8_ENCODER=0
 804 if test "$enable_encoders" = "yes"; then
 805     PKG_CHECK_MODULES([LIBVA], [libva >= va_api_enc_version],
 806         [HAVE_VA_ENC=1], [HAVE_VA_ENC=0])
 807
 808     if test $HAVE_VA_ENC -eq 1; then
 809         saved_CPPFLAGS="$CPPFLAGS"
 810         CPPFLAGS="$LIBVA_CFLAGS"
 811         AC_CHECK_HEADERS([va/va_enc_mpeg2.h va/va_enc_h264.h],
 812             [USE_ENCODERS=1], [HAVE_VA_ENC=0 USE_ENCODERS=0],
 813             [#include <va/va.h>
 814             ])
 815
 816         dnl Check for JPEG Encoding API (0.37.0+)
 817         AC_CHECK_HEADERS([va/va_enc_jpeg.h],
 818             [USE_JPEG_ENCODER=1], [],
 819             [#include <va/va.h>
 820             ])
 821         AC_CACHE_CHECK([for JPEG encoding API],
 822             ac_cv_have_jpeg_encoding_api, [
 823             saved_CPPFLAGS="$CPPFLAGS"
 824             CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 825             saved_LIBS="$LIBS"
 826             LIBS="$LIBS $LIBVA_LIBS"
 827             AC_COMPILE_IFELSE(
 828                 [AC_LANG_PROGRAM(
 829                     [[#include <va/va.h>
 830                       #ifdef HAVE_VA_VA_ENC_JPEG_H
 831                       #include <va/va_enc_jpeg.h>
 832                       #endif
 833                     ]],
 834                     [[VAEncPictureParameterBufferJPEG pic_param;
 835                       VAEncSliceParameterBufferJPEG slice_param;
 836                       VAQMatrixBufferJPEG q_matrix;]])],
 837                 [ac_cv_have_jpeg_encoding_api="yes" USE_JPEG_ENCODER=1],
 838                 [ac_cv_have_jpeg_encoding_api="no"]
 839             )
 840             CPPFLAGS="$saved_CPPFLAGS"
 841             LIBS="$saved_LIBS"
 842         ])
 843
 844         dnl Check for VP8 Encoding API
 845         AC_CHECK_HEADERS([va/va_enc_vp8.h],
 846             [USE_VP8_ENCODER=1], [],
 847             [#include <va/va.h>
 848             ])
 849         AC_CACHE_CHECK([for VP8 encoding API],
 850             ac_cv_have_vp8_encoding_api, [
 851             saved_CPPFLAGS="$CPPFLAGS"
 852             CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 853             saved_LIBS="$LIBS"
 854             LIBS="$LIBS $LIBVA_LIBS"
 855             AC_COMPILE_IFELSE(
 856                 [AC_LANG_PROGRAM(
 857                     [[#include <va/va.h>
 858                       #ifdef HAVE_VA_VA_ENC_VP8_H
 859                       #include <va/va_enc_vp8.h>
 860                       #endif
 861                     ]],
 862                     [[VAEncSequenceParameterBufferVP8 seq_param;
 863                       VAEncPictureParameterBufferVP8 pic_param;
 864                       VAQMatrixBufferVP8 q_matrix;]])],
 865                 [ac_cv_have_vp8_encoding_api="yes" USE_VP8_ENCODER=1],
 866                 [ac_cv_have_vp8_encoding_api="no" USE_VP8_ENCODER=0]
 867             )
 868             CPPFLAGS="$saved_CPPFLAGS"
 869             LIBS="$saved_LIBS"
 870         ])
 871         CPPFLAGS="$saved_CPPFLAGS"
 872     fi
 873 fi
 874
 875 dnl VA/Wayland API
 876 if test "$enable_wayland" = "yes"; then
 877     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 878         [:], [USE_WAYLAND=0])
 879 fi
 880
 881 dnl ---------------------------------------------------------------------------
 882 dnl -- Generate files and summary                                            --
 883 dnl ---------------------------------------------------------------------------
 884
 885 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 886 *:1:*)
 887     ;;
 888 *)
 889     AC_MSG_ERROR([No renderer is enabled])
 890     ;;
 891 esac
 892
 893 AC_DEFINE_UNQUOTED([USE_ENCODERS], $USE_ENCODERS,
 894     [Defined to 1 if video encoders are used])
 895 AM_CONDITIONAL([USE_ENCODERS], [test $USE_ENCODERS -eq 1])
 896
 897 AC_DEFINE_UNQUOTED(USE_JPEG_ENCODER, $USE_JPEG_ENCODER,
 898     [Defined to 1 if JPEG encoder is used])
 899 AM_CONDITIONAL(USE_JPEG_ENCODER, test $USE_JPEG_ENCODER -eq 1)
 900
 901 AC_DEFINE_UNQUOTED(USE_VP8_ENCODER, $USE_VP8_ENCODER,
 902     [Defined to 1 if VP8 encoder is used])
 903 AM_CONDITIONAL(USE_VP8_ENCODER, test $USE_VP8_ENCODER -eq 1)
 904
 905 AC_DEFINE_UNQUOTED(USE_VA_VPP, $USE_VA_VPP,
 906     [Defined to 1 if video post-processing is used])
 907 AM_CONDITIONAL(USE_VA_VPP, test $USE_VA_VPP -eq 1)
 908
 909 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 910     [Defined to 1 if JPEG decoder is used])
 911 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 912
 913 AC_DEFINE_UNQUOTED(USE_VP8_DECODER, $USE_VP8_DECODER,
 914     [Defined to 1 if VP8 decoder is used])
 915 AM_CONDITIONAL(USE_VP8_DECODER, test $USE_VP8_DECODER -eq 1)
 916
 917 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 918     [Defined to 1 if DRM is enabled])
 919 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 920
 921 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 922     [Defined to 1 if X11 is enabled])
 923 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 924
 925 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 926     [Defined to 1 if GLX is enabled])
 927 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 928
 929 AC_DEFINE_UNQUOTED([USE_EGL], [$USE_EGL],
 930     [Defined to 1 if EGL is enabled])
 931 AM_CONDITIONAL([USE_EGL], [test $USE_EGL -eq 1])
 932
 933 AC_DEFINE_UNQUOTED([USE_GLES_VERSION_MASK], [$GLES_VERSION_MASK],
 934     [Defined to the set of enabled OpenGL ES APIs])
 935
 936 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 937     [Defined to 1 if WAYLAND is enabled])
 938 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 939
 940 pkgconfigdir=${libdir}/pkgconfig
 941 AC_SUBST(pkgconfigdir)
 942
 943 AC_CONFIG_FILES([
 944     Makefile
 945     debian.upstream/Makefile
 946     debian.upstream/changelog
 947     debian.upstream/control
 948     debian.upstream/gstreamer$GST_API_VERSION-vaapi-doc.install:\
 949 debian.upstream/gstreamer-vaapi-doc.install.in
 950     debian.upstream/gstreamer$GST_API_VERSION-vaapi.install:\
 951 debian.upstream/gstreamer-vaapi.install.in
 952     debian.upstream/libgstvaapi$GST_PKG_VERSION-dev.install:\
 953 debian.upstream/libgstvaapi-dev.install.in
 954     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 955 debian.upstream/libgstvaapi.install.in
 956     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 957 debian.upstream/libgstvaapi-drm.install.in
 958     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 959 debian.upstream/libgstvaapi-glx.install.in
 960     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 961 debian.upstream/libgstvaapi-wayland.install.in
 962     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 963 debian.upstream/libgstvaapi-x11.install.in
 964     docs/Makefile
 965     docs/reference/Makefile
 966     docs/reference/libs/Makefile
 967     docs/reference/libs/libs-docs.xml
 968     docs/reference/plugins/Makefile
 969     docs/reference/plugins/plugins-docs.xml
 970     ext/Makefile
 971     ext/libvpx/Makefile
 972     gst-libs/Makefile
 973     gst-libs/gst/Makefile
 974     gst-libs/gst/base/Makefile
 975     gst-libs/gst/codecparsers/Makefile
 976     gst-libs/gst/vaapi/Makefile
 977     gst-libs/gst/video/Makefile
 978     gst/Makefile
 979     gst/vaapi/Makefile
 980     patches/Makefile
 981     patches/videoparsers/Makefile
 982     pkgconfig/Makefile
 983     pkgconfig/gstreamer-vaapi-$GST_PKG_VERSION.pc:\
 984 pkgconfig/gstreamer-vaapi.pc.in
 985     pkgconfig/gstreamer-vaapi-drm-$GST_PKG_VERSION.pc:\
 986 pkgconfig/gstreamer-vaapi-drm.pc.in
 987     pkgconfig/gstreamer-vaapi-glx-$GST_PKG_VERSION.pc:\
 988 pkgconfig/gstreamer-vaapi-glx.pc.in
 989     pkgconfig/gstreamer-vaapi-wayland-$GST_PKG_VERSION.pc:\
 990 pkgconfig/gstreamer-vaapi-wayland.pc.in
 991     pkgconfig/gstreamer-vaapi-x11-$GST_PKG_VERSION.pc:\
 992 pkgconfig/gstreamer-vaapi-x11.pc.in
 993     tests/Makefile
 994 ])
 995 AC_OUTPUT
 996
 997 dnl Print summary
 998 yesno() {
 999     test $1 -eq 1 && echo yes || echo no
1000 }
1001
1002 VIDEO_OUTPUTS=""
1003 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
1004 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
1005 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
1006 AS_IF([test $USE_EGL -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS egl"])
1007 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
1008
1009 echo
1010 echo $PACKAGE configuration summary:
1011 echo
1012 echo Installation Prefix .............. : ${prefix}
1013 echo GStreamer API version ............ : $GST_API_VERSION
1014 echo VA-API version ................... : $VA_VERSION_STR
1015 echo Video encoding ................... : $(yesno $USE_ENCODERS)
1016 echo Video outputs .................... : $VIDEO_OUTPUTS
1017 echo