configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.30.2,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.10
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 27, 0, 27)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  82 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  85 then
  86   GST_LOADSAVE_DOC_TYPES="%"
  87 else
  88   GST_LOADSAVE_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121
 122 AG_GST_ARG_DEBUG
 123 AG_GST_ARG_PROFILING
 124 AG_GST_ARG_VALGRIND
 125 AG_GST_ARG_GCOV
 126
 127 AG_GST_ARG_EXAMPLES
 128
 129 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 130 AG_GST_ARG_WITH_PACKAGE_NAME
 131 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 132
 133 AG_GST_PKG_CONFIG_PATH
 134
 135 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 136   ["${srcdir}/gstreamer.doap"],
 137   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 138
 139 dnl building of tests
 140 AC_ARG_ENABLE(tests,
 141   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 142   [
 143     case "${enableval}" in
 144       yes) BUILD_TESTS=yes ;;
 145       no)  BUILD_TESTS=no ;;
 146       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 147     esac
 148   ],
 149 [BUILD_TESTS=yes]) dnl Default value
 150 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 151
 152 dnl tests known to fail
 153 AC_ARG_ENABLE(failing-tests,
 154   AC_HELP_STRING([--disable-failing-tests],
 155     [disable building tests known to fail]),
 156   [
 157     case "${enableval}" in
 158       yes) BUILD_FAILING_TESTS=yes ;;
 159       no)  BUILD_FAILING_TESTS=no ;;
 160       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 161     esac
 162   ],
 163   [BUILD_FAILING_TESTS=no]) dnl Default value
 164 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 165 if test x$BUILD_FAILING_TESTS = xyes; then
 166   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 167 else
 168   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 169 fi
 170
 171 dnl poison destroyed objects
 172 AC_ARG_ENABLE(poisoning,
 173   AC_HELP_STRING([--enable-poisoning],
 174     [enable poisoning of deallocated objects]),
 175   [
 176     case "${enableval}" in
 177       yes) USE_POISONING=yes ;;
 178       no)  USE_POISONING=no ;;
 179       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 180     esac
 181   ],
 182   [USE_POISONING=no]) dnl Default value
 183 if test "x$USE_POISONING" = xyes; then
 184   AC_DEFINE(USE_POISONING, 1,
 185     [Define if we should poison deallocated memory])
 186 fi
 187
 188 dnl *** checks for platform ***
 189
 190 dnl * hardware/architecture *
 191
 192 dnl common/m4/gst-arch.m4
 193 dnl check CPU type
 194 AG_GST_ARCH
 195 dnl substitution for win32/common/config.h
 196 HOST_CPU=$host_cpu
 197 AC_SUBST(HOST_CPU)
 198
 199 dnl common/m4/gst-arch.m4
 200 dnl check for unaligned access
 201 AG_GST_UNALIGNED_ACCESS
 202 dnl create a configure variable for gst/gstconfig.h
 203 if test x${as_cv_unaligned_access} = xyes ; then
 204   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 205 else
 206   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 207 fi
 208 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 209
 210 dnl check for platform specific settings
 211 AG_GST_PLATFORM
 212
 213 dnl * software *
 214
 215 dnl check for large file support
 216 dnl affected plugins must include config.h
 217 AC_SYS_LARGEFILE
 218
 219 dnl *** checks for programs ***
 220
 221 dnl find a compiler
 222 AC_PROG_CC
 223 AC_PROG_CC_STDC
 224
 225 dnl check if the compiler supports '-c' and '-o' options
 226 AM_PROG_CC_C_O
 227
 228 dnl find an assembler
 229 AM_PROG_AS
 230
 231 dnl determine if c++ is available on this system
 232 AC_PROG_CXX
 233 dnl CXX may be set to some default even if no c++ compiler is available
 234 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 235 AC_LANG_PUSH([C++])
 236 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 237 AC_LANG_POP([C++])
 238 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 239 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" == "xyes")
 240
 241 dnl Perl is used in building documentation and in the version checks
 242 AC_PATH_PROG(PERL_PATH, perl, no)
 243 if test x$PERL_PATH = xno; then
 244   AC_MSG_ERROR(Could not find perl)
 245 fi
 246
 247 dnl we require flex and bison for building the parser
 248 if test "x$GST_DISABLE_PARSE" != xyes; then
 249   AG_GST_BISON_CHECK
 250   AG_GST_FLEX_CHECK
 251 fi
 252
 253 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 254 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 255
 256 dnl check for gobject-introspection
 257 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 258
 259 dnl check for documentation tools
 260 AG_GST_DOCBOOK_CHECK
 261 GTK_DOC_CHECK([1.3])
 262 AS_PATH_PYTHON([2.1])
 263 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 264
 265 dnl *** checks for libraries ***
 266
 267 dnl check for libm, for sin()
 268 AC_CHECK_LIBM
 269 AC_SUBST(LIBM)
 270
 271 dnl *** checks for header files ***
 272
 273 dnl check if we have ANSI C header files
 274 AC_HEADER_STDC
 275
 276 dnl Check for ucontext.h
 277 AC_CHECK_HEADERS([ucontext.h])
 278
 279 dnl Check for sys/socket.h
 280 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 281 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 282
 283 dnl check for sys/times.h for tests/examples/adapter/
 284 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 285 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 286 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 287
 288 dnl Check for process.h for getpid() on win32
 289 AC_CHECK_HEADERS([process.h])
 290
 291 dnl Check for sys/utsname.h for uname
 292 AC_CHECK_HEADERS([sys/utsname.h])
 293
 294 dnl Check for stdio_ext.f for __fbufsize
 295 AC_CHECK_HEADERS([stdio_ext.h])
 296
 297 dnl check for pthreads
 298 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 299 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 300
 301 dnl check for sys/prctl for setting thread name on Linux
 302 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 303
 304 dnl Check for valgrind.h
 305 dnl separate from HAVE_VALGRIND because you can have the program, but not
 306 dnl the dev package
 307 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 308
 309 dnl used in gst/gstpoll.c
 310 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 311 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 312 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 313   WIN32_LIBS="-lws2_32"
 314   AC_SUBST(WIN32_LIBS)
 315 fi
 316
 317 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 318 if test "x$BUILD_TESTS" = "xyes"; then
 319   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 320                          __gmpz_init_set_d, ,
 321                          gmp.h,
 322                          GMP_LIBS="-lgmp"
 323                          AC_SUBST(GMP_LIBS)
 324                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 325   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 326                          gsl_rng_uniform_int, -lgslcblas,
 327                          gsl/gsl_rng.h,
 328                          GSL_LIBS="-lgsl -lgslcblas"
 329                          AC_SUBST(GSL_LIBS)
 330                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 331 fi
 332
 333 dnl *** checks for types/defines ***
 334
 335 dnl *** checks for structures ***
 336
 337 dnl *** checks for compiler characteristics ***
 338
 339 dnl check if the compiler supports __uint128_t (gcc)
 340 dnl Actually check for 128-bit division, since that's what we use
 341 dnl uint128_t for.
 342 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 343     AC_TRY_LINK([ ], [
 344       static __uint128_t v1 = 100;
 345       static __uint128_t v2 = 10;
 346       static __uint128_t u;
 347       u = v1 / v2;
 348     ], [
 349       gst_cv_uint128_t=yes
 350     ], [
 351       gst_cv_uint128_t=no
 352     ])
 353 )
 354 if test x$gst_cv_uint128_t = xyes; then
 355   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 356 fi
 357
 358 dnl *** checking for tm_gmtoff ***
 359 AC_MSG_CHECKING([for tm_gmtoff])
 360 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 361         #include <time.h>
 362         int main(void) {
 363           struct tm t;
 364           t.tm_gmtoff = 0;
 365           exit(0);
 366         }]])],
 367   [have_tm_gmtoff=yes
 368    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 369   [have_tm_gmtoff=no],
 370   [have_tm_gmtoff="no (cross compiling)"])
 371 AC_MSG_RESULT($have_tm_gmtoff)
 372
 373
 374 dnl *** checks for library functions ***
 375
 376 AC_CHECK_FUNCS([gmtime_r])
 377 AC_CHECK_FUNCS([sigaction])
 378
 379 dnl check for fseeko()
 380 AC_FUNC_FSEEKO
 381 dnl check for ftello()
 382 AC_CHECK_FUNCS([ftello])
 383
 384 AC_CHECK_FUNCS([fgetpos])
 385 AC_CHECK_FUNCS([fsetpos])
 386
 387 dnl check for poll(), ppoll() and pselect()
 388 AC_CHECK_FUNCS([poll])
 389 AC_CHECK_FUNCS([ppoll])
 390 AC_CHECK_FUNCS([pselect])
 391
 392 dnl ****************************************
 393 dnl *** GLib POLL* compatibility defines ***
 394 dnl ****************************************
 395
 396 AC_MSG_CHECKING([for broken poll])
 397 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 398         #include <stdlib.h>
 399         #include <fcntl.h>
 400         #include <poll.h>
 401         #ifdef HAVE_SYS_POLL_H
 402         #include <sys/poll.h>
 403         #endif
 404         int main(void) {
 405           struct pollfd fds[1];
 406           int fd;
 407           fd = open("/dev/null", 1);
 408           fds[0].fd = fd;
 409           fds[0].events = POLLIN;
 410           fds[0].revents = 0;
 411           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 412                 exit(1);  /* Does not work for devices -- fail */
 413           }
 414           exit(0);
 415         }]])],
 416   [broken_poll=no],
 417   [broken_poll=yes
 418    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 419   [broken_poll="no (cross compiling)"])
 420 AC_MSG_RESULT($broken_poll)
 421
 422 dnl check for mmap()
 423 AC_FUNC_MMAP
 424 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 425
 426 dnl check for posix_memalign(), getpagesize()
 427 AC_CHECK_FUNCS([posix_memalign])
 428 AC_CHECK_FUNCS([getpagesize])
 429
 430 dnl Check for POSIX timers
 431 AC_CHECK_FUNCS(clock_gettime, [], [
 432   AC_CHECK_LIB(rt, clock_gettime, [
 433     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 434     LIBS="$LIBS -lrt"
 435   ])
 436 ])
 437
 438 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 439     AC_TRY_COMPILE([
 440 #include <time.h>
 441 #ifdef HAVE_UNISTD_H
 442 #include <unistd.h>
 443 #endif
 444     ], [
 445 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 446 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 447 #endif
 448     ], [
 449       gst_cv_posix_timers=yes
 450     ], [
 451       gst_cv_posix_timers=no
 452     ])
 453 )
 454
 455 if test "$gst_cv_posix_timers" = "yes"; then
 456   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 457   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 458 else
 459   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 460 fi
 461 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 462 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 463
 464 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 465     AC_TRY_COMPILE([
 466 #include <time.h>
 467 #ifdef HAVE_UNISTD_H
 468 #include <unistd.h>
 469 #endif
 470     ], [
 471 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 472 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 473 #endif
 474     ], [
 475       gst_cv_monotonic_clock=yes
 476     ], [
 477       gst_cv_monotonic_clock=no
 478     ])
 479 )
 480
 481 if test "$gst_cv_monotonic_clock" = "yes"; then
 482   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 483   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 484 else
 485   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 486 fi
 487 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 488 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 489
 490 dnl Check for a way to display the function name in debug output
 491 AG_GST_CHECK_FUNCTION
 492
 493 dnl test for register_printf_specifier or register_printf_function
 494 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 495     [HAVE_PRINTF_EXTENSION=yes])
 496
 497 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 498   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 499   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 500   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 501   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 502       [Defined if we have printf specifier extensions available])
 503 else
 504     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 505     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 506     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 507 fi
 508 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 509 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 510 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 511
 512 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 513 save_cflags="$CFLAGS"
 514 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 515 AC_CHECK_LIB(dl, dladdr,
 516    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 517    LIBS="$LIBS -ldl")
 518 CFLAGS="$save_cflags"
 519
 520 dnl *** checks for socket and nsl libraries ***
 521 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 522 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 523
 524 dnl check for inet_aton()
 525 save_libs="$LIBS"
 526 AC_CHECK_FUNC(inet_aton, ,
 527    AC_CHECK_LIB(nsl, inet_aton, ,
 528       AC_CHECK_LIB(socket, inet_aton, ,
 529          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 530 INET_ATON_LIBS=$LIBS
 531 AC_SUBST(INET_ATON_LIBS)
 532 LIBS="$save_libs"
 533
 534 dnl *** checks for dependency libraries ***
 535
 536 dnl GLib
 537 GLIB_REQ=2.20
 538
 539 AG_GST_GLIB_CHECK([$GLIB_REQ])
 540
 541 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 542 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 543 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 544
 545 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 546 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 547
 548 dnl Check for documentation xrefs
 549 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 550 AC_SUBST(GLIB_PREFIX)
 551
 552 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 553 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 554 then
 555   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 556   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 557 else
 558   dnl check for libxml2 with minimum req version
 559   AG_GST_LIBXML2_CHECK(2.4.9)
 560   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 561 fi
 562 AC_SUBST(GST_DISABLE_XML_DEFINE)
 563
 564 dnl building of unit test libraries
 565 AC_ARG_ENABLE(check,
 566   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 567   [
 568     case "${enableval}" in
 569       yes) BUILD_CHECK=yes ;;
 570       no)  BUILD_CHECK=no ;;
 571       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 572     esac
 573   ], [
 574     dnl Default value
 575     case $host_os in
 576       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 577       *) BUILD_CHECK=yes ;;
 578     esac
 579 ])
 580 dnl bit of a misnomer, but keep the conditional named like this so we don't
 581 dnl have to change too much elsewhere
 582 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 583
 584 dnl configure the desired buffer alignment
 585 AC_ARG_WITH([buffer-alignment],
 586   AS_HELP_STRING([--with-buffer-alignment],[8,N,malloc,pagesize (default is 32)]),
 587   [
 588     if test "x$withval" = "xyes"
 589     then
 590       AC_DEFINE(BUFFER_ALIGNMENT, 32, [Buffer alignment to use])
 591     else
 592       case "${withval}" in
 593         malloc) AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) ;;
 594         pagesize)  AC_DEFINE(BUFFER_ALIGNMENT_PAGESIZE, 1, [Buffer alignment by pagesize]) ;;
 595         *)   AC_DEFINE_UNQUOTED(BUFFER_ALIGNMENT, ${withval}, [Buffer alignment to use]) ;;
 596       esac
 597     fi
 598   ], [
 599     AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default])
 600   ]
 601 )
 602
 603 dnl *** set variables based on configure arguments
 604
 605 dnl set license and copyright notice
 606 GST_LICENSE="LGPL"
 607 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 608 AC_SUBST(GST_LICENSE)
 609
 610 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 611 AS_AC_EXPAND(LIBDIR, $libdir)
 612 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 613 AS_AC_EXPAND(DATADIR, $datadir)
 614 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 615
 616 dnl set location of plugin directory
 617 AG_GST_SET_PLUGINDIR
 618
 619 dnl FIXME: add LIBXML_PKG here if we use it
 620 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 621 AC_SUBST(GST_PKG_DEPS)
 622
 623 dnl define an ERROR_CFLAGS Makefile variable
 624 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs])
 625
 626 dnl define correct level for debugging messages
 627 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 628
 629 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 630
 631 dnl Overview:
 632 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 633 dnl GST_ALL_*:          vars shared by all built objects
 634 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 635 dnl GST_OBJ_*:          additional vars to link to the core library
 636 dnl                     include GST_ALL_*
 637 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 638 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 639
 640 dnl GST_OPTION_CFLAGS
 641 if test "x$USE_DEBUG" = xyes; then
 642    PROFILE_CFLAGS="-g"
 643 fi
 644 AC_SUBST(PROFILE_CFLAGS)
 645
 646 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 647 # functionality from the API that gstreamer uses
 648 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 649 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 650   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 651   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 652 else
 653   DEPRECATED_CFLAGS=""
 654 fi
 655 AC_SUBST(DEPRECATED_CFLAGS)
 656
 657 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 658 dnl make DEPRECATED_CFLAGS=''
 659 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 660 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 661 AC_SUBST(GST_OPTION_CFLAGS)
 662 AC_SUBST(GST_OPTION_CXXFLAGS)
 663
 664 dnl GST_ALL_*
 665 dnl vars common to for all internal objects (core libs, elements, applications)
 666 dnl CFLAGS:
 667 dnl - XML needs to be added because xmlPtr is used in core
 668 dnl - src and build dirs need to be added because every piece that gets built
 669 dnl   will need the GStreamer source and generated headers
 670 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 671 dnl       from LibXML except for in the core library
 672 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $GLIB_EXTRA_CFLAGS $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 673 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $GLIB_EXTRA_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 674
 675 dnl FIXME: check if LTLIBINTL is needed everywhere
 676 dnl I presume it is given that it contains the symbols that _() stuff maps to
 677 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 678
 679 dnl LDFLAGS really should only contain flags, not libs - they get added before
 680 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 681 GST_ALL_LDFLAGS="-no-undefined"
 682
 683 AC_SUBST(GST_ALL_CFLAGS)
 684 AC_SUBST(GST_ALL_CXXFLAGS)
 685 AC_SUBST(GST_ALL_LIBS)
 686 AC_SUBST(GST_ALL_LDFLAGS)
 687
 688 dnl GST_LIB_LDFLAGS
 689 dnl linker flags shared by all libraries
 690 dnl LDFLAGS modifier defining exported symbols from built libraries
 691 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 692 AC_SUBST(GST_LIB_LDFLAGS)
 693
 694 dnl GST_OBJ_*
 695 dnl default vars for all internal objects built on libgstreamer
 696 dnl includes GST_ALL_*
 697 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 698 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 699 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 700 AC_SUBST(GST_OBJ_CFLAGS)
 701 AC_SUBST(GST_OBJ_CXXFLAGS)
 702 AC_SUBST(GST_OBJ_LIBS)
 703
 704 dnl GST_PLUGIN_LDFLAGS
 705 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 706 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 707 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 708
 709 dnl plugin scanner locations
 710 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 711 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 712     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 713 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 714
 715 dnl things for our internal libcheck (must be called even if building
 716 dnl libcheck is disabled because it defines conditionals)
 717 AG_GST_CHECK_CHECKS()
 718
 719 AC_CONFIG_FILES(
 720 Makefile
 721 gst/Makefile
 722 gst/gstconfig.h
 723 gst/gstversion.h
 724 gst/parse/Makefile
 725 libs/Makefile
 726 libs/gst/Makefile
 727 libs/gst/base/Makefile
 728 libs/gst/check/Makefile
 729 libs/gst/check/libcheck/Makefile
 730 libs/gst/check/libcheck/check.h
 731 libs/gst/controller/Makefile
 732 libs/gst/dataprotocol/Makefile
 733 libs/gst/helpers/Makefile
 734 libs/gst/net/Makefile
 735 plugins/Makefile
 736 plugins/indexers/Makefile
 737 plugins/elements/Makefile
 738 po/Makefile.in
 739 tests/Makefile
 740 tests/benchmarks/Makefile
 741 tests/check/Makefile
 742 tests/misc/Makefile
 743 tests/examples/Makefile
 744 tests/examples/adapter/Makefile
 745 tests/examples/controller/Makefile
 746 tests/examples/stepping/Makefile
 747 tests/examples/helloworld/Makefile
 748 tests/examples/launch/Makefile
 749 tests/examples/manual/Makefile
 750 tests/examples/metadata/Makefile
 751 tests/examples/queue/Makefile
 752 tests/examples/streams/Makefile
 753 tests/examples/typefind/Makefile
 754 tools/Makefile
 755 common/Makefile
 756 common/m4/Makefile
 757 docs/Makefile
 758 docs/design/Makefile
 759 docs/faq/Makefile
 760 docs/gst/Makefile
 761 docs/gst/gstreamer.types
 762 docs/libs/Makefile
 763 docs/plugins/Makefile
 764 docs/manual/Makefile
 765 docs/pwg/Makefile
 766 docs/slides/Makefile
 767 docs/xsl/Makefile
 768 docs/version.entities
 769 m4/Makefile
 770 pkgconfig/Makefile
 771 stamp.h
 772 pkgconfig/gstreamer.pc
 773 pkgconfig/gstreamer-uninstalled.pc
 774 pkgconfig/gstreamer-base.pc
 775 pkgconfig/gstreamer-base-uninstalled.pc
 776 pkgconfig/gstreamer-check.pc
 777 pkgconfig/gstreamer-check-uninstalled.pc
 778 pkgconfig/gstreamer-controller.pc
 779 pkgconfig/gstreamer-controller-uninstalled.pc
 780 pkgconfig/gstreamer-dataprotocol.pc
 781 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 782 pkgconfig/gstreamer-net.pc
 783 pkgconfig/gstreamer-net-uninstalled.pc
 784 gst-element-check.m4
 785 gstreamer.spec
 786 )
 787
 788 dnl Create the config.h file for Visual Studio builds
 789 dnl Beware of spaces and /'s in some of the shell variable contents.
 790 sed \
 791     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 792     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 793     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 794     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 795     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 796     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 797     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 798     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 799     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 800     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 801     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 802     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 803     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 804     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 805     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 806     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 807     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 808     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 809     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 810     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 811     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 812     -e 's/.* BUFFER_ALIGNMENT_MALLOC/#define BUFFER_ALIGNMENT_MALLOC 1/' \
 813     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 814     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 815     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 816     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 817     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 818     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 819     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 820     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 821     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 822     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 823     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 824     config.h.in >win32/common/config.h-new
 825
 826 AC_OUTPUT
 827
 828 dnl negate for output
 829 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 830 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 831 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 832 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 833 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 834 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 835 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 836 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 837 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 838
 839 echo "
 840
 841 Configuration
 842         Version                    : ${VERSION}
 843         Source code location       : ${srcdir}
 844         Prefix                     : ${prefix}
 845         Compiler                   : ${CC}
 846         Package name               : ${GST_PACKAGE_NAME}
 847         Package origin             : ${GST_PACKAGE_ORIGIN}
 848
 849         Documentation (manuals)    : ${enable_docbook}
 850         Documentation (API)        : ${enable_gtk_doc}
 851
 852         Debug Logging              : ${enable_gst_debug}
 853         Pipeline XML load/save     : ${enable_loadsave}
 854         Command-line parser        : ${enable_parse}
 855         Option parsing in gst_init : ${enable_option_parsing}
 856         Tracing subsystem          : ${enable_trace}
 857         Allocation tracing         : ${enable_alloc_trace}
 858         Plugin registry            : ${enable_registry}
 859         Plugin support             : ${enable_plugin}
 860         Network support            : ${enable_net}
 861         Unit testing support       : ${BUILD_CHECK}
 862
 863         Debug                      : ${USE_DEBUG}
 864         Profiling                  : ${USE_PROFILING}
 865
 866         Building examples          : ${BUILD_EXAMPLES}
 867         Building test apps         : ${BUILD_TESTS}
 868         Building tests that fail   : ${BUILD_FAILING_TESTS}
 869 "