configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.16.3,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.25
  51 GSTPB_REQ=0.10.25
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 dnl check if the compiler supports do while(0) macros
 120 AG_GST_CHECK_DOWHILE_MACROS
 121
 122 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 123 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 124
 125 dnl check for gconftool-2
 126 dnl this macro defines an am conditional, so it needs to be run always
 127 AM_GCONF_SOURCE_2
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.3])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 AC_CHECK_LIBM
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/rtp/gstasteriskh263.c
 149 AC_CHECK_HEADERS([netinet/in.h])
 150 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 151 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl *** checks for types/defines ***
 157
 158 dnl Check for FIONREAD ioctl declaration.  This check is needed
 159 dnl for the UDP plugin to build on Solaris
 160 GST_CHECK_FIONREAD
 161
 162 dnl *** checks for structures ***
 163
 164 dnl *** checks for compiler characteristics ***
 165
 166 dnl check if we have GCC inline-asm
 167 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 168 if test x$HAVE_GCC_ASM = xyes ; then
 169   AC_DEFINE(HAVE_GCC_ASM, 1,
 170     [Define if compiler supports gcc inline assembly])
 171 fi
 172 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 173
 174 dnl *** checks for library functions ***
 175
 176 LIBS_SAVE=$LIBS
 177 LIBS="$LIBS $LIBM"
 178 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 179 LIBS=$LIBS_SAVE
 180
 181 dnl Check whether isinf() is defined by math.h
 182 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 183     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 184 if test "$ac_cv_have_isinf" = "yes"
 185 then
 186     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 187 fi
 188
 189 dnl Check for mmap (needed by electricfence plugin)
 190 AC_FUNC_MMAP
 191 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194
 195 AC_CHECK_TYPE([struct ip_mreqn], [
 196               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 197               [#include <netinet/in.h>])
 198
 199 dnl *** checks for dependency libraries ***
 200
 201 dnl GLib is required
 202 AG_GST_GLIB_CHECK([2.16])
 203
 204 dnl liboil is required
 205 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 206 if test "x$HAVE_LIBOIL" != "xyes"; then
 207   AC_ERROR([liboil-0.3.8 or later is required])
 208 fi
 209
 210 dnl checks for gstreamer
 211 dnl uninstalled is selected preferentially -- see pkg-config(1)
 212 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 213 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 214 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 217 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 218
 219 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 220 if test -z $GST_TOOLS_DIR; then
 221   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 222 fi
 223 AC_SUBST(GST_TOOLS_DIR)
 224
 225 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 226 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 227
 228 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 229
 230 dnl Check for documentation xrefs
 231 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 232 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 233 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 234 AC_SUBST(GLIB_PREFIX)
 235 AC_SUBST(GST_PREFIX)
 236 AC_SUBST(GSTPB_PREFIX)
 237
 238 dnl GTK is optional and used in examples
 239 if test "x$BUILD_EXAMPLES" = "xyes"; then
 240   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 241   AC_SUBST(GTK_LIBS)
 242   AC_SUBST(GTK_CFLAGS)
 243 fi
 244 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 245
 246 dnl should we install schemas ?
 247 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 248 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 249   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 250   if test x$GCONFTOOL = xno; then
 251     AC_MSG_WARN(Not installing GConf schemas)
 252     HAVE_GCONFTOOL="no"
 253   else
 254     HAVE_GCONFTOOL="yes"
 255   fi
 256   AC_SUBST(HAVE_GCONFTOOL)
 257 ])
 258
 259 dnl *** set variables based on configure arguments ***
 260
 261 dnl set license and copyright notice
 262 GST_LICENSE="LGPL"
 263 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 264 AC_SUBST(GST_LICENSE)
 265
 266 dnl set location of plugin directory
 267 AG_GST_SET_PLUGINDIR
 268
 269 dnl define an ERROR_CFLAGS Makefile variable
 270 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 271
 272 dnl define an ERROR_CXXFLAGS Makefile variable
 273 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 274
 275 dnl define correct level for debugging messages
 276 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 277
 278 dnl used in examples
 279 AG_GST_DEFAULT_ELEMENTS
 280
 281 dnl *** plug-ins to include ***
 282
 283 dnl these are all the gst plug-ins, compilable without additional libs
 284 dnl videofilter is at the top because others depend on it
 285 AG_GST_CHECK_PLUGIN(videofilter)
 286 AG_GST_CHECK_PLUGIN(alpha)
 287 AG_GST_CHECK_PLUGIN(apetag)
 288 AG_GST_CHECK_PLUGIN(audiofx)
 289 AG_GST_CHECK_PLUGIN(auparse)
 290 AG_GST_CHECK_PLUGIN(autodetect)
 291 AG_GST_CHECK_PLUGIN(avi)
 292 AG_GST_CHECK_PLUGIN(cutter)
 293 AG_GST_CHECK_PLUGIN(debugutils)
 294 AG_GST_CHECK_PLUGIN(deinterlace)
 295 AG_GST_CHECK_PLUGIN(effectv)
 296 AG_GST_CHECK_PLUGIN(equalizer)
 297 AG_GST_CHECK_PLUGIN(flv)
 298 AG_GST_CHECK_PLUGIN(id3demux)
 299 AG_GST_CHECK_PLUGIN(icydemux)
 300 AG_GST_CHECK_PLUGIN(interleave)
 301 AG_GST_CHECK_PLUGIN(flx)
 302 AG_GST_CHECK_PLUGIN(goom)
 303 AG_GST_CHECK_PLUGIN(goom2k1)
 304 AG_GST_CHECK_PLUGIN(law)
 305 AG_GST_CHECK_PLUGIN(level)
 306 AG_GST_CHECK_PLUGIN(matroska)
 307 AG_GST_CHECK_PLUGIN(monoscope)
 308 AG_GST_CHECK_PLUGIN(multifile)
 309 AG_GST_CHECK_PLUGIN(multipart)
 310 AG_GST_CHECK_PLUGIN(qtdemux)
 311 AG_GST_CHECK_PLUGIN(replaygain)
 312 AG_GST_CHECK_PLUGIN(rtp)
 313 AG_GST_CHECK_PLUGIN(rtpmanager)
 314 AG_GST_CHECK_PLUGIN(rtsp)
 315 AG_GST_CHECK_PLUGIN(smpte)
 316 AG_GST_CHECK_PLUGIN(spectrum)
 317 AG_GST_CHECK_PLUGIN(udp)
 318 AG_GST_CHECK_PLUGIN(videobox)
 319 AG_GST_CHECK_PLUGIN(videocrop)
 320 AG_GST_CHECK_PLUGIN(videomixer)
 321 AG_GST_CHECK_PLUGIN(wavenc)
 322 AG_GST_CHECK_PLUGIN(wavparse)
 323 AG_GST_CHECK_PLUGIN(y4m)
 324
 325 dnl *** checks for socket and nsl libraries ***
 326 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 327
 328 dnl disable gst plugins we might not be able to build on this
 329 dnl platform: udp and rtsp (ugly but minimally invasive)
 330 dnl FIXME: maybe move to sys
 331 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 332 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 333
 334 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 335   AG_GST_DISABLE_PLUGIN(udp)
 336   AG_GST_DISABLE_PLUGIN(rtsp)
 337 fi
 338
 339 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 340   WIN32_LIBS="-lws2_32"
 341   AC_SUBST(WIN32_LIBS)
 342 fi
 343
 344 dnl disable experimental plug-ins
 345 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 346   AG_GST_DISABLE_PLUGIN(monoscope)
 347 fi
 348
 349 dnl *** sys plug-ins ***
 350
 351 echo
 352 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 353 echo
 354
 355 dnl DirectSound
 356 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 357 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 358   HAVE_DIRECTSOUND="no"
 359   save_CFLAGS="$CFLAGS"
 360   save_LDFLAGS="$LDFLAGS"
 361   save_LIBS="$LIBS"
 362   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 363   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 364   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 365   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 366   AC_LINK_IFELSE([
 367 #include <windows.h>
 368 #include <dxerr9.h>
 369 #include <dsound.h>
 370
 371 int main ()
 372 {
 373   DXGetErrorString9 (0);
 374   DirectSoundCreate(NULL, NULL, NULL);
 375
 376   return 0;
 377 }
 378 ],
 379     [HAVE_DIRECTSOUND="yes"],
 380     [HAVE_DIRECTSOUND="no"])
 381   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 382   CFLAGS=$save_CFLAGS
 383   LDFLAGS=$save_LDFLAGS
 384   LIBS=$save_LIBS
 385
 386   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 387     dnl this is much more than we want
 388     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 389     AC_SUBST(DIRECTSOUND_CFLAGS)
 390     AC_SUBST(DIRECTSOUND_LDFLAGS)
 391     AC_SUBST(DIRECTSOUND_LIBS)
 392   fi
 393   AC_SUBST(HAVE_DIRECTSOUND)
 394 ])
 395
 396 dnl *** OSS audio *** (Linux, *BSD)
 397 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 398 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 399  HAVE_OSS="yes"
 400 dnl Linux and newer BSD versions :
 401  AC_CHECK_HEADER(sys/soundcard.h, [
 402    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 403    ] , [
 404 dnl Some old BSD versions and also newer OpenBSD versions :
 405    AC_CHECK_HEADER(soundcard.h, [
 406      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 407      ], [
 408   dnl Some old BSD versions :
 409      AC_CHECK_HEADER(machine/soundcard.h, [
 410        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 411          [Define if OSS includes are in /machine/])
 412        ], [
 413        HAVE_OSS="no"
 414      ])
 415    ])
 416  ])
 417 ])
 418
 419 dnl *** Sun Audio ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 421 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 422   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 423 ])
 424
 425 dnl *** OSX Audio ***
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 427 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 428   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 429 ])
 430
 431 dnl *** OS X video ***
 432 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 433 HAVE_OSX_VIDEO="no"
 434 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 435   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 436 ])
 437 dnl in case header OpenGL/gl.h is found on other platforms
 438 case "$host" in
 439   *-*darwin*)
 440     dnl do nothing
 441     ;;
 442   *)
 443     HAVE_OSX_VIDEO="no"
 444     ;;
 445 esac
 446
 447
 448 dnl *** Video 4 Linux 2 ***
 449 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 450 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 451 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 452 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 453   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 454   AC_TRY_COMPILE([
 455 #include <sys/types.h>
 456 #ifdef __sun /* Solaris */
 457 #include <sys/types.h>
 458 #include <sys/videodev2.h>
 459 #else /* Linux */
 460 #include <linux/types.h>
 461 #define _LINUX_TIME_H
 462 #define __user
 463 #include <linux/videodev2.h>
 464 #endif
 465 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 466 #error too early v4l2 version or no v4l2 at all
 467 #endif
 468     ], [
 469 return 0;
 470     ], [
 471       HAVE_GST_V4L2="yes"
 472       AC_MSG_RESULT(yes)
 473     ], [
 474       HAVE_GST_V4L2="no"
 475       AC_MSG_RESULT(no)
 476
 477       HAVE_VIDEODEV=no
 478       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 479       [
 480         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 481       ])
 482
 483       if test "x$HAVE_VIDEODEV" = "xyes"; then
 484         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 485         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 486       else
 487         AC_MSG_WARN([video4linux2 was not found])
 488       fi
 489     ])
 490
 491   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 492     dnl check for missing v4l2_buffer declaration (see #135919)
 493     MISSING_DECL=0
 494     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 495     AC_TRY_COMPILE([
 496 #include <sys/types.h>
 497 #ifdef __sun /* Solaris */
 498 #include <sys/types.h>
 499 #include <sys/videodev2.h>
 500 #else /* Linux */
 501 #include <linux/types.h>
 502 #define _LINUX_TIME_H
 503 #define __user
 504 #include <linux/videodev2.h>
 505 #endif
 506     ],[
 507 struct v4l2_buffer buf;
 508 buf.index = 0;
 509 return 0;
 510     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 511     if [ test x$MISSING_DECL = x1 ]; then
 512       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 513     fi
 514
 515     dnl check for XOverlay libraries
 516     AG_GST_CHECK_XV
 517   fi
 518 ])
 519
 520 # Optional gudev for device probing
 521 AC_ARG_WITH([gudev],
 522   AC_HELP_STRING([--with-gudev],
 523     [device detection with gudev]),
 524   [],
 525   [with_gudev=check])
 526 if test x$HAVE_GST_V4L2 = xyes; then
 527   if test x$with_gudev != xno; then
 528       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 529           [ have_gudev=yes
 530             AC_DEFINE(HAVE_GUDEV, 1,
 531                [Whether gudev is available for device detection])
 532             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 533           ], [
 534           have_gudev=no
 535           ])
 536   else
 537     have_gudev=no
 538   fi
 539 fi
 540 AC_SUBST(GUDEV_CFLAGS)
 541 AC_SUBST(GUDEV_LIBS)
 542
 543 # Make libv4l2 non-automagic
 544 AC_ARG_WITH([libv4l2],
 545   AC_HELP_STRING([--with-libv4l2],
 546     [support video buffer conversion using libv4l2]),
 547   [],
 548   [with_libv4l2=check])
 549 if test x$HAVE_GST_V4L2 = xyes; then
 550   if test x$with_libv4l2 != xno; then
 551       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 552           [ have_libv4l2=yes
 553             AC_DEFINE(HAVE_LIBV4L2, 1,
 554                 [Whether libv4l2 is available for video buffer conversion])
 555           ], [
 556           have_libv4l2=no
 557           ])
 558   else
 559     have_libv4l2=no
 560   fi
 561 fi
 562
 563 dnl Check for X11
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 565 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 566                   [ximagesrc], [
 567   AC_PATH_XTRA
 568
 569   dnl now try to find the HEADER
 570   ac_cflags_save="$CFLAGS"
 571   ac_cppflags_save="$CPPFLAGS"
 572   CFLAGS="$CFLAGS $X_CFLAGS"
 573   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 574   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 575
 576   if test "x$HAVE_X" = "xno"
 577   then
 578     AC_MSG_NOTICE([cannot find X11 development files])
 579   else
 580     dnl this is much more than we want
 581     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 582     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 583     dnl it does not add the libs; therefore we add them here
 584     X_LIBS="$X_LIBS -lX11"
 585     AC_SUBST(X_CFLAGS)
 586     AC_SUBST(X_LIBS)
 587
 588     dnl check for Xfixes
 589     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 590     if test "x$HAVE_XFIXES" = "xyes"
 591     then
 592         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 593     fi
 594     AC_SUBST(XFIXES_LIBS)
 595     AC_SUBST(XFIXES_CFLAGS)
 596
 597     dnl check for Xdamage
 598     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 599     if test "x$HAVE_XDAMAGE" = "xyes"
 600     then
 601         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 602     fi
 603     AC_SUBST(XDAMAGE_LIBS)
 604     AC_SUBST(XDAMAGE_CFLAGS)
 605   fi
 606   AC_SUBST(HAVE_X)
 607   CFLAGS="$ac_cflags_save"
 608   CPPFLAGS="$ac_cppflags_save"
 609 ])
 610
 611 dnl FIXME: this should be rolled into the test above, it's just an additional
 612 dnl feature of the ximagesrc plug-in
 613 dnl This is the same as in gst-plugins-base
 614 dnl check for X Shm
 615 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 616 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 617   if test x$HAVE_X = xyes; then
 618     AC_CHECK_LIB(Xext, XShmAttach,
 619                  HAVE_XSHM="yes", HAVE_XSHM="no",
 620                  $X_LIBS)
 621     if test "x$HAVE_XSHM" = "xyes"; then
 622       XSHM_LIBS="-lXext"
 623     else
 624       dnl On AIX, it is in XextSam instead, but we still need -lXext
 625       AC_CHECK_LIB(XextSam, XShmAttach,
 626                    HAVE_XSHM="yes", HAVE_XSHM="no",
 627                    $X_LIBS)
 628       if test "x$HAVE_XSHM" = "xyes"; then
 629         XSHM_LIBS="-lXext -lXextSam"
 630       fi
 631     fi
 632   fi
 633 ], ,[
 634   AC_SUBST(HAVE_XSHM)
 635   AC_SUBST(XSHM_LIBS)
 636 ])
 637
 638 dnl for V4L2, we also need to know if we have XVIDEO
 639 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 640 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 641                   [], [
 642   AG_GST_CHECK_XV
 643 ])
 644
 645 dnl *** ext plug-ins ***
 646 dnl keep this list sorted alphabetically !
 647
 648 if test "x$BUILD_EXTERNAL" = "xyes"; then
 649
 650 echo
 651 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 652 echo
 653
 654 dnl *** aalib ***
 655 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 656 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 657   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 658   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 659 ])
 660
 661 dnl *** annodex ***
 662 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 663 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 664   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 665 ])
 666
 667 dnl *** cairo ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 669 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 670   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 671 ])
 672
 673 dnl **** ESound ****
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 675 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 676   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 677   if test $HAVE_ESD = no
 678   then
 679     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 680     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 681   fi
 682 ])
 683
 684 dnl *** FLAC ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 686 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 687   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 688 ])
 689
 690 dnl *** GConf ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 692 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 693   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 694 ])
 695
 696 dnl *** GDK pixbuf ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 698 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 699   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 700 ])
 701
 702 dnl *** HAL ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 704 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 705   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 706 ])
 707
 708 dnl *** jpeg ***
 709 dnl FIXME: we could use header checks here as well IMO
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 711 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 712   AC_ARG_WITH(jpeg-mmx,
 713     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 714   OLD_LIBS="$LIBS"
 715   if test x$with_jpeg_mmx != x; then
 716     LIBS="$LIBS -L$with_jpeg_mmx"
 717   fi
 718   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 719   JPEG_LIBS="$LIBS -ljpeg-mmx"
 720   LIBS="$OLD_LIBS"
 721   if test x$HAVE_JPEG != xyes; then
 722     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 723     JPEG_LIBS="-ljpeg"
 724   fi
 725   AC_SUBST(JPEG_LIBS)
 726 ])
 727
 728 dnl *** libcaca ***
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 730 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 731   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 732   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 733   if test "x$HAVE_LIBCACA" != "xyes"; then
 734     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 735     dnl see if it compilation works too, might not if we are cross-compiling
 736     if test "x$HAVE_LIBCACA" = "xyes"; then
 737       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 738                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 739     fi
 740   fi
 741 ])
 742
 743 dnl *** libdv ***
 744 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 745 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 746   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 747 ])
 748
 749 dnl *** libpng ***
 750 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 751 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 752   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 753 ])
 754
 755 dnl *** pulseaudio ***
 756 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 757 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 758   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 759   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 760   if test x$HAVE_PULSE_0_9_11 = xyes; then
 761     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 762   fi
 763   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 764   if test x$HAVE_PULSE_0_9_12 = xyes; then
 765     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 766   fi
 767   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 768   if test x$HAVE_PULSE_0_9_13 = xyes; then
 769     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 770   fi
 771   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 772   if test x$HAVE_PULSE_0_9_15 = xyes; then
 773     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 774   fi
 775   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 776   if test x$HAVE_PULSE_0_9_20 = xyes; then
 777     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 778   fi
 779 ])
 780
 781 dnl *** dv1394 ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 783 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 784   dnl first test for libraw1394 >= 1.2.1
 785   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 786   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 787   dnl now see how far we got
 788   if test x$HAVE_RAW1394 = xyes && \
 789      test x$HAVE_LIBIEC61883 = xyes; then
 790        AG_GST_CHECK_LIBHEADER(AVC1394,
 791         avc1394, avc1394_send_command, $RAW1394_LIBS,
 792         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 793        AG_GST_CHECK_LIBHEADER(ROM1394,
 794         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 795         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 796        if test x$HAVE_AVC1394 = xyes && \
 797           test x$HAVE_AVC1394 = xyes && \
 798           test x$HAVE_ROM1394 = xyes; then
 799           HAVE_DV1394=yes
 800           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 801           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 802           AC_SUBST(DV1394_CFLAGS)
 803           AC_SUBST(DV1394_LIBS)
 804         fi
 805   else
 806        if test x$HAVE_RAW1394 = xno; then
 807           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 808           AG_GST_CHECK_LIBHEADER(AVC1394,
 809            avc1394, avc1394_send_command, $RAW1394_LIBS,
 810            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 811           AG_GST_CHECK_LIBHEADER(ROM1394,
 812            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 813            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 814           if test x$HAVE_RAW1394 = xyes && \
 815              test x$HAVE_AVC1394 = xyes && \
 816              test x$HAVE_ROM1394 = xyes; then
 817              HAVE_DV1394=yes
 818              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 819              DV1394_CFLAGS="$RAW1394_CFLAGS"
 820              if test x$HAVE_LIBIEC61883 = xyes; then
 821                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 822                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 823              fi
 824              AC_SUBST(DV1394_CFLAGS)
 825              AC_SUBST(DV1394_LIBS)
 826            fi
 827          fi
 828   fi
 829 ])
 830
 831 dnl *** shout2 ***
 832 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 833 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 834   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 835   if test $HAVE_SHOUT2 = no
 836   then
 837     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 838     AC_SUBST(SHOUT2_CFLAGS)
 839     AC_SUBST(SHOUT2_LIBS)
 840   fi
 841 ])
 842
 843 dnl *** soup ***
 844 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 845 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 846   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 847     HAVE_SOUP="yes"
 848     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 849   ],[
 850     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 851       HAVE_SOUP="no"
 852       AC_MSG_RESULT(no)
 853     ])
 854   ])
 855   AC_SUBST(SOUP_CFLAGS)
 856   AC_SUBST(SOUP_LIBS)
 857 ])
 858
 859 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 860 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 861 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 862 dnl   speex_jitter.h is 1.1.x only
 863 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 864 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 865   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 866   if test $HAVE_SPEEX = no
 867   then
 868     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 869       AC_CHECK_HEADER(speex/speex_jitter.h, [
 870         dnl speex 1.1.x :
 871         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 872           dnl speex 1.1.5 or + :
 873           HAVE_SPEEX="yes"
 874           SPEEX_LIBS="-lspeex"
 875           AC_SUBST(SPEEX_CFLAGS)
 876           AC_SUBST(SPEEX_LIBS)
 877         ],[
 878           HAVE_SPEEX="no"
 879         ])
 880       ],[
 881         dnl speex 1.0.x :
 882           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 883             dnl speex 1.0.4
 884             HAVE_SPEEX="yes"
 885             SPEEX_LIBS="-lspeex"
 886             AC_SUBST(SPEEX_CFLAGS)
 887             AC_SUBST(SPEEX_LIBS)
 888
 889             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 890               [defined if speex 1.0.x API detected])
 891         ],[
 892             HAVE_SPEEX="no"
 893             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 894         ], [
 895 #include <speex/speex.h>
 896         ])
 897       ])
 898     ])
 899   fi
 900 ])
 901
 902 dnl *** taglib ***
 903 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 904 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 905   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 906   if test "x$HAVE_CXX" != "xyes"; then
 907     USE_TAGLIB=false
 908     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 909   else
 910     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 911     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 912         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 913       ], [
 914         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 915     ])
 916     AC_SUBST(TAGLIB_CXXFLAGS)
 917   fi
 918 ])
 919
 920 dnl *** wavpack ***
 921 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 922 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 923   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 924     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 925       HAVE_WAVPACK=yes
 926       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 927     ],[
 928       HAVE_WAVPACK=no
 929       AC_MSG_RESULT(no)
 930     ])
 931   ])
 932   AC_SUBST(WAVPACK_CFLAGS)
 933   AC_SUBST(WAVPACK_LIBS)
 934 ])
 935
 936 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 937 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 938 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 939   AG_GST_CHECK_LIBHEADER(ZLIB,
 940     z, uncompress,, zlib.h, [
 941     HAVE_ZLIB="yes"
 942     ZLIB_LIBS="-lz"
 943     AC_SUBST(ZLIB_LIBS)
 944   ])
 945 ])
 946
 947 dnl *** matroska prefers to have bz2 ***
 948 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 949 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 950   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 951   AC_SUBST(BZ2_LIBS)
 952 ])
 953
 954 else
 955
 956 dnl not building plugins with external dependencies,
 957 dnl but we still need to set the conditionals
 958 AM_CONDITIONAL(USE_AALIB, false)
 959 AM_CONDITIONAL(USE_ANNODEX, false)
 960 AM_CONDITIONAL(USE_BZ2, false)
 961 AM_CONDITIONAL(USE_CAIRO, false)
 962 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 963 AM_CONDITIONAL(USE_DV1394, false)
 964 AM_CONDITIONAL(USE_ESD, false)
 965 AM_CONDITIONAL(USE_FLAC, false)
 966 AM_CONDITIONAL(USE_GCONF, false)
 967 AM_CONDITIONAL(USE_GCONFTOOL, false)
 968 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 969 AM_CONDITIONAL(USE_GST_V4L2, false)
 970 AM_CONDITIONAL(USE_HAL, false)
 971 AM_CONDITIONAL(USE_JPEG, false)
 972 AM_CONDITIONAL(USE_LIBCACA, false)
 973 AM_CONDITIONAL(USE_LIBDV, false)
 974 AM_CONDITIONAL(USE_LIBPNG, false)
 975 AM_CONDITIONAL(USE_OSS, false)
 976 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 977 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 978 AM_CONDITIONAL(USE_PULSE, false)
 979 AM_CONDITIONAL(USE_SHOUT2, false)
 980 AM_CONDITIONAL(USE_SOUP, false)
 981 AM_CONDITIONAL(USE_SPEEX, false)
 982 AM_CONDITIONAL(USE_SUNAUDIO, false)
 983 AM_CONDITIONAL(USE_TAGLIB, false)
 984 AM_CONDITIONAL(USE_WAVPACK, false)
 985 AM_CONDITIONAL(USE_X, false)
 986 AM_CONDITIONAL(USE_XSHM, false)
 987 AM_CONDITIONAL(USE_XVIDEO, false)
 988 AM_CONDITIONAL(USE_ZLIB, false)
 989
 990 fi dnl of EXT plugins
 991
 992 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 993
 994 dnl Overview:
 995 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 996 dnl GST_*:              flags shared by all built objects
 997 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 998 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 999 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1000 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1001
