configure.ac

   1 AC_PREREQ(2.62)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT([GStreamer RTSP Server Library], [1.3.0.1],
   6     [http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],
   7     [gst-rtsp-server])
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 dnl GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl CURRENT, REVISION, AGE
  43 dnl - library source changed -> increment REVISION
  44 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  45 dnl - interfaces added -> increment AGE
  46 dnl - interfaces removed -> AGE = 0
  47 dnl
  48 dnl Keep CURRENT as MINOR * 100 + MICRO
  49 dnl Ex : 1.0.0 => 0
  50 dnl      1.0.3 => 3
  51 dnl      1.1.0 => 100
  52 dnl      1.2.5 => 205
  53 dnl      1.10.9 (who knows) => 1009
  54 dnl
  55 dnl sets GST_LT_LDFLAGS
  56 AS_LIBTOOL(GST, 300, 0, 300)
  57
  58 dnl *** required versions of GStreamer stuff ***
  59 GST_REQ=1.3.0.1
  60 GSTPB_REQ=1.3.0.1
  61 GSTPG_REQ=1.3.0.1
  62 GSTPD_REQ=1.3.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71 AC_CONFIG_MACRO_DIR([m4])
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 #AM_GNU_GETTEXT_VERSION([0.17])
  76 #AM_GNU_GETTEXT([external])
  77 #AG_GST_GETTEXT([gst-rtsp-server-$GST_API_VERSION])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  87 AG_GST_ARG_WITH_PACKAGE_NAME
  88 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  89
  90 AG_GST_PKG_CONFIG_PATH
  91
  92 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
  93   ["${srcdir}/gst-rtsp-server.doap"],
  94   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
  95
  96 dnl building of tests
  97 AC_ARG_ENABLE(tests,
  98   AS_HELP_STRING([--disable-tests],[disable building test apps]),
  99   [
 100     case "${enableval}" in
 101       yes) BUILD_TESTS=yes ;;
 102       no)  BUILD_TESTS=no ;;
 103       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 104     esac
 105   ],
 106 [BUILD_TESTS=yes]) dnl Default value
 107 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 108
 109 dnl *** checks for platform ***
 110
 111 dnl * hardware/architecture *
 112
 113 dnl *** checks for programs ***
 114
 115 dnl find a compiler
 116 AC_PROG_CC
 117 AC_PROG_CC_STDC
 118
 119 dnl check if the compiler supports '-c' and '-o' options
 120 AM_PROG_CC_C_O
 121
 122 dnl find an assembler
 123 AM_PROG_AS
 124
 125 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 126 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 127
 128 dnl check for gobject-introspection
 129 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 130
 131 dnl check for documentation tools
 132 AG_GST_DOCBOOK_CHECK
 133 GTK_DOC_CHECK([1.12])
 134
 135 dnl *** checks for libraries ***
 136
 137 dnl *** checks for header files ***
 138
 139 dnl *** checks for types/defines ***
 140
 141 dnl *** checks for structures ***
 142
 143 dnl *** checks for compiler characteristics ***
 144
 145 dnl *** checks for library functions ***
 146
 147 dnl *** checks for dependancy libraries ***
 148
 149 dnl GLib is required
 150 GLIB_REQ=2.32.0
 151 AC_SUBST([GLIB_REQ])
 152 AG_GST_GLIB_CHECK([$GLIB_REQ])
 153
 154 dnl checks for gstreamer
 155 dnl uninstalled is selected preferentially -- see pkg-config(1)
 156 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], [yes])
 157
 158 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 159 if test -z $GST_TOOLS_DIR; then
 160   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 161 fi
 162 AC_SUBST(GST_TOOLS_DIR)
 163
 164 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 165 AC_SUBST(GST_PLUGINS_DIR)
 166 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 167
 168 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], [yes])
 169
 170 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], [yes])
 171 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 172 AC_SUBST(GSTPB_PLUGINS_DIR)
 173 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 174
 175 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GSTPG_REQ], [yes])
 176 GSTPG_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-good-$GST_API_VERSION --variable pluginsdir`
 177 AC_SUBST(GSTPG_PLUGINS_DIR)
 178 AC_MSG_NOTICE(Using GStreamer Good Plugins in $GSTPG_PLUGINS_DIR)
 179
 180 AG_GST_CHECK_GST_PLUGINS_BAD($GST_API_VERSION, [$GSTPD_REQ], [yes])
 181 GSTPD_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-bad-$GST_API_VERSION --variable pluginsdir`
 182 AC_SUBST(GSTPD_PLUGINS_DIR)
 183 AC_MSG_NOTICE(Using GStreamer Bad Plugins in $GSTPD_PLUGINS_DIR)
 184
 185 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 186 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 187
 188 dnl Check for -Bsymbolic-functions linker flag used to avoid
 189 dnl intra-library PLT jumps, if available.
 190 AC_ARG_ENABLE(Bsymbolic,
 191               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 192               [SAVED_LDFLAGS="${LDFLAGS}"
 193                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 194                LDFLAGS=-Wl,-Bsymbolic-functions
 195                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 196                            AC_MSG_RESULT(yes)
 197                            enable_Bsymbolic=yes],[
 198                            AC_MSG_RESULT(no)
 199                            enable_Bsymbolic=no])
 200                LDFLAGS="${SAVED_LDFLAGS}"])
 201
 202 dnl *** set variables based on configure arguments ***
 203
 204 dnl set license and copyright notice
 205 GST_LICENSE="LGPL"
 206 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 207 AC_SUBST(GST_LICENSE)
 208
 209 dnl set location of plugin directory
 210 AG_GST_SET_PLUGINDIR
 211
 212 dnl set release date/time (and check that release version is in doap file)
 213 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 214   ["${srcdir}/gst-rtsp-server.doap"],
 215   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 216
 217 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 218 dnl make sure it doesn't complain about unused variables if debugging is disabled
 219 NO_WARNINGS=""
 220 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 221
 222 dnl define an ERROR_CFLAGS Makefile variable
 223 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 224
 225 dnl define correct level for debugging messages
 226 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 227
 228 dnl used in examples
 229 AG_GST_DEFAULT_ELEMENTS
 230
 231 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 232
 233 dnl Overview:
 234 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 235 dnl GST_*:              flags shared by built objects to link against GStreamer
 236 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 237 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 238 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 239 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 240
 241 dnl GST_OPTION_CFLAGS
 242 if test "x$USE_DEBUG" = xyes; then
 243    PROFILE_CFLAGS="-g"
 244 fi
 245 AC_SUBST(PROFILE_CFLAGS)
 246
 247 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 248 # functionality from the API that gstreamer uses
 249 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 250 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 251   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 252   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 253 else
 254   DEPRECATED_CFLAGS=""
 255 fi
 256 AC_SUBST(DEPRECATED_CFLAGS)
 257
 258 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 259 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 260 AC_SUBST(GST_OPTION_CFLAGS)
 261
 262 dnl FIXME: do we want to rename to GST_ALL_* ?
 263 dnl prefer internal headers to already installed ones
 264 dnl add GST_OPTION_CFLAGS, but overridable
 265 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 266 AC_SUBST(GST_CFLAGS)
 267 AC_SUBST(GST_LIBS)
 268
 269 dnl GST_ALL_*
 270 dnl vars common to for all internal objects (core libs, elements, applications)
 271 dnl CFLAGS:
 272 dnl - src and build dirs need to be added because every piece that gets built
 273 dnl   will need the GStreamer source and generated headers
 274 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_PLUGINS_BASE_CFLAGS $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 275 AC_SUBST([GST_ALL_CFLAGS])
 276
 277 dnl FIXME: check if LTLIBINTL is needed everywhere
 278 dnl I presume it is given that it contains the symbols that _() stuff maps to
 279 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 280 AC_SUBST([GST_ALL_LIBS])
 281
 282 dnl LDFLAGS really should only contain flags, not libs - they get added before
 283 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 284 GST_ALL_LDFLAGS="-no-undefined"
 285 if test "x${enable_Bsymbolic}" = "xyes"; then
 286   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 287 fi
 288
 289 AC_SUBST(GST_ALL_LDFLAGS)
 290
 291 dnl GST_LIB_LDFLAGS
 292 dnl linker flags shared by all libraries
 293 dnl LDFLAGS modifier defining exported symbols from built libraries
 294 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 295 AC_SUBST(GST_LIB_LDFLAGS)
 296
 297 dnl GST_OBJ_*
 298 dnl default vars for all internal objects built on libgstrtspserver
 299 dnl includes GST_ALL_*
 300 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 301 AC_SUBST([GST_OBJ_CFLAGS])
 302 GST_OBJ_LIBS="\$(top_builddir)/gst/rtsp-server/libgstrtspserver-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 303 AC_SUBST([GST_OBJ_LIBS])
 304
 305 PKG_CHECK_MODULES(LIBCGROUP, libcgroup >= 0.26, HAVE_LIBCGROUP="yes", HAVE_LIBCGROUP="no")
 306 AC_SUBST(LIBCGROUP_CFLAGS)
 307 AC_SUBST(LIBCGROUP_LIBS)
 308 AM_CONDITIONAL(HAVE_LIBCGROUP, test "x$HAVE_LIBCGROUP" = "xyes")
 309
 310 dnl this really should only contain flags, not libs - they get added before
 311 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 312
 313 dnl *** output files ***
 314
 315 dnl keep this alphabetic per directory, please
 316 AC_CONFIG_FILES([
 317 Makefile
 318 gst-rtsp.spec
 319 common/Makefile
 320 common/m4/Makefile
 321 gst/Makefile
 322 gst/rtsp-server/Makefile
 323 examples/Makefile
 324 tests/Makefile
 325 tests/check/Makefile
 326 pkgconfig/Makefile
 327 pkgconfig/gstreamer-rtsp-server.pc
 328 pkgconfig/gstreamer-rtsp-server-uninstalled.pc
 329 docs/Makefile
 330 docs/version.entities
 331 docs/libs/Makefile
 332 ])
 333 AC_OUTPUT
 334
 335 echo "
 336
 337 Configuration
 338         Version                    : ${VERSION}
 339         Source code location       : ${srcdir}
 340         Prefix                     : ${prefix}
 341         Compiler                   : ${CC}
 342         CGroups example            : ${HAVE_LIBCGROUP}
 343
 344 gst-rtsp-server configured. Type 'make' to build.
 345 "