configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.5.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 501, 0, 501)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84
  85 dnl subsystems - can influence other decisions so needs to be high up
  86 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  87 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  88 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  90 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  91 if test "x$GST_DISABLE_PARSE" = xyes; then
  92   AC_DEFINE(GST_DISABLE_PARSE, 1,
  93     [Define if pipeline parsing code is disabled])
  94 fi
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  96 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  97 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  98   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  99     [Define if option parsing is disabled])
 100 fi
 101 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 102 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 104 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 106 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 107 dnl define a substitution to use in docs/gst/gstreamer.types
 108 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 109 then
 110   GST_REGISTRY_DOC_TYPES="%"
 111 else
 112   GST_REGISTRY_DOC_TYPES=
 113 fi
 114 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 115 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 116 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 117
 118 AG_GST_ARG_DEBUG
 119 AG_GST_ARG_PROFILING
 120 AG_GST_ARG_VALGRIND
 121 AG_GST_ARG_GCOV
 122
 123 AG_GST_ARG_EXAMPLES
 124
 125 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 126 AG_GST_ARG_WITH_PACKAGE_NAME
 127 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 128
 129 AG_GST_PKG_CONFIG_PATH
 130
 131 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 132   ["${srcdir}/gstreamer.doap"],
 133   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 134
 135 dnl check for bash completion
 136 AC_ARG_WITH([bash-completion-dir],
 137     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 138         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 139     [],
 140     [with_bash_completion_dir=yes])
 141
 142 if test "x$with_bash_completion_dir" = "xyes"
 143 then
 144     extra_args=
 145
 146     if test "x$prefix" != "xNONE"
 147     then
 148         extra_args="--define-variable=prefix=\"$prefix\""
 149     fi
 150
 151     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 152         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 153         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 154     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 155         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 156         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 157 else
 158     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 159     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 160 fi
 161
 162 AC_SUBST([BASH_COMPLETION_DIR])
 163 AC_SUBST([BASH_HELPERS_DIR])
 164 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 165
 166 dnl build static plugins or not
 167 AC_MSG_CHECKING([whether to build static plugins or not])
 168 AC_ARG_ENABLE(
 169   static-plugins,
 170   AC_HELP_STRING(
 171     [--enable-static-plugins],
 172     [build static plugins @<:@default=no@:>@]),
 173   [AS_CASE(
 174     [$enableval], [no], [], [yes], [],
 175     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 176   [enable_static_plugins=no])
 177 AC_MSG_RESULT([$enable_static_plugins])
 178 if test "x$enable_static_plugins" = xyes; then
 179   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 180     [Define if static plugins should be built])
 181   GST_PLUGIN_LIBTOOLFLAGS=""
 182 else
 183   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 184 fi
 185 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 186 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 187
 188 dnl building of tests
 189 AC_ARG_ENABLE(tests,
 190   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 191   [
 192     case "${enableval}" in
 193       yes) BUILD_TESTS=yes ;;
 194       no)  BUILD_TESTS=no ;;
 195       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 196     esac
 197   ],
 198 [BUILD_TESTS=yes]) dnl Default value
 199 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 200
 201 dnl tests known to fail
 202 AC_ARG_ENABLE(failing-tests,
 203   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 204   [
 205     case "${enableval}" in
 206       yes) BUILD_FAILING_TESTS=yes ;;
 207       no)  BUILD_FAILING_TESTS=no ;;
 208       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 209     esac
 210   ],
 211   [BUILD_FAILING_TESTS=no]) dnl Default value
 212 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 213 if test x$BUILD_FAILING_TESTS = xyes; then
 214   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 215 else
 216   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 217 fi
 218
 219 dnl building of benchmarks
 220 AC_ARG_ENABLE(benchmarks,
 221   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 222   [
 223     case "${enableval}" in
 224       yes) BUILD_BENCHMARKS=yes ;;
 225       no)  BUILD_BENCHMARKS=no ;;
 226       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 227     esac
 228   ],
 229 [BUILD_BENCHMARKS=yes]) dnl Default value
 230 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 231
 232 dnl building of tools
 233 AC_ARG_ENABLE(tools,
 234   AS_HELP_STRING([--disable-tools],[disable building tools]),
 235   [
 236     case "${enableval}" in
 237       yes) BUILD_TOOLS=yes ;;
 238       no)  BUILD_TOOLS=no ;;
 239       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 240     esac
 241   ],
 242 [BUILD_TOOLS=yes]) dnl Default value
 243 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 244
 245 dnl poison destroyed objects
 246 AC_ARG_ENABLE(poisoning,
 247   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 248   [
 249     case "${enableval}" in
 250       yes) USE_POISONING=yes ;;
 251       no)  USE_POISONING=no ;;
 252       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 253     esac
 254   ],
 255   [USE_POISONING=no]) dnl Default value
 256 if test "x$USE_POISONING" = xyes; then
 257   AC_DEFINE(USE_POISONING, 1,
 258     [Define if we should poison deallocated memory])
 259 fi
 260
 261 dnl PTP support parts
 262 AC_MSG_CHECKING([whether PTP support can be enabled])
 263 case "$host_os" in
 264   *android*)
 265     dnl Can't run on Android because of permissions
 266     HAVE_PTP=no
 267     ;;
 268   mingw*|pw32*|cygwin*)
 269     dnl Not ported to Windows yet
 270     HAVE_PTP=no
 271     ;;
 272   darwin*)
 273     dnl Can't run on iOS because of permissions
 274     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 275     ;;
 276   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 277     HAVE_PTP=yes
 278     ;;
 279   *)
 280     HAVE_PTP=no
 281     ;;
 282 esac
 283 AC_MSG_RESULT([$HAVE_PTP])
 284
 285 dnl user/group to change to in gst-ptp-helper
 286 AC_ARG_WITH([ptp-helper-setuid-user],
 287   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 288   [
 289     if test "x$withval" != "x"
 290     then
 291       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 292     fi
 293   ], []
 294 )
 295
 296 dnl group/group to change to in gst-ptp-helper
 297 AC_ARG_WITH([ptp-helper-setuid-group],
 298   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 299   [
 300     if test "x$withval" != "x"
 301     then
 302       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 303     fi
 304   ], []
 305 )
 306
 307 AC_ARG_WITH(
 308   ptp-helper-permissions,
 309   AC_HELP_STRING(
 310     [--with-ptp-helper-permissions],
 311     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 312     [],
 313     [with_ptp_helper_permissions=auto])
 314
 315 gst_ptp_have_cap=no
 316 AG_GST_CHECK_LIBHEADER(CAP, cap,
 317                        cap_init, ,
 318                        sys/capability.h,
 319                        CAP_LIBS="-lcap"
 320                        AC_SUBST(CAP_LIBS)
 321                        gst_ptp_have_cap=yes)
 322
 323 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 324
 325 if test "x$HAVE_PTP" = "xyes"; then
 326 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 327
 328 AC_MSG_CHECKING([how to install gst-ptp-helper])
 329 if test "x$with_ptp_helper_permissions" = "xauto"; then
 330     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 331         with_ptp_helper_permissions="capabilities"
 332     else
 333         with_ptp_helper_permissions="setuid-root"
 334     fi
 335 fi
 336 AC_MSG_RESULT([$with_ptp_helper_permissions])
 337
 338 case "$with_ptp_helper_permissions" in
 339   none)
 340     ;;
 341   setuid-root)
 342      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 343         [Use setuid-root for permissions in PTP helper])
 344     ;;
 345   capabilities)
 346      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 347         [Use capabilities for permissions in PTP helper])
 348     ;;
 349   *)
 350     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 351     ;;
 352 esac
 353
 354 fi
 355
 356 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 357 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 358 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 359
 360 dnl *** checks for platform ***
 361
 362 dnl * hardware/architecture *
 363
 364 dnl common/m4/gst-arch.m4
 365 dnl check CPU type
 366 AG_GST_ARCH
 367 dnl substitution for win32/common/config.h
 368 HOST_CPU=$host_cpu
 369 AC_SUBST(HOST_CPU)
 370
 371 dnl common/m4/gst-arch.m4
 372 dnl check for unaligned access
 373 AG_GST_UNALIGNED_ACCESS
 374 dnl create a configure variable for gst/gstconfig.h
 375 if test x${as_cv_unaligned_access} = xyes ; then
 376   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 377 else
 378   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 379 fi
 380 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 381
 382 dnl check for platform specific settings
 383 AG_GST_PLATFORM
 384
 385 dnl * software *
 386
 387 dnl check for large file support
 388 dnl affected plugins must include config.h
 389 AC_SYS_LARGEFILE
 390
 391 dnl *** checks for programs ***
 392
 393 dnl find a compiler
 394 AC_PROG_CC
 395 AC_PROG_CC_STDC
 396
 397 dnl check if the compiler supports '-c' and '-o' options
 398 AM_PROG_CC_C_O
 399
 400 dnl find an assembler
 401 AM_PROG_AS
 402
 403 dnl determine if c++ is available on this system
 404 AC_PROG_CXX
 405 dnl CXX may be set to some default even if no c++ compiler is available
 406 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 407 AC_LANG_PUSH([C++])
 408 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 409 AC_LANG_POP([C++])
 410 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 411 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 412
 413 dnl Perl is used in building documentation and in the version checks
 414 AC_PATH_PROG(PERL_PATH, perl, no)
 415 if test x$PERL_PATH = xno; then
 416   AC_MSG_ERROR(Could not find perl)
 417 fi
 418
 419 dnl we require flex and bison for building the parser
 420 if test "x$GST_DISABLE_PARSE" != xyes; then
 421   AG_GST_BISON_CHECK
 422   AG_GST_FLEX_CHECK
 423 fi
 424
 425 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 426 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 427
 428 dnl check for gobject-introspection
 429 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 430
 431 dnl check for documentation tools
 432 AG_GST_DOCBOOK_CHECK
 433 GTK_DOC_CHECK([1.12])
 434 AG_GST_PLUGIN_DOCS([1.12])
 435
 436 dnl *** checks for libraries ***
 437
 438 dnl check for libm, for sin()
 439 LT_LIB_M
 440 AC_SUBST(LIBM)
 441
 442 dnl *** checks for header files ***
 443
 444 dnl check if we have ANSI C header files
 445 AC_HEADER_STDC
 446
 447 dnl Check for ucontext.h
 448 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 449
 450 dnl Check for sys/socket.h
 451 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 452 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 453
 454 dnl check for sys/times.h for tests/examples/adapter/
 455 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 456 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 457 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 458
 459 dnl Check for process.h for getpid() on win32
 460 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 461
 462 dnl Check for sys/utsname.h for uname
 463 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 464
 465 dnl Check for stdio_ext.f for __fbufsize
 466 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 467
 468 dnl check for pthreads
 469 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 470 dnl which later checks use in their test code
 471 AX_PTHREAD()
 472 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 473
 474 dnl check for sys/prctl for setting thread name on Linux
 475 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 476
 477 dnl check for pthread_setname_np(const char*)
 478 dnl which is present on OS X 10.6, iOS 3.2 and above
 479 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 480 AC_LINK_IFELSE(
 481     [AC_LANG_PROGRAM(
 482         [#include <pthread.h>],
 483         [pthread_setname_np("example")])],
 484     [AC_MSG_RESULT(yes)
 485      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 486         [Have function pthread_setname_np(const char*)])],
 487     [AC_MSG_RESULT(no)])
 488
 489 dnl check for sys/uio.h for writev()
 490 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 491
 492 dnl Check for valgrind.h
 493 dnl separate from HAVE_VALGRIND because you can have the program, but not
 494 dnl the dev package
 495 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 496
 497 dnl used in gst/gstpoll.c
 498 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 499 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 500 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 501   WIN32_LIBS="-lws2_32"
 502   AC_SUBST(WIN32_LIBS)
 503 fi
 504
 505 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 506 if test "x$BUILD_TESTS" = "xyes"; then
 507   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 508                          __gmpz_init_set_d, ,
 509                          gmp.h,
 510                          GMP_LIBS="-lgmp"
 511                          AC_SUBST(GMP_LIBS)
 512                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 513   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 514                          gsl_rng_uniform_int, -lgslcblas,
 515                          gsl/gsl_rng.h,
 516                          GSL_LIBS="-lgsl -lgslcblas"
 517                          AC_SUBST(GSL_LIBS)
 518                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 519 fi
 520
 521 dnl *** checks for types/defines ***
 522
 523 dnl *** checks for structures ***
 524
 525 dnl *** checks for compiler characteristics ***
 526
 527 dnl check if the compiler supports __uint128_t (gcc)
 528 dnl Actually check for 128-bit division, since that's what we use
 529 dnl uint128_t for.
 530 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 531     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 532       static __uint128_t v1 = 100;
 533       static __uint128_t v2 = 10;
 534       static __uint128_t u;
 535       u = v1 / v2;
 536     ]])],[
 537       gst_cv_uint128_t=yes
 538     ],[
 539       gst_cv_uint128_t=no
 540     ])
 541 )
 542 if test x$gst_cv_uint128_t = xyes; then
 543   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 544 fi
 545
 546 dnl *** checking for tm_gmtoff ***
 547 AC_MSG_CHECKING([for tm_gmtoff])
 548 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 549         #include <time.h>
 550         int main(void) {
 551           struct tm t;
 552           t.tm_gmtoff = 0;
 553           exit(0);
 554         }]])],
 555   [have_tm_gmtoff=yes
 556    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 557   [have_tm_gmtoff=no],
 558   [have_tm_gmtoff="no (cross compiling)"])
 559 AC_MSG_RESULT($have_tm_gmtoff)
 560
 561
 562 dnl *** checks for library functions ***
 563
 564 AC_CHECK_FUNCS([strcasestr])
 565
 566 AC_CHECK_FUNCS([gmtime_r])
 567 AC_CHECK_FUNCS([localtime_r])
 568 AC_CHECK_FUNCS([sigaction])
 569
 570 dnl check for fseeko()
 571 AC_FUNC_FSEEKO
 572 dnl check for ftello()
 573 AC_CHECK_FUNCS([ftello])
 574
 575 AC_CHECK_FUNCS([fgetpos])
 576 AC_CHECK_FUNCS([fsetpos])
 577
 578 dnl check for poll(), ppoll() and pselect()
 579 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 580 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 581 AC_CHECK_FUNCS([poll])
 582 AC_CHECK_FUNCS([ppoll])
 583 AC_CHECK_FUNCS([pselect])
 584
 585 dnl ****************************************
 586 dnl *** GLib POLL* compatibility defines ***
 587 dnl ****************************************
 588
 589 AC_MSG_CHECKING([for broken poll])
 590 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 591         #include <stdlib.h>
 592         #include <fcntl.h>
 593         #ifdef HAVE_SYS_POLL_H
 594         #include <sys/poll.h>
 595         #endif
 596         #ifdef HAVE_POLL_H
 597         #include <poll.h>
 598         #endif
 599         int main(void) {
 600           struct pollfd fds[1];
 601           int fd;
 602           fd = open("/dev/null", 1);
 603           fds[0].fd = fd;
 604           fds[0].events = POLLIN;
 605           fds[0].revents = 0;
 606           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 607                 exit(1);  /* Does not work for devices -- fail */
 608           }
 609           exit(0);
 610         }]])],
 611   [broken_poll=no],
 612   [broken_poll=yes
 613    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 614   [broken_poll="no (cross compiling)"])
 615 AC_MSG_RESULT($broken_poll)
 616
 617 dnl check for mmap()
 618 AC_FUNC_MMAP
 619 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 620
 621 dnl check for posix_memalign(), getpagesize()
 622 AC_CHECK_FUNCS([posix_memalign])
 623 AC_CHECK_FUNCS([getpagesize])
 624
 625 dnl Check for POSIX timers
 626 AC_CHECK_FUNCS(clock_gettime, [], [
 627   AC_CHECK_LIB(rt, clock_gettime, [
 628     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 629     LIBS="$LIBS -lrt"
 630   ], [
 631     AC_CHECK_LIB(pthread, clock_gettime, [
 632       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 633       LIBS="$LIBS -lpthread"
 634     ])
 635   ])
 636 ])
 637
 638 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 639     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 640 #include <time.h>
 641 #ifdef HAVE_UNISTD_H
 642 #include <unistd.h>
 643 #endif
 644     ]], [[
 645 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 646 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 647 #endif
 648     ]])],[
 649       gst_cv_posix_timers=yes
 650     ],[
 651       gst_cv_posix_timers=no
 652     ])
 653 )
 654
 655 if test "$gst_cv_posix_timers" = "yes"; then
 656   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 657   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 658 else
 659   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 660 fi
 661 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 662 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 663
 664 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 665     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 666 #include <time.h>
 667 #ifdef HAVE_UNISTD_H
 668 #include <unistd.h>
 669 #endif
 670     ]], [[
 671 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 672 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 673 #endif
 674     ]])],[
 675       gst_cv_monotonic_clock=yes
 676     ],[
 677       gst_cv_monotonic_clock=no
 678     ])
 679 )
 680
 681 if test "$gst_cv_monotonic_clock" = "yes"; then
 682   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 683   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 684 else
 685   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 686 fi
 687 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 688 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 689
 690 dnl Check for a way to display the function name in debug output
 691 AG_GST_CHECK_FUNCTION
 692
 693 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 694 save_cflags="$CFLAGS"
 695 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 696 AC_CHECK_LIB(dl, dladdr,
 697    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 698    LIBS="$LIBS -ldl")
 699 CFLAGS="$save_cflags"
 700
 701 dnl Check printf stuff
 702 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 703   AC_TYPE_LONG_LONG_INT
 704   AC_TYPE_UNSIGNED_LONG_LONG_INT
 705
 706   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 707     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 708   fi
 709
 710   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 711   gl_AC_HEADER_INTTYPES_H
 712
 713   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 714   gl_AC_HEADER_STDINT_H
 715
 716   AC_CHECK_TYPES(ptrdiff_t)
 717
 718   AC_TYPE_INTMAX_T
 719   AC_TYPE_SIZE_T
 720 fi
 721
 722 dnl *** checks for dependency libraries ***
 723
 724 dnl GLib
 725 GLIB_REQ=2.32.0
 726 AG_GST_GLIB_CHECK([$GLIB_REQ])
 727
 728 dnl Check for documentation xrefs
 729 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 730 AC_SUBST(GLIB_PREFIX)
 731
 732 dnl building of unit test libraries
 733 AC_ARG_ENABLE(check,
 734   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 735   [
 736     case "${enableval}" in
 737       yes) BUILD_CHECK=yes ;;
 738       no)  BUILD_CHECK=no ;;
 739       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 740     esac
 741   ], [
 742     dnl Default value
 743     case $host_os in
 744       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 745       *) BUILD_CHECK=yes ;;
 746     esac
 747 ])
 748 dnl bit of a misnomer, but keep the conditional named like this so we don't
 749 dnl have to change too much elsewhere
 750 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 751
 752 dnl configure the desired memory alignment
 753 AC_ARG_WITH([memory-alignment],
 754   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 755   [
 756     if test "x$withval" = "xyes"
 757     then
 758       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 759     else
 760       case "${withval}" in
 761         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 762         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 763         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 764       esac
 765     fi
 766   ], [
 767     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 768   ]
 769 )
 770
 771 dnl Check for -Bsymbolic-functions linker flag used to avoid
 772 dnl intra-library PLT jumps, if available.
 773 AC_ARG_ENABLE(Bsymbolic,
 774               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 775               [SAVED_LDFLAGS="${LDFLAGS}"
 776                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 777                LDFLAGS=-Wl,-Bsymbolic-functions
 778                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 779                            AC_MSG_RESULT(yes)
 780                            enable_Bsymbolic=yes],[
 781                            AC_MSG_RESULT(no)
 782                            enable_Bsymbolic=no])
 783                LDFLAGS="${SAVED_LDFLAGS}"])
 784
 785
 786 dnl *** set variables based on configure arguments
 787
 788 dnl set license and copyright notice
 789 GST_LICENSE="LGPL"
 790 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 791 AC_SUBST(GST_LICENSE)
 792
 793 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 794 AS_AC_EXPAND(LIBDIR, $libdir)
 795 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 796 AS_AC_EXPAND(DATADIR, $datadir)
 797 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 798
 799 dnl set location of plugin directory
 800 AG_GST_SET_PLUGINDIR
 801
 802 dnl make sure it doesn't complain about unused variables if debugging is disabled
 803 NO_WARNINGS=""
 804 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 805   NO_WARNINGS="-Wno-unused"
 806 fi
 807
 808 dnl define an ERROR_CFLAGS Makefile variable
 809 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 810
 811 dnl special warning flags for gst/printf
 812 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 813 AC_SUBST(PRINTF_CFLAGS)
 814
 815 dnl define correct level for debugging messages
 816 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 817
 818 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 819
 820 dnl Overview:
 821 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 822 dnl GST_ALL_*:          vars shared by all built objects
 823 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 824 dnl GST_OBJ_*:          additional vars to link to the core library
 825 dnl                     include GST_ALL_*
 826 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 827 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 828
 829 dnl GST_OPTION_CFLAGS
 830 if test "x$USE_DEBUG" = xyes; then
 831    PROFILE_CFLAGS="-g"
 832 fi
 833 AC_SUBST(PROFILE_CFLAGS)
 834
 835 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 836 # functionality from the API that gstreamer uses
 837 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 838 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 839   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 840   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 841 else
 842   DEPRECATED_CFLAGS=""
 843 fi
 844 AC_SUBST(DEPRECATED_CFLAGS)
 845
 846 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 847 dnl make DEPRECATED_CFLAGS=''
 848 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 849 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 850 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 851 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 852 AC_SUBST(GST_OPTION_CFLAGS)
 853 AC_SUBST(GST_OPTION_CXXFLAGS)
 854
 855 dnl GST_ALL_*
 856 dnl vars common to for all internal objects (core libs, elements, applications)
 857 dnl CFLAGS:
 858 dnl - src and build dirs need to be added because every piece that gets built
 859 dnl   will need the GStreamer source and generated headers
 860 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 861 dnl       from LibXML except for in the core library
 862 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 863 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 864
 865 dnl FIXME: check if LTLIBINTL is needed everywhere
 866 dnl I presume it is given that it contains the symbols that _() stuff maps to
 867 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 868
 869 dnl LDFLAGS really should only contain flags, not libs - they get added before
 870 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 871 GST_ALL_LDFLAGS="-no-undefined"
 872 if test "x${enable_Bsymbolic}" = "xyes"; then
 873   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 874 fi
 875
 876 AC_SUBST(GST_ALL_CFLAGS)
 877 AC_SUBST(GST_ALL_CXXFLAGS)
 878 AC_SUBST(GST_ALL_LIBS)
 879 AC_SUBST(GST_ALL_LDFLAGS)
 880
 881 dnl GST_LIB_LDFLAGS
 882 dnl linker flags shared by all libraries
 883 dnl LDFLAGS modifier defining exported symbols from built libraries
 884 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 885 AC_SUBST(GST_LIB_LDFLAGS)
 886
 887 dnl GST_OBJ_*
 888 dnl default vars for all internal objects built on libgstreamer
 889 dnl includes GST_ALL_*
 890 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 891 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 892 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 893 AC_SUBST(GST_OBJ_CFLAGS)
 894 AC_SUBST(GST_OBJ_CXXFLAGS)
 895 AC_SUBST(GST_OBJ_LIBS)
 896
 897 dnl GST_PLUGIN_LDFLAGS
 898 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 899 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 900 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 901
 902 dnl plugin scanner locations
 903 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 904 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 905     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 906 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 907
 908 dnl ptp helper locations
 909 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
 910 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
 911     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
 912 AC_SUBST(GST_PTP_HELPER_INSTALLED)
 913
 914 dnl things for our internal libcheck (must be called even if building
 915 dnl libcheck is disabled because it defines conditionals)
 916 AG_GST_CHECK_CHECKS()
 917
 918 AC_CONFIG_FILES(
 919 Makefile
 920 data/Makefile
 921 gst/Makefile
 922 gst/gstconfig.h
 923 gst/gstversion.h
 924 gst/parse/Makefile
 925 gst/printf/Makefile
 926 libs/Makefile
 927 libs/gst/Makefile
 928 libs/gst/base/Makefile
 929 libs/gst/check/Makefile
 930 libs/gst/check/libcheck/Makefile
 931 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
 932 libs/gst/controller/Makefile
 933 libs/gst/helpers/Makefile
 934 libs/gst/net/Makefile
 935 plugins/Makefile
 936 plugins/elements/Makefile
 937 po/Makefile.in
 938 tests/Makefile
 939 tests/benchmarks/Makefile
 940 tests/check/Makefile
 941 tests/misc/Makefile
 942 tests/examples/Makefile
 943 tests/examples/adapter/Makefile
 944 tests/examples/controller/Makefile
 945 tests/examples/stepping/Makefile
 946 tests/examples/helloworld/Makefile
 947 tests/examples/manual/Makefile
 948 tests/examples/memory/Makefile
 949 tests/examples/netclock/Makefile
 950 tests/examples/ptp/Makefile
 951 tests/examples/streamiddemux/Makefile
 952 tests/examples/streams/Makefile
 953 tools/Makefile
 954 common/Makefile
 955 common/m4/Makefile
 956 docs/Makefile
 957 docs/design/Makefile
 958 docs/faq/Makefile
 959 docs/gst/Makefile
 960 docs/gst/gstreamer.types
 961 docs/libs/Makefile
 962 docs/plugins/Makefile
 963 docs/manual/Makefile
 964 docs/pwg/Makefile
 965 docs/slides/Makefile
 966 docs/xsl/Makefile
 967 docs/version.entities
 968 m4/Makefile
 969 pkgconfig/Makefile
 970 stamp.h
 971 pkgconfig/gstreamer.pc
 972 pkgconfig/gstreamer-uninstalled.pc
 973 pkgconfig/gstreamer-base.pc
 974 pkgconfig/gstreamer-base-uninstalled.pc
 975 pkgconfig/gstreamer-check.pc
 976 pkgconfig/gstreamer-check-uninstalled.pc
 977 pkgconfig/gstreamer-controller.pc
 978 pkgconfig/gstreamer-controller-uninstalled.pc
 979 pkgconfig/gstreamer-net.pc
 980 pkgconfig/gstreamer-net-uninstalled.pc
 981 gstreamer.spec
 982 )
 983
 984 dnl Create the config.h file for Visual Studio builds
 985 dnl Beware of spaces and /'s in some of the shell variable contents.
 986 sed \
 987     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 988     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 989     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 990     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 991     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 992     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 993     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 994     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 995     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 996     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 997     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 998     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 999     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1000     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1001     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1002     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1003     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1004     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1005     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1006     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1007     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
