configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.11.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl CURRENT, REVISION, AGE
  40 dnl - library source changed -> increment REVISION
  41 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  42 dnl - interfaces added -> increment AGE
  43 dnl - interfaces removed -> AGE = 0
  44 dnl sets GST_LT_LDFLAGS
  45 AS_LIBTOOL(GST, 8, 0, 8)
  46
  47 dnl FIXME: this macro doesn't actually work;
  48 dnl the generated libtool script has no support for the listed tags.
  49 dnl So this needs to be fixed first if we want to use this
  50 dnl AS_LIBTOOL_TAGS
  51
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.11.1
  56
  57 dnl *** autotools stuff ****
  58
  59 dnl allow for different autotools
  60 AS_AUTOTOOLS_ALTERNATE
  61
  62 dnl Add parameters for aclocal
  63 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  64
  65 dnl set up gettext
  66 dnl the version check needs to stay here because autopoint greps for it
  67 AM_GNU_GETTEXT_VERSION([0.11.5])
  68 AM_GNU_GETTEXT([external])
  69 GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  70
  71 dnl *** check for arguments to configure ***
  72
  73 GST_ARG_DEBUG
  74 GST_ARG_PROFILING
  75 GST_ARG_VALGRIND
  76 GST_ARG_GCOV
  77
  78 GST_ARG_EXAMPLES
  79
  80 GST_ARG_WITH_PKG_CONFIG_PATH
  81 GST_ARG_WITH_PACKAGE_NAME
  82 GST_ARG_WITH_PACKAGE_ORIGIN
  83
  84 dnl let distro override plugin install helper path
  85 AC_ARG_WITH(install-plugins-helper,
  86   AC_HELP_STRING([--with-install-plugins-helper],
  87     [specify path of helper script to call to install plugins]),
  88   [
  89     case "${withval}" in
  90       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  91       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  92       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  93     esac
  94   ],
  95   [
  96     dnl Default value
  97     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
  98   ]
  99 )
 100 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 101 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 102     [plugin install helper script])
 103 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 104
 105
 106 dnl these are all the gst plug-ins, compilable without additional libs
 107 GST_PLUGINS_ALL="\
 108         adder \
 109         audioconvert \
 110         audiorate \
 111         audioresample \
 112         audiotestsrc \
 113         ffmpegcolorspace \
 114         gdp \
 115         playback \
 116         typefind \
 117         videotestsrc \
 118         videorate \
 119         videoscale \
 120         volume \
 121         "
 122 AC_SUBST(GST_PLUGINS_ALL)
 123
 124 GST_PLUGINS_SELECTED=""
 125
 126 AC_ARG_WITH(plugins,
 127     AC_HELP_STRING([--with-plugins],
 128       [comma-separated list of plug-ins to compile]),
 129     [for i in `echo $withval | tr , ' '`; do
 130         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 131         then
 132             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 133         else
 134             echo "plug-in $i not recognized, ignoring..."
 135         fi
 136     done],
 137     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 138
 139 AC_SUBST(GST_PLUGINS_SELECTED)
 140
 141 dnl ext plug-ins; plug-ins that have external dependencies
 142 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 143   [HAVE_EXTERNAL=yes], enabled,
 144   [
 145     AC_MSG_NOTICE(building external plug-ins)
 146     BUILD_EXTERNAL="yes"
 147   ],[
 148     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 149     BUILD_EXTERNAL="no"
 150   ])
 151 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 152
 153 dnl *** checks for platform ***
 154
 155 dnl * hardware/architecture *
 156
 157 dnl common/m4/gst-arch.m4
 158 dnl check CPU type
 159 GST_ARCH
 160
 161 dnl *** checks for programs ***
 162
 163 dnl find a compiler
 164 AC_PROG_CC
 165
 166 dnl determine c++ compiler
 167 AC_PROG_CXX
 168 dnl determine if c++ is available on this system
 169 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 170
 171 dnl determine c++ preprocessor
 172 dnl FIXME: do we need this ?
 173 AC_PROG_CXXCPP
 174
 175 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 176 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 177
 178 dnl check for documentation tools
 179 GTK_DOC_CHECK([1.3])
 180 AS_PATH_PYTHON([2.1])
 181 GST_PLUGIN_DOCS([1.3],[2.1])
 182
 183 dnl *** checks for libraries ***
 184
 185 dnl For interactive UNIX (a Sun thing)
 186 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 187 AC_ISC_POSIX
 188
 189 dnl *** checks for header files ***
 190
 191 dnl check if we have ANSI C header files
 192 AC_HEADER_STDC
 193
 194 dnl used in gst/ffmpegcolorspace/mem.c
 195 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 196 AC_CHECK_HEADERS([malloc.h])
 197
 198 dnl used in gst/subparse/gstsubparse.c
 199 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 200 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 201
 202 dnl used in gst/tcp
 203 AC_CHECK_HEADERS([sys/socket.h],
 204   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 205 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 206
 207 dnl used in gst-libs/gst/utils and associated unit test
 208 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 209
 210 dnl ffmpegcolorspace includes _stdint.h
 211 dnl also, Windows does not have long long
 212 AX_CREATE_STDINT_H
 213
 214 dnl *** checks for functions ***
 215 AC_CHECK_FUNCS([localtime_r])
 216
 217 dnl *** checks for types/defines ***
 218
 219 dnl Check for FIONREAD ioctl declaration
 220 dnl used in gst/tcp
 221 GST_CHECK_FIONREAD
 222
 223 dnl *** checks for structures ***
 224
 225 dnl *** checks for compiler characteristics ***
 226
 227 dnl make sure we can use "inline" from C code
 228 AC_C_INLINE
 229
 230 dnl *** checks for library functions ***
 231
 232 dnl Check for fast float to int casting as defined in C99
 233 dnl used in gst-libs/gst/floatcast/floatcast.h
 234 AC_C99_FUNC_LRINT
 235 AC_C99_FUNC_LRINTF
 236
 237 dnl Check for a way to display the function name in debug output
 238 GST_CHECK_FUNCTION
 239
 240 dnl *** checks for dependency libraries ***
 241
 242 dnl GLib is required
 243 GST_GLIB_CHECK([2.6])
 244
 245 dnl liboil is required
 246 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 247 if test "x$HAVE_LIBOIL" != "xyes"
 248 then
 249   AC_ERROR([liboil-0.3.8 or later is required])
 250 fi
 251
 252 dnl checks for gstreamer
 253 dnl uninstalled is selected preferentially -- see pkg-config(1)
 254 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 255 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 256 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 257 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 258 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 259
 260 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 261 dnl check for "check", unit testing library/header
 262 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 263 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 264
 265 dnl Check for documentation xrefs
 266 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 267 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 268 AC_SUBST(GLIB_PREFIX)
 269 AC_SUBST(GST_PREFIX)
 270
 271 dnl GTK is optional and used in examples
 272 HAVE_GTK=NO
 273 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 274 if test "x$HAVE_GTK_22" = "xyes"; then
 275   HAVE_GTK=yes
 276   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 277   AC_SUBST(GTK_VERSION)
 278   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 279   AC_SUBST(GTK_BASE_DIR)
 280 else
 281   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 282 fi
 283 if test "x$HAVE_GTK_20" = "xyes"; then
 284   HAVE_GTK=yes
 285 fi
 286 GTK_CFLAGS=$GTK2_CFLAGS
 287 GTK_LIBS=$GTK2_LIBS
 288 AC_SUBST(GTK_LIBS)
 289 AC_SUBST(GTK_CFLAGS)
 290 AC_SUBST(HAVE_GTK)
 291 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 292
 293 dnl *** set variables based on configure arguments ***
 294
 295 dnl set license and copyright notice
 296 GST_LICENSE="LGPL"
 297 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 298 AC_SUBST(GST_LICENSE)
 299
 300 dnl set location of plugin directory
 301 GST_SET_PLUGINDIR
 302
 303 dnl define an ERROR_CFLAGS Makefile variable
 304 GST_SET_ERROR_CFLAGS($GST_CVS)
 305
 306 dnl define correct level for debugging messages
 307 GST_SET_LEVEL_DEFAULT($GST_CVS)
 308
 309 dnl used in examples
 310 GST_DEFAULT_ELEMENTS
 311
 312 dnl *** sys plug-ins ***
 313
 314 echo
 315 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 316 echo
 317
 318 dnl *** X11 ***
 319 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 320 GST_CHECK_FEATURE(X, [X libraries and plugins],
 321                   [ximagesink], [
 322   AC_PATH_XTRA
 323   ac_cflags_save="$CFLAGS"
 324   ac_cppflags_save="$CPPFLAGS"
 325   CFLAGS="$CFLAGS $X_CFLAGS"
 326   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 327
 328   dnl now try to find the HEADER
 329   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 330
 331   if test "x$HAVE_X" = "xno"
 332   then
 333     AC_MSG_NOTICE([cannot find X11 development files])
 334   else
 335     dnl this is much more than we want
 336     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 337     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 338     dnl it does not add the libs; therefore we add them here
 339     X_LIBS="$X_LIBS -lX11"
 340     AC_SUBST(X_CFLAGS)
 341     AC_SUBST(X_LIBS)
 342   fi
 343   AC_SUBST(HAVE_X)
 344   CFLAGS="$ac_cflags_save"
 345   CPPFLAGS="$ac_cppflags_save"
 346 ])
 347
 348 dnl Check for Xv extension
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 350 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 351                   [xvimagesink], [
 352   GST_CHECK_XV
 353 ])
 354
 355 dnl check for X Shm
 356 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 357 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 358   if test x$HAVE_X = xyes; then
 359     AC_CHECK_LIB(Xext, XShmAttach,
 360                  HAVE_XSHM="yes", HAVE_XSHM="no",
 361                  $X_LIBS)
 362     if test "x$HAVE_XSHM" = "xyes"; then
 363       XSHM_LIBS="-lXext"
 364     else
 365       dnl On AIX, it is in XextSam instead, but we still need -lXext
 366       AC_CHECK_LIB(XextSam, XShmAttach,
 367                    HAVE_XSHM="yes", HAVE_XSHM="no",
 368                    $X_LIBS)
 369       if test "x$HAVE_XSHM" = "xyes"; then
 370         XSHM_LIBS="-lXext -lXextSam"
 371       fi
 372     fi
 373   fi
 374 ], , [
 375   AC_SUBST(HAVE_XSHM)
 376   AC_SUBST(XSHM_LIBS)
 377 ])
 378
 379 dnl v4l/v4l2 checks have been moved down because they require X
 380
 381 dnl *** Video 4 Linux ***
 382 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 383 dnl renamed to GST_V4L in accordance with V4L2 below
 384 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 385 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 386   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 387 #include <sys/types.h>
 388 #define _LINUX_TIME_H
 389 #define __user
 390 #include <linux/videodev.h>
 391   ])
 392
 393   dnl we can build v4l without Xv, but then we won't have XOverlay support
 394   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 395   then
 396     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 397     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 398   fi
 399 ])
 400
 401 dnl *** ext plug-ins ***
 402 dnl keep this list sorted alphabetically !
 403
 404 if test "x$BUILD_EXTERNAL" = "xyes"; then
 405
 406 echo
 407 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 408 echo
 409
 410 dnl *** alsa ***
 411 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 412 GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 413   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 414     HAVE_ALSA="yes"
 415     AC_SUBST(ALSA_CFLAGS)
 416     AC_SUBST(ALSA_LIBS)
 417   ], [
 418     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 419   ])
 420 ])
 421
 422 dnl *** CDParanoia ***
 423 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 424 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 425   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 426                       cdda_open, -lm,
 427                       cdda_interface.h,
 428                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 429                       HEADER_DIR="no"
 430                       FOUND_CDPARANOIA="yes")
 431   if test "x$FOUND_CDPARANOIA" != "xyes";
 432   then
 433     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 434                         cdda_open, -lm,
 435                         cdda/cdda_interface.h,
 436                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 437                         HEADER_DIR="yes"
 438                         FOUND_CDPARANOIA="yes")
 439   fi
 440   if test "x$HEADER_DIR" = "xyes";
 441   then
 442     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 443                        defined if cdda headers are in a cdda/ directory)
 444   fi
 445   AC_SUBST(CDPARANOIA_LIBS)
 446 ])
 447 dnl FIXME : add second check somehow if that is necessary
 448 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 449 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 450
 451 dnl *** GNOME VFS ***
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 453 GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 454   GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 455 ])
 456
 457 dnl *** libvisual ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 459 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 460   GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 461   if test $HAVE_LIBVISUAL = no
 462   then
 463     GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 464   fi
 465 ])
 466
 467 dnl *** ogg ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 469 GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 470   GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 471   if test $HAVE_OGG = no
 472   then
 473     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 474     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 475   fi
 476 ])
 477
 478 dnl *** pango ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 480 GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 481   GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 482 ])
 483
 484 dnl *** theora ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 486 GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 487   GST_PKG_CHECK_MODULES(THEORA, theora)
 488   if test $HAVE_THEORA = no
 489   then
 490     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 491     AC_SUBST(THEORA_LIBS)
 492   fi
 493 ])
 494
 495 dnl *** vorbis ***
 496 dnl AM_PATH_VORBIS only takes two options
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 498 GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 499   GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 500   if test $HAVE_VORBIS = no
 501   then
 502     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 503     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 504   fi
 505 ])
 506
 507 if test "x$HAVE_VORBIS" = "xyes"; then
 508   ac_cflags_save="$CFLAGS"
 509   dnl FIXME: does this work on non-gcc? -- Company
 510   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 511   CFLAGS="-Wall -Werror"
 512   AC_COMPILE_IFELSE(
 513     AC_LANG_PROGRAM([
 514 #include <vorbis/codec.h>
 515                      ],[
 516 vorbis_dsp_state *v;
 517
 518 vorbis_synthesis_restart (v);
 519                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 520   if test "x$HAVE_VSR" = "xyes"; then
 521     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 522                        [defined if vorbis_synthesis_restart is present])
 523   fi
 524   CFLAGS="$ac_cflags_save"
 525 fi
 526
 527 else
 528
 529 dnl not building plugins with external dependencies,
 530 dnl but we still need to set the conditionals
 531 AM_CONDITIONAL(USE_ALSA, false)
 532 AM_CONDITIONAL(USE_CDPARANOIA, false)
 533 AM_CONDITIONAL(USE_GNOME_VFS, false)
 534 AM_CONDITIONAL(USE_LIBVISUAL, false)
 535 AM_CONDITIONAL(USE_OGG, false)
 536 AM_CONDITIONAL(USE_PANGO, false)
 537 AM_CONDITIONAL(USE_THEORA, false)
 538 AM_CONDITIONAL(USE_VORBIS, false)
 539
 540 fi dnl of EXT plugins
 541
 542 dnl seeking needs freetype, so check for it here
 543 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 544   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 545 ])
 546 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 547 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 548 AC_SUBST(FT2_CFLAGS)
 549 AC_SUBST(FT2_LIBS)
 550
 551 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 552
 553 dnl Overview:
 554 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 555 dnl GST_*:              flags shared by built objects to link against GStreamer
 556 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 557 dnl                          (compare to other modules) or for i18n
 558 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 559 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 560 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 561 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 562
 563 dnl GST_OPTION_CFLAGS
 564 if test "x$USE_DEBUG" = xyes; then
 565    PROFILE_CFLAGS="-g"
 566 fi
 567 AC_SUBST(PROFILE_CFLAGS)
 568
 569 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 570 AC_SUBST(DEPRECATED_CFLAGS)
 571
 572 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 573 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 574 AC_SUBST(GST_OPTION_CFLAGS)
 575
 576 dnl our libraries need to be versioned correctly
 577 AC_SUBST(GST_LT_LDFLAGS)
 578
 579 dnl GST_PLUGINS_BASE_CFLAGS
 580 dnl prefer internal headers to already installed ones
 581 dnl also add builddir include for enumtypes and marshal
 582 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 583 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 584
 585 dnl FIXME: do we want to rename to GST_ALL_* ?
 586 dnl add GST_OPTION_CFLAGS, but overridable
 587 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 588 AC_SUBST(GST_CFLAGS)
 589 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 590 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 591 AC_SUBST(GST_LIBS)
 592
 593 dnl LDFLAGS really should only contain flags, not libs - they get added before
 594 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 595 GST_ALL_LDFLAGS="-no-undefined"
 596 AC_SUBST(GST_ALL_LDFLAGS)
 597
 598 dnl GST_LIB_LDFLAGS
 599 dnl linker flags shared by all libraries
 600 dnl LDFLAGS modifier defining exported symbols from built libraries
 601 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 602 AC_SUBST(GST_LIB_LDFLAGS)
 603
 604 dnl this really should only contain flags, not libs - they get added before
 605 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 606 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 607 AC_SUBST(GST_PLUGIN_LDFLAGS)
 608
 609 dnl *** output files ***
 610
 611 AC_CONFIG_FILES(
 612 Makefile
 613 gst-plugins-base.spec
 614 gst/Makefile
 615 gst/adder/Makefile
 616 gst/audioconvert/Makefile
 617 gst/audiorate/Makefile
 618 gst/audioresample/Makefile
 619 gst/audiotestsrc/Makefile
 620 gst/ffmpegcolorspace/Makefile
 621 gst/gdp/Makefile
 622 gst/playback/Makefile
 623 gst/subparse/Makefile
 624 gst/tcp/Makefile
 625 gst/typefind/Makefile
 626 gst/videotestsrc/Makefile
 627 gst/videorate/Makefile
 628 gst/videoscale/Makefile
 629 gst/volume/Makefile
 630 sys/Makefile
 631 sys/ximage/Makefile
 632 sys/xvimage/Makefile
 633 sys/v4l/Makefile
 634 ext/Makefile
 635 ext/alsa/Makefile
 636 ext/cdparanoia/Makefile
 637 ext/gnomevfs/Makefile
 638 ext/libvisual/Makefile
 639 ext/ogg/Makefile
 640 ext/pango/Makefile
 641 ext/theora/Makefile
 642 ext/vorbis/Makefile
 643 gst-libs/Makefile
 644 gst-libs/gst/Makefile
 645 gst-libs/gst/audio/Makefile
 646 gst-libs/gst/cdda/Makefile
 647 gst-libs/gst/floatcast/Makefile
 648 gst-libs/gst/interfaces/Makefile
 649 gst-libs/gst/netbuffer/Makefile
 650 gst-libs/gst/riff/Makefile
 651 gst-libs/gst/rtp/Makefile
 652 gst-libs/gst/tag/Makefile
 653 gst-libs/gst/utils/Makefile
 654 gst-libs/gst/video/Makefile
 655 tools/Makefile
 656 win32/common/config.h
 657 pkgconfig/Makefile
 658 pkgconfig/gstreamer-plugins-base.pc
 659 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 660 tests/Makefile
 661 tests/check/Makefile
 662 tests/examples/Makefile
 663 tests/examples/seek/Makefile
 664 tests/examples/volume/Makefile
 665 tests/icles/Makefile
 666 docs/Makefile
 667 docs/design/Makefile
 668 docs/libs/Makefile
 669 docs/plugins/Makefile
 670 docs/version.entities
 671 po/Makefile.in
 672 common/Makefile
 673 common/m4/Makefile
 674 m4/Makefile
 675 )
 676 AC_OUTPUT
 677
 678 GST_OUTPUT_PLUGINS