configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.11.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1100, 0, 1100)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.11.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl checks for gstreamer
 284 dnl uninstalled is selected preferentially -- see pkg-config(1)
 285 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 286 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 288 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 289 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 290 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 291
 292 dnl Check for documentation xrefs
 293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 294 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 295 AC_SUBST(GLIB_PREFIX)
 296 AC_SUBST(GST_PREFIX)
 297
 298 dnl GTK is optional and only used in examples
 299 HAVE_GTK=no
 300 HAVE_GTK_X11=no
 301 GTK_REQ=3.10
 302 if test "x$BUILD_EXAMPLES" = "xyes"; then
 303   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 304   dnl some examples need gtk+-x11
 305   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 306   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 307   AC_SUBST(GTK_LIBS)
 308   AC_SUBST(GTK_CFLAGS)
 309 fi
 310 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 311 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 312 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 313
 314 HAVE_QT=no
 315 HAVE_QT_MOC=no
 316 dnl QT is optional and only used in examples
 317 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 318   HAVE_QT=yes
 319 ], [
 320   HAVE_QT=no
 321 ])
 322 if test "x$HAVE_QT" = "xyes"; then
 323   AC_CHECK_TOOL(QT_MOC, moc)
 324   AC_MSG_CHECKING([for Qt5 moc])
 325   mocversion=`$QT_MOC -v 2>&1`
 326   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 327   if test x"$mocversiongrep" != x"$mocversion"; then
 328     AC_MSG_RESULT([no])
 329     # moc was not the qt5 one, try with moc-qt5
 330     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 331     AC_MSG_CHECKING([for Qt5 moc-qt5])
 332     mocversion=`$QT_MOC -v 2>&1`
 333     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 334     if test x"$mocversiongrep" != x"$mocversion"; then
 335       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 336       AC_MSG_CHECKING([for qtchooser])
 337       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 338       mocversion=`$qt5tooldir/moc -v 2>&1`
 339       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 340       if test x"$mocversiongrep" != x"$mocversion"; then
 341         # no valid moc found
 342         QT_MOC="no"
 343       else
 344         QT_MOC=$qt5tooldir/moc
 345       fi
 346     else
 347       QT_MOC=$QT_MOC
 348     fi
 349   fi
 350   AC_SUBST(QT_MOC)
 351   AC_MSG_RESULT([$QT_MOC])
 352 fi
 353 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 354 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 355
 356 dnl chck for linux headers needed by the joystick seek example
 357 AC_COMPILE_IFELSE(
 358 [
 359   AC_LANG_PROGRAM([
 360     #include <linux/input.h>
 361     #include <linux/joystick.h>
 362   ],[
 363     struct js_event js;
 364     js.type = JS_EVENT_AXIS;
 365   ])
 366 ], [
 367   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 368 ], [
 369   HAVE_LINUX_JOYSTICK_HEADERS="no"
 370 ])
 371 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 372
 373 dnl Check for -Bsymbolic-functions linker flag used to avoid
 374 dnl intra-library PLT jumps, if available.
 375 AC_ARG_ENABLE(Bsymbolic,
 376               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 377               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 378                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 379                LDFLAGS=-Wl,-Bsymbolic-functions
 380                LIBS=
 381                AC_TRY_LINK([], [return 0],
 382                            AC_MSG_RESULT(yes)
 383                            enable_Bsymbolic=yes,
 384                            AC_MSG_RESULT(no)
 385                            enable_Bsymbolic=no)
 386                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 387
 388
 389 dnl *** set variables based on configure arguments ***
 390
 391 dnl set license and copyright notice
 392 GST_LICENSE="LGPL"
 393 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 394 AC_SUBST(GST_LICENSE)
 395
 396 dnl set location of plugin directory
 397 AG_GST_SET_PLUGINDIR
 398
 399 dnl set release date/time
 400 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 401   ["${srcdir}/gst-plugins-base.doap"],
 402   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 403
 404 dnl build static plugins or not
 405 AC_MSG_CHECKING([whether to build static plugins or not])
 406 AC_ARG_ENABLE(
 407   static-plugins,
 408   AC_HELP_STRING(
 409     [--enable-static-plugins],
 410     [build static plugins @<:@default=no@:>@]),
 411   [AS_CASE(
 412     [$enableval], [no], [], [yes], [],
 413     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 414   [enable_static_plugins=no])
 415 AC_MSG_RESULT([$enable_static_plugins])
 416 if test "x$enable_static_plugins" = xyes; then
 417   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 418     [Define if static plugins should be built])
 419   GST_PLUGIN_LIBTOOLFLAGS=""
 420 else
 421   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 422 fi
 423 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 424 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 425
 426 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 427 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 428 if test x$enable_static = xyes -a x$enable_shared = xno; then
 429   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 430 fi
 431
 432 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 433 dnl make sure it doesn't complain about unused variables if debugging is disabled
 434 NO_WARNINGS=""
 435 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 436
 437 dnl define an ERROR_CFLAGS Makefile variable
 438 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 439 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 440     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 441     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 442     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 443     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 444
 445 dnl define an ERROR_CXXFLAGS Makefile variable
 446 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 447     -Wmissing-declarations -Wredundant-decls -Wundef
 448     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 449     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 450     -Wno-multichar $NO_WARNINGS])
 451
 452 dnl define correct level for debugging messages
 453 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 454
 455 dnl used in examples
 456 AG_GST_DEFAULT_ELEMENTS
 457
 458 dnl needed for encoding-target
 459 GST_DATADIR="$GST_PREFIX/share"
 460 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 461 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 462
 463 dnl behaviour of speex based audio resampler
 464 AC_MSG_CHECKING(which audio resample format to use for integer)
 465 AC_ARG_WITH([audioresample_format],
 466         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 467         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 468 AC_MSG_RESULT($ac_cv_audioresample_format)
 469 case $ac_cv_audioresample_format in
 470   int)
 471     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 472     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 473   ;;
 474   float)
 475     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 476     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 477   ;;
 478   auto)
 479     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 480     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 481 esac
 482
 483 dnl Check for mmap (needed by allocators library)
 484 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 485
 486 dnl *** plug-ins to include ***
 487
 488 dnl these are all the gst plug-ins, compilable without additional libs
 489 AG_GST_CHECK_PLUGIN(adder)
 490 AG_GST_CHECK_PLUGIN(app)
 491 AG_GST_CHECK_PLUGIN(audioconvert)
 492 AG_GST_CHECK_PLUGIN(audiorate)
 493 AG_GST_CHECK_PLUGIN(audiotestsrc)
 494 AG_GST_CHECK_PLUGIN(encoding)
 495 AG_GST_CHECK_PLUGIN(videoconvert)
 496 AG_GST_CHECK_PLUGIN(gio)
 497 AG_GST_CHECK_PLUGIN(playback)
 498 AG_GST_CHECK_PLUGIN(audioresample)
 499 AG_GST_CHECK_PLUGIN(subparse)
 500 AG_GST_CHECK_PLUGIN(tcp)
 501 AG_GST_CHECK_PLUGIN(typefind)
 502 AG_GST_CHECK_PLUGIN(videotestsrc)
 503 AG_GST_CHECK_PLUGIN(videorate)
 504 AG_GST_CHECK_PLUGIN(videoscale)
 505 AG_GST_CHECK_PLUGIN(volume)
 506
 507 dnl iso-codes is optional, used by libgsttag
 508 AC_ARG_ENABLE(iso-codes,
 509 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 510 [case "${enableval}" in
 511   yes) enable_iso_codes=yes ;;
 512   no)  enable_iso_codes=no ;;
 513   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 514 esac
 515 ],
 516 [enable_iso_codes=yes]) dnl Default value
 517
 518 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 519 if test "x$enable_iso_codes" = "xyes"; then
 520   AC_MSG_RESULT([yes])
 521   have_iso_codes=no
 522   AC_MSG_CHECKING([whether iso-codes are available on this system])
 523   if $PKG_CONFIG iso-codes; then
 524     AC_MSG_RESULT([yes])
 525     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 526     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 527       AC_MSG_RESULT([yes])
 528       AC_MSG_CHECKING([for iso-codes prefix])
 529       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 530       if test -d "$ISO_CODES_PREFIX"; then
 531         AC_MSG_RESULT([yes])
 532         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 533         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 534         ISO_639_DOMAIN="iso_639"
 535         AC_MSG_CHECKING([ISO_639_DOMAIN])
 536         AC_MSG_RESULT([$ISO_639_DOMAIN])
 537         have_iso_codes=yes
 538         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 539         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 540         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 541         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 542       else
 543         AC_MSG_RESULT([no])
 544       fi
 545     else
 546       AC_MSG_RESULT([no])
 547     fi
 548   else
 549     AC_MSG_RESULT([no])
 550   fi
 551   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 552 else
 553   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 554   AM_CONDITIONAL(USE_ISO_CODES, false)
 555 fi
 556
 557 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 558 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 559 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 560   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 561       HAVE_ZLIB="yes"
 562     ], [
 563       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 564         HAVE_ZLIB="yes"
 565         ZLIB_LIBS="-lz"
 566         AC_SUBST(ZLIB_LIBS)
 567       ])
 568     ])
 569 ])
 570
 571 dnl *** sys plug-ins ***
 572
 573 echo
 574 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 575 echo
 576
 577 dnl *** X11 ***
 578 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 579 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 580                   [ximagesink], [
 581   AG_GST_PKG_CHECK_MODULES(X, x11)
 582 ])
 583
 584 dnl Check for Xv extension
 585 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 586 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 587                   [xvimagesink], [
 588   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 589 ])
 590
 591 dnl check for X Shm
 592 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 593 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 594   if test x$HAVE_X = xyes; then
 595     PKG_CHECK_MODULES(XSHM, xext, [
 596       AC_CHECK_LIB(Xext, XShmAttach, [
 597         HAVE_XSHM="yes"
 598       ], [
 599         HAVE_XSHM="no"
 600         XSHM_LIBS=""
 601       ], [ $X_LIBS ])
 602     ], [
 603       HAVE_XSHM="no"
 604     ])
 605   fi
 606 ], , [
 607   AC_SUBST(HAVE_XSHM)
 608   AC_SUBST(XSHM_LIBS)
 609 ])
 610
 611 dnl *** ext plug-ins ***
 612 dnl keep this list sorted alphabetically !
 613
 614 if test "x$BUILD_EXTERNAL" = "xyes"; then
 615
 616 echo
 617 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 618 echo
 619
 620 dnl *** alsa ***
 621 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 622 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 623   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 624     HAVE_ALSA="yes"
 625     AC_SUBST(ALSA_CFLAGS)
 626     AC_SUBST(ALSA_LIBS)
 627   ], [
 628     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 629   ])
 630 ])
 631
 632 dnl *** CDParanoia ***
 633 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 634 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 635 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 636   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 637     HAVE_CDPARANOIA="yes"
 638   ], [
 639     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 640                         cdda_open, -lm,
 641                         cdda_interface.h,
 642                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 643                         HEADER_DIR="no"
 644                         FOUND_CDPARANOIA="yes")
 645     if test "x$FOUND_CDPARANOIA" != "xyes";
 646     then
 647       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 648                           cdda_open, -lm,
 649                           cdda/cdda_interface.h,
 650                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 651                           HEADER_DIR="yes"
 652                           FOUND_CDPARANOIA="yes")
 653     fi
 654     if test "x$HEADER_DIR" = "xyes";
 655     then
 656       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 657                          defined if cdda headers are in a cdda/ directory)
 658     fi
 659     if test "x$FOUND_CDPARANOIA" = "xyes";
 660     then
 661       AC_CHECK_LIB(cdda_paranoia,
 662                    paranoia_cachemodel_size,
 663                    : ,
 664                    HAVE_CDPARANOIA=no,
 665                  [-lcdda_interface])
 666     fi
 667
 668     AC_SUBST(CDPARANOIA_LIBS)
 669   ])
 670 ])
 671 dnl FIXME : add second check somehow if that is necessary
 672 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 673 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 674
 675 dnl *** ivorbis ***
 676 dnl AM_PATH_IVORBIS only takes two options
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 678 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 679   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 680   if test $HAVE_IVORBIS = no
 681   then
 682     IVORBIS_LIBS=
 683     IVORBIS_CFLAGS=
 684     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 685       [IVORBIS_LIBS=-lvorbisidec
 686       HAVE_IVORBIS=yes
 687       case $host in
 688       arm-*-*)
 689         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 690       esac
 691       ],
 692       HAVE_IVORBIS=no)
 693     AC_SUBST(IVORBIS_LIBS)
 694     AC_SUBST(IVORBIS_CFLAGS)
 695   else
 696     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 697       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 698       USE_TREMOLO=no)
 699   fi
 700 ])
 701
 702 dnl *** libvisual ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 704 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 705   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 706   if test x$HAVE_LIBVISUAL = xyes; then
 707     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 708   fi
 709   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 710   if test x$LIBVIS_PLUGINSDIR != x; then
 711     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 712         "$LIBVIS_PLUGINSDIR",
 713         [directory in which the detected libvisual's plugins are located])
 714   fi
 715 ])
 716
 717 dnl *** ogg ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 719 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 720   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 721 ])
 722
 723 dnl *** Opus ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 725 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 726   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 727           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 728           HAVE_OPUS="yes"
 729   ], [
 730           HAVE_OPUS="no"
 731   ])
 732   AC_SUBST(OPUS_CFLAGS)
 733   AC_SUBST(OPUS_LIBS)
 734 ])
 735
 736 dnl *** pango ***
 737 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 738 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 739   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 740 ])
 741
 742 dnl *** theora ***
 743 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 744 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 745   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 746 ])
 747
 748 dnl *** vorbis ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 750 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 751   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 752 ])
 753
 754 if test "x$HAVE_VORBIS" = "xyes"; then
 755   ac_cflags_save="$CFLAGS"
 756   AC_COMPILE_IFELSE([
 757     AC_LANG_PROGRAM([[
 758 #include <vorbis/codec.h>
 759                      ]],[[
 760 vorbis_dsp_state *v;
 761
 762 vorbis_synthesis_restart (v);
 763                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 764   if test "x$HAVE_VSR" = "xyes"; then
 765     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 766                        [defined if vorbis_synthesis_restart is present])
 767   fi
 768   CFLAGS="$ac_cflags_save"
 769 fi
 770
 771 else
 772
 773 dnl not building plugins with external dependencies,
 774 dnl but we still need to set the conditionals
 775 AM_CONDITIONAL(USE_ALSA, false)
 776 AM_CONDITIONAL(USE_CDPARANOIA, false)
 777 AM_CONDITIONAL(USE_IVORBIS, false)
 778 AM_CONDITIONAL(USE_LIBVISUAL, false)
 779 AM_CONDITIONAL(USE_OGG, false)
 780 AM_CONDITIONAL(USE_OPUS, false)
 781 AM_CONDITIONAL(USE_PANGO, false)
 782 AM_CONDITIONAL(USE_THEORA, false)
 783 AM_CONDITIONAL(USE_VORBIS, false)
 784
 785 fi dnl of EXT plugins
 786
 787 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 788 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 789     HAVE_GIO_UNIX_2_0="yes",
 790     HAVE_GIO_UNIX_2_0="no")
 791 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 792
 793 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 794
 795 dnl Overview:
 796 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 797 dnl GST_*:              flags shared by built objects to link against GStreamer
 798 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 799 dnl                          (compare to other modules) or for i18n
 800 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 801 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 802 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 803 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 804
 805 dnl GST_OPTION_CFLAGS
 806 if test "x$USE_DEBUG" = xyes; then
 807    PROFILE_CFLAGS="-g"
 808 fi
 809 AC_SUBST(PROFILE_CFLAGS)
 810
 811 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 812   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 813   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 814 else
 815   DEPRECATED_CFLAGS=""
 816 fi
 817 AC_SUBST(DEPRECATED_CFLAGS)
 818
 819 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 820 dnl at make time with e.g. make ERROR_CFLAGS=""
 821 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 822 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 823 AC_SUBST(GST_OPTION_CFLAGS)
 824 AC_SUBST(GST_OPTION_CXXFLAGS)
 825
 826 dnl our libraries need to be versioned correctly
 827 AC_SUBST(GST_LT_LDFLAGS)
 828
 829 dnl GST_PLUGINS_BASE_CFLAGS
 830 dnl prefer internal headers to already installed ones
 831 dnl also add builddir include for enumtypes and marshal
 832 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 833 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 834
 835 dnl FIXME: do we want to rename to GST_ALL_* ?
 836 dnl add GST_OPTION_CFLAGS, but overridable
 837 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 838 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 839 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 840 AC_SUBST(GST_CFLAGS)
 841 AC_SUBST(GST_CXXFLAGS)
 842 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 843 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 844 AC_SUBST(GST_LIBS)
 845
 846 dnl LDFLAGS really should only contain flags, not libs - they get added before
 847 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 848 GST_ALL_LDFLAGS="-no-undefined"
 849 if test "x${enable_Bsymbolic}" = "xyes"; then
 850   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 851 fi
 852 AC_SUBST(GST_ALL_LDFLAGS)
 853
 854 dnl GST_LIB_LDFLAGS
 855 dnl linker flags shared by all libraries
 856 dnl LDFLAGS modifier defining exported symbols from built libraries
 857 dnl (export _gst_foo but not __gst_foo)
 858 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 859 AC_SUBST(GST_LIB_LDFLAGS)
 860
 861 dnl this really should only contain flags, not libs - they get added before
 862 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 863 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 864 AC_SUBST(GST_PLUGIN_LDFLAGS)
 865
 866 dnl *** output files ***
 867
 868 $MKDIR_P tests/check/orc
 869
 870 AC_CONFIG_FILES(
 871 Makefile
 872 gst-plugins-base.spec
 873 gst/Makefile
 874 gst/adder/Makefile
 875 gst/app/Makefile
 876 gst/audioconvert/Makefile
 877 gst/audiorate/Makefile
 878 gst/audioresample/Makefile
 879 gst/audiotestsrc/Makefile
 880 gst/encoding/Makefile
 881 gst/videoconvert/Makefile
 882 gst/gio/Makefile
 883 gst/pbtypes/Makefile
 884 gst/playback/Makefile
 885 gst/subparse/Makefile
 886 gst/tcp/Makefile
 887 gst/typefind/Makefile
 888 gst/videotestsrc/Makefile
 889 gst/videorate/Makefile
 890 gst/videoscale/Makefile
 891 gst/volume/Makefile
 892 sys/Makefile
 893 sys/ximage/Makefile
 894 sys/xvimage/Makefile
 895 ext/Makefile
 896 ext/alsa/Makefile
 897 ext/cdparanoia/Makefile
 898 ext/libvisual/Makefile
 899 ext/ogg/Makefile
 900 ext/opus/Makefile
 901 ext/pango/Makefile
 902 ext/theora/Makefile
 903 ext/vorbis/Makefile
 904 gst-libs/Makefile
 905 gst-libs/gst/Makefile
 906 gst-libs/gst/allocators/Makefile
 907 gst-libs/gst/audio/Makefile
 908 gst-libs/gst/app/Makefile
 909 gst-libs/gst/fft/Makefile
 910 gst-libs/gst/riff/Makefile
 911 gst-libs/gst/rtp/Makefile
 912 gst-libs/gst/rtsp/Makefile
 913 gst-libs/gst/sdp/Makefile
 914 gst-libs/gst/tag/Makefile
 915 gst-libs/gst/pbutils/Makefile
 916 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 917 gst-libs/gst/video/Makefile
 918 tools/Makefile
 919 pkgconfig/Makefile
 920 pkgconfig/gstreamer-allocators.pc
 921 pkgconfig/gstreamer-allocators-uninstalled.pc
 922 pkgconfig/gstreamer-audio.pc
 923 pkgconfig/gstreamer-audio-uninstalled.pc
 924 pkgconfig/gstreamer-app.pc
 925 pkgconfig/gstreamer-app-uninstalled.pc
 926 pkgconfig/gstreamer-fft.pc
 927 pkgconfig/gstreamer-fft-uninstalled.pc
 928 pkgconfig/gstreamer-pbutils.pc
 929 pkgconfig/gstreamer-pbutils-uninstalled.pc
 930 pkgconfig/gstreamer-riff.pc
 931 pkgconfig/gstreamer-riff-uninstalled.pc
 932 pkgconfig/gstreamer-rtp.pc
 933 pkgconfig/gstreamer-rtp-uninstalled.pc
 934 pkgconfig/gstreamer-rtsp.pc
 935 pkgconfig/gstreamer-rtsp-uninstalled.pc
 936 pkgconfig/gstreamer-sdp.pc
 937 pkgconfig/gstreamer-sdp-uninstalled.pc
 938 pkgconfig/gstreamer-tag.pc
 939 pkgconfig/gstreamer-tag-uninstalled.pc
 940 pkgconfig/gstreamer-video.pc
 941 pkgconfig/gstreamer-video-uninstalled.pc
 942 pkgconfig/gstreamer-plugins-base.pc
 943 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 944 tests/Makefile
 945 tests/check/Makefile
 946 tests/examples/Makefile
 947 tests/examples/app/Makefile
 948 tests/examples/audio/Makefile
 949 tests/examples/decodebin_next/Makefile
 950 tests/examples/dynamic/Makefile
 951 tests/examples/encoding/Makefile
 952 tests/examples/fft/Makefile
 953 tests/examples/gio/Makefile
 954 tests/examples/overlay/Makefile
 955 tests/examples/seek/Makefile
 956 tests/examples/snapshot/Makefile
 957 tests/examples/playback/Makefile
 958 tests/examples/playrec/Makefile
 959 tests/files/Makefile
 960 tests/icles/Makefile
 961 tests/icles/playback/Makefile
 962 docs/Makefile
 963 docs/design/Makefile
 964 docs/libs/Makefile
 965 docs/plugins/Makefile
 966 docs/version.entities
 967 po/Makefile.in
 968 common/Makefile
 969 common/m4/Makefile
 970 m4/Makefile
 971 )
 972
 973 dnl Create the config.h file for Visual Studio builds
 974 dnl Beware of spaces and /'s in some of the shell variable contents.
 975 sed \
 976     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 977     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 978     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 979     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 980     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 981     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 982     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 983     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 984     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 985     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 986     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 987     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 988     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 989     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 990     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 991     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 992     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 993     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 994     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 995     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 996     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 997     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 998     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 999     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1000     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1001     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1002     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1003     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1004     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1005     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1006     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1007     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1008     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1009     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1010     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1011     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1012     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1013     config.h.in >win32/common/config.h-new
1014
1015
1016
1017 AC_OUTPUT
1018
1019 AG_GST_OUTPUT_PLUGINS
1020 ORC_OUTPUT
1021