1002 dnl GST_OPTION_CFLAGS
1003 if test "x$USE_DEBUG" = xyes; then
1004    PROFILE_CFLAGS="-g"
1005 fi
1006 AC_SUBST(PROFILE_CFLAGS)
1007
1008 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1009   dnl Define _only_ during CVS (not pre-releases or releases)
1010   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1011 else
1012   DEPRECATED_CFLAGS=""
1013 fi
1014 AC_SUBST(DEPRECATED_CFLAGS)
1015
1016 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1017 dnl at make time with e.g. make ERROR_CFLAGS=""
1018 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1019 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1020 AC_SUBST(GST_OPTION_CFLAGS)
1021 AC_SUBST(GST_OPTION_CXXFLAGS)
1022
1023 dnl our libraries need to be versioned correctly
1024 AC_SUBST(GST_LT_LDFLAGS)
1025
1026 dnl FIXME: do we want to rename to GST_ALL_* ?
1027 dnl prefer internal headers to already installed ones
1028 dnl also add builddir include for enumtypes and marshal
1029 dnl add ERROR_CFLAGS, but overridable
1030 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1031 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1032 AC_SUBST(GST_CFLAGS)
1033 AC_SUBST(GST_CXXFLAGS)
1034 AC_SUBST(GST_LIBS)
1035
1036 dnl LDFLAGS really should only contain flags, not libs - they get added before
1037 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1038 GST_ALL_LDFLAGS="-no-undefined"
1039 AC_SUBST(GST_ALL_LDFLAGS)
1040
1041 dnl this really should only contain flags, not libs - they get added before
1042 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1043 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1044 AC_SUBST(GST_PLUGIN_LDFLAGS)
1045
1046 SHAVE_INIT([common],[enable])
1047 dnl *** output files ***
1048
1049 dnl keep this alphabetic per directory, please
1050 AC_CONFIG_FILES(
1051 Makefile
1052 common/shave
1053 common/shave-libtool
1054 gst/Makefile
1055 gst/alpha/Makefile
1056 gst/apetag/Makefile
1057 gst/audiofx/Makefile
1058 gst/auparse/Makefile
1059 gst/autodetect/Makefile
1060 gst/avi/Makefile
1061 gst/cutter/Makefile
1062 gst/deinterlace/Makefile
1063 gst/debugutils/Makefile
1064 gst/effectv/Makefile
1065 gst/equalizer/Makefile
1066 gst/flv/Makefile
1067 gst/id3demux/Makefile
1068 gst/icydemux/Makefile
1069 gst/interleave/Makefile
1070 gst/goom/Makefile
1071 gst/goom2k1/Makefile
1072 gst/law/Makefile
1073 gst/level/Makefile
1074 gst/matroska/Makefile
1075 gst/monoscope/Makefile
1076 gst/multifile/Makefile
1077 gst/multipart/Makefile
1078 gst/qtdemux/Makefile
1079 gst/replaygain/Makefile
1080 gst/rtp/Makefile
1081 gst/rtpmanager/Makefile
1082 gst/rtsp/Makefile
1083 gst/smpte/Makefile
1084 gst/spectrum/Makefile
1085 gst/udp/Makefile
1086 gst/videobox/Makefile
1087 gst/videocrop/Makefile
1088 gst/videofilter/Makefile
1089 gst/videomixer/Makefile
1090 gst/wavenc/Makefile
1091 gst/wavparse/Makefile
1092 gst/flx/Makefile
1093 gst/y4m/Makefile
1094 ext/jpeg/Makefile
1095 ext/Makefile
1096 ext/aalib/Makefile
1097 ext/annodex/Makefile
1098 ext/cairo/Makefile
1099 ext/dv/Makefile
1100 ext/esd/Makefile
1101 ext/flac/Makefile
1102 ext/gconf/Makefile
1103 ext/gdk_pixbuf/Makefile
1104 ext/hal/Makefile
1105 ext/ladspa/Makefile
1106 ext/libcaca/Makefile
1107 ext/libpng/Makefile
1108 ext/pulse/Makefile
1109 ext/raw1394/Makefile
1110 ext/shout2/Makefile
1111 ext/soup/Makefile
1112 ext/speex/Makefile
1113 ext/taglib/Makefile
1114 ext/wavpack/Makefile
1115 sys/Makefile
1116 sys/directsound/Makefile
1117 sys/oss/Makefile
1118 sys/sunaudio/Makefile
1119 sys/osxaudio/Makefile
1120 sys/osxvideo/Makefile
1121 sys/v4l2/Makefile
1122 sys/waveform/Makefile
1123 sys/ximage/Makefile
1124 po/Makefile.in
1125 tests/Makefile
1126 tests/check/Makefile
1127 tests/examples/Makefile
1128 tests/examples/audiofx/Makefile
1129 tests/examples/equalizer/Makefile
1130 tests/examples/level/Makefile
1131 tests/examples/rtp/Makefile
1132 tests/examples/spectrum/Makefile
1133 tests/examples/v4l2/Makefile
1134 tests/files/Makefile
1135 tests/icles/Makefile
1136 gconf/Makefile
1137 gconf/gstreamer.schemas
1138 common/Makefile
1139 common/m4/Makefile
1140 m4/Makefile
1141 docs/Makefile
1142 docs/plugins/Makefile
1143 docs/version.entities
1144 pkgconfig/Makefile
1145 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1146 gst-plugins-good.spec
1147 )
1148
1149 dnl Create the config.h file for Visual Studio builds
1150 dnl Beware of spaces and /'s in some of the shell variable contents.
1151 sed \
1152     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1153     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1154     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1155     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1156     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1157     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1158     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1159     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1160     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1161     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1162     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1163     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1164     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1165     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1166     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1167     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1168     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1169     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1170     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1171     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1172     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1173     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1174     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1175     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1176     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1177     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1178     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1179     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1180     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1181     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1182     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1183     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1184     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1185     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1186     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1187     config.h.in >win32/common/config.h-new
1188
1189 AC_OUTPUT
1190
1191 AG_GST_OUTPUT_PLUGINS