configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.11.92,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE([enable])
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl GStreamer versioning, this is mostly informational
  38 dnl GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  39 dnl GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  40 dnl GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  41 dnl GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  42 dnl Change this to the above for non-pre
  43 GST_VERSION_MAJOR=1
  44 GST_VERSION_MINOR=0
  45 GST_VERSION_MICRO=0
  46 GST_VERSION_NANO=0
  47 AC_SUBST(GST_VERSION_MAJOR)
  48 AC_SUBST(GST_VERSION_MINOR)
  49 AC_SUBST(GST_VERSION_MICRO)
  50 AC_SUBST(GST_VERSION_NANO)
  51
  52 dnl our libraries and install dirs use GST_API_VERSION in the filename
  53 dnl to allow side-by-side installation of different API versions
  54 GST_API_VERSION=1.0
  55 AC_SUBST(GST_API_VERSION)
  56 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  57   [GStreamer API Version])
  58
  59 dnl CURRENT, REVISION, AGE
  60 dnl - library source changed -> increment REVISION
  61 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  62 dnl - interfaces added -> increment AGE
  63 dnl - interfaces removed -> AGE = 0
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 0, 0, 0)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84
  85 dnl subsystems - can influence other decisions so needs to be high up
  86 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  87 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  88 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  90 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  91 if test "x$GST_DISABLE_PARSE" = xyes; then
  92   AC_DEFINE(GST_DISABLE_PARSE, 1,
  93     [Define if pipeline parsing code is disabled])
  94 fi
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  96 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  97 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  98   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  99     [Define if option parsing is disabled])
 100 fi
 101 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 102 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 104 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 106 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 107 dnl define a substitution to use in docs/gst/gstreamer.types
 108 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 109 then
 110   GST_REGISTRY_DOC_TYPES="%"
 111 else
 112   GST_REGISTRY_DOC_TYPES=
 113 fi
 114 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 115 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 116 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 117
 118 AG_GST_ARG_DEBUG
 119 AG_GST_ARG_PROFILING
 120 AG_GST_ARG_VALGRIND
 121 AG_GST_ARG_GCOV
 122
 123 AG_GST_ARG_EXAMPLES
 124
 125 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 126 AG_GST_ARG_WITH_PACKAGE_NAME
 127 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 128
 129 AG_GST_PKG_CONFIG_PATH
 130
 131 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 132   ["${srcdir}/gstreamer.doap"],
 133   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 134
 135 dnl building of tests
 136 AC_ARG_ENABLE(tests,
 137   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 138   [
 139     case "${enableval}" in
 140       yes) BUILD_TESTS=yes ;;
 141       no)  BUILD_TESTS=no ;;
 142       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 143     esac
 144   ],
 145 [BUILD_TESTS=yes]) dnl Default value
 146 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 147
 148 dnl tests known to fail
 149 AC_ARG_ENABLE(failing-tests,
 150   AC_HELP_STRING([--disable-failing-tests],
 151     [disable building tests known to fail]),
 152   [
 153     case "${enableval}" in
 154       yes) BUILD_FAILING_TESTS=yes ;;
 155       no)  BUILD_FAILING_TESTS=no ;;
 156       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 157     esac
 158   ],
 159   [BUILD_FAILING_TESTS=no]) dnl Default value
 160 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 161 if test x$BUILD_FAILING_TESTS = xyes; then
 162   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 163 else
 164   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 165 fi
 166
 167 dnl poison destroyed objects
 168 AC_ARG_ENABLE(poisoning,
 169   AC_HELP_STRING([--enable-poisoning],
 170     [enable poisoning of deallocated objects]),
 171   [
 172     case "${enableval}" in
 173       yes) USE_POISONING=yes ;;
 174       no)  USE_POISONING=no ;;
 175       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 176     esac
 177   ],
 178   [USE_POISONING=no]) dnl Default value
 179 if test "x$USE_POISONING" = xyes; then
 180   AC_DEFINE(USE_POISONING, 1,
 181     [Define if we should poison deallocated memory])
 182 fi
 183
 184 dnl *** checks for platform ***
 185
 186 dnl * hardware/architecture *
 187
 188 dnl common/m4/gst-arch.m4
 189 dnl check CPU type
 190 AG_GST_ARCH
 191 dnl substitution for win32/common/config.h
 192 HOST_CPU=$host_cpu
 193 AC_SUBST(HOST_CPU)
 194
 195 dnl common/m4/gst-arch.m4
 196 dnl check for unaligned access
 197 AG_GST_UNALIGNED_ACCESS
 198 dnl create a configure variable for gst/gstconfig.h
 199 if test x${as_cv_unaligned_access} = xyes ; then
 200   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 201 else
 202   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 203 fi
 204 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 205
 206 dnl check for platform specific settings
 207 AG_GST_PLATFORM
 208
 209 dnl * software *
 210
 211 dnl check for large file support
 212 dnl affected plugins must include config.h
 213 AC_SYS_LARGEFILE
 214
 215 dnl *** checks for programs ***
 216
 217 dnl find a compiler
 218 AC_PROG_CC
 219 AC_PROG_CC_STDC
 220
 221 dnl check if the compiler supports '-c' and '-o' options
 222 AM_PROG_CC_C_O
 223
 224 dnl find an assembler
 225 AM_PROG_AS
 226
 227 dnl determine if c++ is available on this system
 228 AC_PROG_CXX
 229 dnl CXX may be set to some default even if no c++ compiler is available
 230 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 231 AC_LANG_PUSH([C++])
 232 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 233 AC_LANG_POP([C++])
 234 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 235 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 236
 237 dnl Perl is used in building documentation and in the version checks
 238 AC_PATH_PROG(PERL_PATH, perl, no)
 239 if test x$PERL_PATH = xno; then
 240   AC_MSG_ERROR(Could not find perl)
 241 fi
 242
 243 dnl we require flex and bison for building the parser
 244 if test "x$GST_DISABLE_PARSE" != xyes; then
 245   AG_GST_BISON_CHECK
 246   AG_GST_FLEX_CHECK
 247 fi
 248
 249 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 250 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 251
 252 dnl check for gobject-introspection
 253 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 254
 255 dnl check for documentation tools
 256 AG_GST_DOCBOOK_CHECK
 257 GTK_DOC_CHECK([1.3])
 258 AS_PATH_PYTHON([2.1])
 259 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 260
 261 dnl *** checks for libraries ***
 262
 263 dnl check for libm, for sin()
 264 LT_LIB_M
 265 AC_SUBST(LIBM)
 266
 267 dnl *** checks for header files ***
 268
 269 dnl check if we have ANSI C header files
 270 AC_HEADER_STDC
 271
 272 dnl Check for ucontext.h
 273 AC_CHECK_HEADERS([ucontext.h])
 274
 275 dnl Check for sys/socket.h
 276 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 277 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 278
 279 dnl check for sys/times.h for tests/examples/adapter/
 280 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 281 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 282 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 283
 284 dnl Check for process.h for getpid() on win32
 285 AC_CHECK_HEADERS([process.h])
 286
 287 dnl Check for sys/utsname.h for uname
 288 AC_CHECK_HEADERS([sys/utsname.h])
 289
 290 dnl Check for stdio_ext.f for __fbufsize
 291 AC_CHECK_HEADERS([stdio_ext.h])
 292
 293 dnl check for pthreads
 294 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 295 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 296
 297 dnl check for sys/prctl for setting thread name on Linux
 298 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 299
 300 dnl Check for valgrind.h
 301 dnl separate from HAVE_VALGRIND because you can have the program, but not
 302 dnl the dev package
 303 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 304
 305 dnl used in gst/gstpoll.c
 306 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 307 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 308 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 309   WIN32_LIBS="-lws2_32"
 310   AC_SUBST(WIN32_LIBS)
 311 fi
 312
 313 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 314 if test "x$BUILD_TESTS" = "xyes"; then
 315   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 316                          __gmpz_init_set_d, ,
 317                          gmp.h,
 318                          GMP_LIBS="-lgmp"
 319                          AC_SUBST(GMP_LIBS)
 320                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 321   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 322                          gsl_rng_uniform_int, -lgslcblas,
 323                          gsl/gsl_rng.h,
 324                          GSL_LIBS="-lgsl -lgslcblas"
 325                          AC_SUBST(GSL_LIBS)
 326                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 327 fi
 328
 329 dnl *** checks for types/defines ***
 330
 331 dnl *** checks for structures ***
 332
 333 dnl *** checks for compiler characteristics ***
 334
 335 dnl check if the compiler supports __uint128_t (gcc)
 336 dnl Actually check for 128-bit division, since that's what we use
 337 dnl uint128_t for.
 338 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 339     AC_TRY_LINK([ ], [
 340       static __uint128_t v1 = 100;
 341       static __uint128_t v2 = 10;
 342       static __uint128_t u;
 343       u = v1 / v2;
 344     ], [
 345       gst_cv_uint128_t=yes
 346     ], [
 347       gst_cv_uint128_t=no
 348     ])
 349 )
 350 if test x$gst_cv_uint128_t = xyes; then
 351   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 352 fi
 353
 354 dnl *** checking for tm_gmtoff ***
 355 AC_MSG_CHECKING([for tm_gmtoff])
 356 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 357         #include <time.h>
 358         int main(void) {
 359           struct tm t;
 360           t.tm_gmtoff = 0;
 361           exit(0);
 362         }]])],
 363   [have_tm_gmtoff=yes
 364    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 365   [have_tm_gmtoff=no],
 366   [have_tm_gmtoff="no (cross compiling)"])
 367 AC_MSG_RESULT($have_tm_gmtoff)
 368
 369
 370 dnl *** checks for library functions ***
 371
 372 AC_CHECK_FUNCS([gmtime_r])
 373 AC_CHECK_FUNCS([localtime_r])
 374 AC_CHECK_FUNCS([sigaction])
 375
 376 dnl check for fseeko()
 377 AC_FUNC_FSEEKO
 378 dnl check for ftello()
 379 AC_CHECK_FUNCS([ftello])
 380
 381 AC_CHECK_FUNCS([fgetpos])
 382 AC_CHECK_FUNCS([fsetpos])
 383
 384 dnl check for poll(), ppoll() and pselect()
 385 AC_CHECK_FUNCS([poll])
 386 AC_CHECK_FUNCS([ppoll])
 387 AC_CHECK_FUNCS([pselect])
 388
 389 AC_CHECK_HEADERS([sys/poll.h])
 390
 391 dnl ****************************************
 392 dnl *** GLib POLL* compatibility defines ***
 393 dnl ****************************************
 394
 395 AC_MSG_CHECKING([for broken poll])
 396 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 397         #include <stdlib.h>
 398         #include <fcntl.h>
 399         #include <poll.h>
 400         #ifdef HAVE_SYS_POLL_H
 401         #include <sys/poll.h>
 402         #endif
 403         int main(void) {
 404           struct pollfd fds[1];
 405           int fd;
 406           fd = open("/dev/null", 1);
 407           fds[0].fd = fd;
 408           fds[0].events = POLLIN;
 409           fds[0].revents = 0;
 410           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 411                 exit(1);  /* Does not work for devices -- fail */
 412           }
 413           exit(0);
 414         }]])],
 415   [broken_poll=no],
 416   [broken_poll=yes
 417    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 418   [broken_poll="no (cross compiling)"])
 419 AC_MSG_RESULT($broken_poll)
 420
 421 dnl check for mmap()
 422 AC_FUNC_MMAP
 423 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 424
 425 dnl check for posix_memalign(), getpagesize()
 426 AC_CHECK_FUNCS([posix_memalign])
 427 AC_CHECK_FUNCS([getpagesize])
 428
 429 dnl Check for POSIX timers
 430 AC_CHECK_FUNCS(clock_gettime, [], [
 431   AC_CHECK_LIB(rt, clock_gettime, [
 432     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 433     LIBS="$LIBS -lrt"
 434   ])
 435 ])
 436
 437 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 438     AC_TRY_COMPILE([
 439 #include <time.h>
 440 #ifdef HAVE_UNISTD_H
 441 #include <unistd.h>
 442 #endif
 443     ], [
 444 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 445 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 446 #endif
 447     ], [
 448       gst_cv_posix_timers=yes
 449     ], [
 450       gst_cv_posix_timers=no
 451     ])
 452 )
 453
 454 if test "$gst_cv_posix_timers" = "yes"; then
 455   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 456   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 457 else
 458   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 459 fi
 460 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 461 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 462
 463 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 464     AC_TRY_COMPILE([
 465 #include <time.h>
 466 #ifdef HAVE_UNISTD_H
 467 #include <unistd.h>
 468 #endif
 469     ], [
 470 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 471 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 472 #endif
 473     ], [
 474       gst_cv_monotonic_clock=yes
 475     ], [
 476       gst_cv_monotonic_clock=no
 477     ])
 478 )
 479
 480 if test "$gst_cv_monotonic_clock" = "yes"; then
 481   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 482   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 483 else
 484   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 485 fi
 486 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 487 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 488
 489 dnl Check for a way to display the function name in debug output
 490 AG_GST_CHECK_FUNCTION
 491
 492 dnl test for register_printf_specifier or register_printf_function
 493 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 494     [HAVE_PRINTF_EXTENSION=yes])
 495
 496 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 497   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 498   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 499   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 500   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 501       [Defined if we have printf specifier extensions available])
 502 else
 503     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 504     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 505     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 506 fi
 507 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 508 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 509 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 510
 511 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 512 save_cflags="$CFLAGS"
 513 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 514 AC_CHECK_LIB(dl, dladdr,
 515    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 516    LIBS="$LIBS -ldl")
 517 CFLAGS="$save_cflags"
 518
 519 dnl *** checks for dependency libraries ***
 520
 521 dnl GLib
 522 GLIB_REQ=2.31.14
 523 AG_GST_GLIB_CHECK([$GLIB_REQ])
 524
 525 dnl Check for documentation xrefs
 526 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 527 AC_SUBST(GLIB_PREFIX)
 528
 529 dnl building of unit test libraries
 530 AC_ARG_ENABLE(check,
 531   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 532   [
 533     case "${enableval}" in
 534       yes) BUILD_CHECK=yes ;;
 535       no)  BUILD_CHECK=no ;;
 536       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 537     esac
 538   ], [
 539     dnl Default value
 540     case $host_os in
 541       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 542       *) BUILD_CHECK=yes ;;
 543     esac
 544 ])
 545 dnl bit of a misnomer, but keep the conditional named like this so we don't
 546 dnl have to change too much elsewhere
 547 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 548
 549 dnl configure the desired memory alignment
 550 AC_ARG_WITH([memory-alignment],
 551   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 552   [
 553     if test "x$withval" = "xyes"
 554     then
 555       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 556     else
 557       case "${withval}" in
 558         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 559         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 560         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 561       esac
 562     fi
 563   ], [
 564     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 565   ]
 566 )
 567
 568 dnl Check for -Bsymbolic-functions linker flag used to avoid
 569 dnl intra-library PLT jumps, if available.
 570 AC_ARG_ENABLE(Bsymbolic,
 571               [AC_HELP_STRING([--disable-Bsymbolic],
 572                               [avoid linking with -Bsymbolic])],,
 573               [SAVED_LDFLAGS="${LDFLAGS}"
 574                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 575                LDFLAGS=-Wl,-Bsymbolic-functions
 576                AC_TRY_LINK([], [int main (void) { return 0; }],
 577                            AC_MSG_RESULT(yes)
 578                            enable_Bsymbolic=yes,
 579                            AC_MSG_RESULT(no)
 580                            enable_Bsymbolic=no)
 581                LDFLAGS="${SAVED_LDFLAGS}"])
 582
 583
 584 dnl *** set variables based on configure arguments
 585
 586 dnl set license and copyright notice
 587 GST_LICENSE="LGPL"
 588 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 589 AC_SUBST(GST_LICENSE)
 590
 591 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 592 AS_AC_EXPAND(LIBDIR, $libdir)
 593 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 594 AS_AC_EXPAND(DATADIR, $datadir)
 595 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 596
 597 dnl set location of plugin directory
 598 AG_GST_SET_PLUGINDIR
 599
 600 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 601 AC_SUBST(GST_PKG_DEPS)
 602
 603 dnl make sure it doesn't complain about unused variables if debugging is disabled
 604 NO_WARNINGS=""
 605 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 606   NO_WARNINGS="-Wno-unused"
 607 fi
 608
 609 dnl define an ERROR_CFLAGS Makefile variable
 610 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 611
 612 dnl define correct level for debugging messages
 613 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 614
 615 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 616
 617 dnl Overview:
 618 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 619 dnl GST_ALL_*:          vars shared by all built objects
 620 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 621 dnl GST_OBJ_*:          additional vars to link to the core library
 622 dnl                     include GST_ALL_*
 623 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 624 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 625
 626 dnl GST_OPTION_CFLAGS
 627 if test "x$USE_DEBUG" = xyes; then
 628    PROFILE_CFLAGS="-g"
 629 fi
 630 AC_SUBST(PROFILE_CFLAGS)
 631
 632 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 633 # functionality from the API that gstreamer uses
 634 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 635 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 636   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 637   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 638 else
 639   DEPRECATED_CFLAGS=""
 640 fi
 641 AC_SUBST(DEPRECATED_CFLAGS)
 642
 643 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 644 dnl make DEPRECATED_CFLAGS=''
 645 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 646 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 647 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS -DGST_USE_UNSTABLE_API"
 648 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS -DGST_USE_UNSTABLE_API"
 649 AC_SUBST(GST_OPTION_CFLAGS)
 650 AC_SUBST(GST_OPTION_CXXFLAGS)
 651
 652 dnl GST_ALL_*
 653 dnl vars common to for all internal objects (core libs, elements, applications)
 654 dnl CFLAGS:
 655 dnl - src and build dirs need to be added because every piece that gets built
 656 dnl   will need the GStreamer source and generated headers
 657 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 658 dnl       from LibXML except for in the core library
 659 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 660 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 661
 662 dnl FIXME: check if LTLIBINTL is needed everywhere
 663 dnl I presume it is given that it contains the symbols that _() stuff maps to
 664 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 665
 666 dnl LDFLAGS really should only contain flags, not libs - they get added before
 667 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 668 GST_ALL_LDFLAGS="-no-undefined"
 669 if test "x${enable_Bsymbolic}" = "xyes"; then
 670   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 671 fi
 672
 673 AC_SUBST(GST_ALL_CFLAGS)
 674 AC_SUBST(GST_ALL_CXXFLAGS)
 675 AC_SUBST(GST_ALL_LIBS)
 676 AC_SUBST(GST_ALL_LDFLAGS)
 677
 678 dnl GST_LIB_LDFLAGS
 679 dnl linker flags shared by all libraries
 680 dnl LDFLAGS modifier defining exported symbols from built libraries
 681 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 682 AC_SUBST(GST_LIB_LDFLAGS)
 683
 684 dnl GST_OBJ_*
 685 dnl default vars for all internal objects built on libgstreamer
 686 dnl includes GST_ALL_*
 687 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 688 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 689 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 690 AC_SUBST(GST_OBJ_CFLAGS)
 691 AC_SUBST(GST_OBJ_CXXFLAGS)
 692 AC_SUBST(GST_OBJ_LIBS)
 693
 694 dnl GST_PLUGIN_LDFLAGS
 695 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 696 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 697 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 698
 699 dnl plugin scanner locations
 700 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 701 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 702     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 703 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 704
 705 dnl things for our internal libcheck (must be called even if building
 706 dnl libcheck is disabled because it defines conditionals)
 707 AG_GST_CHECK_CHECKS()
 708
 709 AC_CONFIG_FILES(
 710 Makefile
 711 gst/Makefile
 712 gst/gstconfig.h
 713 gst/gstversion.h
 714 gst/parse/Makefile
 715 libs/Makefile
 716 libs/gst/Makefile
 717 libs/gst/base/Makefile
 718 libs/gst/check/Makefile
 719 libs/gst/check/libcheck/Makefile
 720 libs/gst/check/libcheck/check.h
 721 libs/gst/controller/Makefile
 722 libs/gst/helpers/Makefile
 723 libs/gst/net/Makefile
 724 plugins/Makefile
 725 plugins/elements/Makefile
 726 po/Makefile.in
 727 tests/Makefile
 728 tests/benchmarks/Makefile
 729 tests/check/Makefile
 730 tests/misc/Makefile
 731 tests/examples/Makefile
 732 tests/examples/adapter/Makefile
 733 tests/examples/controller/Makefile
 734 tests/examples/stepping/Makefile
 735 tests/examples/helloworld/Makefile
 736 tests/examples/launch/Makefile
 737 tests/examples/manual/Makefile
 738 tests/examples/metadata/Makefile
 739 tests/examples/queue/Makefile
 740 tests/examples/streams/Makefile
 741 tests/examples/typefind/Makefile
 742 tools/Makefile
 743 common/Makefile
 744 common/m4/Makefile
 745 docs/Makefile
 746 docs/design/Makefile
 747 docs/faq/Makefile
 748 docs/gst/Makefile
 749 docs/gst/gstreamer.types
 750 docs/libs/Makefile
 751 docs/plugins/Makefile
 752 docs/manual/Makefile
 753 docs/pwg/Makefile
 754 docs/slides/Makefile
 755 docs/xsl/Makefile
 756 docs/version.entities
 757 m4/Makefile
 758 pkgconfig/Makefile
 759 stamp.h
 760 pkgconfig/gstreamer.pc
 761 pkgconfig/gstreamer-uninstalled.pc
 762 pkgconfig/gstreamer-base.pc
 763 pkgconfig/gstreamer-base-uninstalled.pc
 764 pkgconfig/gstreamer-check.pc
 765 pkgconfig/gstreamer-check-uninstalled.pc
 766 pkgconfig/gstreamer-controller.pc
 767 pkgconfig/gstreamer-controller-uninstalled.pc
 768 pkgconfig/gstreamer-net.pc
 769 pkgconfig/gstreamer-net-uninstalled.pc
 770 gst-element-check.m4
 771 gstreamer.spec
 772 )
 773
 774 dnl Create the config.h file for Visual Studio builds
 775 dnl Beware of spaces and /'s in some of the shell variable contents.
 776 sed \
 777     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 778     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 779     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 780     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 781     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 782     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 783     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 784     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 785     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 786     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 787     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 788     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 789     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 790     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 791     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 792     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 793     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 794     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 795     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 796     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 797     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 798     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 799     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 800     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 801     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 802     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 803     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 804     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 805     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 806     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 807     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 808     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 809     config.h.in >win32/common/config.h-new
 810
 811 AC_OUTPUT
 812
 813 dnl negate for output
 814 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 815 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 816 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 817 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 818 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 819 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 820 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 821
 822 echo "
 823
 824 Configuration
 825         Version                    : ${VERSION}
 826         Source code location       : ${srcdir}
 827         Prefix                     : ${prefix}
 828         Compiler                   : ${CC}
 829         Package name               : ${GST_PACKAGE_NAME}
 830         Package origin             : ${GST_PACKAGE_ORIGIN}
 831
 832         Documentation (manuals)    : ${enable_docbook}
 833         Documentation (API)        : ${enable_gtk_doc}
 834
 835         Debug Logging              : ${enable_gst_debug}
 836         Command-line parser        : ${enable_parse}
 837         Option parsing in gst_init : ${enable_option_parsing}
 838         Tracing subsystem          : ${enable_trace}
 839         Allocation tracing         : ${enable_alloc_trace}
 840         Plugin registry            : ${enable_registry}
 841         Plugin support             : ${enable_plugin}
 842         Unit testing support       : ${BUILD_CHECK}
 843
 844         Debug                      : ${USE_DEBUG}
 845         Profiling                  : ${USE_PROFILING}
 846
 847         Building examples          : ${BUILD_EXAMPLES}
 848         Building test apps         : ${BUILD_TESTS}
 849         Building tests that fail   : ${BUILD_FAILING_TESTS}
 850 "