configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.6.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.17
  50 GSTPB_REQ=0.10.17
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 dnl these are all the gst plug-ins, compilable without additional libs
  80 dnl videofilter is at the top because others depend on it
  81 GST_PLUGINS_ALL="\
  82                 videofilter \
  83                 alpha \
  84                 apetag \
  85                 audiofx \
  86                 auparse \
  87                 autodetect \
  88                 avi \
  89                 cutter \
  90                 debug \
  91                 effectv \
  92                 id3demux \
  93                 icydemux \
  94                 flx \
  95                 goom \
  96                 law \
  97                 level \
  98                 matroska \
  99                 monoscope \
 100                 multipart \
 101                 qtdemux \
 102                 rtp     \
 103                 rtsp    \
 104                 smpte   \
 105                 udp     \
 106                 videobox \
 107                 videocrop \
 108                 videomixer \
 109                 wavenc \
 110                 wavparse \
 111                 "
 112 AC_SUBST(GST_PLUGINS_ALL)
 113
 114 GST_PLUGINS_SELECTED=""
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 dnl disable gst plugins we might not be able to build on this
 118 dnl platform: udp and rtsp (ugly but minimally invasive)
 119 dnl FIXME: maybe move to sys
 120 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 121 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 122
 123 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 124   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 125   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 126 fi
 127
 128 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 129   WIN32_LIBS="-lws2_32"
 130   AC_SUBST(WIN32_LIBS)
 131 fi
 132
 133 AG_GST_ARG_ENABLE_EXTERNAL
 134
 135 AG_GST_ARG_ENABLE_EXPERIMENTAL
 136 USE_GST_V4L2=$BUILD_EXPERIMENTAL
 137 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 138         GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 139 fi
 140
 141 AC_SUBST(GST_PLUGINS_SELECTED)
 142
 143 dnl *** checks for platform ***
 144
 145 dnl * hardware/architecture *
 146
 147 dnl common/m4/gst-arch.m4
 148 dnl check CPU type
 149 AG_GST_ARCH
 150
 151 dnl Determine endianness
 152 AC_C_BIGENDIAN
 153
 154 dnl *** checks for programs ***
 155
 156 dnl find a compiler
 157 AC_PROG_CC
 158
 159 dnl determine c++ compiler
 160 AC_PROG_CXX
 161 dnl determine if c++ is available on this system
 162 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 163
 164 dnl determine c++ preprocessor
 165 dnl FIXME: do we need this ?
 166 AC_PROG_CXXCPP
 167
 168 AS_PROG_OBJC
 169
 170 dnl check if the compiler supports '-c' and '-o' options
 171 AM_PROG_CC_C_O
 172
 173 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 174 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 175
 176 dnl check for gconftool-2
 177 dnl this macro defines an am conditional, so it needs to be run always
 178 AM_GCONF_SOURCE_2
 179
 180 dnl check for documentation tools
 181 GTK_DOC_CHECK([1.3])
 182 AS_PATH_PYTHON([2.1])
 183 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 184
 185 dnl *** checks for libraries ***
 186
 187 dnl check for libm, for sin()
 188 AC_CHECK_LIBM
 189 AC_SUBST(LIBM)
 190
 191 dnl *** checks for header files ***
 192
 193 dnl check if we have ANSI C header files
 194 AC_HEADER_STDC
 195
 196 dnl used by ext/wavpack
 197 AX_CREATE_STDINT_H
 198
 199 dnl used in gst/rtp/gstasteriskh263.c
 200 AC_CHECK_HEADERS([netinet/in.h])
 201 AC_CHECK_HEADERS([winsock2.h])
 202 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 203
 204 dnl used in gst/udp
 205 AC_CHECK_HEADERS([sys/time.h])
 206
 207 dnl *** checks for types/defines ***
 208
 209 dnl Check for FIONREAD ioctl declaration.  This check is needed
 210 dnl for the UDP plugin to build on Solaris
 211 GST_CHECK_FIONREAD
 212
 213 dnl *** checks for structures ***
 214
 215 dnl *** checks for compiler characteristics ***
 216
 217 dnl FIXME: check if this is used; was used for floatcast.h in base
 218 dnl Check for fast float to int casting as defined in C99
 219 AC_C99_FUNC_LRINT
 220 AC_C99_FUNC_LRINTF
 221
 222 dnl *** checks for library functions ***
 223
 224 LIBS_SAVE=$LIBS
 225 LIBS="$LIBS $LIBM"
 226 AC_CHECK_FUNCS(rint)
 227 LIBS=$LIBS_SAVE
 228
 229 dnl Check for mmap (needed by electricfence plugin)
 230 AC_FUNC_MMAP
 231 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 232
 233 dnl *** checks for dependency libraries ***
 234
 235 dnl GLib is required
 236 AG_GST_GLIB_CHECK([2.6])
 237
 238 dnl liboil is required
 239 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 240 if test "x${HAVE_LIBOIL}" != xyes ; then
 241   AC_ERROR([liboil-0.3.8 or later is required])
 242 fi
 243
 244 dnl checks for gstreamer
 245 dnl uninstalled is selected preferentially -- see pkg-config(1)
 246 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 247 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 248 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 249 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 250 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 251 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 252
 253 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 254 if test -z $GST_TOOLS_DIR; then
 255   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 256 fi
 257 AC_SUBST(GST_TOOLS_DIR)
 258
 259 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 260 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 261
 262 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 263
 264 dnl Check for documentation xrefs
 265 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 266 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 267 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 268 AC_SUBST(GLIB_PREFIX)
 269 AC_SUBST(GST_PREFIX)
 270 AC_SUBST(GSTPB_PREFIX)
 271
 272 dnl GTK is optional and used in examples
 273 HAVE_GTK=NO
 274 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 275 if test "x$HAVE_GTK_22" = "xyes"; then
 276   HAVE_GTK=yes
 277   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 278   AC_SUBST(GTK_VERSION)
 279   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 280   AC_SUBST(GTK_BASE_DIR)
 281   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 282   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 283   AC_SUBST(GTK_BASE_DIR)
 284 else
 285   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 286 fi
 287 if test "x$HAVE_GTK_20" = "xyes"; then
 288   HAVE_GTK=yes
 289 fi
 290 GTK_CFLAGS=$GTK2_CFLAGS
 291 GTK_LIBS=$GTK2_LIBS
 292 AC_SUBST(GTK_LIBS)
 293 AC_SUBST(GTK_CFLAGS)
 294 AC_SUBST(HAVE_GTK)
 295 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 296
 297 dnl should we install schemas ?
 298 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 299 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 300   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 301   if test x$GCONFTOOL = xno; then
 302     AC_MSG_WARN(Not installing GConf schemas)
 303     HAVE_GCONFTOOL="no"
 304   else
 305     HAVE_GCONFTOOL="yes"
 306   fi
 307   AC_SUBST(HAVE_GCONFTOOL)
 308 ])
 309
 310 dnl *** set variables based on configure arguments ***
 311
 312 dnl set license and copyright notice
 313 GST_LICENSE="LGPL"
 314 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 315 AC_SUBST(GST_LICENSE)
 316
 317 dnl set location of plugin directory
 318 AG_GST_SET_PLUGINDIR
 319
 320 dnl define an ERROR_CFLAGS Makefile variable
 321 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 322
 323 dnl define correct level for debugging messages
 324 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 325
 326 dnl used in examples
 327 AG_GST_DEFAULT_ELEMENTS
 328
 329 dnl *** sys plug-ins ***
 330
 331 echo
 332 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 333 echo
 334
 335 dnl DirectDraw
 336 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 337 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 338   HAVE_DIRECTDRAW="no"
 339   save_CFLAGS="$CFLAGS"
 340   save_LDFLAGS="$LDFLAGS"
 341   save_LIBS="$LIBS"
 342   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 343   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 344   LIBS="$LIBS -lddraw -lgdi32"
 345   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 346   AC_LINK_IFELSE([
 347 #include <windows.h>
 348 #include <ddraw.h>
 349
 350 int main ()
 351 {
 352   GetStockObject(0);
 353   DirectDrawCreate(NULL, NULL, NULL);
 354
 355   return 0;
 356 }
 357 ],
 358     [HAVE_DIRECTDRAW="yes"],
 359     [HAVE_DIRECTDRAW="no"])
 360   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 361   CFLAGS=$save_CFLAGS
 362   LDFLAGS=$save_LDFLAGS
 363   LIBS=$save_LIBS
 364
 365   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 366     dnl this is much more than we want
 367     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 368     AC_SUBST(DIRECTDRAW_CFLAGS)
 369     AC_SUBST(DIRECTDRAW_LDFLAGS)
 370     AC_SUBST(DIRECTDRAW_LIBS)
 371   fi
 372   AC_SUBST(HAVE_DIRECTDRAW)
 373 ])
 374
 375 dnl DirectSound
 376 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 377 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 378   HAVE_DIRECTSOUND="no"
 379   save_CFLAGS="$CFLAGS"
 380   save_LDFLAGS="$LDFLAGS"
 381   save_LIBS="$LIBS"
 382   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 383   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 384   LIBS="$LIBS -ldsound -ldxerr9"
 385   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 386   AC_LINK_IFELSE([
 387 #include <windows.h>
 388 #include <dxerr9.h>
 389 #include <dsound.h>
 390
 391 int main ()
 392 {
 393   DXGetErrorString9 (0);
 394   DirectSoundCreate(NULL, NULL, NULL);
 395
 396   return 0;
 397 }
 398 ],
 399     [HAVE_DIRECTSOUND="yes"],
 400     [HAVE_DIRECTSOUND="no"])
 401   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 402   CFLAGS=$save_CFLAGS
 403   LDFLAGS=$save_LDFLAGS
 404   LIBS=$save_LIBS
 405
 406   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 407     dnl this is much more than we want
 408     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 409     AC_SUBST(DIRECTSOUND_CFLAGS)
 410     AC_SUBST(DIRECTSOUND_LDFLAGS)
 411     AC_SUBST(DIRECTSOUND_LIBS)
 412   fi
 413   AC_SUBST(HAVE_DIRECTSOUND)
 414 ])
 415
 416 dnl *** OSS audio *** (Linux, *BSD)
 417 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 418 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 419  HAVE_OSS="yes"
 420 dnl Linux and newer BSD versions :
 421  AC_CHECK_HEADER(sys/soundcard.h, [
 422    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 423    ] , [
 424 dnl Some old BSD versions and also newer OpenBSD versions :
 425    AC_CHECK_HEADER(soundcard.h, [
 426      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 427      ], [
 428   dnl Some old BSD versions :
 429      AC_CHECK_HEADER(machine/soundcard.h, [
 430        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 431          [Define if OSS includes are in /machine/])
 432        ], [
 433        HAVE_OSS="no"
 434      ])
 435    ])
 436  ])
 437 ])
 438
 439 dnl *** Sun Audio ***
 440 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 441 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 442   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 443 ])
 444
 445 dnl *** OSX Audio ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 447 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 448   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 449 ])
 450
 451 dnl *** OS X video ***
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 453 HAVE_OSX_VIDEO="no"
 454 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 455   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 456 ])
 457 dnl in case header OpenGL/gl.h is found on other platforms
 458 case "$host" in
 459   *-*darwin*)
 460     dnl do nothing
 461     ;;
 462   *)
 463     HAVE_OSX_VIDEO="no"
 464     ;;
 465 esac
 466
 467
 468 dnl *** Video 4 Linux 2 ***
 469 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 470 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 472 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 473   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 474   AC_TRY_COMPILE([
 475 #include <sys/types.h>
 476 #ifdef __sun /* Solaris */
 477 #include <sys/types.h>
 478 #include <sys/videodev2.h>
 479 #else /* Linux */
 480 #include <linux/types.h>
 481 #define _LINUX_TIME_H
 482 #define __user
 483 #include <linux/videodev2.h>
 484 #endif
 485 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 486 #error too early v4l2 version or no v4l2 at all
 487 #endif
 488     ], [
 489 return 0;
 490     ], [
 491       HAVE_GST_V4L2="yes"
 492       AC_MSG_RESULT(yes)
 493     ], [
 494       HAVE_GST_V4L2="no"
 495       AC_MSG_RESULT(no)
 496
 497       HAVE_VIDEODEV=no
 498       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 499       [
 500         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 501       ])
 502
 503       if test "x$HAVE_VIDEODEV" = "xyes"; then
 504         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 505         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 506       else
 507         AC_MSG_WARN([video4linux2 was not found])
 508       fi
 509     ])
 510
 511   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 512     dnl check for missing v4l2_buffer declaration (see #135919)
 513     MISSING_DECL=0
 514     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 515     AC_TRY_COMPILE([
 516 #include <sys/types.h>
 517 #ifdef __sun /* Solaris */
 518 #include <sys/types.h>
 519 #include <sys/videodev2.h>
 520 #else /* Linux */
 521 #include <linux/types.h>
 522 #define _LINUX_TIME_H
 523 #define __user
 524 #include <linux/videodev2.h>
 525 #endif
 526     ],[
 527 struct v4l2_buffer buf;
 528 buf.index = 0;
 529 return 0;
 530     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 531     if [ test x$MISSING_DECL = x1 ]; then
 532       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 533     fi
 534
 535     dnl check for XOverlay libraries
 536     AG_GST_CHECK_XV
 537   fi
 538 ])
 539
 540 dnl Check for X11
 541 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 542 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 543                   [ximagesrc], [
 544   AC_PATH_XTRA
 545
 546   dnl now try to find the HEADER
 547   ac_cflags_save="$CFLAGS"
 548   ac_cppflags_save="$CPPFLAGS"
 549   CFLAGS="$CFLAGS $X_CFLAGS"
 550   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 551   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 552
 553   if test "x$HAVE_X" = "xno"
 554   then
 555     AC_MSG_NOTICE([cannot find X11 development files])
 556   else
 557     dnl this is much more than we want
 558     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 559     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 560     dnl it does not add the libs; therefore we add them here
 561     X_LIBS="$X_LIBS -lX11"
 562     AC_SUBST(X_CFLAGS)
 563     AC_SUBST(X_LIBS)
 564
 565     dnl check for Xfixes
 566     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 567     if test "x$HAVE_XFIXES" = "xyes"
 568     then
 569         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 570     fi
 571     AC_SUBST(XFIXES_LIBS)
 572     AC_SUBST(XFIXES_CFLAGS)
 573
 574     dnl check for Xdamage
 575     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 576     if test "x$HAVE_XDAMAGE" = "xyes"
 577     then
 578         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 579     fi
 580     AC_SUBST(XDAMAGE_LIBS)
 581     AC_SUBST(XDAMAGE_CFLAGS)
 582   fi
 583   AC_SUBST(HAVE_X)
 584   CFLAGS="$ac_cflags_save"
 585   CPPFLAGS="$ac_cppflags_save"
 586 ])
 587
 588 dnl FIXME: this should be rolled into the test above, it's just an additional
 589 dnl feature of the ximagesrc plug-in
 590 dnl This is the same as in gst-plugins-base
 591 dnl check for X Shm
 592 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 593 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 594   if test x$HAVE_X = xyes; then
 595     AC_CHECK_LIB(Xext, XShmAttach,
 596                  HAVE_XSHM="yes", HAVE_XSHM="no",
 597                  $X_LIBS)
 598     if test "x$HAVE_XSHM" = "xyes"; then
 599       XSHM_LIBS="-lXext"
 600     else
 601       dnl On AIX, it is in XextSam instead, but we still need -lXext
 602       AC_CHECK_LIB(XextSam, XShmAttach,
 603                    HAVE_XSHM="yes", HAVE_XSHM="no",
 604                    $X_LIBS)
 605       if test "x$HAVE_XSHM" = "xyes"; then
 606         XSHM_LIBS="-lXext -lXextSam"
 607       fi
 608     fi
 609   fi
 610 ], ,[
 611   AC_SUBST(HAVE_XSHM)
 612   AC_SUBST(XSHM_LIBS)
 613 ])
 614
 615 dnl for V4L2, we also need to know if we have XVIDEO
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 617 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 618                   [], [
 619   AG_GST_CHECK_XV
 620 ])
 621
 622 dnl *** ext plug-ins ***
 623 dnl keep this list sorted alphabetically !
 624
 625 if test "x$BUILD_EXTERNAL" = "xyes"; then
 626
 627 echo
 628 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 629 echo
 630
 631 dnl *** aalib ***
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 633 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 634   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 635   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 636 ])
 637
 638 dnl *** annodex ***
 639 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 640 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 641   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 642 ])
 643
 644 dnl *** cairo ***
 645 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 646 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 647   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 648 ])
 649
 650 dnl *** cdio ***
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 652 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 653   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 654 ])
 655
 656 dnl **** ESound ****
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 658 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 659   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 660   if test $HAVE_ESD = no
 661   then
 662     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 663     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 664   fi
 665 ])
 666
 667 dnl *** FLAC ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 669 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 670   #if FLAC_API_VERSION_CURRENT < 8
 671   #error "legacy flac API"
 672   #endif
 673   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 674
 675 if test "x$legacy_flac" = "xyes"; then
 676 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 677   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 678   dnl API change in FLAC 1.1.1, so require that...
 679   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 680   if test x$HAVE_FLAC = xyes; then
 681     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 682                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 683 #include <FLAC/seekable_stream_encoder.h>
 684                   ])
 685   fi
 686   AC_SUBST(FLAC_LIBS)
 687 ])
 688 else
 689 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 690   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 691   dnl API change in FLAC 1.1.3, so require that...
 692   if test x$HAVE_FLAC = xyes; then
 693     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 694                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 695 #include <FLAC/stream_encoder.h>
 696                   ])
 697   fi
 698   AC_SUBST(FLAC_LIBS)
 699 ])
 700 fi
 701
 702 dnl *** GConf ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 704 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 705   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 706 ])
 707
 708 dnl *** GDK pixbuf ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 710 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 711   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 712 ])
 713
 714 dnl *** HAL ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 716 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 717   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 718 ])
 719
 720 dnl *** jpeg ***
 721 dnl FIXME: we could use header checks here as well IMO
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 723 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 724   AC_ARG_WITH(jpeg-mmx,
 725     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 726   OLD_LIBS="$LIBS"
 727   if test x$with_jpeg_mmx != x; then
 728     LIBS="$LIBS -L$with_jpeg_mmx"
 729   fi
 730   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 731   JPEG_LIBS="$LIBS -ljpeg-mmx"
 732   LIBS="$OLD_LIBS"
 733   if test x$HAVE_JPEG != xyes; then
 734     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 735     JPEG_LIBS="-ljpeg"
 736   fi
 737   AC_SUBST(JPEG_LIBS)
 738 ])
 739
 740 dnl *** ladspa ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 742 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 743   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 744 ], disabled)
 745
 746 dnl *** libcaca ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 748 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 749   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 750   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 751   if test "x$HAVE_LIBCACA" != "xyes"; then
 752     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 753     dnl see if it compilation works too, might not if we are cross-compiling
 754     if test "x$HAVE_LIBCACA" = "xyes"; then
 755       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 756                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 757     fi
 758   fi
 759 ])
 760
 761 dnl *** libdv ***
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 763 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 764   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 765 ])
 766
 767 dnl *** libpng ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 769 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 770   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 771 ])
 772
 773 dnl *** dv1394 ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 775 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 776   dnl first test for libraw1394 >= 1.2.1
 777   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 778   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 779   dnl now see how far we got
 780   if test x$HAVE_RAW1394 = xyes && \
 781      test x$HAVE_LIBIEC61883 = xyes; then
 782        AG_GST_CHECK_LIBHEADER(AVC1394,
 783         avc1394, avc1394_send_command, $RAW1394_LIBS,
 784         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 785        AG_GST_CHECK_LIBHEADER(ROM1394,
 786         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 787         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 788        if test x$HAVE_AVC1394 = xyes && \
 789           test x$HAVE_AVC1394 = xyes && \
 790           test x$HAVE_ROM1394 = xyes; then
 791           HAVE_DV1394=yes
 792           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 793           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 794           AC_SUBST(DV1394_CFLAGS)
 795           AC_SUBST(DV1394_LIBS)
 796         fi
 797   else
 798        if test x$HAVE_RAW1394 = xno; then
 799           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 800           AG_GST_CHECK_LIBHEADER(AVC1394,
 801            avc1394, avc1394_send_command, $RAW1394_LIBS,
 802            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 803           AG_GST_CHECK_LIBHEADER(ROM1394,
 804            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 805            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 806           if test x$HAVE_RAW1394 = xyes && \
 807              test x$HAVE_AVC1394 = xyes && \
 808              test x$HAVE_ROM1394 = xyes; then
 809              HAVE_DV1394=yes
 810              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 811              DV1394_CFLAGS="$RAW1394_CFLAGS"
 812              if test x$HAVE_LIBIEC61883 = xyes; then
 813                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 814                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 815              fi
 816              AC_SUBST(DV1394_CFLAGS)
 817              AC_SUBST(DV1394_LIBS)
 818            fi
 819          fi
 820   fi
 821 ])
 822
 823 dnl *** shout2 ***
 824 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 825 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 826   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 827   if test $HAVE_SHOUT2 = no
 828   then
 829     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 830     AC_SUBST(SHOUT2_CFLAGS)
 831     AC_SUBST(SHOUT2_LIBS)
 832   fi
 833 ])
 834
 835 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 836 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 837 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 838 dnl   speex_jitter.h is 1.1.x only
 839 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 840 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 841   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 842   if test $HAVE_SPEEX = no
 843   then
 844     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 845       AC_CHECK_HEADER(speex/speex_jitter.h, [
 846         dnl speex 1.1.x :
 847         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 848           dnl speex 1.1.5 or + :
 849           HAVE_SPEEX="yes"
 850           SPEEX_LIBS="-lspeex"
 851           AC_SUBST(SPEEX_CFLAGS)
 852           AC_SUBST(SPEEX_LIBS)
 853         ],[
 854           HAVE_SPEEX="no"
 855         ])
 856       ],[
 857         dnl speex 1.0.x :
 858           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 859             dnl speex 1.0.4
 860             HAVE_SPEEX="yes"
 861             SPEEX_LIBS="-lspeex"
 862             AC_SUBST(SPEEX_CFLAGS)
 863             AC_SUBST(SPEEX_LIBS)
 864
 865             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 866               [defined if speex 1.0.x API detected])
 867         ],[
 868             HAVE_SPEEX="no"
 869             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 870         ], [
 871 #include <speex/speex.h>
 872         ])
 873       ])
 874     ])
 875   fi
 876 ])
 877
 878 dnl *** taglib ***
 879 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 880 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 881   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 882   if test "x$HAVE_CXX" != "xyes"; then
 883     USE_TAGLIB=false
 884     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 885   fi
 886 ])
 887
 888 dnl *** wavpack ***
 889 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 890 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 891   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 892     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 893       HAVE_WAVPACK=yes
 894       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 895     ],[
 896       HAVE_WAVPACK=no
 897       AC_MSG_RESULT(no)
 898     ])
 899   ])
 900   AC_SUBST(WAVPACK_CFLAGS)
 901   AC_SUBST(WAVPACK_LIBS)
 902 ])
 903
 904 dnl *** qtdemux & id3demux prefer to have zlib ***
 905 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 906 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 907   AG_GST_CHECK_LIBHEADER(ZLIB,
 908     z, uncompress,, zlib.h, [
 909     HAVE_ZLIB="yes"
 910     ZLIB_LIBS="-lz"
 911     AC_SUBST(ZLIB_LIBS)
 912   ])
 913 ])
 914
 915 else
 916
 917 dnl not building plugins with external dependencies,
 918 dnl but we still need to set the conditionals
 919 AM_CONDITIONAL(USE_GCONFTOOL, false)
 920 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 921 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 922 AM_CONDITIONAL(USE_OSS, false)
 923 AM_CONDITIONAL(USE_SUNAUDIO, false)
 924 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 925 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 926 AM_CONDITIONAL(USE_X, false)
 927 AM_CONDITIONAL(USE_XSHM, false)
 928 AM_CONDITIONAL(USE_AALIB, false)
 929 AM_CONDITIONAL(USE_ANNODEX, false)
 930 AM_CONDITIONAL(USE_CAIRO, false)
 931 AM_CONDITIONAL(USE_CDIO, false)
 932 AM_CONDITIONAL(USE_ESD, false)
 933 AM_CONDITIONAL(USE_FLAC, false)
 934 AM_CONDITIONAL(USE_GCONF, false)
 935 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 936 AM_CONDITIONAL(USE_HAL, false)
 937 AM_CONDITIONAL(USE_JPEG, false)
 938 AM_CONDITIONAL(USE_LADSPA, false)
 939 AM_CONDITIONAL(USE_LIBCACA, false)
 940 AM_CONDITIONAL(USE_LIBDV, false)
 941 AM_CONDITIONAL(USE_LIBPNG, false)
 942 AM_CONDITIONAL(USE_DV1394, false)
 943 AM_CONDITIONAL(USE_SHOUT2, false)
 944 AM_CONDITIONAL(USE_SPEEX, false)
 945 AM_CONDITIONAL(USE_TAGLIB, false)
 946 AM_CONDITIONAL(USE_WAVPACK, false)
 947 AM_CONDITIONAL(USE_ZLIB, false)
 948
 949 fi dnl of EXT plugins
 950
 951 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 952
 953 dnl Overview:
 954 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 955 dnl GST_*:              flags shared by all built objects
 956 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 957 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 958 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 959 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 960
 961 dnl GST_OPTION_CFLAGS
 962 if test "x$USE_DEBUG" = xyes; then
 963    PROFILE_CFLAGS="-g"
 964 fi
 965 AC_SUBST(PROFILE_CFLAGS)
 966
 967 if test "x$GST_CVS" = "xyes"; then
 968   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 969 else
 970   DEPRECATED_CFLAGS=""
 971 fi
 972 AC_SUBST(DEPRECATED_CFLAGS)
 973
 974 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 975 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 976 AC_SUBST(GST_OPTION_CFLAGS)
 977
 978 dnl our libraries need to be versioned correctly
 979 AC_SUBST(GST_LT_LDFLAGS)
 980
 981 dnl FIXME: do we want to rename to GST_ALL_* ?
 982 dnl prefer internal headers to already installed ones
 983 dnl also add builddir include for enumtypes and marshal
 984 dnl add ERROR_CFLAGS, but overridable
 985 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 986 AC_SUBST(GST_CFLAGS)
 987 AC_SUBST(GST_LIBS)
 988
 989 dnl LDFLAGS really should only contain flags, not libs - they get added before
 990 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 991 GST_ALL_LDFLAGS="-no-undefined"
 992 AC_SUBST(GST_ALL_LDFLAGS)
 993
 994 dnl this really should only contain flags, not libs - they get added before
 995 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 996 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 997 AC_SUBST(GST_PLUGIN_LDFLAGS)
 998
 999 dnl *** output files ***
