configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.4.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl FIXME: this macro doesn't actually work;
  40 dnl the generated libtool script has no support for the listed tags.
  41 dnl So this needs to be fixed first if we want to use this
  42 dnl AS_LIBTOOL_TAGS
  43
  44 AM_PROG_LIBTOOL
  45
  46 dnl *** required versions of GStreamer stuff ***
  47 GST_REQ=0.10.9.1
  48 GSTPB_REQ=0.10.9.1
  49
  50 dnl *** autotools stuff ****
  51
  52 dnl allow for different autotools
  53 AS_AUTOTOOLS_ALTERNATE
  54
  55 dnl Add parameters for aclocal
  56 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  57
  58 dnl set up gettext
  59 dnl the version check needs to stay here because autopoint greps for it
  60 AM_GNU_GETTEXT_VERSION([0.11.5])
  61 AM_GNU_GETTEXT([external])
  62 GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  63
  64 dnl *** check for arguments to configure ***
  65
  66 GST_ARG_DEBUG
  67 GST_ARG_PROFILING
  68 GST_ARG_VALGRIND
  69 GST_ARG_GCOV
  70
  71 GST_ARG_EXAMPLES
  72
  73 GST_ARG_WITH_PKG_CONFIG_PATH
  74 GST_ARG_WITH_PACKAGE_NAME
  75 GST_ARG_WITH_PACKAGE_ORIGIN
  76
  77 dnl these are all the gst plug-ins, compilable without additional libs
  78 dnl videofilter is at the top because others depend on it
  79 GST_PLUGINS_ALL="\
  80                 videofilter \
  81                 alpha \
  82                 apetag \
  83                 audiofxgood \
  84                 auparse \
  85                 autodetect \
  86                 avi \
  87                 cutter \
  88                 debug \
  89                 effectv \
  90                 id3demux \
  91                 icydemux \
  92                 flx \
  93                 goom \
  94                 law \
  95                 level \
  96                 matroska \
  97                 monoscope \
  98                 multipart \
  99                 rtp     \
 100                 rtsp    \
 101                 smpte   \
 102                 udp     \
 103                 videobox \
 104                 videomixer \
 105                 wavenc \
 106                 wavparse \
 107                 "
 108 AC_SUBST(GST_PLUGINS_ALL)
 109
 110 GST_PLUGINS_SELECTED=""
 111
 112 AC_ARG_WITH(plugins,
 113     AC_HELP_STRING([--with-plugins],
 114       [comma-separated list of plug-ins to compile]),
 115     [for i in `echo $withval | tr , ' '`; do
 116         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 117         then
 118             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 119         else
 120             echo "plug-in $i not recognized, ignoring..."
 121         fi
 122     done],
 123     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 124
 125 dnl disable gst plugins we might not be able to build on this
 126 dnl platform: udp and rtsp (ugly but minimally invasive)
 127 dnl FIXME: maybe move to sys
 128 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 129 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 130
 131 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 132   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 133   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 134 fi
 135
 136 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 137   WIN32_LIBS="-lws2_32"
 138   AC_SUBST(WIN32_LIBS)
 139 fi
 140
 141 dnl disable monoscope plugin
 142 GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 143
 144 AC_SUBST(GST_PLUGINS_SELECTED)
 145
 146 dnl ext plug-ins; plug-ins that have external dependencies
 147 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 148   [HAVE_EXTERNAL=yes], enabled,
 149   [
 150     AC_MSG_NOTICE(building external plug-ins)
 151     BUILD_EXTERNAL="yes"
 152   ],[
 153     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 154     BUILD_EXTERNAL="no"
 155   ])
 156 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 157
 158 dnl *** checks for platform ***
 159
 160 dnl * hardware/architecture *
 161
 162 dnl common/m4/gst-arch.m4
 163 dnl check CPU type
 164 GST_ARCH
 165
 166 dnl Determine endianness
 167 AC_C_BIGENDIAN
 168
 169 dnl *** checks for programs ***
 170
 171 dnl find a compiler
 172 AC_PROG_CC
 173
 174 dnl determine c++ compiler
 175 AC_PROG_CXX
 176 dnl determine if c++ is available on this system
 177 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 178
 179 dnl determine c++ preprocessor
 180 dnl FIXME: do we need this ?
 181 AC_PROG_CXXCPP
 182
 183 AS_PROG_OBJC
 184
 185 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 186 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 187
 188 dnl check for gconftool-2
 189 dnl this macro defines an am conditional, so it needs to be run always
 190 AM_GCONF_SOURCE_2
 191
 192 dnl check for documentation tools
 193 GTK_DOC_CHECK([1.3])
 194 AS_PATH_PYTHON([2.1])
 195 GST_PLUGIN_DOCS([1.3],[2.1])
 196
 197 dnl *** checks for libraries ***
 198
 199 dnl *** checks for header files ***
 200
 201 dnl check if we have ANSI C header files
 202 AC_HEADER_STDC
 203
 204 dnl used in gst/rtp/gstasteriskh263.c
 205 AC_CHECK_HEADERS([netinet/in.h])
 206 AC_CHECK_HEADERS([winsock2.h])
 207 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 208
 209 dnl *** checks for types/defines ***
 210
 211 dnl Check for FIONREAD ioctl declaration.  This check is needed
 212 dnl for the UDP plugin to build on Solaris
 213 GST_CHECK_FIONREAD
 214
 215 dnl *** checks for structures ***
 216
 217 dnl *** checks for compiler characteristics ***
 218
 219 dnl FIXME: check if this is used; was used for floatcast.h in base
 220 dnl Check for fast float to int casting as defined in C99
 221 AC_C99_FUNC_LRINT
 222 AC_C99_FUNC_LRINTF
 223
 224 dnl *** checks for library functions ***
 225
 226 dnl Check for mmap (needed by electricfence plugin)
 227 AC_FUNC_MMAP
 228 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 229
 230 dnl *** checks for dependancy libraries ***
 231
 232 dnl GLib is required
 233 GST_GLIB_CHECK([2.6])
 234
 235 dnl liboil is required
 236 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 237 if test "x${HAVE_LIBOIL}" != xyes ; then
 238   AC_ERROR([liboil-0.3 is required])
 239 fi
 240
 241 dnl checks for gstreamer
 242 dnl uninstalled is selected preferentially -- see pkg-config(1)
 243 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 244 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 245 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 246 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 247 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 248 GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 249
 250 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 251 if test -z $GST_TOOLS_DIR; then
 252   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 253 fi
 254 AC_SUBST(GST_TOOLS_DIR)
 255
 256 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 257 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 258
 259 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 260 dnl check for "check", unit testing library/header
 261 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 262 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 263
 264 dnl GTK is optional and used in examples
 265 HAVE_GTK=NO
 266 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 267 if test "x$HAVE_GTK_22" = "xyes"; then
 268   HAVE_GTK=yes
 269   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 270   AC_SUBST(GTK_VERSION)
 271   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 272   AC_SUBST(GTK_BASE_DIR)
 273   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 274   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 275   AC_SUBST(GTK_BASE_DIR)
 276 else
 277   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 278 fi
 279 if test "x$HAVE_GTK_20" = "xyes"; then
 280   HAVE_GTK=yes
 281 fi
 282 GTK_CFLAGS=$GTK2_CFLAGS
 283 GTK_LIBS=$GTK2_LIBS
 284 AC_SUBST(GTK_LIBS)
 285 AC_SUBST(GTK_CFLAGS)
 286 AC_SUBST(HAVE_GTK)
 287 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 288
 289 dnl should we install schemas ?
 290 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 291 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 292   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 293   if test x$GCONFTOOL = xno; then
 294     AC_MSG_WARN(Not installing GConf schemas)
 295     HAVE_GCONFTOOL="no"
 296   else
 297     HAVE_GCONFTOOL="yes"
 298   fi
 299   AC_SUBST(HAVE_GCONFTOOL)
 300 ])
 301
 302 dnl *** set variables based on configure arguments ***
 303
 304 dnl set license and copyright notice
 305 GST_LICENSE="LGPL"
 306 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 307 AC_SUBST(GST_LICENSE)
 308
 309 dnl set location of plugin directory
 310 GST_SET_PLUGINDIR
 311
 312 dnl define an ERROR_CFLAGS Makefile variable
 313 GST_SET_ERROR_CFLAGS($GST_CVS)
 314
 315 dnl define correct level for debugging messages
 316 GST_SET_LEVEL_DEFAULT($GST_CVS)
 317
 318 dnl used in examples
 319 GST_DEFAULT_ELEMENTS
 320
 321 dnl *** sys plug-ins ***
 322
 323 echo
 324 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 325 echo
 326
 327 dnl *** OSS audio *** (Linux, *BSD)
 328 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 329 GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 330  HAVE_OSS="yes"
 331 dnl Linux and newer BSD versions :
 332  AC_CHECK_HEADER(sys/soundcard.h, [
 333    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 334    ] , [
 335 dnl Some old BSD versions and also newer OpenBSD versions :
 336    AC_CHECK_HEADER(soundcard.h, [
 337      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 338      ], [
 339   dnl Some old BSD versions :
 340      AC_CHECK_HEADER(machine/soundcard.h, [
 341        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 342          [Define if OSS includes are in /machine/])
 343        ], [
 344        HAVE_OSS="no"
 345      ])
 346    ])
 347  ])
 348 ])
 349
 350 dnl *** Sun Audio ***
 351 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 352 GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 353   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 354 ])
 355
 356
 357 dnl Check for X11
 358 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 359 GST_CHECK_FEATURE(X, [X libraries and plugins],
 360                   [ximagesrc], [
 361   AC_PATH_XTRA
 362
 363   dnl now try to find the HEADER
 364   ac_cflags_save="$CFLAGS"
 365   ac_cppflags_save="$CPPFLAGS"
 366   CFLAGS="$CFLAGS $X_CFLAGS"
 367   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 368   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 369
 370   if test "x$HAVE_X" = "xno"
 371   then
 372     AC_MSG_NOTICE([cannot find X11 development files])
 373   else
 374     dnl this is much more than we want
 375     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 376     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 377     dnl it does not add the libs; therefore we add them here
 378     X_LIBS="$X_LIBS -lX11"
 379     AC_SUBST(X_CFLAGS)
 380     AC_SUBST(X_LIBS)
 381
 382     dnl check for Xfixes
 383     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 384     if test "x$HAVE_XFIXES" = "xyes"
 385     then
 386         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 387     fi
 388     AC_SUBST(XFIXES_LIBS)
 389     AC_SUBST(XFIXES_CFLAGS)
 390
 391     dnl check for Xdamage
 392     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 393     if test "x$HAVE_XDAMAGE" = "xyes"
 394     then
 395         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 396     fi
 397     AC_SUBST(XDAMAGE_LIBS)
 398     AC_SUBST(XDAMAGE_CFLAGS)
 399   fi
 400   AC_SUBST(HAVE_X)
 401   CFLAGS="$ac_cflags_save"
 402   CPPFLAGS="$ac_cppflags_save"
 403 ])
 404
 405 dnl FIXME: this should be rolled into the test above, it's just an additional
 406 dnl feature of the ximagesrc plug-in
 407 dnl This is the same as in gst-plugins-base
 408 dnl check for X Shm
 409 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 410 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 411   if test x$HAVE_X = xyes; then
 412     AC_CHECK_LIB(Xext, XShmAttach,
 413                  HAVE_XSHM="yes", HAVE_XSHM="no",
 414                  $X_LIBS)
 415     if test "x$HAVE_XSHM" = "xyes"; then
 416       XSHM_LIBS="-lXext"
 417     else
 418       dnl On AIX, it is in XextSam instead, but we still need -lXext
 419       AC_CHECK_LIB(XextSam, XShmAttach,
 420                    HAVE_XSHM="yes", HAVE_XSHM="no",
 421                    $X_LIBS)
 422       if test "x$HAVE_XSHM" = "xyes"; then
 423         XSHM_LIBS="-lXext -lXextSam"
 424       fi
 425     fi
 426   fi
 427 ], ,[
 428   AC_SUBST(HAVE_XSHM)
 429   AC_SUBST(XSHM_LIBS)
 430 ])
 431
 432 dnl *** ext plug-ins ***
 433 dnl keep this list sorted alphabetically !
 434
 435 if test "x$BUILD_EXTERNAL" = "xyes"; then
 436
 437 echo
 438 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 439 echo
 440
 441 dnl *** aalib ***
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 443 GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 444   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 445   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 446 ])
 447
 448 dnl *** annodex ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 450 GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 451   GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 452 ])
 453
 454 dnl *** cairo ***
 455 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 456 GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 457   GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 458 ])
 459
 460 dnl *** cdio ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 462 GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 463   GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 464 ])
 465
 466 dnl **** ESound ****
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 468 GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 469   GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 470   if test $HAVE_ESD = no
 471   then
 472     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 473     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 474   fi
 475 ])
 476
 477 dnl *** FLAC ***
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 479 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 480   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 481   dnl API change in FLAC 1.1.1, so require that...
 482   if test x$HAVE_FLAC = xyes; then
 483     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 484                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 485 #include <FLAC/seekable_stream_encoder.h>
 486                   ])
 487   fi
 488   AC_SUBST(FLAC_LIBS)
 489 ])
 490
 491 dnl *** GConf ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 493 GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 494   GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 495 ])
 496
 497 dnl *** GDK pixbuf ***
 498 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 499 GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 500   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 501 ])
 502
 503 dnl *** HAL ***
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 505 GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 506   GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 507 ])
 508
 509 dnl *** jpeg ***
 510 dnl FIXME: we could use header checks here as well IMO
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 512 GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 513   AC_ARG_WITH(jpeg-mmx,
 514     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 515   OLD_LIBS="$LIBS"
 516   if test x$with_jpeg_mmx != x; then
 517     LIBS="$LIBS -L$with_jpeg_mmx"
 518   fi
 519   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 520   JPEG_LIBS="$LIBS -ljpeg-mmx"
 521   LIBS="$OLD_LIBS"
 522   if test x$HAVE_JPEG != xyes; then
 523     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 524     JPEG_LIBS="-ljpeg"
 525   fi
 526   AC_SUBST(JPEG_LIBS)
 527 ])
 528
 529 dnl *** ladspa ***
 530 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 531 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 532   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 533 ])
 534
 535 dnl *** libcaca ***
 536 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 537 GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 538   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 539   AC_SUBST(LIBCACA_CFLAGS)
 540   AC_SUBST(LIBCACA_LIBS)
 541 ])
 542
 543 dnl *** libdv ***
 544 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 545 GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 546   GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 547 ])
 548
 549 dnl *** libpng ***
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 551 GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 552   GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 553 ])
 554
 555 dnl *** dv1394 ***
 556 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 557 GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 558   dnl first test for libraw1394 >= 1.2.1
 559   GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 560   GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 561   dnl now see how far we got
 562   if test x$HAVE_RAW1394 = xyes && \
 563      test x$HAVE_LIBIEC61883 = xyes; then
 564        GST_CHECK_LIBHEADER(AVC1394,
 565         avc1394, avc1394_send_command, $RAW1394_LIBS,
 566         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 567        GST_CHECK_LIBHEADER(ROM1394,
 568         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 569         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 570        if test x$HAVE_AVC1394 = xyes && \
 571           test x$HAVE_AVC1394 = xyes && \
 572           test x$HAVE_ROM1394 = xyes; then
 573           HAVE_DV1394=yes
 574           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 575           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 576           AC_SUBST(DV1394_CFLAGS)
 577           AC_SUBST(DV1394_LIBS)
 578         fi
 579   else
 580        if test x$HAVE_RAW1394 = xno; then
 581           GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 582           GST_CHECK_LIBHEADER(AVC1394,
 583            avc1394, avc1394_send_command, $RAW1394_LIBS,
 584            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 585           GST_CHECK_LIBHEADER(ROM1394,
 586            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 587            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 588           if test x$HAVE_RAW1394 = xyes && \
 589              test x$HAVE_AVC1394 = xyes && \
 590              test x$HAVE_ROM1394 = xyes; then
 591              HAVE_DV1394=yes
 592              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 593              DV1394_CFLAGS="$RAW1394_CFLAGS"
 594              if test x$HAVE_LIBIEC61883 = xyes; then
 595                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 596                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 597              fi
 598              AC_SUBST(DV1394_CFLAGS)
 599              AC_SUBST(DV1394_LIBS)
 600            fi
 601          fi
 602   fi
 603 ])
 604
 605 dnl *** shout2 ***
 606 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 607 GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 608   GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 609   if test $HAVE_SHOUT2 = no
 610   then
 611     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 612     AC_SUBST(SHOUT2_CFLAGS)
 613     AC_SUBST(SHOUT2_LIBS)
 614   fi
 615 ])
 616
 617 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 618 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 619 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 620 dnl   speex_jitter.h is 1.1.x only
 621 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 622 GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 623   GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 624   if test $HAVE_SPEEX = no
 625   then
 626     GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 627       AC_CHECK_HEADER(speex/speex_jitter.h, [
 628         dnl speex 1.1.x :
 629         GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 630           dnl speex 1.1.5 or + :
 631           HAVE_SPEEX="yes"
 632           SPEEX_LIBS="-lspeex"
 633           AC_SUBST(SPEEX_CFLAGS)
 634           AC_SUBST(SPEEX_LIBS)
 635         ],[
 636           HAVE_SPEEX="no"
 637         ])
 638       ],[
 639         dnl speex 1.0.x :
 640           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 641             dnl speex 1.0.4
 642             HAVE_SPEEX="yes"
 643             SPEEX_LIBS="-lspeex"
 644             AC_SUBST(SPEEX_CFLAGS)
 645             AC_SUBST(SPEEX_LIBS)
 646
 647             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 648               [defined if speex 1.0.x API detected])
 649         ],[
 650             HAVE_SPEEX="no"
 651             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 652         ], [
 653 #include <speex/speex.h>
 654         ])
 655       ])
 656     ])
 657   fi
 658 ])
 659
 660 dnl *** taglib ***
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 662 GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 663   GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 664   if test "x$HAVE_CXX" != "xyes"; then
 665     USE_TAGLIB=false
 666     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 667   fi
 668 ])
 669
 670 dnl *** id3demux prefers to have zlib ***
 671 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 672 GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux],, [
 673   GST_CHECK_LIBHEADER(ZLIB,
 674     z, uncompress,, zlib.h, [
 675     HAVE_ZLIB="yes"
 676     ZLIB_LIBS="-lz"
 677     AC_SUBST(ZLIB_LIBS)
 678   ])
 679 ])
 680
 681 else
 682
 683 dnl not building plugins with external dependencies,
 684 dnl but we still need to set the conditionals
 685 AM_CONDITIONAL(USE_GCONFTOOL, false)
 686 AM_CONDITIONAL(USE_OSS, false)
 687 AM_CONDITIONAL(USE_SUNAUDIO, false)
 688 AM_CONDITIONAL(USE_X, false)
 689 AM_CONDITIONAL(USE_XSHM, false)
 690 AM_CONDITIONAL(USE_AALIB, false)
 691 AM_CONDITIONAL(USE_ANNODEX, false)
 692 AM_CONDITIONAL(USE_CAIRO, false)
 693 AM_CONDITIONAL(USE_CDIO, false)
 694 AM_CONDITIONAL(USE_ESD, false)
 695 AM_CONDITIONAL(USE_FLAC, false)
 696 AM_CONDITIONAL(USE_GCONF, false)
 697 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 698 AM_CONDITIONAL(USE_HAL, false)
 699 AM_CONDITIONAL(USE_JPEG, false)
 700 AM_CONDITIONAL(USE_LADSPA, false)
 701 AM_CONDITIONAL(USE_LIBCACA, false)
 702 AM_CONDITIONAL(USE_LIBDV, false)
 703 AM_CONDITIONAL(USE_LIBPNG, false)
 704 AM_CONDITIONAL(USE_DV1394, false)
 705 AM_CONDITIONAL(USE_SHOUT2, false)
 706 AM_CONDITIONAL(USE_SPEEX, false)
 707 AM_CONDITIONAL(USE_TAGLIB, false)
 708 AM_CONDITIONAL(USE_ZLIB, false)
 709
 710 fi dnl of EXT plugins
 711
 712 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 713
 714 dnl Overview:
 715 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 716 dnl GST_*:              flags shared by all built objects
 717 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 718 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 719 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 720 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 721
 722 dnl GST_OPTION_CFLAGS
 723 if test "x$USE_DEBUG" = xyes; then
 724    PROFILE_CFLAGS="-g"
 725 fi
 726 AC_SUBST(PROFILE_CFLAGS)
 727
 728 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 729 AC_SUBST(DEPRECATED_CFLAGS)
 730
 731 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 732 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 733 AC_SUBST(GST_OPTION_CFLAGS)
 734
 735 dnl our libraries need to be versioned correctly
 736 AC_SUBST(GST_LT_LDFLAGS)
 737
 738 dnl FIXME: do we want to rename to GST_ALL_* ?
 739 dnl prefer internal headers to already installed ones
 740 dnl also add builddir include for enumtypes and marshal
 741 dnl add ERROR_CFLAGS, but overridable
 742 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 743 AC_SUBST(GST_CFLAGS)
 744 AC_SUBST(GST_LIBS)
 745
 746 dnl LDFLAGS really should only contain flags, not libs - they get added before
 747 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 748 GST_ALL_LDFLAGS="-no-undefined"
 749 AC_SUBST(GST_ALL_LDFLAGS)
 750
 751 dnl this really should only contain flags, not libs - they get added before
 752 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 753 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 754 AC_SUBST(GST_PLUGIN_LDFLAGS)
 755
 756 dnl *** output files ***
 757
 758 dnl keep this alphabetic per directory, please
 759 AC_CONFIG_FILES(
 760 Makefile
 761 gst/Makefile
 762 gst/alpha/Makefile
 763 gst/apetag/Makefile
 764 gst/audiofxgood/Makefile
 765 gst/auparse/Makefile
 766 gst/autodetect/Makefile
 767 gst/avi/Makefile
 768 gst/cutter/Makefile
 769 gst/debug/Makefile
 770 gst/effectv/Makefile
 771 gst/id3demux/Makefile
 772 gst/icydemux/Makefile
 773 gst/goom/Makefile
 774 gst/law/Makefile
 775 gst/level/Makefile
 776 gst/matroska/Makefile
 777 gst/monoscope/Makefile
 778 gst/multipart/Makefile
 779 gst/rtp/Makefile
 780 gst/rtsp/Makefile
 781 gst/smpte/Makefile
 782 gst/udp/Makefile
 783 gst/videobox/Makefile
 784 gst/videofilter/Makefile
 785 gst/videomixer/Makefile
 786 gst/wavenc/Makefile
 787 gst/wavparse/Makefile
 788 gst/flx/Makefile
 789 ext/jpeg/Makefile
 790 ext/Makefile
 791 ext/aalib/Makefile
 792 ext/annodex/Makefile
 793 ext/cairo/Makefile
 794 ext/cdio/Makefile
 795 ext/dv/Makefile
 796 ext/esd/Makefile
 797 ext/flac/Makefile
 798 ext/gconf/Makefile
 799 ext/gdk_pixbuf/Makefile
 800 ext/hal/Makefile
 801 ext/ladspa/Makefile
 802 ext/libcaca/Makefile
 803 ext/libpng/Makefile
 804 ext/raw1394/Makefile
 805 ext/shout2/Makefile
 806 ext/speex/Makefile
 807 ext/taglib/Makefile
 808 sys/Makefile
 809 sys/oss/Makefile
 810 sys/sunaudio/Makefile
 811 sys/ximage/Makefile
 812 po/Makefile.in
 813 tests/Makefile
 814 tests/check/Makefile
 815 tests/icles/Makefile
 816 tests/examples/Makefile
 817 tests/examples/level/Makefile
 818 gconf/Makefile
 819 gconf/gstreamer.schemas
 820 common/Makefile
 821 common/m4/Makefile
 822 m4/Makefile
 823 docs/Makefile
 824 docs/plugins/Makefile
 825 docs/version.entities
 826 win32/common/config.h
 827 pkgconfig/Makefile
 828 pkgconfig/gstreamer-plugins-good-uninstalled.pc
 829 gst-plugins-good.spec
 830 )
 831 AC_OUTPUT
 832
 833 GST_OUTPUT_PLUGINS