configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.19.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 16, 0, 16)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.11.5])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 113 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 115 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 116 dnl define a substitution to use in docs/gst/gstreamer.types
 117 if test "x$GST_DISABLE_INDEX" = "xyes"
 118 then
 119   GST_INDEX_DOC_TYPES="%"
 120 else
 121   GST_INDEX_DOC_TYPES=
 122 fi
 123 AC_SUBST(GST_INDEX_DOC_TYPES)
 124 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 125 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 126 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 127 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 128 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 129 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 130
 131 AG_GST_ARG_DEBUG
 132 AG_GST_ARG_PROFILING
 133 AG_GST_ARG_VALGRIND
 134 AG_GST_ARG_GCOV
 135
 136 AG_GST_ARG_EXAMPLES
 137
 138 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 139 AG_GST_ARG_WITH_PACKAGE_NAME
 140 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 141
 142 dnl building of tests
 143 AC_ARG_ENABLE(tests,
 144   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_TESTS=yes ;;
 148       no)  BUILD_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 150     esac
 151   ],
 152 [BUILD_TESTS=yes]) dnl Default value
 153 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 154
 155 dnl tests known to fail
 156 AC_ARG_ENABLE(failing-tests,
 157   AC_HELP_STRING([--disable-failing-tests],
 158     [disable building tests known to fail]),
 159   [
 160     case "${enableval}" in
 161       yes) BUILD_FAILING_TESTS=yes ;;
 162       no)  BUILD_FAILING_TESTS=no ;;
 163       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 164     esac
 165   ],
 166   [BUILD_FAILING_TESTS=no]) dnl Default value
 167 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 168 if test x$BUILD_FAILING_TESTS = xyes; then
 169   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 170 else
 171   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 172 fi
 173
 174 dnl poison destroyed objects
 175 AC_ARG_ENABLE(poisoning,
 176   AC_HELP_STRING([--enable-poisoning],
 177     [enable poisoning of deallocated objects]),
 178   [
 179     case "${enableval}" in
 180       yes) USE_POISONING=yes ;;
 181       no)  USE_POISONING=no ;;
 182       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 183     esac
 184   ],
 185   [USE_POISONING=no]) dnl Default value
 186 if test "x$USE_POISONING" = xyes; then
 187   AC_DEFINE(USE_POISONING, 1,
 188     [Define if we should poison deallocated memory])
 189 fi
 190
 191 dnl Use binary registry
 192 AC_ARG_ENABLE(binary-registry,
 193   AC_HELP_STRING([--enable-binary-registry],
 194     [enable experimental binary registry]),
 195   [
 196     case "${enableval}" in
 197       yes) USE_BINARY_REGISTRY=yes ;;
 198       no)  USE_BINARY_REGISTRY=no ;;
 199       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
 200     esac
 201   ],
 202   [USE_BINARY_REGISTRY=no]) dnl Default value
 203
 204 if test "x$USE_BINARY_REGISTRY" = xyes; then
 205   dnl for config.h:
 206   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 207     [Define if we should use binary registry instead xml registry])
 208 fi
 209 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 210
 211 dnl *** checks for platform ***
 212
 213 dnl * hardware/architecture *
 214
 215 dnl common/m4/gst-arch.m4
 216 dnl check CPU type
 217 AG_GST_ARCH
 218 dnl substitution for win32/common/config.h
 219 HOST_CPU=$host_cpu
 220 AC_SUBST(HOST_CPU)
 221
 222 dnl common/m4/gst-arch.m4
 223 dnl check for unaligned access
 224 AG_GST_UNALIGNED_ACCESS
 225 dnl create a configure variable for gst/gstconfig.h
 226 if test x${as_cv_unaligned_access} = xyes ; then
 227   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 228 else
 229   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 230 fi
 231 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 232
 233 dnl check for extra platform specific plugin suffixes
 234 case $host_os in
 235      darwin* | rhapsody*)
 236         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 237         ;;
 238      *)
 239         ;;
 240 esac
 241
 242 dnl * software *
 243
 244 dnl check for large file support
 245 dnl affected plugins must include config.h
 246 AC_SYS_LARGEFILE
 247
 248 dnl HAVE_WIN32 currently means "disable POSIXisms".
 249 case "$host" in
 250   *-*-mingw*)
 251     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 252     ;;
 253   *)
 254     ;;
 255 esac
 256
 257 dnl *** checks for programs ***
 258
 259 dnl find a compiler
 260 AC_PROG_CC
 261
 262 dnl check if the compiler supports '-c' and '-o' options
 263 AM_PROG_CC_C_O
 264
 265 dnl find an assembler
 266 AM_PROG_AS
 267
 268 dnl Perl is used in building documentation and in the version checks
 269 AC_PATH_PROG(PERL_PATH, perl, no)
 270 if test x$PERL_PATH = xno; then
 271   AC_MSG_ERROR(Could not find perl)
 272 fi
 273
 274 dnl we require flex and bison for building the parser
 275 AG_GST_BISON_CHECK
 276 AG_GST_FLEX_CHECK
 277
 278 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 279 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 280
 281 dnl check for documentation tools
 282 AG_GST_DOCBOOK_CHECK
 283 GTK_DOC_CHECK([1.3])
 284 AS_PATH_PYTHON([2.1])
 285 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 286
 287 dnl *** checks for libraries ***
 288
 289 dnl For interactive UNIX (a Sun thing)
 290 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 291 AC_ISC_POSIX
 292
 293 dnl check for libm, for sin()
 294 AC_CHECK_LIBM
 295 AC_SUBST(LIBM)
 296
 297 dnl *** checks for header files ***
 298
 299 dnl check if we have ANSI C header files
 300 AC_HEADER_STDC
 301
 302 dnl Check for ucontext.h
 303 AC_CHECK_HEADERS([ucontext.h])
 304
 305 dnl Check for sys/socket.h
 306 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 307 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 308
 309 dnl check for sys/times.h for tests/examples/adapter/
 310 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 311 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 312 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 313
 314 dnl Check for process.h for getpid() on win32
 315 AC_CHECK_HEADERS([process.h])
 316
 317 dnl Check for sys/utsname.h for uname
 318 AC_CHECK_HEADERS([sys/utsname.h])
 319
 320 dnl Check for stdio_ext.f for __fbufsize
 321 AC_CHECK_HEADERS([stdio_ext.h])
 322
 323 dnl *** checks for types/defines ***
 324
 325 dnl *** checks for structures ***
 326
 327 dnl *** checks for compiler characteristics ***
 328
 329 dnl make sure we can use "inline" from C code
 330 AC_C_INLINE
 331
 332 OPT_CFLAGS=
 333 dnl Check for some compiler flags that optimize our code.
 334 if test "x$GCC" = xyes; then
 335   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 336 fi
 337
 338 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 339 dnl flag
 340 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 341 dnl symbolic register names in inline asm
 342 if test x$HAVE_CPU_PPC = xyes ; then
 343   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 344     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 345 fi
 346
 347 dnl *** checks for library functions ***
 348
 349 AC_CHECK_FUNCS([sigaction])
 350
 351 dnl we use fork in the registry code
 352 AC_CHECK_FUNCS([fork])
 353
 354 dnl check for fseeko()
 355 AC_FUNC_FSEEKO
 356 dnl check for ftello()
 357 AC_CHECK_FUNCS([ftello])
 358
 359 AC_CHECK_FUNCS([fgetpos])
 360 AC_CHECK_FUNCS([fsetpos])
 361
 362 dnl check for poll(), ppoll() and pselect()
 363 AC_CHECK_FUNCS([poll])
 364 AC_CHECK_FUNCS([ppoll])
 365 AC_CHECK_FUNCS([pselect])
 366
 367 dnl check for mmap()
 368 AC_FUNC_MMAP
 369 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 370
 371 dnl Check for POSIX timers
 372 AC_CHECK_FUNCS(clock_gettime, [], [
 373   AC_CHECK_LIB(rt, clock_gettime, [
 374     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 375     LIBS="$LIBS -lrt"
 376   ])
 377 ])
 378
 379 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 380     AC_TRY_COMPILE([
 381 #include <time.h>
 382 #ifdef HAVE_UNISTD_H
 383 #include <unistd.h>
 384 #endif
 385     ], [
 386 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 387 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 388 #endif
 389       return 0;
 390     ], [
 391       gst_cv_posix_timers=yes
 392     ], [
 393       gst_cv_posix_timers=no
 394     ])
 395 )
 396
 397 if test "$gst_cv_posix_timers" = "yes"; then
 398   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 399   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 400 else
 401   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 402 fi
 403 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 404 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 405
 406 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 407     AC_TRY_COMPILE([
 408 #include <time.h>
 409 #ifdef HAVE_UNISTD_H
 410 #include <unistd.h>
 411 #endif
 412     ], [
 413 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 414 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 415 #endif
 416       return 0;
 417     ], [
 418       gst_cv_monotonic_clock=yes
 419     ], [
 420       gst_cv_monotonic_clock=no
 421     ])
 422 )
 423
 424 if test "$gst_cv_monotonic_clock" = "yes"; then
 425   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 426   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 427 else
 428   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 429 fi
 430 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 431 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 432
 433 dnl Check for a way to display the function name in debug output
 434 AG_GST_CHECK_FUNCTION
 435
 436 dnl test for register_printf_function
 437 AC_CHECK_FUNC(register_printf_function,
 438   [
 439     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 440     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 441     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 442     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 443       [Defined if we have register_printf_function ()])
 444   ], [
 445     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 446     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 447     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 448   ]
 449 )
 450 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 451 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 452 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 453
 454 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 455 save_cflags="$CFLAGS"
 456 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 457 AC_CHECK_LIB(dl, dladdr,
 458    AC_DEFINE(HAVE_DLADDR, 1,
 459              [Defined if we have dladdr ()]))
 460 CFLAGS="$save_cflags"
 461
 462 dnl check for inet_aton()
 463 save_libs="$LIBS"
 464 AC_CHECK_FUNC(inet_aton, ,
 465    AC_CHECK_LIB(nsl, inet_aton, ,
 466       AC_CHECK_LIB(socket, inet_aton, ,
 467          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 468 INET_ATON_LIBS=$LIBS
 469 AC_SUBST(INET_ATON_LIBS)
 470 LIBS="$save_libs"
 471
 472 dnl *** checks for dependency libraries ***
 473
 474 dnl GLib
 475 GLIB_REQ=2.12
 476
 477 AG_GST_GLIB_CHECK([$GLIB_REQ])
 478
 479 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 480 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 481 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 482
 483 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 484 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 485
 486 dnl Check for documentation xrefs
 487 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 488 AC_SUBST(GLIB_PREFIX)
 489
 490 dnl libxml 2 is optional in some cases
 491 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 492    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 493    test "x$USE_BINARY_REGISTRY" = "xyes" )
 494 then
 495   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 496   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 497 else
 498   dnl check for libxml2 with minimum req version
 499   AG_GST_LIBXML2_CHECK(2.4.9)
 500   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 501 fi
 502 AC_SUBST(GST_DISABLE_XML_DEFINE)
 503
 504 dnl check for "check", unit testing library/header
 505 AM_PATH_CHECK(0.9.2,
 506     [
 507         HAVE_CHECK=yes
 508         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 509         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 510     ],
 511     HAVE_CHECK=no)
 512 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 513
 514 dnl pkg-config check that for libcheck that works for cross-compiling
 515 dnl but not normal compilation on Fedora & Ubuntu:
 516 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 517 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 518 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 519 dnl )
 520
 521 dnl *** set variables based on configure arguments
 522
 523 dnl set license and copyright notice
 524 GST_LICENSE="LGPL"
 525 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 526 AC_SUBST(GST_LICENSE)
 527
 528 dnl define LIBDIR so we can inform people where we live
 529 AS_AC_EXPAND(LIBDIR, $libdir)
 530 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 531
 532 dnl set location of plugin directory
 533 AG_GST_SET_PLUGINDIR
 534
 535 dnl FIXME: add LIBXML_PKG here if we use it
 536 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 537 AC_SUBST(GST_PKG_DEPS)
 538
 539 dnl define an ERROR_CFLAGS Makefile variable
 540 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 541
 542 dnl define correct level for debugging messages
 543 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 544
 545 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 546
 547 dnl Overview:
 548 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 549 dnl GST_ALL_*:          vars shared by all built objects
 550 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 551 dnl GST_OBJ_*:          additional vars to link to the core library
 552 dnl                     include GST_ALL_*
 553 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 554 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 555
 556 dnl GST_OPTION_CFLAGS
 557 if test "x$USE_DEBUG" = xyes; then
 558    PROFILE_CFLAGS="-g"
 559 fi
 560 AC_SUBST(PROFILE_CFLAGS)
 561
 562 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 563 # functionality from the API that gstreamer uses
 564 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 565 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 566   dnl Define _only_ during CVS (not pre-releases or releases)
 567   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 568 else
 569   DEPRECATED_CFLAGS=""
 570 fi
 571 AC_SUBST(DEPRECATED_CFLAGS)
 572
 573 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 574 dnl make DEPRECATED_CFLAGS=''
 575 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 576 AC_SUBST(GST_OPTION_CFLAGS)
 577
 578 dnl GST_ALL_*
 579 dnl vars common to for all internal objects (core libs, elements, applications)
 580 dnl CFLAGS:
 581 dnl - XML needs to be added because xmlPtr is used in core
 582 dnl - src and build dirs need to be added because every piece that gets built
 583 dnl   will need the GStreamer source and generated headers
 584 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 585 dnl       from LibXML except for in the core library
 586 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 587
 588 dnl FIXME: check if LTLIBINTL is needed everywhere
 589 dnl I presume it is given that it contains the symbols that _() stuff maps to
 590 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 591
 592 dnl LDFLAGS really should only contain flags, not libs - they get added before
 593 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 594 GST_ALL_LDFLAGS="-no-undefined"
 595
 596 AC_SUBST(GST_ALL_CFLAGS)
 597 AC_SUBST(GST_ALL_LIBS)
 598 AC_SUBST(GST_ALL_LDFLAGS)
 599
 600 dnl GST_LIB_LDFLAGS
 601 dnl linker flags shared by all libraries
 602 dnl LDFLAGS modifier defining exported symbols from built libraries
 603 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 604 AC_SUBST(GST_LIB_LDFLAGS)
 605 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 606 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 607 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 608 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 609   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 610 fi
 611 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 612
 613 dnl GST_OBJ_*
 614 dnl default vars for all internal objects built on libgstreamer
 615 dnl includes GST_ALL_*
 616 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 617 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 618 AC_SUBST(GST_OBJ_CFLAGS)
 619 AC_SUBST(GST_OBJ_LIBS)
 620
 621 dnl GST_PLUGIN_LDFLAGS
 622 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 623 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 624 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 625
 626 AC_CONFIG_FILES(
 627 Makefile
 628 gst/Makefile
 629 gst/gstconfig.h
 630 gst/gstversion.h
 631 gst/parse/Makefile
 632 libs/Makefile
 633 libs/gst/Makefile
 634 libs/gst/base/Makefile
 635 libs/gst/check/Makefile
 636 libs/gst/controller/Makefile
 637 libs/gst/dataprotocol/Makefile
 638 libs/gst/net/Makefile
 639 plugins/Makefile
 640 plugins/indexers/Makefile
 641 plugins/elements/Makefile
 642 po/Makefile.in
 643 tests/Makefile
 644 tests/benchmarks/Makefile
 645 tests/check/Makefile
 646 tests/misc/Makefile
 647 tests/examples/Makefile
 648 tests/examples/adapter/Makefile
 649 tests/examples/controller/Makefile
 650 tests/examples/helloworld/Makefile
 651 tests/examples/launch/Makefile
 652 tests/examples/manual/Makefile
 653 tests/examples/metadata/Makefile
 654 tests/examples/queue/Makefile
 655 tests/examples/typefind/Makefile
 656 tests/examples/xml/Makefile
 657 tools/Makefile
 658 common/Makefile
 659 common/m4/Makefile
 660 docs/Makefile
 661 docs/design/Makefile
 662 docs/faq/Makefile
 663 docs/gst/Makefile
 664 docs/gst/gstreamer.types
 665 docs/libs/Makefile
 666 docs/plugins/Makefile
 667 docs/manual/Makefile
 668 docs/pwg/Makefile
 669 docs/slides/Makefile
 670 docs/xsl/Makefile
 671 docs/version.entities
 672 win32/common/config.h
 673 pkgconfig/Makefile
 674 stamp.h
 675 pkgconfig/gstreamer.pc
 676 pkgconfig/gstreamer-uninstalled.pc
 677 pkgconfig/gstreamer-base.pc
 678 pkgconfig/gstreamer-base-uninstalled.pc
 679 pkgconfig/gstreamer-check.pc
 680 pkgconfig/gstreamer-check-uninstalled.pc
 681 pkgconfig/gstreamer-controller.pc
 682 pkgconfig/gstreamer-controller-uninstalled.pc
 683 pkgconfig/gstreamer-dataprotocol.pc
 684 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 685 pkgconfig/gstreamer-net.pc
 686 pkgconfig/gstreamer-net-uninstalled.pc
 687 gst-element-check.m4
 688 gstreamer.spec
 689 )
 690
 691 AC_OUTPUT