configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 1300, 0, 1300)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.13.0.1
  50 GSTPB_REQ=1.13.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl check for pthreads
 149 AX_PTHREAD
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used by ext/wavpack
 157 AX_CREATE_STDINT_H
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/socket.h])
 164
 165 dnl *** checks for types/defines ***
 166
 167 dnl Check for FIONREAD ioctl declaration.  This check is needed
 168 dnl for the UDP plugin to build on Solaris
 169 GST_CHECK_FIONREAD
 170
 171 dnl *** checks for structures ***
 172
 173 dnl *** checks for compiler characteristics ***
 174
 175 dnl check if we have GCC inline-asm
 176 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 177 if test x$HAVE_GCC_ASM = xyes ; then
 178   AC_DEFINE(HAVE_GCC_ASM, 1,
 179     [Define if compiler supports gcc inline assembly])
 180 fi
 181 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 182
 183 dnl *** checks for library functions ***
 184
 185 LIBS_SAVE=$LIBS
 186 LIBS="$LIBS $LIBM"
 187 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 188 LIBS=$LIBS_SAVE
 189
 190 dnl Check whether isinf() is defined by math.h
 191 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 193 if test "$ac_cv_have_isinf" = "yes"
 194 then
 195     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 196 fi
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199 AC_FUNC_MMAP
 200 AC_CHECK_SIZEOF([off_t])
 201 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 202
 203 dnl Check for mmap (needed by electricfence plugin)
 204
 205 AC_CHECK_TYPE([struct ip_mreqn], [
 206               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 207               [#include <netinet/in.h>])
 208
 209 dnl *** checks for dependency libraries ***
 210
 211
 212 dnl GLib
 213 GLIB_REQ=2.40.0
 214 AG_GST_GLIB_CHECK([$GLIB_REQ])
 215
 216 dnl Orc
 217 ORC_CHECK([0.4.17])
 218
 219 dnl checks for gstreamer
 220 dnl uninstalled is selected preferentially -- see pkg-config(1)
 221 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 225 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 226 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 227
 228 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 229 if test -z $GST_TOOLS_DIR; then
 230   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 231 fi
 232 AC_SUBST(GST_TOOLS_DIR)
 233
 234 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 235 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 236
 237 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 238
 239 dnl Check for documentation xrefs
 240 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 241 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 242 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 243 AC_SUBST(GLIB_PREFIX)
 244 AC_SUBST(GST_PREFIX)
 245 AC_SUBST(GSTPB_PREFIX)
 246
 247 dnl GTK is optional and used in examples
 248 HAVE_GTK=no
 249 GTK_REQ=3.0.0
 250 if test "x$BUILD_EXAMPLES" = "xyes"; then
 251   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 252   dnl some examples need gtk+-x11
 253   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 254   AC_SUBST(GTK_LIBS)
 255   AC_SUBST(GTK_CFLAGS)
 256 fi
 257 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 258 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 259
 260 dnl Check for -Bsymbolic-functions linker flag used to avoid
 261 dnl intra-library PLT jumps, if available.
 262 AC_ARG_ENABLE(Bsymbolic,
 263               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 264               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 265                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 266                LDFLAGS=-Wl,-Bsymbolic-functions
 267                LIBS=
 268                AC_TRY_LINK([], [return 0],
 269                            AC_MSG_RESULT(yes)
 270                            enable_Bsymbolic=yes,
 271                            AC_MSG_RESULT(no)
 272                            enable_Bsymbolic=no)
 273                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 274
 275 dnl *** set variables based on configure arguments ***
 276
 277 dnl set license and copyright notice
 278 GST_LICENSE="LGPL"
 279 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 280 AC_SUBST(GST_LICENSE)
 281
 282 dnl set location of plugin directory
 283 AG_GST_SET_PLUGINDIR
 284
 285 dnl set release date/time
 286 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 287   ["${srcdir}/gst-plugins-good.doap"],
 288   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 289
 290 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 291 dnl make sure it doesn't complain about unused variables if debugging is disabled
 292 NO_WARNINGS=""
 293 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 294
 295 dnl define an ERROR_CFLAGS Makefile variable
 296 dnl -Wundef: too many broken headers
 297 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 298       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299       -Wwrite-strings -Wold-style-definition -Waggregate-return
 300       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301       -Wnested-externs $NO_WARNINGS])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 308         $NO_WARNINGS])
 309
 310 dnl define an ERROR_OBJCFLAGS Makefile variable
 311 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 312       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 313       -Wwrite-strings -Wold-style-definition
 314       -Winit-self -Wmissing-include-dirs -Wno-multichar
 315       -Wnested-externs $NO_WARNINGS])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(dtmf)
 338 AG_GST_CHECK_PLUGIN(effectv)
 339 AG_GST_CHECK_PLUGIN(equalizer)
 340 AG_GST_CHECK_PLUGIN(flv)
 341 AG_GST_CHECK_PLUGIN(flx)
 342 AG_GST_CHECK_PLUGIN(goom)
 343 AG_GST_CHECK_PLUGIN(goom2k1)
 344 AG_GST_CHECK_PLUGIN(icydemux)
 345 AG_GST_CHECK_PLUGIN(id3demux)
 346 AG_GST_CHECK_PLUGIN(imagefreeze)
 347 AG_GST_CHECK_PLUGIN(interleave)
 348 AG_GST_CHECK_PLUGIN(isomp4)
 349 AG_GST_CHECK_PLUGIN(law)
 350 AG_GST_CHECK_PLUGIN(level)
 351 AG_GST_CHECK_PLUGIN(matroska)
 352 AG_GST_CHECK_PLUGIN(monoscope)
 353 AG_GST_CHECK_PLUGIN(multifile)
 354 AG_GST_CHECK_PLUGIN(multipart)
 355 AG_GST_CHECK_PLUGIN(replaygain)
 356 AG_GST_CHECK_PLUGIN(rtp)
 357 AG_GST_CHECK_PLUGIN(rtpmanager)
 358 AG_GST_CHECK_PLUGIN(rtsp)
 359 AG_GST_CHECK_PLUGIN(shapewipe)
 360 AG_GST_CHECK_PLUGIN(smpte)
 361 AG_GST_CHECK_PLUGIN(spectrum)
 362 AG_GST_CHECK_PLUGIN(udp)
 363 AG_GST_CHECK_PLUGIN(videobox)
 364 AG_GST_CHECK_PLUGIN(videocrop)
 365 AG_GST_CHECK_PLUGIN(videofilter)
 366 AG_GST_CHECK_PLUGIN(videomixer)
 367 AG_GST_CHECK_PLUGIN(wavenc)
 368 AG_GST_CHECK_PLUGIN(wavparse)
 369 AG_GST_CHECK_PLUGIN(y4m)
 370
 371 dnl disable experimental plug-ins
 372 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 373   AG_GST_DISABLE_PLUGIN(monoscope)
 374 fi
 375
 376 dnl *** sys plug-ins ***
 377
 378 echo
 379 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 380 echo
 381
 382 dnl DirectSound
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 384 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 385   HAVE_DIRECTSOUND="no"
 386   save_CFLAGS="$CFLAGS"
 387   save_LDFLAGS="$LDFLAGS"
 388   save_LIBS="$LIBS"
 389   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 390   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 391   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 392   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 393   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 394 #include <windows.h>
 395 #include <dxerr9.h>
 396 #include <dsound.h>
 397 ]], [[
 398   DXGetErrorString9 (0);
 399   DirectSoundCreate(NULL, NULL, NULL);
 400   CLSIDFromString(NULL, NULL);
 401 ]])
 402 ],
 403     [HAVE_DIRECTSOUND="yes"],
 404     [HAVE_DIRECTSOUND="no"])
 405   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 406   CFLAGS=$save_CFLAGS
 407   LDFLAGS=$save_LDFLAGS
 408   LIBS=$save_LIBS
 409
 410   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 411     dnl this is much more than we want
 412     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 413     AC_SUBST(DIRECTSOUND_CFLAGS)
 414     AC_SUBST(DIRECTSOUND_LDFLAGS)
 415     AC_SUBST(DIRECTSOUND_LIBS)
 416   fi
 417   AC_SUBST(HAVE_DIRECTSOUND)
 418 ])
 419
 420 dnl *** Win32 WaveOut ***
 421 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 422 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 423   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 424 ])
 425
 426 dnl *** OSS audio *** (Linux, *BSD)
 427 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 428 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 429  HAVE_OSS="yes"
 430 dnl Linux and newer BSD versions :
 431  AC_CHECK_HEADER(sys/soundcard.h, [
 432    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 433    ] , [
 434 dnl Some old BSD versions and also newer OpenBSD versions :
 435    AC_CHECK_HEADER(soundcard.h, [
 436      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 437      ], [
 438   dnl Some old BSD versions :
 439      AC_CHECK_HEADER(machine/soundcard.h, [
 440        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 441          [Define if OSS includes are in /machine/])
 442        ], [
 443        HAVE_OSS="no"
 444      ])
 445    ])
 446  ])
 447 ])
 448
 449 dnl *** oss4 ***
 450 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 451 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 452   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 453   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 454       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 455       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 456 ])
 457
 458 dnl *** OSX Audio ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 460 HAVE_IOS="no"
 461 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 462   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 463     [HAVE_OSX_AUDIO="yes"],
 464     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 465     [
 466       HAVE_OSX_AUDIO="yes"
 467       HAVE_IOS="yes"
 468     ], [
 469       HAVE_OSX_AUDIO="no"
 470       HAVE_IOS="no"
 471     ])]
 472   )
 473 ])
 474 if test "x$HAVE_IOS" = "xyes"; then
 475   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 476 fi
 477 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 478
 479 dnl *** OS X video ***
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 481 HAVE_OSX_VIDEO="no"
 482 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 483   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 484
 485   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 486   dnl also require Snow Leopard or newer
 487
 488   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 489         #include <AvailabilityMacros.h>
 490         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 491         #error Too old OSX version
 492         #endif
 493       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 494 ])
 495
 496 dnl *** Video 4 Linux 2 ***
 497 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 498 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 499 HAVE_GST_V4L2=no
 500 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 501   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 502   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 503   [
 504     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 505     [
 506       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 507     ])
 508   ])
 509   if test "x$HAVE_VIDEODEV" = "xno"; then
 510      AC_MSG_WARN([video4linux2 was not found])
 511   fi
 512 ])
 513
 514 # Optional gudev for device probing
 515 AC_ARG_WITH([gudev],
 516   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 517   [],
 518   [with_gudev=check])
 519 if test x$HAVE_GST_V4L2 = xyes; then
 520   if test x$with_gudev != xno; then
 521     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 522       [ AC_DEFINE(HAVE_GUDEV, 1,
 523           [Whether gudev is available for device detection])
 524       ],
 525       [true])
 526   fi
 527 fi
 528
 529 AC_SUBST(GUDEV_CFLAGS)
 530 AC_SUBST(GUDEV_LIBS)
 531
 532 # Make libv4l2 non-automagic
 533 AC_ARG_WITH([libv4l2],
 534   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 535   [],
 536   [with_libv4l2=check])
 537 if test x$HAVE_GST_V4L2 = xyes; then
 538   if test x$with_libv4l2 != xno; then
 539       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 540           [ have_libv4l2=yes
 541             AC_DEFINE(HAVE_LIBV4L2, 1,
 542                 [Whether libv4l2 is available for video buffer conversion])
 543           ], [
 544           have_libv4l2=no
 545           ])
 546   else
 547     have_libv4l2=no
 548   fi
 549 fi
 550
 551 dnl Allow enabling v4l2 device probing
 552 AS_CASE([$host],
 553     [*-*linux*],
 554       [AS_CASE([$host_cpu],
 555         [arm*], [
 556           enable_v4l2_probe="yes"],
 557         [aarch64*], [
 558           enable_v4l2_probe="yes"])])
 559 AC_ARG_ENABLE(
 560   v4l2-probe,
 561   AC_HELP_STRING(
 562     [--enable-v4l2-probe],
 563     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 564 if test "x$enable_v4l2_probe" = "xyes"; then
 565   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 566     [Define if Video4Linux probe shall be run at plugin load])
 567 fi
 568
 569 dnl Check for X11
 570 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 571 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 572                   [ximagesrc], [
 573   PKG_CHECK_MODULES([X], [x11], [
 574     HAVE_X="yes"
 575     dnl check for Xfixes
 576     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 577       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 578     ], [ HAVE_XFIXES="no" ])
 579
 580     dnl check for Xdamage
 581     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 582       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 583     ], [ HAVE_XDAMAGE="no" ])
 584
 585     dnl check for X Shm
 586     PKG_CHECK_MODULES([XEXT], [ xext ], [
 587       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 588         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 589         XSHM_LIBS="$XEXT_LIBS"
 590         XSHM_CFLAGS="$XEXT_CFLAGS"
 591       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 592     ])
 593     AC_SUBST(XSHM_LIBS)
 594     AC_SUBST(XSHM_CFLAGS)
 595   ], [ HAVE_X="no" ])
 596 ])
 597
 598 dnl *** ext plug-ins ***
 599 dnl keep this list sorted alphabetically !
 600
 601 if test "x$BUILD_EXTERNAL" = "xyes"; then
 602
 603 echo
 604 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 605 echo
 606
 607 dnl *** aalib ***
 608 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 609 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 610   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 611 ])
 612
 613 dnl *** cairo ***
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 615 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 616   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 617 ])
 618
 619 dnl *** FLAC ***
 620 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 621 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 622   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 623 ])
 624
 625 dnl *** GDK pixbuf ***
 626 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 627 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 628   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 629 ])
 630
 631 dnl *** Jack ***
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 633 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 634   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 635   AC_SUBST(JACK_CFLAGS)
 636   AC_SUBST(JACK_LIBS)
 637
 638   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 639   if test x$HAVE_JACK_0_120_1 = xyes; then
 640     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 641   fi
 642   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 643   if test x$HAVE_JACK_1_9_7 = xyes; then
 644     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 645   fi
 646
 647 ])
 648
 649 dnl *** jpeg ***
 650 dnl FIXME: we could use header checks here as well IMO
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 652 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 653   AC_ARG_WITH(jpeg-mmx,
 654     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 655   OLD_LIBS="$LIBS"
 656   if test x$with_jpeg_mmx != x; then
 657     LIBS="$LIBS -L$with_jpeg_mmx"
 658   fi
 659   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 660   JPEG_LIBS="$LIBS -ljpeg-mmx"
 661   LIBS="$OLD_LIBS"
 662   if test x$HAVE_JPEG != xyes; then
 663     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 664     JPEG_LIBS="-ljpeg"
 665   fi
 666   AC_SUBST(JPEG_LIBS)
 667 ])
 668
 669 dnl *** lame ***
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 671 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 672   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 673   [
 674     HAVE_LAME="yes"
 675     LAME_LIBS="-lmp3lame $LIBM"
 676     dnl is lame presets available
 677     LAME_CFLAGS=""
 678     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 679     ])
 680     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 681         void *ptr = &lame_set_VBR_quality
 682       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 683     ])
 684   AC_SUBST(LAME_CFLAGS)
 685   AC_SUBST(LAME_LIBS)
 686   ])
 687 ])
 688
 689 dnl *** libcaca ***
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 691 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 692   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 693 ])
 694
 695 dnl *** libdv ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 697 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 698   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 699 ])
 700
 701 dnl *** libpng ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 703 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 704   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 705   if test $HAVE_LIBPNG = "yes"; then
 706     PKG_CHECK_MODULES(LIBPNG_1_5, libpng >= 1.5.1, [
 707         AC_DEFINE(HAVE_LIBPNG_1_5, 1, [Defined if libpng version is 1.5.1 or newer])
 708       ], [true])
 709   fi
 710 ])
 711
 712 dnl *** mpg123 ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_MPG123, true)
 714 AG_GST_CHECK_FEATURE(MPG123, [mpg123 audio decoder], mpg123, [
 715   PKG_CHECK_MODULES(MPG123, libmpg123 >= 1.13, HAVE_MPG123="yes", HAVE_MPG123="no")
 716   AC_SUBST(MPG123_CFLAGS)
 717   AC_SUBST(MPG123_LIBS)
 718 ])
 719
 720 dnl *** pulseaudio ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 722 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 723
 724   dnl used in ext/pulse/pulseutil.c
 725   AC_CHECK_HEADERS([process.h])
 726
 727   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 728 ])
 729
 730 dnl *** dv1394 ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 732 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 733   dnl first test for libraw1394 >= 2.0.0
 734   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 735   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 736   dnl now see how far we got
 737   if test x$HAVE_RAW1394 = xyes && \
 738      test x$HAVE_LIBIEC61883 = xyes; then
 739        AG_GST_CHECK_LIBHEADER(AVC1394,
 740         avc1394, avc1394_send_command, $RAW1394_LIBS,
 741         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 742        AG_GST_CHECK_LIBHEADER(ROM1394,
 743         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 744         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 745        if test x$HAVE_AVC1394 = xyes && \
 746           test x$HAVE_AVC1394 = xyes && \
 747           test x$HAVE_ROM1394 = xyes; then
 748           HAVE_DV1394=yes
 749           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 750           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 751           AC_SUBST(DV1394_CFLAGS)
 752           AC_SUBST(DV1394_LIBS)
 753         fi
 754   else
 755        if test x$HAVE_RAW1394 = xno; then
 756           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 757           AG_GST_CHECK_LIBHEADER(AVC1394,
 758            avc1394, avc1394_send_command, $RAW1394_LIBS,
 759            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 760           AG_GST_CHECK_LIBHEADER(ROM1394,
 761            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 762            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 763           if test x$HAVE_RAW1394 = xyes && \
 764              test x$HAVE_AVC1394 = xyes && \
 765              test x$HAVE_ROM1394 = xyes; then
 766              HAVE_DV1394=yes
 767              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 768              DV1394_CFLAGS="$RAW1394_CFLAGS"
 769              if test x$HAVE_LIBIEC61883 = xyes; then
 770                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 771                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 772              fi
 773              AC_SUBST(DV1394_CFLAGS)
 774              AC_SUBST(DV1394_LIBS)
 775            fi
 776          fi
 777   fi
 778 ])
 779 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 780
 781 dnl *** shout2 ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 783 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 784   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 785 ])
 786
 787 dnl *** soup ***
 788 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 789 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 790   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 791   AC_SUBST(SOUP_CFLAGS)
 792   AC_SUBST(SOUP_LIBS)
 793 ])
 794
 795 dnl *** speex ***
 796 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 797 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 798   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 799 ])
 800
 801 dnl *** taglib ***
 802 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 803 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 804   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 805   if test "x$HAVE_CXX" != "xyes"; then
 806     USE_TAGLIB=false
 807     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 808   else
 809     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 810     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 811         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 812       ], [
 813         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 814     ])
 815     AC_SUBST(TAGLIB_CXXFLAGS)
 816   fi
 817 ])
 818
 819 dnl *** twolame ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 821 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 822   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 823       HAVE_TWOLAME="yes"], [
 824       HAVE_TWOLAME="no"
 825   ])
 826   AC_SUBST(TWOLAME_CFLAGS)
 827   AC_SUBST(TWOLAME_LIBS)
 828 ])
 829
 830
 831 dnl *** vpx ***
 832 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 833 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 834   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 835   HAVE_VP8=no
 836   HAVE_VP9=no
 837
 838   if test $HAVE_VPX = "yes"; then
 839     OLD_LIBS="$LIBS"
 840     OLD_CFLAGS="$CFLAGS"
 841     CFLAGS="$CFLAGS $VPX_CFLAGS"
 842     LIBS="$LIBS $VPX_LIBS"
 843     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 844       HAVE_VP8=yes
 845       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 846     ])
 847     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 848       HAVE_VP8=yes
 849       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 850     ])
 851
 852     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 853       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 854         HAVE_VP9=yes
 855         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 856       ])
 857       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 858         HAVE_VP9=yes
 859         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 860       ])
 861     ], [true])
 862
 863     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 864       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 865     ], [true])
 866
 867     LIBS="$OLD_LIBS"
 868     CFLAGS="$OLD_CFLAGS"
 869   fi
 870   AC_SUBST(VPX_LIBS)
 871   AC_SUBST(VPX_CFLAGS)
 872 ])
 873
 874 dnl *** wavpack ***
 875 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 876 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 877   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 878 ])
 879
 880 dnl *** qtdemux & matroska prefer to have zlib ***
 881 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 882 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 883   AG_GST_CHECK_LIBHEADER(ZLIB,
 884     z, uncompress,, zlib.h, [
 885     HAVE_ZLIB="yes"
 886     ZLIB_LIBS="-lz"
 887     AC_SUBST(ZLIB_LIBS)
 888   ])
 889 ])
 890
 891 dnl *** matroska prefers to have bz2 ***
 892 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 893 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 894   save_LIBS=$LIBS
 895   LIBS="$LIBS -lbz2"
 896   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 897   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 898   AC_MSG_RESULT($HAVE_BZ2)
 899   LIBS=$save_LIBS
 900   if test "x$HAVE_BZ2" = "xyes"; then
 901     BZ2_LIBS="-lbz2"
 902   fi
 903   AC_SUBST(BZ2_LIBS)
 904 ])
 905
 906 else
 907
 908 dnl not building plugins with external dependencies,
 909 dnl but we still need to set the conditionals
 910 AM_CONDITIONAL(USE_AALIB, false)
 911 AM_CONDITIONAL(USE_BZ2, false)
 912 AM_CONDITIONAL(USE_CAIRO, false)
 913 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 914 AM_CONDITIONAL(USE_DV1394, false)
 915 AM_CONDITIONAL(USE_FLAC, false)
 916 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 917 AM_CONDITIONAL(USE_JACK, false)
 918 AM_CONDITIONAL(USE_JPEG, false)
 919 AM_CONDITIONAL(USE_LAME, false)
 920 AM_CONDITIONAL(USE_LIBCACA, false)
 921 AM_CONDITIONAL(USE_LIBDV, false)
 922 AM_CONDITIONAL(USE_LIBIEC61883, false)
 923 AM_CONDITIONAL(USE_LIBPNG, false)
 924 AM_CONDITIONAL(USE_MPG123, false)
 925 AM_CONDITIONAL(USE_OSS, false)
 926 AM_CONDITIONAL(USE_OSS4, false)
 927 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 928 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 929 AM_CONDITIONAL(USE_PULSE, false)
 930 AM_CONDITIONAL(USE_SHOUT2, false)
 931 AM_CONDITIONAL(USE_SOUP, false)
 932 AM_CONDITIONAL(USE_SPEEX, false)
 933 AM_CONDITIONAL(USE_TAGLIB, false)
 934 AM_CONDITIONAL(USE_TWOLAME, false)
 935 AM_CONDITIONAL(USE_VPX, false)
 936 AM_CONDITIONAL(USE_WAVEFORM, false)
 937 AM_CONDITIONAL(USE_WAVPACK, false)
 938 AM_CONDITIONAL(USE_X, false)
 939 AM_CONDITIONAL(USE_ZLIB, false)
 940
 941 fi dnl of EXT plugins
 942
 943 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 944
 945 dnl Overview:
 946 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 947 dnl GST_*:              flags shared by all built objects
 948 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 949 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 950 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 951 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 952
 953 dnl GST_OPTION_CFLAGS
 954 if test "x$USE_DEBUG" = xyes; then
 955    PROFILE_CFLAGS="-g"
 956 fi
 957 AC_SUBST(PROFILE_CFLAGS)
 958
 959 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 960   dnl Define _only_ for git (not pre-releases or releases)
 961   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 962 else
 963   DEPRECATED_CFLAGS=""
 964 fi
 965 AC_SUBST(DEPRECATED_CFLAGS)
 966
 967 VISIBILITY_CFLAGS=""
 968 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 969 AC_SUBST(VISIBILITY_CFLAGS)
 970
 971 VISIBILITY_CXXFLAGS=""
 972 if test "x$HAVE_CXX" = "xyes"; then
 973   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 974 fi
 975 AC_SUBST(VISIBILITY_CXXFLAGS)
 976
 977 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 978 dnl at make time with e.g. make ERROR_CFLAGS=""
 979 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 980 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 981 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 982 AC_SUBST(GST_OPTION_CFLAGS)
 983 AC_SUBST(GST_OPTION_CXXFLAGS)
 984 AC_SUBST(GST_OPTION_OBJCFLAGS)
 985
 986 dnl our libraries need to be versioned correctly
 987 AC_SUBST(GST_LT_LDFLAGS)
 988
 989 dnl FIXME: do we want to rename to GST_ALL_* ?
 990 dnl prefer internal headers to already installed ones
 991 dnl also add builddir include for enumtypes and marshal
 992 dnl add ERROR_CFLAGS, but overridable
 993 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 994 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 995 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 996 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 997 AC_SUBST(GST_CFLAGS)
 998 AC_SUBST(GST_CXXFLAGS)
 999 AC_SUBST(GST_OBJCFLAGS)