1008     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1009     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1010     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
1011     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1012     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
1013     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1014     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1015     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1016     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
1017     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
1018     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1019     config.h.in >win32/common/config.h-new
1020
1021 AC_OUTPUT
1022
1023 dnl negate for output
1024 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1025 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1026 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1027 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
1028 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
1029 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1030 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1031
1032 echo "
1033
1034 Configuration
1035         Version                    : ${VERSION}
1036         Source code location       : ${srcdir}
1037         Prefix                     : ${prefix}
1038         Compiler                   : ${CC}
1039         Package name               : ${GST_PACKAGE_NAME}
1040         Package origin             : ${GST_PACKAGE_ORIGIN}
1041
1042         Documentation (manuals)    : ${enable_docbook}
1043         Documentation (API)        : ${enable_gtk_doc}
1044
1045         Debug Logging              : ${enable_gst_debug}
1046         Command-line parser        : ${enable_parse}
1047         Option parsing in gst_init : ${enable_option_parsing}
1048         Tracing subsystem          : ${enable_trace}
1049         Allocation tracing         : ${enable_alloc_trace}
1050         Plugin registry            : ${enable_registry}
1051         Plugin support             : ${enable_plugin}
1052         Static plugins             : ${enable_static_plugins}
1053         Unit testing support       : ${BUILD_CHECK}
1054         PTP clock support          : ${HAVE_PTP}
1055
1056         Debug                      : ${USE_DEBUG}
1057         Profiling                  : ${USE_PROFILING}
1058
1059         Building benchmarks        : ${BUILD_BENCHMARKS}
1060         Building examples          : ${BUILD_EXAMPLES}
1061         Building test apps         : ${BUILD_TESTS}
1062         Building tests that fail   : ${BUILD_FAILING_TESTS}
1063         Building tools             : ${BUILD_TOOLS}
1064 "