1000
1001 dnl keep this alphabetic per directory, please
1002 AC_CONFIG_FILES(
1003 Makefile
1004 gst/Makefile
1005 gst/alpha/Makefile
1006 gst/apetag/Makefile
1007 gst/audiofx/Makefile
1008 gst/auparse/Makefile
1009 gst/autodetect/Makefile
1010 gst/avi/Makefile
1011 gst/cutter/Makefile
1012 gst/debug/Makefile
1013 gst/effectv/Makefile
1014 gst/id3demux/Makefile
1015 gst/icydemux/Makefile
1016 gst/goom/Makefile
1017 gst/law/Makefile
1018 gst/level/Makefile
1019 gst/matroska/Makefile
1020 gst/monoscope/Makefile
1021 gst/multipart/Makefile
1022 gst/qtdemux/Makefile
1023 gst/rtp/Makefile
1024 gst/rtsp/Makefile
1025 gst/smpte/Makefile
1026 gst/udp/Makefile
1027 gst/videobox/Makefile
1028 gst/videocrop/Makefile
1029 gst/videofilter/Makefile
1030 gst/videomixer/Makefile
1031 gst/wavenc/Makefile
1032 gst/wavparse/Makefile
1033 gst/flx/Makefile
1034 ext/jpeg/Makefile
1035 ext/Makefile
1036 ext/aalib/Makefile
1037 ext/annodex/Makefile
1038 ext/cairo/Makefile
1039 ext/cdio/Makefile
1040 ext/dv/Makefile
1041 ext/esd/Makefile
1042 ext/flac/Makefile
1043 ext/gconf/Makefile
1044 ext/gdk_pixbuf/Makefile
1045 ext/hal/Makefile
1046 ext/ladspa/Makefile
1047 ext/libcaca/Makefile
1048 ext/libpng/Makefile
1049 ext/raw1394/Makefile
1050 ext/shout2/Makefile
1051 ext/speex/Makefile
1052 ext/taglib/Makefile
1053 ext/wavpack/Makefile
1054 sys/Makefile
1055 sys/directdraw/Makefile
1056 sys/directsound/Makefile
1057 sys/oss/Makefile
1058 sys/sunaudio/Makefile
1059 sys/osxaudio/Makefile
1060 sys/osxvideo/Makefile
1061 sys/v4l2/Makefile
1062 sys/waveform/Makefile
1063 sys/ximage/Makefile
1064 po/Makefile.in
1065 tests/Makefile
1066 tests/check/Makefile
1067 tests/examples/Makefile
1068 tests/examples/level/Makefile
1069 tests/examples/rtp/Makefile
1070 tests/files/Makefile
1071 tests/icles/Makefile
1072 gconf/Makefile
1073 gconf/gstreamer.schemas
1074 common/Makefile
1075 common/m4/Makefile
1076 m4/Makefile
1077 docs/Makefile
1078 docs/plugins/Makefile
1079 docs/version.entities
1080 win32/common/config.h
1081 pkgconfig/Makefile
1082 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1083 gst-plugins-good.spec
1084 )
1085 AC_OUTPUT
1086
1087 AG_GST_OUTPUT_PLUGINS