configure.ac

   1 AC_INIT
   2 AC_CANONICAL_TARGET([])
   3
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AS_VERSION(gstreamer, GST_VERSION, 0, 7, 0, 1, GST_CVS="no", GST_CVS="yes")
   7
   8 if test x$program_suffix = xNONE ; then
   9   program_suffix=-$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  10 fi
  11
  12 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  13 AM_MAINTAINER_MODE
  14 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  15
  16 dnl our libraries and install dirs use major.minor as a version
  17 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  18 AC_SUBST(GST_MAJORMINOR)
  19
  20 AC_PROG_CC
  21 dnl For interactive UNIX (a Sun thing)
  22 AC_ISC_POSIX
  23
  24 dnl CURRENT, REVISION, AGE
  25 dnl - library source changed -> increment REVISION
  26 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  27 dnl - interfaces added -> increment AGE
  28 dnl - interfaces removed -> AGE = 0
  29 AS_LIBTOOL(GST, 3, 0, 0)
  30
  31 AC_CONFIG_SRCDIR([gst/gst.c])
  32 AM_CONFIG_HEADER(config.h)
  33
  34 dnl Add parameters for aclocal
  35 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  36 ACLOCAL="$ACLOCAL -I common/m4 $ACLOCAL_FLAGS"
  37
  38 AM_PROG_CC_STDC
  39 AM_PROG_AS
  40 AS="${CC}"
  41
  42 dnl AC_PROC_INTLTOOL([0.26])
  43 dnl AM_GNU_GETTEXT([external])
  44 ALL_LINGUAS="de"
  45 GETTEXT_PACKAGE=gstreamer-$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  46 AC_SUBST(GETTEXT_PACKAGE)
  47 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],"$GETTEXT_PACKAGE",[gettext package name])
  48 AM_GLIB_GNU_GETTEXT
  49
  50 AM_GLIB_DEFINE_LOCALEDIR(GST_LOCALEDIR)
  51
  52 dnl decide on error flags
  53 AS_COMPILER_FLAG(-Wall,GST_ERROR="$GST_ERROR -Wall",GST_ERROR="$GST_ERROR")
  54 if test "x$GST_CVS" = "xyes"; then
  55   AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  56 fi
  57
  58 dnl We disable static building for development, for time savings
  59 dnl *NOTE*: dnl this line before release, so release does static too
  60 dnl AM_DISABLE_STATIC
  61
  62 AC_HEADER_STDC([])
  63
  64
  65 dnl ##############################
  66 dnl # Do automated configuration #
  67 dnl ##############################
  68
  69 dnl Check for tools:
  70 dnl ================
  71
  72 dnl allow for different autotools
  73 AS_AUTOTOOLS_ALTERNATE()
  74
  75 dnl modify pkg-config path
  76 AC_ARG_WITH(pkg-config-path,
  77    AC_HELP_STRING([--with-pkg-config-path],
  78                   [colon-separated list of pkg-config(1) dirs]),
  79    [export PKG_CONFIG_PATH=${withval}])
  80
  81 GST_DOC()
  82 GST_ARCH()
  83
  84 dnl Perl is used in building documentation
  85 AC_PATH_PROG(PERL_PATH, perl, no)
  86 if test x$PERL_PATH = xno; then
  87   AC_MSG_ERROR(Could not find perl)
  88 fi
  89
  90 dnl we require bison for building of some of the marshal files
  91 dnl FIXME: check if AC_PROG_YACC is suitable here
  92 AC_PATH_PROG(BISON_PATH, bison, no)
  93 if test x$BISON_PATH = xno; then
  94   AC_MSG_ERROR(Could not find bison)
  95 fi
  96
  97 dnl we require flex for building the parser
  98 dnl FIXME: check if AC_PROG_LEX is suitable here
  99 AC_PATH_PROG(FLEX_PATH, flex, no)
 100 if test x$FLEX_PATH = xno; then
 101   AC_MSG_ERROR(Could not find flex)
 102 fi
 103
 104 dnl
 105 dnl We should really use AC_SYS_LARGEFILE, but the problem is
 106 dnl many of the plugins don't include "config.h".  To assure
 107 dnl binary compatibility, it is necessary that all gstreamer
 108 dnl code be compiled with the same sizeof(off_t), so we use
 109 dnl the following crude hack.
 110 dnl
 111
 112 dnl
 113 dnl GST_CFLAGS are split up as GST_EXT_CFLAGS and GST_INT_CFLAGS
 114 dnl same for libs
 115 dnl this is so we can make GST_CFLAGS for external modules available
 116 dnl without mixing in internal (uninstalled) CFLAGS
 117 dnl
 118
 119 dnl disable deprecated functions internally
 120 GST_INT_CFLAGS="-DGST_DISABLE_DEPRECATED"
 121
 122 AC_MSG_CHECKING(for large file support)
 123 AC_TRY_RUN([
 124 #define _LARGEFILE_SOURCE
 125 #define _FILE_OFFSET_BITS 64
 126 #include <sys/types.h>
 127 int main () { return !(sizeof(off_t) == 8); }
 128 ],
 129 [
 130 AC_MSG_RESULT(yes)
 131 GST_EXT_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 132 ],
 133 [
 134 AC_MSG_RESULT(no)
 135 ],
 136 [
 137 AC_MSG_RESULT(no)
 138 ])
 139
 140 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 141 AC_CHECK_MCSC()
 142 if test "$ac_cv_check_mcsc" == "yes"; then
 143   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, $HAVE_MAKECONTEXT,
 144                      [defined if we have makecontext ()])
 145 fi
 146
 147 dnl Check for a way to display the function name in debug output
 148 GST_CHECK_FUNCTION()
 149
 150 dnl Check for essential libraries first:
 151 dnl ====================================
 152
 153 dnl === GLib 2 ===
 154 dnl Minimum required version of GLib2
 155 dnl required for compilation without warnings
 156 GLIB2_REQ="2.0.1"
 157 AC_SUBST(GLIB2_REQ)
 158
 159 dnl Check for glib2
 160 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,HAVE_GLIB2=yes,HAVE_GLIB2=no)
 161 GLIB_LIBS=$GLIB2_LIBS
 162 GLIB_CFLAGS=$GLIB2_CFLAGS
 163 AC_SUBST(GLIB_LIBS)
 164 AC_SUBST(GLIB_CFLAGS)
 165
 166 if test "x$HAVE_GLIB2" = "xno"; then
 167   AC_MSG_ERROR([GStreamer requires GLib 2.0 to compile.])
 168 fi
 169
 170 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 171 AC_SUBST(GST_PKG_DEPS)
 172
 173 dnl === libxml 2 ===
 174 dnl Minimum required version of libxml2
 175 LIBXML2_REQ="2.4.9"
 176 AC_SUBST(LIBXML2_REQ)
 177
 178 dnl check for libxml2
 179 GST_LIBXML2_CHECK()
 180
 181 dnl popt checks
 182 dnl FIXME: This test passes on popt 1.6.2, maybe earlier, but popt 1.6.2
 183 dnl        causes segfaults on gst_init. Write a working test if possible.
 184 GST_CHECK_LIBHEADER(POPT, popt, poptStrippedArgv,, popt.h, POPT_LIBS="-lpopt",
 185   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 186                 download the latest version from
 187                 ftp://ftp.rpm.org/pub/rpm/dist/])
 188 )
 189 AC_MSG_NOTICE(Checking for POPT_TABLEEND)
 190 AC_COMPILE_IFELSE([
 191 #include <popt.h>
 192 int main ()
 193 {
 194 #ifndef POPT_TABLEEND
 195 #error
 196 #else
 197   return 0;
 198 #endif
 199 }
 200 ],, [
 201   dnl it failed
 202   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 203                 download the latest version from
 204                 ftp://ftp.rpm.org/pub/rpm/dist/])
 205 ])
 206
 207 dnl Check for atomic.h
 208 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 209 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 210 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 211 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 212 if test x$HAVE_ATOMIC_H = xyes; then
 213   AC_LINK_IFELSE([
 214 #include "asm/atomic.h"
 215 main() {atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 216   ],, [
 217     # Not successful
 218     if test x$HAVE_ATOMIC_H = xyes; then
 219       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 220     fi
 221     HAVE_ATOMIC_H=no
 222   ])
 223 fi
 224
 225 dnl Check for ucontext.h
 226 AC_CHECK_HEADER(ucontext.h, AC_DEFINE(HAVE_UCONTEXT_H, 1, [defined if we have ucontext.h]))
 227
 228 dnl ######################################################################
 229 dnl # Check command line parameters, and set shell variables accordingly #
 230 dnl ######################################################################
 231
 232 dnl FIXME: simplify all this down using a few m4 macros
 233
 234 AC_ARG_ENABLE(libmmx,
 235 AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
 236 [case "${enableval}" in
 237   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 238   no)  USE_LIBMMX=no ;;
 239   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 240 esac],
 241 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 242
 243 AC_ARG_ENABLE(atomic,
 244 AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 245 [case "${enableval}" in
 246   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 247   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 248   no)  USE_ATOMIC_H=no;;
 249   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 250 esac],
 251 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 252
 253 AC_ARG_ENABLE(fast-stack-trash,
 254 AC_HELP_STRING([--enable-fast-stack-trash],[use fast memory allocator (i586 or above)]),
 255 [case "${enableval}" in
 256   yes) USE_FAST_STACK_TRASH=yes;;
 257   noset) USE_FAST_STACK_TRASH=no;;
 258   no)  USE_FAST_STACK_TRASH=no;;
 259   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 260 esac],
 261 [USE_FAST_STACK_TRASH=yes]) dnl Default value
 262
 263 AC_ARG_ENABLE(plugin-builddir,
 264 AC_HELP_STRING([--enable-plugin-builddir],[allow tests/demos to use non-installed plugins]),
 265 [case "${enableval}" in
 266   yes) PLUGINS_USE_BUILDDIR=yes ;;
 267   no)  PLUGINS_USE_BUILDDIR=no ;;
 268   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 269 esac],
 270 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 271
 272 AC_ARG_ENABLE(profiling,
 273 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 274 [case "${enableval}" in
 275   yes) USE_PROFILING=yes ;;
 276   no)  UES_PROFILING=no ;;
 277   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 278 esac],
 279 [USE_PROFILING=no]) dnl Default value
 280
 281 dnl use a cache dir for storing element registry info.
 282 dnl default to building registry in the source tree if we are enabling plugin build dir
 283 if test "x$PLUGINS_USE_BUILDDIR" = "xyes"; then
 284   GST_CACHE_DIR=`pwd`
 285 else
 286   dnl ${localstatedir} points to PREFIX/var
 287   GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 288 fi
 289 AC_ARG_WITH(cachedir,
 290 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 291 [case "${withval}" in
 292   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 293   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 294   *) GST_CACHE_DIR="${withval}" ;;
 295 esac],
 296 [:]) dnl Default value
 297
 298 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 299 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 300
 301
 302 dnl building of tests
 303 AC_ARG_ENABLE(tests,
 304 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 305 [case "${enableval}" in
 306   yes) BUILD_TESTS=yes ;;
 307   no)  BUILD_TESTS=no ;;
 308   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 309 esac],
 310 [BUILD_TESTS=yes]) dnl Default value
 311 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 312
 313 dnl tests known to fail
 314 AC_ARG_ENABLE(failing-tests,
 315 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 316 [case "${enableval}" in
 317   yes) BUILD_FAILING_TESTS=yes ;;
 318   no)  BUILD_FAILING_TESTS=no ;;
 319   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 320 esac],
 321 [BUILD_FAILING_TESTS=no]) dnl Default value
 322 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 323 if test x$BUILD_FAILING_TESTS = xyes; then
 324   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 325 else
 326   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 327 fi
 328
 329 AC_ARG_ENABLE(examples,
 330 AC_HELP_STRING([--disable-examples],[disable building examples]),
 331 [case "${enableval}" in
 332   yes) BUILD_EXAMPLES=yes ;;
 333   no)  BUILD_EXAMPLES=no ;;
 334   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 335 esac],
 336 [BUILD_EXAMPLES=yes]) dnl Default value
 337 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 338
 339 dnl poison destroyed objects
 340 AC_ARG_ENABLE(poisoning,
 341 AC_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 342 [case "${enableval}" in
 343   yes) USE_POISONING=yes ;;
 344   no)  USE_POISONING=no ;;
 345   *) AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 346 esac],
 347 [USE_POISONING=no]) dnl Default value
 348
 349 dnl Next, check for the optional components:
 350 dnl ========================================
 351
 352 dnl debugging stuff
 353 AC_ARG_ENABLE(debug,
 354 AC_HELP_STRING([--disable-debug],[disable addition of -g debugging info]),
 355 [case "${enableval}" in
 356   yes) USE_DEBUG=yes ;;
 357   no)  USE_DEBUG=no ;;
 358   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 359 esac],
 360 [USE_DEBUG=yes]) dnl Default value
 361 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, true)
 362 GST_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
 363
 364 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_LOADSAVE, true)
 365 GST_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
 366 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TYPEFIND, true)
 367 GST_SUBSYSTEM_DISABLE(TYPEFIND,[typefind plugin],)
 368 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_AUTOPLUG, true)
 369 GST_SUBSYSTEM_DISABLE(AUTOPLUG,[autoplugger subsystem])
 370 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PARSE, true)
 371 GST_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
 372 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TRACE, true)
 373 GST_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 374 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, true)
 375 GST_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 376
 377 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_REGISTRY, true)
 378 GST_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 379 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, true)
 380 GST_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 381 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_INDEX, true)
 382 GST_SUBSYSTEM_DISABLE(INDEX,[index])
 383 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PLUGIN, true)
 384 GST_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 385 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_URI, true)
 386 GST_SUBSYSTEM_DISABLE(URI,[uri handlers])
 387
 388 dnl ################################################
 389 dnl # Set defines according to variables set above #
 390 dnl ################################################
 391
 392
 393 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 394 dnl HAVE_ and it is likely to be easier to stick with the old name
 395 if test "x$USE_LIBMMX" = xyes; then
 396   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 397 fi
 398
 399 if test "x$USE_ATOMIC_H" = xyes; then
 400   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 401 fi
 402
 403 if test "x$USE_FAST_STACK_TRASH" = xyes; then
 404   AC_DEFINE(USE_FAST_STACK_TRASH, 1, [Define if we should use i586 optimized stack functions])
 405 fi
 406
 407 if test "x$USE_POISONING" = xyes; then
 408   AC_DEFINE(USE_POISONING, 1, [Define if we should poison deallocated memory])
 409 fi
 410
 411 dnl test if we have pthread_attr_setstack; if not use the older calls
 412 AC_CHECK_LIB(pthread, pthread_attr_setstack,
 413    AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACK, 1,
 414              [Defined if libpthread has pthread_attr_setstack ()]))
 415
 416 dnl test if we have posix_memalign; FreeBSD doesn't
 417 AC_CHECK_FUNC(posix_memalign,
 418    AC_DEFINE(HAVE_POSIX_MEMALIGN, 1,
 419              [Defined if we have posix_memalign ()]))
 420
 421 dnl test for sigaction()
 422 AC_CHECK_FUNC(sigaction,
 423    AC_DEFINE(HAVE_SIGACTION, 1,
 424              [Defined if we have sigaction ()]))
 425
 426 dnl test if we have dladdr(); we use it for debugging
 427 save_cflags="$CFLAGS"
 428 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 429 AC_CHECK_LIB(dl, dladdr,
 430    AC_DEFINE(HAVE_DLADDR, 1,
 431              [Defined if we have dladdr ()]))
 432 CFLAGS="$save_cflags"
 433
 434 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 435   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 436 fi
 437
 438 if test "x$USE_DEBUG" = xyes; then
 439    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 440 fi
 441
 442 dnl #############################
 443 dnl # Set automake conditionals #
 444 dnl #############################
 445
 446 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 447 dnl HAVE_ and it is likely to be easier to stick with the old name
 448 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 449
 450 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 451 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 452
 453 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
 454
 455
 456 dnl ############################
 457 dnl # Set up some more defines #
 458 dnl ############################
 459
 460 dnl Set location of registry dir.
 461 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Define the registry directory])
 462 AC_SUBST(GST_CACHE_DIR)
 463
 464 dnl Set location of plugin directory
 465 if test "x${prefix}" = "xNONE"; then
 466   PLUGINS_DIR=${ac_default_prefix}/lib/gstreamer-$GST_MAJORMINOR
 467 else
 468   PLUGINS_DIR=${prefix}/lib/gstreamer-$GST_MAJORMINOR
 469 fi
 470 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 471 AC_SUBST(PLUGINS_DIR)
 472
 473 dnl Set location of uninstalled plugin directory
 474 PLUGINS_BUILDDIR=`pwd`
 475 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR, "$PLUGINS_BUILDDIR", [Define the uninstalled plugin directory])
 476 AC_SUBST(PLUGINS_BUILDDIR)
 477
 478 dnl since glib and xml are package deps, there's no need to include their cflags
 479 dnl in the pkg-config file
 480
 481 dnl for pkg-config
 482 GST_PKG_CFLAGS=$GST_EXT_CFLAGS
 483 GST_PKG_LIBS=$GST_EXT_LIBS
 484 AC_SUBST(GST_PKG_CFLAGS)
 485 AC_SUBST(GST_PKG_LIBS)
 486
 487 dnl finalize _CFLAGS and _LIBS
 488 dnl add GLIB and XML if necessary to EXT_*
 489 GST_CFLAGS="$GST_EXT_CFLAGS $XML_CFLAGS $GLIB_CFLAGS"
 490 GST_LIBS="$GST_EXT_LIBS $XML_LIBS $GLIB_LIBS -lpopt"
 491
 492 dnl Private vars for libgst only
 493 LIBGST_LIBS="$GST_LIBS"
 494 LIBGST_CFLAGS="$GST_CFLAGS -I\$(top_srcdir) $GST_ERROR"
 495 AC_SUBST(LIBGST_LIBS)
 496 AC_SUBST(LIBGST_CFLAGS)
 497
 498 dnl Vars for everyone else
 499 GST_INT_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la"
 500 GST_INT_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)/include"
 501
 502 AC_SUBST(GST_CFLAGS, "$LIBGST_CFLAGS $GST_INT_CFLAGS")
 503 AC_SUBST(GST_LIBS, "$LIBGST_LIBS $GST_INT_LIBS")
 504
 505 GST_PLUGIN_LDFLAGS="-module -avoid-version"
 506 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 507
 508
 509 dnl ##################################################
 510 dnl # deps for examples from manual                  #
 511 dnl ##################################################
 512
 513 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 514                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 515 AC_SUBST(LIBGNOMEUI_CFLAGS)
 516 AC_SUBST(LIBGNOMEUI_LIBS)
 517 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 518
 519 dnl ##################################################
 520 dnl # Prepare informative messages to display at end #
 521 dnl ##################################################
 522
 523 infomessages=
 524
 525 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 526   infomessages="$infomessages
 527 *** Warning: You have configured using the --enable-plugin-builddir option.
 528
 529 This option is for development purposes only: binaries built with
 530 it should be used with code in the build tree only.  To build an
 531 installable version, use ./configure without the --enable-plugin-builddir
 532 option.  Note that the autogen.sh script supplies the plugin builddir
 533 option automatically -- run ./autogen.sh -- --disable-plugin-builddir to make
 534 an installable build.
 535
 536 "
 537 fi
 538
 539 dnl #########################
 540 dnl # Make the output files #
 541 dnl #########################
 542
 543 dnl libs/ext/Makefile
 544 dnl nothing there yet !
 545 AC_OUTPUT(
 546 Makefile
 547 include/Makefile
 548 gst/Makefile
 549 gst/gstconfig.h
 550 gst/gstversion.h
 551 gst/autoplug/Makefile
 552 gst/indexers/Makefile
 553 gst/elements/Makefile
 554 gst/parse/Makefile
 555 gst/schedulers/Makefile
 556 gst/types/Makefile
 557 gst/registries/Makefile
 558 libs/Makefile
 559 libs/gst/Makefile
 560 libs/gst/getbits/Makefile
 561 libs/gst/control/Makefile
 562 libs/ext/Makefile
 563 po/Makefile.in
 564 tests/Makefile
 565 tests/bufspeed/Makefile
 566 tests/memchunk/Makefile
 567 tests/muxing/Makefile
 568 tests/seeking/Makefile
 569 tests/sched/Makefile
 570 tests/threadstate/Makefile
 571 testsuite/Makefile
 572 testsuite/bytestream/Makefile
 573 testsuite/caps/Makefile
 574 testsuite/cleanup/Makefile
 575 testsuite/clock/Makefile
 576 testsuite/debug/Makefile
 577 testsuite/dynparams/Makefile
 578 testsuite/elements/Makefile
 579 testsuite/indexers/Makefile
 580 testsuite/parse/Makefile
 581 testsuite/plugin/Makefile
 582 testsuite/refcounting/Makefile
 583 testsuite/threads/Makefile
 584 examples/Makefile
 585 examples/autoplug/Makefile
 586 examples/cutter/Makefile
 587 examples/helloworld/Makefile
 588 examples/helloworld2/Makefile
 589 examples/launch/Makefile
 590 examples/manual/Makefile
 591 examples/mixer/Makefile
 592 examples/pingpong/Makefile
 593 examples/plugins/Makefile
 594 examples/queue/Makefile
 595 examples/queue2/Makefile
 596 examples/queue3/Makefile
 597 examples/queue4/Makefile
 598 examples/thread/Makefile
 599 examples/typefind/Makefile
 600 examples/xml/Makefile
 601 tools/Makefile
 602 docs/Makefile
 603 docs/faq/Makefile
 604 docs/gst/Makefile
 605 docs/libs/Makefile
 606 docs/manual/Makefile
 607 docs/pwg/Makefile
 608 docs/plugins/Makefile
 609 docs/plugins/gstreamer-plugins.types
 610 docs/xsl/Makefile
 611 pkgconfig/Makefile
 612 stamp.h
 613 pkgconfig/gstreamer.pc
 614 pkgconfig/gstreamer-uninstalled.pc
 615 pkgconfig/gstreamer-control.pc
 616 pkgconfig/gstreamer-control-uninstalled.pc
 617 gstreamer.spec,
 618 echo "$infomessages", infomessages="$infomessages"
 619 )