configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT([GStreamer Ugly Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-ugly])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER(config.h)
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AS_LIBTOOL(GST, 2, 0, 2)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.1.0
  49 GSTPB_REQ=1.1.0
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION(0.17)
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101 AC_PROG_CC_STDC
 102
 103 dnl determine c++ compiler
 104 AC_PROG_CXX
 105 dnl determine if c++ is available on this system
 106 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 107
 108 dnl check if the compiler supports '-c' and '-o' options
 109 AM_PROG_CC_C_O
 110
 111 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 112 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 113
 114 dnl check if the compiler supports do while(0) macros
 115 AG_GST_CHECK_DOWHILE_MACROS
 116
 117 dnl check for documentation tools
 118 GTK_DOC_CHECK([1.12])
 119 AG_GST_PLUGIN_DOCS([1.12])
 120
 121 dnl *** checks for libraries ***
 122
 123 dnl check for libm, for sin()
 124 LT_LIB_M
 125 AC_SUBST(LIBM)
 126
 127 dnl *** checks for header files ***
 128
 129 dnl used by ext/a52dec
 130 AX_CREATE_STDINT_H
 131
 132 dnl Check for malloc.h
 133 AC_CHECK_HEADERS([malloc.h])
 134
 135 dnl *** checks for types/defines ***
 136
 137 dnl *** checks for structures ***
 138
 139 dnl *** checks for compiler characteristics ***
 140
 141 dnl *** checks for library functions ***
 142
 143 dnl Check for a way to display the function name in debug output
 144 AG_GST_CHECK_FUNCTION
 145
 146 dnl *** checks for dependency libraries ***
 147
 148 dnl GLib is required
 149 GLIB_REQ=2.32.0
 150 AG_GST_GLIB_CHECK([$GLIB_REQ])
 151
 152 ORC_CHECK([0.4.16])
 153
 154 dnl checks for gstreamer
 155 dnl uninstalled is selected preferentially -- see pkg-config(1)
 156 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 157 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 158 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 159 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 160 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 161
 162 dnl Check for documentation xrefs
 163 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 164 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 165 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 166 AC_SUBST(GLIB_PREFIX)
 167 AC_SUBST(GST_PREFIX)
 168 AC_SUBST(GSTPB_PREFIX)
 169
 170 dnl Needed by plugins that use g_module_*() API
 171 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 172
 173 dnl *** set variables based on configure arguments ***
 174
 175 dnl set license and copyright notice
 176 GST_LICENSE="LGPL"
 177 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 178 AC_SUBST(GST_LICENSE)
 179
 180 dnl set location of plugin directory
 181 AG_GST_SET_PLUGINDIR
 182
 183 dnl set release date/time
 184 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 185   ["${srcdir}/gst-plugins-ugly.doap"],
 186   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 187
 188 dnl define an ERROR_CFLAGS Makefile variable
 189 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 190     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 191     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 192     -Winit-self -Wmissing-include-dirs -Waddress
 193     -Waggregate-return -Wno-multichar -Wnested-externs ])
 194
 195 dnl define an ERROR_CXXFLAGS Makefile variable
 196 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 197     -Wmissing-declarations -Wredundant-decls
 198     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 199     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 200     -Wno-multichar])
 201
 202 dnl define correct level for debugging messages
 203 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 204
 205 dnl used in examples
 206 AG_GST_DEFAULT_ELEMENTS
 207
 208 dnl *** plug-ins to include ***
 209
 210 dnl Non ported plugins (non-dependant, then dependant)
 211 dnl Make sure you have a space before and after all plugins
 212 GST_PLUGINS_NONPORTED=" "
 213 AC_SUBST(GST_PLUGINS_NONPORTED)
 214
 215 dnl these are all the gst plug-ins, compilable without additional libs
 216 AG_GST_CHECK_PLUGIN(asfdemux)
 217 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 218 AG_GST_CHECK_PLUGIN(dvdsub)
 219 AG_GST_CHECK_PLUGIN(xingmux)
 220 AG_GST_CHECK_PLUGIN(realmedia)
 221
 222 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 223
 224 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 225   WIN32_LIBS="-lws2_32"
 226   AC_SUBST(WIN32_LIBS)
 227 fi
 228
 229 dnl *** ext plug-ins ***
 230 dnl keep this list sorted alphabetically !
 231
 232 if test "x$BUILD_EXTERNAL" = "xyes"; then
 233
 234 echo
 235 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 236 echo
 237
 238 dnl *** a52dec ***
 239 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 240 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 241   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 242 ])
 243
 244 dnl *** amr-nb ***
 245 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 246 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 247   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 248     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 249       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 250     fi
 251     HAVE_AMRNB="yes"
 252   ], [
 253     HAVE_AMRNB="no"
 254   ])
 255   AC_SUBST(AMRNB_CFLAGS)
 256   AC_SUBST(AMRNB_LIBS)
 257 ])
 258
 259 dnl *** amr-wb dec ***
 260 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 261 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 262   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 263     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 264       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 265     fi
 266     HAVE_AMRWB="yes"
 267   ], [
 268     HAVE_AMRWB="no"
 269   ])
 270   AC_SUBST(AMRWB_CFLAGS)
 271   AC_SUBST(AMRWB_LIBS)
 272 ])
 273
 274 dnl *** cdio ***
 275 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 276 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 277   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 278 ])
 279
 280 dnl *** dvdread ***
 281 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 282 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 283   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 284   AC_SUBST(DVDREAD_LIBS)
 285 ])
 286
 287 dnl *** lame ***
 288 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 289 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 290   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 291   [
 292     HAVE_LAME="yes"
 293     LAME_LIBS="-lmp3lame $LIBM"
 294     dnl is lame presets available
 295     LAME_CFLAGS=""
 296     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 297     ])
 298     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 299         void *ptr = &lame_set_VBR_quality
 300       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 301     ])
 302   AC_SUBST(LAME_CFLAGS)
 303   AC_SUBST(LAME_LIBS)
 304   ])
 305 ])
 306
 307 dnl *** mad ***
 308 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 309 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 310
 311   dnl check with pkg-config first
 312   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 313   MAD_LIBS="$MAD_LIBS"
 314   if test "x$HAVE_MAD" = "xno"; then
 315     dnl fall back to oldskool detection
 316     AC_CHECK_HEADER(mad.h, [
 317       AC_CHECK_LIB(mad, mad_decoder_finish,
 318         HAVE_MAD="yes" MAD_LIBS="-lmad")
 319     ])
 320   fi
 321 ])
 322 AC_SUBST(MAD_LIBS)
 323
 324 dnl *** mpeg2dec ***
 325 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 326 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 327   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 328 ])
 329
 330 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 331 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 332 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 333   GST_PATH_SIDPLAY()
 334 ])
 335
 336 dnl *** twolame ***
 337 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 338 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 339   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 340       HAVE_TWOLAME="yes"], [
 341       HAVE_TWOLAME="no"
 342   ])
 343   AC_SUBST(TWOLAME_CFLAGS)
 344   AC_SUBST(TWOLAME_LIBS)
 345 ])
 346
 347 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 348 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 349 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 350   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120.0)
 351 ])
 352
 353 else
 354
 355 dnl not building plugins with external dependencies,
 356 dnl but we still need to set the conditionals
 357
 358 AM_CONDITIONAL(USE_A52DEC, false)
 359 AM_CONDITIONAL(USE_AMRNB, false)
 360 AM_CONDITIONAL(USE_AMRWB, false)
 361 AM_CONDITIONAL(USE_CDIO, false)
 362 AM_CONDITIONAL(USE_DVDREAD, false)
 363 AM_CONDITIONAL(USE_LAME, false)
 364 AM_CONDITIONAL(USE_MAD, false)
 365 AM_CONDITIONAL(USE_MPEG2DEC, false)
 366 AM_CONDITIONAL(USE_SIDPLAY, false)
 367 AM_CONDITIONAL(USE_TWOLAME, false)
 368 AM_CONDITIONAL(USE_X264, false)
 369
 370 fi dnl of EXT plugins
 371
 372 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 373
 374 dnl Overview:
 375 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 376 dnl GST_*:              flags shared by built objects to link against GStreamer
 377 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 378 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 379 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 380 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 381
 382 dnl GST_OPTION_CFLAGS
 383 if test "x$USE_DEBUG" = xyes; then
 384    PROFILE_CFLAGS="-g"
 385 fi
 386 AC_SUBST(PROFILE_CFLAGS)
 387
 388 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 389   dnl Define _only_ during CVS (not pre-releases or releases)
 390   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 391 else
 392   DEPRECATED_CFLAGS=""
 393 fi
 394 AC_SUBST(DEPRECATED_CFLAGS)
 395
 396 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 397 dnl at make time with e.g. make ERROR_CFLAGS=""
 398 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 399 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 400 AC_SUBST(GST_OPTION_CFLAGS)
 401 AC_SUBST(GST_OPTION_CXXFLAGS)
 402
 403 dnl FIXME: do we want to rename to GST_ALL_* ?
 404 dnl prefer internal headers to already installed ones
 405 dnl also add builddir include for enumtypes and marshal
 406 dnl add GST_OPTION_CFLAGS, but overridable
 407 GST_CFLAGS="$GST_CFLAGS"
 408 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 409 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 410 AC_SUBST(GST_CFLAGS)
 411 AC_SUBST(GST_CXXFLAGS)
 412 AC_SUBST(GST_LIBS)
 413
 414 dnl LDFLAGS really should only contain flags, not libs - they get added before
 415 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 416 GST_ALL_LDFLAGS="-no-undefined"
 417 AC_SUBST(GST_ALL_LDFLAGS)
 418
 419 dnl this really should only contain flags, not libs - they get added before
 420 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 421 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 422 AC_SUBST(GST_PLUGIN_LDFLAGS)
 423
 424 dnl *** output files ***
 425
 426 AC_CONFIG_FILES(
 427 Makefile
 428 common/Makefile
 429 common/m4/Makefile
 430 gst-libs/Makefile
 431 gst-libs/gst/Makefile
 432 gst/Makefile
 433 gst/asfdemux/Makefile
 434 gst/dvdlpcmdec/Makefile
 435 gst/dvdsub/Makefile
 436 gst/realmedia/Makefile
 437 gst/xingmux/Makefile
 438 ext/Makefile
 439 ext/a52dec/Makefile
 440 ext/amrnb/Makefile
 441 ext/amrwbdec/Makefile
 442 ext/cdio/Makefile
 443 ext/dvdread/Makefile
 444 ext/lame/Makefile
 445 ext/mad/Makefile
 446 ext/mpeg2dec/Makefile
 447 ext/sidplay/Makefile
 448 ext/twolame/Makefile
 449 ext/x264/Makefile
 450 docs/Makefile
 451 docs/plugins/Makefile
 452 docs/version.entities
 453 tests/Makefile
 454 tests/check/Makefile
 455 m4/Makefile
 456 po/Makefile.in
 457 pkgconfig/Makefile
 458 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 459 gst-plugins-ugly.spec
 460 )
 461
 462 dnl Create the config.h file for Visual Studio builds
 463 dnl Beware of spaces and /'s in some of the shell variable contents.
 464 sed \
 465     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 466     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 467     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 468     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 469     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 470     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 471     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 472     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 473     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 474     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 475     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 476     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 477     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 478     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 479     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 480     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 481     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 482     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 483     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 484     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 485     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 486     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 487     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 488     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 489     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 490     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 491     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 492     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 493     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 494     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 495     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 496     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 497     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 498     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 499     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 500     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 501     config.h.in >win32/common/config.h-new
 502
 503 AC_OUTPUT
 504
 505 AG_GST_OUTPUT_PLUGINS
 506
 507 ORC_OUTPUT