configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(Gst-RTSP, 0.10.0.1,
   7     http://gstreamer.net/,
   8     gst-rtsp)
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_CVS="no", GST_CVS="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl our libraries and install dirs use major.minor as a version
  32 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  33 dnl we override it here if we need to for the release candidate of new series
  34 GST_MAJORMINOR=0.10
  35 AC_SUBST(GST_MAJORMINOR)
  36
  37 AM_PROG_LIBTOOL
  38
  39 dnl *** required versions of GStreamer stuff ***
  40 GST_REQ=0.10.20
  41 GSTPB_REQ=0.10.20
  42
  43 dnl export for .pc files
  44 AC_SUBST([GST_REQ])
  45 AC_SUBST([GSTPB_REQ])
  46
  47 dnl *** autotools stuff ****
  48
  49 dnl allow for different autotools
  50 AS_AUTOTOOLS_ALTERNATE
  51
  52 dnl Add parameters for aclocal
  53 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  54
  55 dnl *** check for arguments to configure ***
  56
  57 AG_GST_ARG_DEBUG
  58 AG_GST_ARG_VALGRIND
  59 AG_GST_ARG_GCOV
  60 AG_GST_ARG_WITH_PACKAGE_NAME
  61 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  62
  63 dnl *** checks for platform ***
  64
  65 dnl * hardware/architecture *
  66
  67 dnl *** checks for programs ***
  68
  69 dnl find a compiler
  70 AC_PROG_CC
  71
  72 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  73 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  74
  75 dnl check for documentation tools
  76 AG_GST_DOCBOOK_CHECK
  77 GTK_DOC_CHECK([1.3])
  78
  79 dnl GTK is optional and used in examples
  80 HAVE_GTK=NO
  81 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
  82 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
  83
  84 dnl *** checks for libraries ***
  85
  86 dnl *** checks for header files ***
  87
  88 dnl *** checks for types/defines ***
  89
  90 dnl *** checks for structures ***
  91
  92 dnl *** checks for compiler characteristics ***
  93
  94 dnl *** checks for library functions ***
  95
  96 dnl *** checks for dependancy libraries ***
  97
  98 dnl GLib is required (GStreamer is ok with GLib-2.8, but we want at least 2.10)
  99 GLIB_REQ=2.10.0
 100 AC_SUBST([GLIB_REQ])
 101 AG_GST_GLIB_CHECK([$GLIB_REQ])
 102
 103 dnl checks for gstreamer
 104 dnl uninstalled is selected preferentially -- see pkg-config(1)
 105 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 106
 107 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 108 if test -z $GST_TOOLS_DIR; then
 109   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 110 fi
 111 AC_SUBST(GST_TOOLS_DIR)
 112
 113 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 114 AC_SUBST(GST_PLUGINS_DIR)
 115 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 116
 117 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 118
 119 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 120 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 121 AC_SUBST(GSTPB_PLUGINS_DIR)
 122 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 123
 124 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 125
 126 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 127 dnl check for "check", unit testing library/header
 128 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 129 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 130
 131 dnl *** set variables based on configure arguments ***
 132
 133 dnl set license and copyright notice
 134 GST_LICENSE="LGPL"
 135 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 136 AC_SUBST(GST_LICENSE)
 137
 138 dnl set location of plugin directory
 139 AG_GST_SET_PLUGINDIR
 140
 141 dnl define an ERROR_CFLAGS Makefile variable
 142 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 143
 144 dnl define correct level for debugging messages
 145 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 146
 147 dnl used in examples
 148 AG_GST_DEFAULT_ELEMENTS
 149
 150 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 151
 152 dnl Overview:
 153 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 154 dnl GST_*:              flags shared by built objects to link against GStreamer
 155 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 156 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 157 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 158 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 159
 160 dnl GST_OPTION_CFLAGS
 161 if test "x$USE_DEBUG" = xyes; then
 162    PROFILE_CFLAGS="-g"
 163 fi
 164 AC_SUBST(PROFILE_CFLAGS)
 165
 166 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 167 AC_SUBST(DEPRECATED_CFLAGS)
 168
 169 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 170 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 171 AC_SUBST(GST_OPTION_CFLAGS)
 172
 173 dnl FIXME: do we want to rename to GST_ALL_* ?
 174 dnl prefer internal headers to already installed ones
 175 dnl add GST_OPTION_CFLAGS, but overridable
 176 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 177 AC_SUBST(GST_CFLAGS)
 178 AC_SUBST(GST_LIBS)
 179
 180 dnl GST_ALL_*
 181 dnl vars common to for all internal objects (core libs, elements, applications)
 182 dnl CFLAGS:
 183 dnl - src and build dirs need to be added because every piece that gets built
 184 dnl   will need the GStreamer source and generated headers
 185 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 186 AC_SUBST([GST_ALL_CFLAGS])
 187
 188 dnl FIXME: check if LTLIBINTL is needed everywhere
 189 dnl I presume it is given that it contains the symbols that _() stuff maps to
 190 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 191 AC_SUBST([GST_ALL_LIBS])
 192
 193 dnl LDFLAGS really should only contain flags, not libs - they get added before
 194 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 195 GST_ALL_LDFLAGS="-no-undefined"
 196 AC_SUBST(GST_ALL_LDFLAGS)
 197
 198 dnl GST_OBJ_*
 199 dnl default vars for all internal objects built on libgstphonon
 200 dnl includes GST_ALL_*
 201 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 202 AC_SUBST([GST_OBJ_CFLAGS])
 203 GST_OBJ_LIBS="\$(top_builddir)/gst-phonon/libgstphonon.la \$(GST_ALL_LIBS)"
 204 AC_SUBST([GST_OBJ_LIBS])
 205
 206 dnl this really should only contain flags, not libs - they get added before
 207 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 208
 209 dnl *** output files ***
 210
 211 dnl keep this alphabetic per directory, please
 212 AC_CONFIG_FILES([
 213 Makefile
 214 gst-rtsp.spec
 215 common/Makefile
 216 common/m4/Makefile
 217 m4/Makefile
 218 gst/Makefile
 219 gst/rtsp-server/Makefile
 220 examples/Makefile
 221 bindings/Makefile
 222 bindings/python/Makefile
 223 bindings/python/codegen/Makefile
 224 pkgconfig/Makefile
 225 pkgconfig/gst-rtsp-server.pc
 226 ])
 227 AC_OUTPUT
 228
 229 echo "Gst-rtsp-server configured. Type 'make' to build."