configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.5.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl GStreamer versioning, this is mostly informational
  37 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  38 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  39 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  40 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  41 AC_SUBST(GST_VERSION_MAJOR)
  42 AC_SUBST(GST_VERSION_MINOR)
  43 AC_SUBST(GST_VERSION_MICRO)
  44 AC_SUBST(GST_VERSION_NANO)
  45
  46 dnl our libraries and install dirs use GST_API_VERSION in the filename
  47 dnl to allow side-by-side installation of different API versions
  48 GST_API_VERSION=1.0
  49 AC_SUBST(GST_API_VERSION)
  50 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  51   [GStreamer API Version])
  52
  53 dnl CURRENT, REVISION, AGE
  54 dnl - library source changed -> increment REVISION
  55 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  56 dnl - interfaces added -> increment AGE
  57 dnl - interfaces removed -> AGE = 0
  58 dnl
  59 dnl Keep CURRENT as MINOR * 100 + MICRO
  60 dnl Ex : 1.0.0 => 0
  61 dnl      1.0.3 => 3
  62 dnl      1.1.0 => 100
  63 dnl      1.2.5 => 205
  64 dnl      1.10.9 (who knows) => 1009
  65 dnl
  66 dnl sets GST_LT_LDFLAGS
  67 AS_LIBTOOL(GST, 501, 0, 501)
  68
  69 dnl *** autotools stuff ****
  70
  71 dnl allow for different autotools
  72 AS_AUTOTOOLS_ALTERNATE
  73
  74 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  75 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  76
  77 dnl set up gettext
  78 dnl the version check needs to stay here because autopoint greps for it
  79 AM_GNU_GETTEXT_VERSION([0.17])
  80 AM_GNU_GETTEXT([external])
  81 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  82
  83 dnl *** check for arguments to configure ***
  84
  85 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  86
  87 dnl subsystems - can influence other decisions so needs to be high up
  88 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  90 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 118 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 119
 120 AG_GST_ARG_DEBUG
 121 AG_GST_ARG_PROFILING
 122 AG_GST_ARG_VALGRIND
 123 AG_GST_ARG_GCOV
 124
 125 AG_GST_ARG_EXAMPLES
 126
 127 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 128 AG_GST_ARG_WITH_PACKAGE_NAME
 129 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 130
 131 AG_GST_PKG_CONFIG_PATH
 132
 133 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 134   ["${srcdir}/gstreamer.doap"],
 135   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 136
 137 dnl check for bash completion
 138 AC_ARG_WITH([bash-completion-dir],
 139     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 140         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 141     [],
 142     [with_bash_completion_dir=yes])
 143
 144 if test "x$with_bash_completion_dir" = "xyes"
 145 then
 146     extra_args=
 147
 148     if test "x$prefix" != "xNONE"
 149     then
 150         extra_args="--define-variable=prefix=\"$prefix\""
 151     fi
 152
 153     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 154         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 155         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 156     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 157         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 158         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 159 else
 160     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 161     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 162 fi
 163
 164 AC_SUBST([BASH_COMPLETION_DIR])
 165 AC_SUBST([BASH_HELPERS_DIR])
 166 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 167
 168 dnl build static plugins or not
 169 AC_MSG_CHECKING([whether to build static plugins or not])
 170 AC_ARG_ENABLE(
 171   static-plugins,
 172   AC_HELP_STRING(
 173     [--enable-static-plugins],
 174     [build static plugins @<:@default=no@:>@]),
 175   [AS_CASE(
 176     [$enableval], [no], [], [yes], [],
 177     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 178   [enable_static_plugins=no])
 179 AC_MSG_RESULT([$enable_static_plugins])
 180 if test "x$enable_static_plugins" = xyes; then
 181   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 182     [Define if static plugins should be built])
 183   GST_PLUGIN_LIBTOOLFLAGS=""
 184 else
 185   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 186 fi
 187 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 188 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 189
 190 dnl building of tests
 191 AC_ARG_ENABLE(tests,
 192   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 193   [
 194     case "${enableval}" in
 195       yes) BUILD_TESTS=yes ;;
 196       no)  BUILD_TESTS=no ;;
 197       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 198     esac
 199   ],
 200 [BUILD_TESTS=yes]) dnl Default value
 201 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 202
 203 dnl tests known to fail
 204 AC_ARG_ENABLE(failing-tests,
 205   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 206   [
 207     case "${enableval}" in
 208       yes) BUILD_FAILING_TESTS=yes ;;
 209       no)  BUILD_FAILING_TESTS=no ;;
 210       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 211     esac
 212   ],
 213   [BUILD_FAILING_TESTS=no]) dnl Default value
 214 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 215 if test x$BUILD_FAILING_TESTS = xyes; then
 216   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 217 else
 218   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 219 fi
 220
 221 dnl building of benchmarks
 222 AC_ARG_ENABLE(benchmarks,
 223   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 224   [
 225     case "${enableval}" in
 226       yes) BUILD_BENCHMARKS=yes ;;
 227       no)  BUILD_BENCHMARKS=no ;;
 228       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 229     esac
 230   ],
 231 [BUILD_BENCHMARKS=yes]) dnl Default value
 232 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 233
 234 dnl building of tools
 235 AC_ARG_ENABLE(tools,
 236   AS_HELP_STRING([--disable-tools],[disable building tools]),
 237   [
 238     case "${enableval}" in
 239       yes) BUILD_TOOLS=yes ;;
 240       no)  BUILD_TOOLS=no ;;
 241       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 242     esac
 243   ],
 244 [BUILD_TOOLS=yes]) dnl Default value
 245 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 246
 247 dnl poison destroyed objects
 248 AC_ARG_ENABLE(poisoning,
 249   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 250   [
 251     case "${enableval}" in
 252       yes) USE_POISONING=yes ;;
 253       no)  USE_POISONING=no ;;
 254       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 255     esac
 256   ],
 257   [USE_POISONING=no]) dnl Default value
 258 if test "x$USE_POISONING" = xyes; then
 259   AC_DEFINE(USE_POISONING, 1,
 260     [Define if we should poison deallocated memory])
 261 fi
 262
 263 dnl *** checks for platform ***
 264
 265 dnl * hardware/architecture *
 266
 267 dnl common/m4/gst-arch.m4
 268 dnl check CPU type
 269 AG_GST_ARCH
 270 dnl substitution for win32/common/config.h
 271 HOST_CPU=$host_cpu
 272 AC_SUBST(HOST_CPU)
 273
 274 dnl common/m4/gst-arch.m4
 275 dnl check for unaligned access
 276 AG_GST_UNALIGNED_ACCESS
 277 dnl create a configure variable for gst/gstconfig.h
 278 if test x${as_cv_unaligned_access} = xyes ; then
 279   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 280 else
 281   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 282 fi
 283 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 284
 285 dnl check for platform specific settings
 286 AG_GST_PLATFORM
 287
 288 dnl * software *
 289
 290 dnl check for large file support
 291 dnl affected plugins must include config.h
 292 AC_SYS_LARGEFILE
 293
 294 dnl *** checks for programs ***
 295
 296 dnl find a compiler
 297 AC_PROG_CC
 298 AC_PROG_CC_STDC
 299
 300 dnl check if the compiler supports '-c' and '-o' options
 301 AM_PROG_CC_C_O
 302
 303 dnl find an assembler
 304 AM_PROG_AS
 305
 306 dnl determine if c++ is available on this system
 307 AC_PROG_CXX
 308 dnl CXX may be set to some default even if no c++ compiler is available
 309 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 310 AC_LANG_PUSH([C++])
 311 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 312 AC_LANG_POP([C++])
 313 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 314 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 315
 316 dnl Perl is used in building documentation and in the version checks
 317 AC_PATH_PROG(PERL_PATH, perl, no)
 318 if test x$PERL_PATH = xno; then
 319   AC_MSG_ERROR(Could not find perl)
 320 fi
 321
 322 dnl we require flex and bison for building the parser
 323 if test "x$GST_DISABLE_PARSE" != xyes; then
 324   AG_GST_BISON_CHECK
 325   AG_GST_FLEX_CHECK
 326 fi
 327
 328 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 329 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 330
 331 dnl check for gobject-introspection
 332 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 333
 334 dnl check for documentation tools
 335 AG_GST_DOCBOOK_CHECK
 336 GTK_DOC_CHECK([1.12])
 337 AG_GST_PLUGIN_DOCS([1.12])
 338
 339 dnl *** checks for libraries ***
 340
 341 dnl check for libm, for sin()
 342 LT_LIB_M
 343 AC_SUBST(LIBM)
 344
 345 dnl *** checks for header files ***
 346
 347 dnl check if we have ANSI C header files
 348 AC_HEADER_STDC
 349
 350 dnl Check for ucontext.h
 351 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 352
 353 dnl Check for sys/socket.h
 354 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 355 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 356
 357 dnl check for sys/times.h for tests/examples/adapter/
 358 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 359 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 360 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 361
 362 dnl Check for process.h for getpid() on win32
 363 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 364
 365 dnl Check for sys/utsname.h for uname
 366 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 367
 368 dnl Check for stdio_ext.f for __fbufsize
 369 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 370
 371 dnl check for pthreads
 372 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 373 dnl which later checks use in their test code
 374 AX_PTHREAD()
 375 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 376
 377 dnl check for sys/prctl for setting thread name on Linux
 378 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 379
 380 dnl check for pthread_setname_np(const char*)
 381 dnl which is present on OS X 10.6, iOS 3.2 and above
 382 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 383 AC_LINK_IFELSE(
 384     [AC_LANG_PROGRAM(
 385         [#include <pthread.h>],
 386         [pthread_setname_np("example")])],
 387     [AC_MSG_RESULT(yes)
 388      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 389         [Have function pthread_setname_np(const char*)])],
 390     [AC_MSG_RESULT(no)])
 391
 392 dnl check for sys/uio.h for writev()
 393 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 394
 395 dnl Check for valgrind.h
 396 dnl separate from HAVE_VALGRIND because you can have the program, but not
 397 dnl the dev package
 398 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 399
 400 dnl used in gst/gstpoll.c
 401 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 402 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 403 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 404   WIN32_LIBS="-lws2_32"
 405   AC_SUBST(WIN32_LIBS)
 406 fi
 407
 408 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 409 if test "x$BUILD_TESTS" = "xyes"; then
 410   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 411                          __gmpz_init_set_d, ,
 412                          gmp.h,
 413                          GMP_LIBS="-lgmp"
 414                          AC_SUBST(GMP_LIBS)
 415                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 416   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 417                          gsl_rng_uniform_int, -lgslcblas,
 418                          gsl/gsl_rng.h,
 419                          GSL_LIBS="-lgsl -lgslcblas"
 420                          AC_SUBST(GSL_LIBS)
 421                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 422 fi
 423
 424 dnl *** checks for types/defines ***
 425
 426 dnl *** checks for structures ***
 427
 428 dnl *** checks for compiler characteristics ***
 429
 430 dnl check if the compiler supports __uint128_t (gcc)
 431 dnl Actually check for 128-bit division, since that's what we use
 432 dnl uint128_t for.
 433 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 434     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 435       static __uint128_t v1 = 100;
 436       static __uint128_t v2 = 10;
 437       static __uint128_t u;
 438       u = v1 / v2;
 439     ]])],[
 440       gst_cv_uint128_t=yes
 441     ],[
 442       gst_cv_uint128_t=no
 443     ])
 444 )
 445 if test x$gst_cv_uint128_t = xyes; then
 446   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 447 fi
 448
 449 dnl *** checking for tm_gmtoff ***
 450 AC_MSG_CHECKING([for tm_gmtoff])
 451 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 452         #include <time.h>
 453         int main(void) {
 454           struct tm t;
 455           t.tm_gmtoff = 0;
 456           exit(0);
 457         }]])],
 458   [have_tm_gmtoff=yes
 459    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 460   [have_tm_gmtoff=no],
 461   [have_tm_gmtoff="no (cross compiling)"])
 462 AC_MSG_RESULT($have_tm_gmtoff)
 463
 464
 465 dnl *** checks for library functions ***
 466
 467 AC_CHECK_FUNCS([strcasestr])
 468
 469 AC_CHECK_FUNCS([gmtime_r])
 470 AC_CHECK_FUNCS([localtime_r])
 471 AC_CHECK_FUNCS([sigaction])
 472
 473 dnl check for fseeko()
 474 AC_FUNC_FSEEKO
 475 dnl check for ftello()
 476 AC_CHECK_FUNCS([ftello])
 477
 478 AC_CHECK_FUNCS([fgetpos])
 479 AC_CHECK_FUNCS([fsetpos])
 480
 481 dnl check for poll(), ppoll() and pselect()
 482 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 483 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 484 AC_CHECK_FUNCS([poll])
 485 AC_CHECK_FUNCS([ppoll])
 486 AC_CHECK_FUNCS([pselect])
 487
 488 dnl ****************************************
 489 dnl *** GLib POLL* compatibility defines ***
 490 dnl ****************************************
 491
 492 AC_MSG_CHECKING([for broken poll])
 493 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 494         #include <stdlib.h>
 495         #include <fcntl.h>
 496         #ifdef HAVE_SYS_POLL_H
 497         #include <sys/poll.h>
 498         #endif
 499         #ifdef HAVE_POLL_H
 500         #include <poll.h>
 501         #endif
 502         int main(void) {
 503           struct pollfd fds[1];
 504           int fd;
 505           fd = open("/dev/null", 1);
 506           fds[0].fd = fd;
 507           fds[0].events = POLLIN;
 508           fds[0].revents = 0;
 509           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 510                 exit(1);  /* Does not work for devices -- fail */
 511           }
 512           exit(0);
 513         }]])],
 514   [broken_poll=no],
 515   [broken_poll=yes
 516    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 517   [broken_poll="no (cross compiling)"])
 518 AC_MSG_RESULT($broken_poll)
 519
 520 dnl check for mmap()
 521 AC_FUNC_MMAP
 522 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 523
 524 dnl check for posix_memalign(), getpagesize()
 525 AC_CHECK_FUNCS([posix_memalign])
 526 AC_CHECK_FUNCS([getpagesize])
 527
 528 dnl Check for POSIX timers
 529 AC_CHECK_FUNCS(clock_gettime, [], [
 530   AC_CHECK_LIB(rt, clock_gettime, [
 531     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 532     LIBS="$LIBS -lrt"
 533   ], [
 534     AC_CHECK_LIB(pthread, clock_gettime, [
 535       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 536       LIBS="$LIBS -lpthread"
 537     ])
 538   ])
 539 ])
 540
 541 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 542     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 543 #include <time.h>
 544 #ifdef HAVE_UNISTD_H
 545 #include <unistd.h>
 546 #endif
 547     ]], [[
 548 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 549 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 550 #endif
 551     ]])],[
 552       gst_cv_posix_timers=yes
 553     ],[
 554       gst_cv_posix_timers=no
 555     ])
 556 )
 557
 558 if test "$gst_cv_posix_timers" = "yes"; then
 559   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 560   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 561 else
 562   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 563 fi
 564 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 565 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 566
 567 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 568     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 569 #include <time.h>
 570 #ifdef HAVE_UNISTD_H
 571 #include <unistd.h>
 572 #endif
 573     ]], [[
 574 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 575 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 576 #endif
 577     ]])],[
 578       gst_cv_monotonic_clock=yes
 579     ],[
 580       gst_cv_monotonic_clock=no
 581     ])
 582 )
 583
 584 if test "$gst_cv_monotonic_clock" = "yes"; then
 585   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 586   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 587 else
 588   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 589 fi
 590 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 591 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 592
 593 dnl Check for a way to display the function name in debug output
 594 AG_GST_CHECK_FUNCTION
 595
 596 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 597 save_cflags="$CFLAGS"
 598 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 599 AC_CHECK_LIB(dl, dladdr,
 600    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 601    LIBS="$LIBS -ldl")
 602 CFLAGS="$save_cflags"
 603
 604 dnl Check printf stuff
 605 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 606   AC_TYPE_LONG_LONG_INT
 607   AC_TYPE_UNSIGNED_LONG_LONG_INT
 608
 609   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 610     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 611   fi
 612
 613   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 614   gl_AC_HEADER_INTTYPES_H
 615
 616   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 617   gl_AC_HEADER_STDINT_H
 618
 619   AC_CHECK_TYPES(ptrdiff_t)
 620
 621   AC_TYPE_INTMAX_T
 622   AC_TYPE_SIZE_T
 623 fi
 624
 625 dnl *** checks for dependency libraries ***
 626
 627 dnl GLib
 628 GLIB_REQ=2.32.0
 629 AG_GST_GLIB_CHECK([$GLIB_REQ])
 630
 631 dnl Check for documentation xrefs
 632 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 633 AC_SUBST(GLIB_PREFIX)
 634
 635 dnl building of unit test libraries
 636 AC_ARG_ENABLE(check,
 637   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 638   [
 639     case "${enableval}" in
 640       yes) BUILD_CHECK=yes ;;
 641       no)  BUILD_CHECK=no ;;
 642       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 643     esac
 644   ], [
 645     dnl Default value
 646     case $host_os in
 647       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 648       *) BUILD_CHECK=yes ;;
 649     esac
 650 ])
 651 dnl bit of a misnomer, but keep the conditional named like this so we don't
 652 dnl have to change too much elsewhere
 653 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 654
 655 dnl configure the desired memory alignment
 656 AC_ARG_WITH([memory-alignment],
 657   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 658   [
 659     if test "x$withval" = "xyes"
 660     then
 661       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 662     else
 663       case "${withval}" in
 664         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 665         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 666         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 667       esac
 668     fi
 669   ], [
 670     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 671   ]
 672 )
 673
 674 dnl Check for -Bsymbolic-functions linker flag used to avoid
 675 dnl intra-library PLT jumps, if available.
 676 AC_ARG_ENABLE(Bsymbolic,
 677               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 678               [SAVED_LDFLAGS="${LDFLAGS}"
 679                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 680                LDFLAGS=-Wl,-Bsymbolic-functions
 681                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 682                            AC_MSG_RESULT(yes)
 683                            enable_Bsymbolic=yes],[
 684                            AC_MSG_RESULT(no)
 685                            enable_Bsymbolic=no])
 686                LDFLAGS="${SAVED_LDFLAGS}"])
 687
 688
 689 dnl *** set variables based on configure arguments
 690
 691 dnl set license and copyright notice
 692 GST_LICENSE="LGPL"
 693 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 694 AC_SUBST(GST_LICENSE)
 695
 696 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 697 AS_AC_EXPAND(LIBDIR, $libdir)
 698 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 699 AS_AC_EXPAND(DATADIR, $datadir)
 700 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 701
 702 dnl set location of plugin directory
 703 AG_GST_SET_PLUGINDIR
 704
 705 dnl make sure it doesn't complain about unused variables if debugging is disabled
 706 NO_WARNINGS=""
 707 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 708   NO_WARNINGS="-Wno-unused"
 709 fi
 710
 711 dnl define an ERROR_CFLAGS Makefile variable
 712 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 713
 714 dnl special warning flags for gst/printf
 715 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 716 AC_SUBST(PRINTF_CFLAGS)
 717
 718 dnl define correct level for debugging messages
 719 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 720
 721 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 722
 723 dnl Overview:
 724 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 725 dnl GST_ALL_*:          vars shared by all built objects
 726 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 727 dnl GST_OBJ_*:          additional vars to link to the core library
 728 dnl                     include GST_ALL_*
 729 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 730 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 731
 732 dnl GST_OPTION_CFLAGS
 733 if test "x$USE_DEBUG" = xyes; then
 734    PROFILE_CFLAGS="-g"
 735 fi
 736 AC_SUBST(PROFILE_CFLAGS)
 737
 738 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 739 # functionality from the API that gstreamer uses
 740 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 741 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 742   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 743   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 744 else
 745   DEPRECATED_CFLAGS=""
 746 fi
 747 AC_SUBST(DEPRECATED_CFLAGS)
 748
 749 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 750 dnl make DEPRECATED_CFLAGS=''
 751 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 752 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 753 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 754 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 755 AC_SUBST(GST_OPTION_CFLAGS)
 756 AC_SUBST(GST_OPTION_CXXFLAGS)
 757
 758 dnl GST_ALL_*
 759 dnl vars common to for all internal objects (core libs, elements, applications)
 760 dnl CFLAGS:
 761 dnl - src and build dirs need to be added because every piece that gets built
 762 dnl   will need the GStreamer source and generated headers
 763 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 764 dnl       from LibXML except for in the core library
 765 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 766 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 767
 768 dnl FIXME: check if LTLIBINTL is needed everywhere
 769 dnl I presume it is given that it contains the symbols that _() stuff maps to
 770 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 771
 772 dnl LDFLAGS really should only contain flags, not libs - they get added before
 773 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 774 GST_ALL_LDFLAGS="-no-undefined"
 775 if test "x${enable_Bsymbolic}" = "xyes"; then
 776   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 777 fi
 778
 779 AC_SUBST(GST_ALL_CFLAGS)
 780 AC_SUBST(GST_ALL_CXXFLAGS)
 781 AC_SUBST(GST_ALL_LIBS)
 782 AC_SUBST(GST_ALL_LDFLAGS)
 783
 784 dnl GST_LIB_LDFLAGS
 785 dnl linker flags shared by all libraries
 786 dnl LDFLAGS modifier defining exported symbols from built libraries
 787 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 788 AC_SUBST(GST_LIB_LDFLAGS)
 789
 790 dnl GST_OBJ_*
 791 dnl default vars for all internal objects built on libgstreamer
 792 dnl includes GST_ALL_*
 793 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 794 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 795 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 796 AC_SUBST(GST_OBJ_CFLAGS)
 797 AC_SUBST(GST_OBJ_CXXFLAGS)
 798 AC_SUBST(GST_OBJ_LIBS)
 799
 800 dnl GST_PLUGIN_LDFLAGS
 801 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 802 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 803 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 804
 805 dnl plugin scanner locations
 806 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 807 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 808     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 809 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 810
 811 dnl things for our internal libcheck (must be called even if building
 812 dnl libcheck is disabled because it defines conditionals)
 813 AG_GST_CHECK_CHECKS()
 814
 815 AC_CONFIG_FILES(
 816 Makefile
 817 data/Makefile
 818 gst/Makefile
 819 gst/gstconfig.h
 820 gst/gstversion.h
 821 gst/parse/Makefile
 822 gst/printf/Makefile
 823 libs/Makefile
 824 libs/gst/Makefile
 825 libs/gst/base/Makefile
 826 libs/gst/check/Makefile
 827 libs/gst/check/libcheck/Makefile
 828 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
 829 libs/gst/controller/Makefile
 830 libs/gst/helpers/Makefile
 831 libs/gst/net/Makefile
 832 plugins/Makefile
 833 plugins/elements/Makefile
 834 po/Makefile.in
 835 tests/Makefile
 836 tests/benchmarks/Makefile
 837 tests/check/Makefile
 838 tests/misc/Makefile
 839 tests/examples/Makefile
 840 tests/examples/adapter/Makefile
 841 tests/examples/controller/Makefile
 842 tests/examples/stepping/Makefile
 843 tests/examples/helloworld/Makefile
 844 tests/examples/launch/Makefile
 845 tests/examples/manual/Makefile
 846 tests/examples/memory/Makefile
 847 tests/examples/metadata/Makefile
 848 tests/examples/netclock/Makefile
 849 tests/examples/queue/Makefile
 850 tests/examples/streamiddemux/Makefile
 851 tests/examples/streams/Makefile
 852 tests/examples/typefind/Makefile
 853 tools/Makefile
 854 common/Makefile
 855 common/m4/Makefile
 856 docs/Makefile
 857 docs/design/Makefile
 858 docs/faq/Makefile
 859 docs/gst/Makefile
 860 docs/gst/gstreamer.types
 861 docs/libs/Makefile
 862 docs/plugins/Makefile
 863 docs/manual/Makefile
 864 docs/pwg/Makefile
 865 docs/slides/Makefile
 866 docs/xsl/Makefile
 867 docs/version.entities
 868 m4/Makefile
 869 pkgconfig/Makefile
 870 stamp.h
 871 pkgconfig/gstreamer.pc
 872 pkgconfig/gstreamer-uninstalled.pc
 873 pkgconfig/gstreamer-base.pc
 874 pkgconfig/gstreamer-base-uninstalled.pc
 875 pkgconfig/gstreamer-check.pc
 876 pkgconfig/gstreamer-check-uninstalled.pc
 877 pkgconfig/gstreamer-controller.pc
 878 pkgconfig/gstreamer-controller-uninstalled.pc
 879 pkgconfig/gstreamer-net.pc
 880 pkgconfig/gstreamer-net-uninstalled.pc
 881 gstreamer.spec
 882 )
 883
 884 dnl Create the config.h file for Visual Studio builds
 885 dnl Beware of spaces and /'s in some of the shell variable contents.
 886 sed \
 887     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 888     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 889     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 890     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 891     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 892     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 893     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 894     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 895     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 896     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 897     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 898     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 899     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 900     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 901     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 902     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 903     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 904     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 905     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 906     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 907     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 908     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 909     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 910     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 911     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 912     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 913     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 914     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 915     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 916     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 917     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 918     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 919     config.h.in >win32/common/config.h-new
 920
 921 AC_OUTPUT
 922
 923 dnl negate for output
 924 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 925 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 926 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 927 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 928 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 929 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 930 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 931
 932 echo "
 933
 934 Configuration
 935         Version                    : ${VERSION}
 936         Source code location       : ${srcdir}
 937         Prefix                     : ${prefix}
 938         Compiler                   : ${CC}
 939         Package name               : ${GST_PACKAGE_NAME}
 940         Package origin             : ${GST_PACKAGE_ORIGIN}
 941
 942         Documentation (manuals)    : ${enable_docbook}
 943         Documentation (API)        : ${enable_gtk_doc}
 944
 945         Debug Logging              : ${enable_gst_debug}
 946         Command-line parser        : ${enable_parse}
 947         Option parsing in gst_init : ${enable_option_parsing}
 948         Tracing subsystem          : ${enable_trace}
 949         Allocation tracing         : ${enable_alloc_trace}
 950         Plugin registry            : ${enable_registry}
 951         Plugin support             : ${enable_plugin}
 952         Static plugins             : ${enable_static_plugins}
 953         Unit testing support       : ${BUILD_CHECK}
 954
 955         Debug                      : ${USE_DEBUG}
 956         Profiling                  : ${USE_PROFILING}
 957
 958         Building benchmarks        : ${BUILD_BENCHMARKS}
 959         Building examples          : ${BUILD_EXAMPLES}
 960         Building test apps         : ${BUILD_TESTS}
 961         Building tests that fail   : ${BUILD_FAILING_TESTS}
 962         Building tools             : ${BUILD_TOOLS}
 963 "