1000 AC_SUBST(GST_LIBS)
1001
1002 dnl LDFLAGS really should only contain flags, not libs - they get added before
1003 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1004 GST_ALL_LDFLAGS="-no-undefined"
1005 if test "x${enable_Bsymbolic}" = "xyes"; then
1006   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1007 fi
1008 AC_SUBST(GST_ALL_LDFLAGS)
1009
1010 dnl this really should only contain flags, not libs - they get added before
1011 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1012 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
1013 AC_SUBST(GST_PLUGIN_LDFLAGS)
1014
1015 dnl *** output files ***
1016
1017 $MKDIR_P tests/check/orc
1018
1019 dnl keep this alphabetic per directory, please
1020 AC_CONFIG_FILES(
1021 Makefile
1022 gst/Makefile
1023 gst/alpha/Makefile
1024 gst/apetag/Makefile
1025 gst/audiofx/Makefile
1026 gst/audioparsers/Makefile
1027 gst/auparse/Makefile
1028 gst/autodetect/Makefile
1029 gst/avi/Makefile
1030 gst/cutter/Makefile
1031 gst/deinterlace/Makefile
1032 gst/dtmf/Makefile
1033 gst/debugutils/Makefile
1034 gst/effectv/Makefile
1035 gst/equalizer/Makefile
1036 gst/flv/Makefile
1037 gst/goom/Makefile
1038 gst/goom2k1/Makefile
1039 gst/id3demux/Makefile
1040 gst/icydemux/Makefile
1041 gst/imagefreeze/Makefile
1042 gst/interleave/Makefile
1043 gst/isomp4/Makefile
1044 gst/law/Makefile
1045 gst/level/Makefile
1046 gst/matroska/Makefile
1047 gst/monoscope/Makefile
1048 gst/multifile/Makefile
1049 gst/multipart/Makefile
1050 gst/replaygain/Makefile
1051 gst/rtp/Makefile
1052 gst/rtpmanager/Makefile
1053 gst/rtsp/Makefile
1054 gst/shapewipe/Makefile
1055 gst/smpte/Makefile
1056 gst/spectrum/Makefile
1057 gst/udp/Makefile
1058 gst/videobox/Makefile
1059 gst/videocrop/Makefile
1060 gst/videofilter/Makefile
1061 gst/videomixer/Makefile
1062 gst/wavenc/Makefile
1063 gst/wavparse/Makefile
1064 gst/flx/Makefile
1065 gst/y4m/Makefile
1066 ext/Makefile
1067 ext/aalib/Makefile
1068 ext/cairo/Makefile
1069 ext/dv/Makefile
1070 ext/flac/Makefile
1071 ext/gdk_pixbuf/Makefile
1072 ext/jack/Makefile
1073 ext/jpeg/Makefile
1074 ext/lame/Makefile
1075 ext/libcaca/Makefile
1076 ext/libpng/Makefile
1077 ext/mpg123/Makefile
1078 ext/pulse/Makefile
1079 ext/raw1394/Makefile
1080 ext/shout2/Makefile
1081 ext/soup/Makefile
1082 ext/speex/Makefile
1083 ext/taglib/Makefile
1084 ext/twolame/Makefile
1085 ext/vpx/Makefile
1086 ext/wavpack/Makefile
1087 sys/Makefile
1088 sys/directsound/Makefile
1089 sys/oss/Makefile
1090 sys/oss4/Makefile
1091 sys/osxaudio/Makefile
1092 sys/osxvideo/Makefile
1093 sys/v4l2/Makefile
1094 sys/waveform/Makefile
1095 sys/ximage/Makefile
1096 po/Makefile.in
1097 tests/Makefile
1098 tests/check/Makefile
1099 tests/examples/Makefile
1100 tests/examples/audiofx/Makefile
1101 tests/examples/cairo/Makefile
1102 tests/examples/equalizer/Makefile
1103 tests/examples/jack/Makefile
1104 tests/examples/level/Makefile
1105 tests/examples/rtp/Makefile
1106 tests/examples/shapewipe/Makefile
1107 tests/examples/spectrum/Makefile
1108 tests/examples/v4l2/Makefile
1109 tests/files/Makefile
1110 tests/icles/Makefile
1111 common/Makefile
1112 common/m4/Makefile
1113 m4/Makefile
1114 docs/Makefile
1115 docs/plugins/Makefile
1116 docs/version.entities
1117 pkgconfig/Makefile
1118 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1119 )
1120 AC_OUTPUT
1121
1122 AG_GST_OUTPUT_PLUGINS
1123 ORC_OUTPUT
1124