configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.15.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 11, 0, 11)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.15.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127 AG_GST_ARG_WITH_PLUGINS
 128 AC_SUBST(GST_PLUGINS_SELECTED)
 129
 130 AG_GST_ARG_ENABLE_EXTERNAL
 131
 132 dnl *** checks for platform ***
 133
 134 dnl * hardware/architecture *
 135
 136 dnl common/m4/gst-arch.m4
 137 dnl check CPU type
 138 AG_GST_ARCH
 139
 140 dnl check for large file support
 141 dnl affected plugins must include config.h
 142 AC_SYS_LARGEFILE
 143
 144 dnl *** checks for programs ***
 145
 146 dnl find a compiler
 147 AC_PROG_CC
 148
 149 dnl check if the compiler supports '-c' and '-o' options
 150 AM_PROG_CC_C_O
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for documentation tools
 156 GTK_DOC_CHECK([1.3])
 157 AS_PATH_PYTHON([2.1])
 158 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 159
 160 dnl *** checks for libraries ***
 161
 162 dnl For interactive UNIX (a Sun thing)
 163 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 164 AC_ISC_POSIX
 165
 166 dnl libm, for sin() etc.
 167 AC_CHECK_LIBM
 168 AC_SUBST(LIBM)
 169
 170 dnl *** checks for header files ***
 171
 172 dnl check if we have ANSI C header files
 173 AC_HEADER_STDC
 174
 175 dnl used in gst/ffmpegcolorspace/mem.c
 176 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 177 AC_CHECK_HEADERS([malloc.h])
 178
 179 dnl used in gst/subparse/gstsubparse.c
 180 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 181 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 182
 183 if test "x$HAVE_REGEX_H" = "xyes"; then
 184   ac_cppflags_save="$CPPFLAGS"
 185   CPPFLAGS="-Wall -Werror `$PKG_CONFIG --cflags libxml-2.0`"
 186   AC_COMPILE_IFELSE(
 187     AC_LANG_PROGRAM([
 188 #include <libxml/HTMLparser.h>
 189                      ],[
 190 #ifndef LIBXML_HTML_ENABLED
 191 #error libxml2 has no HTML support
 192 #endif /* LIBXML_HTML_ENABLED */
 193                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 194   CPPFLAGS="$ac_cppflags_save"
 195
 196   if test "x$HAVE_LIBXML_HTML" = "xyes"; then
 197     GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED subparse"
 198   else
 199     GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 200   fi
 201 else
 202   GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 203   HAVE_LIBXML_HTML="no"
 204 fi
 205 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 206
 207 dnl used in gst/tcp
 208 AC_CHECK_HEADERS([sys/socket.h],
 209   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 210 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 211 if test "x$HAVE_SYS_SOCKET_H" = "xyes"; then
 212   GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED tcp"
 213 else
 214   GST_PLUGINS_NO="\t[tcp]\n$GST_PLUGINS_NO"
 215 fi
 216
 217 dnl used in gst-libs/gst/rtsp
 218 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 219 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 220   WIN32_LIBS="-lws2_32"
 221   AC_SUBST(WIN32_LIBS)
 222 fi
 223
 224 dnl check for hstrerror, for gst-libs/gst/rtsp
 225 save_libs="$LIBS"
 226 AC_CHECK_FUNC(hstrerror, ,
 227     AC_CHECK_LIB(resolv, hstrerror, ,
 228         [AC_DEFINE(NO_HSTRERROR, 1,
 229              [Define if you have no native hstrerror() function.])]))
 230 HSTRERROR_LIBS=$LIBS
 231 AC_SUBST(HSTRERROR_LIBS)
 232 LIBS="$save_libs"
 233
 234 dnl used in gst-libs/gst/pbutils and associated unit test
 235 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 236
 237 dnl ffmpegcolorspace includes _stdint.h
 238 dnl also, Windows does not have long long
 239 AX_CREATE_STDINT_H
 240
 241 dnl *** checks for functions ***
 242 AC_CHECK_FUNCS([localtime_r])
 243
 244 dnl *** checks for types/defines ***
 245
 246 dnl Check for FIONREAD ioctl declaration
 247 dnl used in gst/tcp
 248 GST_CHECK_FIONREAD
 249
 250 dnl *** checks for structures ***
 251
 252 dnl *** checks for compiler characteristics ***
 253
 254 dnl make sure we can use "inline" from C code
 255 AC_C_INLINE
 256
 257 dnl *** checks for library functions ***
 258
 259 dnl check for fseeko()
 260 AC_FUNC_FSEEKO
 261
 262 dnl Check for fast float to int casting as defined in C99
 263 dnl used in gst-libs/gst/floatcast/floatcast.h
 264 AC_C99_FUNC_LRINT
 265 AC_C99_FUNC_LRINTF
 266
 267 dnl Check for a way to display the function name in debug output
 268 AG_GST_CHECK_FUNCTION
 269
 270 dnl *** checks for dependency libraries ***
 271
 272 dnl GLib is required
 273 AG_GST_GLIB_CHECK([2.6])
 274
 275 dnl liboil is required
 276 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 277 if test "x$HAVE_LIBOIL" != "xyes"
 278 then
 279   AC_ERROR([liboil-0.3.8 or later is required])
 280 fi
 281
 282 dnl checks for gstreamer
 283 dnl uninstalled is selected preferentially -- see pkg-config(1)
 284 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 285 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 286 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 287 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 288 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 289 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 290
 291 dnl Check for documentation xrefs
 292 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 293 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 294 AC_SUBST(GLIB_PREFIX)
 295 AC_SUBST(GST_PREFIX)
 296
 297 dnl GTK is optional and used in examples
 298 HAVE_GTK=NO
 299 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 300 if test "x$HAVE_GTK_22" = "xyes"; then
 301   HAVE_GTK=yes
 302   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 303   AC_SUBST(GTK_VERSION)
 304   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 305   AC_SUBST(GTK_BASE_DIR)
 306 else
 307   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 308 fi
 309 if test "x$HAVE_GTK_20" = "xyes"; then
 310   HAVE_GTK=yes
 311 fi
 312 GTK_CFLAGS=$GTK2_CFLAGS
 313 GTK_LIBS=$GTK2_LIBS
 314 AC_SUBST(GTK_LIBS)
 315 AC_SUBST(GTK_CFLAGS)
 316 AC_SUBST(HAVE_GTK)
 317 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 318
 319 dnl *** set variables based on configure arguments ***
 320
 321 dnl set license and copyright notice
 322 GST_LICENSE="LGPL"
 323 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 324 AC_SUBST(GST_LICENSE)
 325
 326 dnl set location of plugin directory
 327 AG_GST_SET_PLUGINDIR
 328
 329 dnl define an ERROR_CFLAGS Makefile variable
 330 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 331
 332 dnl define correct level for debugging messages
 333 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 334
 335 dnl used in examples
 336 AG_GST_DEFAULT_ELEMENTS
 337
 338 dnl *** sys plug-ins ***
 339
 340 echo
 341 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 342 echo
 343
 344 dnl *** X11 ***
 345 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 346 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 347                   [ximagesink], [
 348   AC_PATH_XTRA
 349   ac_cflags_save="$CFLAGS"
 350   ac_cppflags_save="$CPPFLAGS"
 351   CFLAGS="$CFLAGS $X_CFLAGS"
 352   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 353
 354   dnl now try to find the HEADER
 355   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 356
 357   if test "x$HAVE_X" = "xno"
 358   then
 359     AC_MSG_NOTICE([cannot find X11 development files])
 360   else
 361     dnl this is much more than we want
 362     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 363     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 364     dnl it does not add the libs; therefore we add them here
 365     X_LIBS="$X_LIBS -lX11"
 366     AC_SUBST(X_CFLAGS)
 367     AC_SUBST(X_LIBS)
 368   fi
 369   AC_SUBST(HAVE_X)
 370   CFLAGS="$ac_cflags_save"
 371   CPPFLAGS="$ac_cppflags_save"
 372 ])
 373
 374 dnl Check for Xv extension
 375 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 376 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 377                   [xvimagesink], [
 378   AG_GST_CHECK_XV
 379 ])
 380
 381 dnl check for X Shm
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 383 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 384   if test x$HAVE_X = xyes; then
 385     AC_CHECK_LIB(Xext, XShmAttach,
 386                  HAVE_XSHM="yes", HAVE_XSHM="no",
 387                  $X_LIBS)
 388     if test "x$HAVE_XSHM" = "xyes"; then
 389       XSHM_LIBS="-lXext"
 390     else
 391       dnl On AIX, it is in XextSam instead, but we still need -lXext
 392       AC_CHECK_LIB(XextSam, XShmAttach,
 393                    HAVE_XSHM="yes", HAVE_XSHM="no",
 394                    $X_LIBS)
 395       if test "x$HAVE_XSHM" = "xyes"; then
 396         XSHM_LIBS="-lXext -lXextSam"
 397       fi
 398     fi
 399   fi
 400 ], , [
 401   AC_SUBST(HAVE_XSHM)
 402   AC_SUBST(XSHM_LIBS)
 403 ])
 404
 405 dnl v4l/v4l2 checks have been moved down because they require X
 406
 407 dnl *** Video 4 Linux ***
 408 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 409 dnl renamed to GST_V4L in accordance with V4L2 below
 410 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 411 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 412   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 413 #include <sys/types.h>
 414 #define _LINUX_TIME_H
 415 #define __user
 416 #include <linux/videodev.h>
 417   ])
 418
 419   dnl we can build v4l without Xv, but then we won't have XOverlay support
 420   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 421   then
 422     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 423     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 424   fi
 425 ])
 426
 427 dnl *** ext plug-ins ***
 428 dnl keep this list sorted alphabetically !
 429
 430 if test "x$BUILD_EXTERNAL" = "xyes"; then
 431
 432 echo
 433 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 434 echo
 435
 436 dnl *** alsa ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 438 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 439   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 440     HAVE_ALSA="yes"
 441     AC_SUBST(ALSA_CFLAGS)
 442     AC_SUBST(ALSA_LIBS)
 443   ], [
 444     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 445   ])
 446 ])
 447
 448 dnl *** CDParanoia ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 450 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 451   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 452                       cdda_open, -lm,
 453                       cdda_interface.h,
 454                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 455                       HEADER_DIR="no"
 456                       FOUND_CDPARANOIA="yes")
 457   if test "x$FOUND_CDPARANOIA" != "xyes";
 458   then
 459     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 460                         cdda_open, -lm,
 461                         cdda/cdda_interface.h,
 462                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 463                         HEADER_DIR="yes"
 464                         FOUND_CDPARANOIA="yes")
 465   fi
 466   if test "x$HEADER_DIR" = "xyes";
 467   then
 468     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 469                        defined if cdda headers are in a cdda/ directory)
 470   fi
 471   AC_SUBST(CDPARANOIA_LIBS)
 472 ])
 473 dnl FIXME : add second check somehow if that is necessary
 474 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 475 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 476
 477 dnl *** GNOME VFS ***
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 479 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 480   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 481 ])
 482
 483 dnl *** libvisual ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 485 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 486   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 487   if test $HAVE_LIBVISUAL = no
 488   then
 489     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 490   fi
 491 ])
 492
 493 dnl *** ogg ***
 494 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 495 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 496   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 497   if test $HAVE_OGG = no
 498   then
 499     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 500     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 501   fi
 502 ])
 503
 504 dnl *** pango ***
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 506 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 507   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 508 ])
 509
 510 dnl *** theora ***
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 512 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 513   dnl this check will work as long as theora uses 1.0.x or similar for the
 514   dnl first post-alpha release and not just 1.0
 515   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 516 ])
 517
 518 dnl *** vorbis ***
 519 dnl AM_PATH_VORBIS only takes two options
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 521 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 522   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 523   if test $HAVE_VORBIS = no
 524   then
 525     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 526     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 527   fi
 528 ])
 529
 530 if test "x$HAVE_VORBIS" = "xyes"; then
 531   ac_cflags_save="$CFLAGS"
 532   dnl FIXME: does this work on non-gcc? -- Company
 533   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 534   CFLAGS="-Wall -Werror"
 535   AC_COMPILE_IFELSE(
 536     AC_LANG_PROGRAM([
 537 #include <vorbis/codec.h>
 538                      ],[
 539 vorbis_dsp_state *v;
 540
 541 vorbis_synthesis_restart (v);
 542                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 543   if test "x$HAVE_VSR" = "xyes"; then
 544     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 545                        [defined if vorbis_synthesis_restart is present])
 546   fi
 547   CFLAGS="$ac_cflags_save"
 548 fi
 549
 550 else
 551
 552 dnl not building plugins with external dependencies,
 553 dnl but we still need to set the conditionals
 554 AM_CONDITIONAL(USE_ALSA, false)
 555 AM_CONDITIONAL(USE_CDPARANOIA, false)
 556 AM_CONDITIONAL(USE_GNOME_VFS, false)
 557 AM_CONDITIONAL(USE_LIBVISUAL, false)
 558 AM_CONDITIONAL(USE_OGG, false)
 559 AM_CONDITIONAL(USE_PANGO, false)
 560 AM_CONDITIONAL(USE_THEORA, false)
 561 AM_CONDITIONAL(USE_VORBIS, false)
 562
 563 fi dnl of EXT plugins
 564
 565 dnl seeking needs freetype, so check for it here
 566 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 567   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 568 ])
 569 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 570 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 571 AC_SUBST(FT2_CFLAGS)
 572 AC_SUBST(FT2_LIBS)
 573
 574 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 575
 576 dnl Overview:
 577 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 578 dnl GST_*:              flags shared by built objects to link against GStreamer
 579 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 580 dnl                          (compare to other modules) or for i18n
 581 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 582 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 583 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 584 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 585
 586 dnl GST_OPTION_CFLAGS
 587 if test "x$USE_DEBUG" = xyes; then
 588    PROFILE_CFLAGS="-g"
 589 fi
 590 AC_SUBST(PROFILE_CFLAGS)
 591
 592 if test "x$GST_CVS" = "xyes"; then
 593   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 594 else
 595   DEPRECATED_CFLAGS=""
 596 fi
 597 AC_SUBST(DEPRECATED_CFLAGS)
 598
 599 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 600 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 601 AC_SUBST(GST_OPTION_CFLAGS)
 602
 603 dnl our libraries need to be versioned correctly
 604 AC_SUBST(GST_LT_LDFLAGS)
 605
 606 dnl GST_PLUGINS_BASE_CFLAGS
 607 dnl prefer internal headers to already installed ones
 608 dnl also add builddir include for enumtypes and marshal
 609 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 610 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 611
 612 dnl FIXME: do we want to rename to GST_ALL_* ?
 613 dnl add GST_OPTION_CFLAGS, but overridable
 614 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 615 AC_SUBST(GST_CFLAGS)
 616 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 617 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 618 AC_SUBST(GST_LIBS)
 619
 620 dnl LDFLAGS really should only contain flags, not libs - they get added before
 621 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 622 GST_ALL_LDFLAGS="-no-undefined"
 623 AC_SUBST(GST_ALL_LDFLAGS)
 624
 625 dnl GST_LIB_LDFLAGS
 626 dnl linker flags shared by all libraries
 627 dnl LDFLAGS modifier defining exported symbols from built libraries
 628 dnl (export _gst_foo but not __gst_foo)
 629 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 630 AC_SUBST(GST_LIB_LDFLAGS)
 631
 632 dnl this really should only contain flags, not libs - they get added before
 633 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 634 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 635 AC_SUBST(GST_PLUGIN_LDFLAGS)
 636
 637 dnl *** output files ***
 638
 639 AC_CONFIG_FILES(
 640 Makefile
 641 gst-plugins-base.spec
 642 gst/Makefile
 643 gst/adder/Makefile
 644 gst/audioconvert/Makefile
 645 gst/audiorate/Makefile
 646 gst/audioresample/Makefile
 647 gst/audiotestsrc/Makefile
 648 gst/ffmpegcolorspace/Makefile
 649 gst/gdp/Makefile
 650 gst/playback/Makefile
 651 gst/subparse/Makefile
 652 gst/tcp/Makefile
 653 gst/typefind/Makefile
 654 gst/videotestsrc/Makefile
 655 gst/videorate/Makefile
 656 gst/videoscale/Makefile
 657 gst/volume/Makefile
 658 sys/Makefile
 659 sys/ximage/Makefile
 660 sys/xvimage/Makefile
 661 sys/v4l/Makefile
 662 ext/Makefile
 663 ext/alsa/Makefile
 664 ext/cdparanoia/Makefile
 665 ext/gnomevfs/Makefile
 666 ext/libvisual/Makefile
 667 ext/ogg/Makefile
 668 ext/pango/Makefile
 669 ext/theora/Makefile
 670 ext/vorbis/Makefile
 671 gst-libs/Makefile
 672 gst-libs/gst/Makefile
 673 gst-libs/gst/audio/Makefile
 674 gst-libs/gst/cdda/Makefile
 675 gst-libs/gst/fft/Makefile
 676 gst-libs/gst/floatcast/Makefile
 677 gst-libs/gst/interfaces/Makefile
 678 gst-libs/gst/netbuffer/Makefile
 679 gst-libs/gst/riff/Makefile
 680 gst-libs/gst/rtp/Makefile
 681 gst-libs/gst/rtsp/Makefile
 682 gst-libs/gst/sdp/Makefile
 683 gst-libs/gst/tag/Makefile
 684 gst-libs/gst/pbutils/Makefile
 685 gst-libs/gst/video/Makefile
 686 tools/Makefile
 687 win32/common/config.h
 688 pkgconfig/Makefile
 689 pkgconfig/gstreamer-audio.pc
 690 pkgconfig/gstreamer-audio-uninstalled.pc
 691 pkgconfig/gstreamer-cdda.pc
 692 pkgconfig/gstreamer-cdda-uninstalled.pc
 693 pkgconfig/gstreamer-fft.pc
 694 pkgconfig/gstreamer-fft-uninstalled.pc
 695 pkgconfig/gstreamer-floatcast.pc
 696 pkgconfig/gstreamer-floatcast-uninstalled.pc
 697 pkgconfig/gstreamer-interfaces.pc
 698 pkgconfig/gstreamer-interfaces-uninstalled.pc
 699 pkgconfig/gstreamer-netbuffer.pc
 700 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 701 pkgconfig/gstreamer-pbutils.pc
 702 pkgconfig/gstreamer-pbutils-uninstalled.pc
 703 pkgconfig/gstreamer-riff.pc
 704 pkgconfig/gstreamer-riff-uninstalled.pc
 705 pkgconfig/gstreamer-rtp.pc
 706 pkgconfig/gstreamer-rtp-uninstalled.pc
 707 pkgconfig/gstreamer-rtsp.pc
 708 pkgconfig/gstreamer-rtsp-uninstalled.pc
 709 pkgconfig/gstreamer-sdp.pc
 710 pkgconfig/gstreamer-sdp-uninstalled.pc
 711 pkgconfig/gstreamer-tag.pc
 712 pkgconfig/gstreamer-tag-uninstalled.pc
 713 pkgconfig/gstreamer-video.pc
 714 pkgconfig/gstreamer-video-uninstalled.pc
 715 pkgconfig/gstreamer-plugins-base.pc
 716 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 717 tests/Makefile
 718 tests/check/Makefile
 719 tests/examples/Makefile
 720 tests/examples/dynamic/Makefile
 721 tests/examples/seek/Makefile
 722 tests/examples/volume/Makefile
 723 tests/examples/snapshot/Makefile
 724 tests/icles/Makefile
 725 docs/Makefile
 726 docs/design/Makefile
 727 docs/libs/Makefile
 728 docs/plugins/Makefile
 729 docs/version.entities
 730 po/Makefile.in
 731 common/Makefile
 732 common/m4/Makefile
 733 m4/Makefile
 734 )
 735 AC_OUTPUT
 736
 737 AG_GST_OUTPUT_PLUGINS