configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.6.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.17
  50 GSTPB_REQ=0.10.17
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 dnl these are all the gst plug-ins, compilable without additional libs
  80 dnl videofilter is at the top because others depend on it
  81 GST_PLUGINS_ALL="\
  82                 videofilter \
  83                 alpha \
  84                 apetag \
  85                 audiofx \
  86                 auparse \
  87                 autodetect \
  88                 avi \
  89                 cutter \
  90                 debug \
  91                 effectv \
  92                 equalizer \
  93                 id3demux \
  94                 icydemux \
  95                 flx \
  96                 goom \
  97                 law \
  98                 level \
  99                 matroska \
 100                 monoscope \
 101                 multipart \
 102                 qtdemux \
 103                 rtp     \
 104                 rtsp    \
 105                 smpte   \
 106                 spectrum \
 107                 udp     \
 108                 videobox \
 109                 videocrop \
 110                 videomixer \
 111                 wavenc \
 112                 wavparse \
 113                 "
 114 AC_SUBST(GST_PLUGINS_ALL)
 115
 116 GST_PLUGINS_SELECTED=""
 117 AG_GST_ARG_WITH_PLUGINS
 118
 119 dnl disable gst plugins we might not be able to build on this
 120 dnl platform: udp and rtsp (ugly but minimally invasive)
 121 dnl FIXME: maybe move to sys
 122 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 123 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 124
 125 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 126   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 127   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 128 fi
 129
 130 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 131   WIN32_LIBS="-lws2_32"
 132   AC_SUBST(WIN32_LIBS)
 133 fi
 134
 135 AG_GST_ARG_ENABLE_EXTERNAL
 136
 137 AG_GST_ARG_ENABLE_EXPERIMENTAL
 138 USE_GST_V4L2=$BUILD_EXPERIMENTAL
 139 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 140         GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 141 fi
 142
 143 AC_SUBST(GST_PLUGINS_SELECTED)
 144
 145 dnl *** checks for platform ***
 146
 147 dnl * hardware/architecture *
 148
 149 dnl common/m4/gst-arch.m4
 150 dnl check CPU type
 151 AG_GST_ARCH
 152
 153 dnl Determine endianness
 154 AC_C_BIGENDIAN
 155
 156 dnl *** checks for programs ***
 157
 158 dnl find a compiler
 159 AC_PROG_CC
 160
 161 dnl determine c++ compiler
 162 AC_PROG_CXX
 163 dnl determine if c++ is available on this system
 164 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 165
 166 dnl determine c++ preprocessor
 167 dnl FIXME: do we need this ?
 168 AC_PROG_CXXCPP
 169
 170 AS_PROG_OBJC
 171
 172 dnl check if the compiler supports '-c' and '-o' options
 173 AM_PROG_CC_C_O
 174
 175 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 176 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 177
 178 dnl check for gconftool-2
 179 dnl this macro defines an am conditional, so it needs to be run always
 180 AM_GCONF_SOURCE_2
 181
 182 dnl check for documentation tools
 183 GTK_DOC_CHECK([1.3])
 184 AS_PATH_PYTHON([2.1])
 185 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 186
 187 dnl *** checks for libraries ***
 188
 189 dnl check for libm, for sin()
 190 AC_CHECK_LIBM
 191 AC_SUBST(LIBM)
 192
 193 dnl *** checks for header files ***
 194
 195 dnl check if we have ANSI C header files
 196 AC_HEADER_STDC
 197
 198 dnl used by ext/wavpack
 199 AX_CREATE_STDINT_H
 200
 201 dnl used in gst/rtp/gstasteriskh263.c
 202 AC_CHECK_HEADERS([netinet/in.h])
 203 AC_CHECK_HEADERS([winsock2.h])
 204 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 205
 206 dnl used in gst/udp
 207 AC_CHECK_HEADERS([sys/time.h])
 208
 209 dnl *** checks for types/defines ***
 210
 211 dnl Check for FIONREAD ioctl declaration.  This check is needed
 212 dnl for the UDP plugin to build on Solaris
 213 GST_CHECK_FIONREAD
 214
 215 dnl *** checks for structures ***
 216
 217 dnl *** checks for compiler characteristics ***
 218
 219 dnl FIXME: check if this is used; was used for floatcast.h in base
 220 dnl Check for fast float to int casting as defined in C99
 221 AC_C99_FUNC_LRINT
 222 AC_C99_FUNC_LRINTF
 223
 224 dnl *** checks for library functions ***
 225
 226 LIBS_SAVE=$LIBS
 227 LIBS="$LIBS $LIBM"
 228 AC_CHECK_FUNCS(rint)
 229 LIBS=$LIBS_SAVE
 230
 231 dnl Check for mmap (needed by electricfence plugin)
 232 AC_FUNC_MMAP
 233 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 234
 235 dnl *** checks for dependency libraries ***
 236
 237 dnl GLib is required
 238 AG_GST_GLIB_CHECK([2.6])
 239
 240 dnl liboil is required
 241 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 242 if test "x${HAVE_LIBOIL}" != xyes ; then
 243   AC_ERROR([liboil-0.3.8 or later is required])
 244 fi
 245
 246 dnl checks for gstreamer
 247 dnl uninstalled is selected preferentially -- see pkg-config(1)
 248 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 249 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 250 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 251 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 252 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 253 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 254
 255 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 256 if test -z $GST_TOOLS_DIR; then
 257   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 258 fi
 259 AC_SUBST(GST_TOOLS_DIR)
 260
 261 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 262 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 263
 264 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 265
 266 dnl Check for documentation xrefs
 267 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 268 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 269 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 270 AC_SUBST(GLIB_PREFIX)
 271 AC_SUBST(GST_PREFIX)
 272 AC_SUBST(GSTPB_PREFIX)
 273
 274 dnl GTK is optional and used in examples
 275 HAVE_GTK=NO
 276 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 277 if test "x$HAVE_GTK_22" = "xyes"; then
 278   HAVE_GTK=yes
 279   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 280   AC_SUBST(GTK_VERSION)
 281   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 282   AC_SUBST(GTK_BASE_DIR)
 283   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 284   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 285   AC_SUBST(GTK_BASE_DIR)
 286 else
 287   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 288 fi
 289 if test "x$HAVE_GTK_20" = "xyes"; then
 290   HAVE_GTK=yes
 291 fi
 292 GTK_CFLAGS=$GTK2_CFLAGS
 293 GTK_LIBS=$GTK2_LIBS
 294 AC_SUBST(GTK_LIBS)
 295 AC_SUBST(GTK_CFLAGS)
 296 AC_SUBST(HAVE_GTK)
 297 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 298
 299 dnl should we install schemas ?
 300 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 301 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 302   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 303   if test x$GCONFTOOL = xno; then
 304     AC_MSG_WARN(Not installing GConf schemas)
 305     HAVE_GCONFTOOL="no"
 306   else
 307     HAVE_GCONFTOOL="yes"
 308   fi
 309   AC_SUBST(HAVE_GCONFTOOL)
 310 ])
 311
 312 dnl *** set variables based on configure arguments ***
 313
 314 dnl set license and copyright notice
 315 GST_LICENSE="LGPL"
 316 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 317 AC_SUBST(GST_LICENSE)
 318
 319 dnl set location of plugin directory
 320 AG_GST_SET_PLUGINDIR
 321
 322 dnl define an ERROR_CFLAGS Makefile variable
 323 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 324
 325 dnl define correct level for debugging messages
 326 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 327
 328 dnl used in examples
 329 AG_GST_DEFAULT_ELEMENTS
 330
 331 dnl *** sys plug-ins ***
 332
 333 echo
 334 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 335 echo
 336
 337 dnl DirectDraw
 338 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 339 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 340   HAVE_DIRECTDRAW="no"
 341   save_CFLAGS="$CFLAGS"
 342   save_LDFLAGS="$LDFLAGS"
 343   save_LIBS="$LIBS"
 344   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 345   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 346   LIBS="$LIBS -lddraw -lgdi32"
 347   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 348   AC_LINK_IFELSE([
 349 #include <windows.h>
 350 #include <ddraw.h>
 351
 352 int main ()
 353 {
 354   GetStockObject(0);
 355   DirectDrawCreate(NULL, NULL, NULL);
 356
 357   return 0;
 358 }
 359 ],
 360     [HAVE_DIRECTDRAW="yes"],
 361     [HAVE_DIRECTDRAW="no"])
 362   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 363   CFLAGS=$save_CFLAGS
 364   LDFLAGS=$save_LDFLAGS
 365   LIBS=$save_LIBS
 366
 367   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 368     dnl this is much more than we want
 369     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 370     AC_SUBST(DIRECTDRAW_CFLAGS)
 371     AC_SUBST(DIRECTDRAW_LDFLAGS)
 372     AC_SUBST(DIRECTDRAW_LIBS)
 373   fi
 374   AC_SUBST(HAVE_DIRECTDRAW)
 375 ])
 376
 377 dnl DirectSound
 378 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 379 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 380   HAVE_DIRECTSOUND="no"
 381   save_CFLAGS="$CFLAGS"
 382   save_LDFLAGS="$LDFLAGS"
 383   save_LIBS="$LIBS"
 384   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 385   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 386   LIBS="$LIBS -ldsound -ldxerr9"
 387   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 388   AC_LINK_IFELSE([
 389 #include <windows.h>
 390 #include <dxerr9.h>
 391 #include <dsound.h>
 392
 393 int main ()
 394 {
 395   DXGetErrorString9 (0);
 396   DirectSoundCreate(NULL, NULL, NULL);
 397
 398   return 0;
 399 }
 400 ],
 401     [HAVE_DIRECTSOUND="yes"],
 402     [HAVE_DIRECTSOUND="no"])
 403   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 404   CFLAGS=$save_CFLAGS
 405   LDFLAGS=$save_LDFLAGS
 406   LIBS=$save_LIBS
 407
 408   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 409     dnl this is much more than we want
 410     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 411     AC_SUBST(DIRECTSOUND_CFLAGS)
 412     AC_SUBST(DIRECTSOUND_LDFLAGS)
 413     AC_SUBST(DIRECTSOUND_LIBS)
 414   fi
 415   AC_SUBST(HAVE_DIRECTSOUND)
 416 ])
 417
 418 dnl *** OSS audio *** (Linux, *BSD)
 419 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 420 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 421  HAVE_OSS="yes"
 422 dnl Linux and newer BSD versions :
 423  AC_CHECK_HEADER(sys/soundcard.h, [
 424    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 425    ] , [
 426 dnl Some old BSD versions and also newer OpenBSD versions :
 427    AC_CHECK_HEADER(soundcard.h, [
 428      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 429      ], [
 430   dnl Some old BSD versions :
 431      AC_CHECK_HEADER(machine/soundcard.h, [
 432        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 433          [Define if OSS includes are in /machine/])
 434        ], [
 435        HAVE_OSS="no"
 436      ])
 437    ])
 438  ])
 439 ])
 440
 441 dnl *** Sun Audio ***
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 443 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 444   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 445 ])
 446
 447 dnl *** OSX Audio ***
 448 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 449 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 450   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 451 ])
 452
 453 dnl *** OS X video ***
 454 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 455 HAVE_OSX_VIDEO="no"
 456 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 457   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 458 ])
 459 dnl in case header OpenGL/gl.h is found on other platforms
 460 case "$host" in
 461   *-*darwin*)
 462     dnl do nothing
 463     ;;
 464   *)
 465     HAVE_OSX_VIDEO="no"
 466     ;;
 467 esac
 468
 469
 470 dnl *** Video 4 Linux 2 ***
 471 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 472 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 473 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 474 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 475   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 476   AC_TRY_COMPILE([
 477 #include <sys/types.h>
 478 #ifdef __sun /* Solaris */
 479 #include <sys/types.h>
 480 #include <sys/videodev2.h>
 481 #else /* Linux */
 482 #include <linux/types.h>
 483 #define _LINUX_TIME_H
 484 #define __user
 485 #include <linux/videodev2.h>
 486 #endif
 487 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 488 #error too early v4l2 version or no v4l2 at all
 489 #endif
 490     ], [
 491 return 0;
 492     ], [
 493       HAVE_GST_V4L2="yes"
 494       AC_MSG_RESULT(yes)
 495     ], [
 496       HAVE_GST_V4L2="no"
 497       AC_MSG_RESULT(no)
 498
 499       HAVE_VIDEODEV=no
 500       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 501       [
 502         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 503       ])
 504
 505       if test "x$HAVE_VIDEODEV" = "xyes"; then
 506         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 507         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 508       else
 509         AC_MSG_WARN([video4linux2 was not found])
 510       fi
 511     ])
 512
 513   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 514     dnl check for missing v4l2_buffer declaration (see #135919)
 515     MISSING_DECL=0
 516     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 517     AC_TRY_COMPILE([
 518 #include <sys/types.h>
 519 #ifdef __sun /* Solaris */
 520 #include <sys/types.h>
 521 #include <sys/videodev2.h>
 522 #else /* Linux */
 523 #include <linux/types.h>
 524 #define _LINUX_TIME_H
 525 #define __user
 526 #include <linux/videodev2.h>
 527 #endif
 528     ],[
 529 struct v4l2_buffer buf;
 530 buf.index = 0;
 531 return 0;
 532     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 533     if [ test x$MISSING_DECL = x1 ]; then
 534       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 535     fi
 536
 537     dnl check for XOverlay libraries
 538     AG_GST_CHECK_XV
 539   fi
 540 ])
 541
 542 dnl Check for X11
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 544 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 545                   [ximagesrc], [
 546   AC_PATH_XTRA
 547
 548   dnl now try to find the HEADER
 549   ac_cflags_save="$CFLAGS"
 550   ac_cppflags_save="$CPPFLAGS"
 551   CFLAGS="$CFLAGS $X_CFLAGS"
 552   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 553   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 554
 555   if test "x$HAVE_X" = "xno"
 556   then
 557     AC_MSG_NOTICE([cannot find X11 development files])
 558   else
 559     dnl this is much more than we want
 560     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 561     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 562     dnl it does not add the libs; therefore we add them here
 563     X_LIBS="$X_LIBS -lX11"
 564     AC_SUBST(X_CFLAGS)
 565     AC_SUBST(X_LIBS)
 566
 567     dnl check for Xfixes
 568     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 569     if test "x$HAVE_XFIXES" = "xyes"
 570     then
 571         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 572     fi
 573     AC_SUBST(XFIXES_LIBS)
 574     AC_SUBST(XFIXES_CFLAGS)
 575
 576     dnl check for Xdamage
 577     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 578     if test "x$HAVE_XDAMAGE" = "xyes"
 579     then
 580         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 581     fi
 582     AC_SUBST(XDAMAGE_LIBS)
 583     AC_SUBST(XDAMAGE_CFLAGS)
 584   fi
 585   AC_SUBST(HAVE_X)
 586   CFLAGS="$ac_cflags_save"
 587   CPPFLAGS="$ac_cppflags_save"
 588 ])
 589
 590 dnl FIXME: this should be rolled into the test above, it's just an additional
 591 dnl feature of the ximagesrc plug-in
 592 dnl This is the same as in gst-plugins-base
 593 dnl check for X Shm
 594 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 595 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 596   if test x$HAVE_X = xyes; then
 597     AC_CHECK_LIB(Xext, XShmAttach,
 598                  HAVE_XSHM="yes", HAVE_XSHM="no",
 599                  $X_LIBS)
 600     if test "x$HAVE_XSHM" = "xyes"; then
 601       XSHM_LIBS="-lXext"
 602     else
 603       dnl On AIX, it is in XextSam instead, but we still need -lXext
 604       AC_CHECK_LIB(XextSam, XShmAttach,
 605                    HAVE_XSHM="yes", HAVE_XSHM="no",
 606                    $X_LIBS)
 607       if test "x$HAVE_XSHM" = "xyes"; then
 608         XSHM_LIBS="-lXext -lXextSam"
 609       fi
 610     fi
 611   fi
 612 ], ,[
 613   AC_SUBST(HAVE_XSHM)
 614   AC_SUBST(XSHM_LIBS)
 615 ])
 616
 617 dnl for V4L2, we also need to know if we have XVIDEO
 618 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 619 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 620                   [], [
 621   AG_GST_CHECK_XV
 622 ])
 623
 624 dnl *** ext plug-ins ***
 625 dnl keep this list sorted alphabetically !
 626
 627 if test "x$BUILD_EXTERNAL" = "xyes"; then
 628
 629 echo
 630 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 631 echo
 632
 633 dnl *** aalib ***
 634 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 635 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 636   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 637   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 638 ])
 639
 640 dnl *** annodex ***
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 642 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 643   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 644 ])
 645
 646 dnl *** cairo ***
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 648 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 649   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 650 ])
 651
 652 dnl *** cdio ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 654 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 655   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 656 ])
 657
 658 dnl **** ESound ****
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 660 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 661   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 662   if test $HAVE_ESD = no
 663   then
 664     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 665     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 666   fi
 667 ])
 668
 669 dnl *** FLAC ***
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 671 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 672   #if FLAC_API_VERSION_CURRENT < 8
 673   #error "legacy flac API"
 674   #endif
 675   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 676
 677 if test "x$legacy_flac" = "xyes"; then
 678 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 679   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 680   dnl API change in FLAC 1.1.1, so require that...
 681   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 682   if test x$HAVE_FLAC = xyes; then
 683     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 684                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 685 #include <FLAC/seekable_stream_encoder.h>
 686                   ])
 687   fi
 688   AC_SUBST(FLAC_LIBS)
 689 ])
 690 else
 691 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 692   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 693   dnl API change in FLAC 1.1.3, so require that...
 694   if test x$HAVE_FLAC = xyes; then
 695     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 696                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 697 #include <FLAC/stream_encoder.h>
 698                   ])
 699   fi
 700   AC_SUBST(FLAC_LIBS)
 701 ])
 702 fi
 703
 704 dnl *** GConf ***
 705 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 706 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 707   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 708 ])
 709
 710 dnl *** GDK pixbuf ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 712 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 713   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 714 ])
 715
 716 dnl *** HAL ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 718 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 719   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 720 ])
 721
 722 dnl *** jpeg ***
 723 dnl FIXME: we could use header checks here as well IMO
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 725 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 726   AC_ARG_WITH(jpeg-mmx,
 727     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 728   OLD_LIBS="$LIBS"
 729   if test x$with_jpeg_mmx != x; then
 730     LIBS="$LIBS -L$with_jpeg_mmx"
 731   fi
 732   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 733   JPEG_LIBS="$LIBS -ljpeg-mmx"
 734   LIBS="$OLD_LIBS"
 735   if test x$HAVE_JPEG != xyes; then
 736     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 737     JPEG_LIBS="-ljpeg"
 738   fi
 739   AC_SUBST(JPEG_LIBS)
 740 ])
 741
 742 dnl *** ladspa ***
 743 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 744 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 745   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 746 ], disabled)
 747
 748 dnl *** libcaca ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 750 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 751   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 752   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 753   if test "x$HAVE_LIBCACA" != "xyes"; then
 754     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 755     dnl see if it compilation works too, might not if we are cross-compiling
 756     if test "x$HAVE_LIBCACA" = "xyes"; then
 757       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 758                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 759     fi
 760   fi
 761 ])
 762
 763 dnl *** libdv ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 765 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 766   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 767 ])
 768
 769 dnl *** libpng ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 771 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 772   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 773 ])
 774
 775 dnl *** dv1394 ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 777 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 778   dnl first test for libraw1394 >= 1.2.1
 779   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 780   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 781   dnl now see how far we got
 782   if test x$HAVE_RAW1394 = xyes && \
 783      test x$HAVE_LIBIEC61883 = xyes; then
 784        AG_GST_CHECK_LIBHEADER(AVC1394,
 785         avc1394, avc1394_send_command, $RAW1394_LIBS,
 786         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 787        AG_GST_CHECK_LIBHEADER(ROM1394,
 788         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 789         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 790        if test x$HAVE_AVC1394 = xyes && \
 791           test x$HAVE_AVC1394 = xyes && \
 792           test x$HAVE_ROM1394 = xyes; then
 793           HAVE_DV1394=yes
 794           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 795           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 796           AC_SUBST(DV1394_CFLAGS)
 797           AC_SUBST(DV1394_LIBS)
 798         fi
 799   else
 800        if test x$HAVE_RAW1394 = xno; then
 801           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 802           AG_GST_CHECK_LIBHEADER(AVC1394,
 803            avc1394, avc1394_send_command, $RAW1394_LIBS,
 804            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 805           AG_GST_CHECK_LIBHEADER(ROM1394,
 806            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 807            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 808           if test x$HAVE_RAW1394 = xyes && \
 809              test x$HAVE_AVC1394 = xyes && \
 810              test x$HAVE_ROM1394 = xyes; then
 811              HAVE_DV1394=yes
 812              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 813              DV1394_CFLAGS="$RAW1394_CFLAGS"
 814              if test x$HAVE_LIBIEC61883 = xyes; then
 815                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 816                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 817              fi
 818              AC_SUBST(DV1394_CFLAGS)
 819              AC_SUBST(DV1394_LIBS)
 820            fi
 821          fi
 822   fi
 823 ])
 824
 825 dnl *** shout2 ***
 826 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 827 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 828   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 829   if test $HAVE_SHOUT2 = no
 830   then
 831     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 832     AC_SUBST(SHOUT2_CFLAGS)
 833     AC_SUBST(SHOUT2_LIBS)
 834   fi
 835 ])
 836
 837 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 838 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 839 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 840 dnl   speex_jitter.h is 1.1.x only
 841 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 842 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 843   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 844   if test $HAVE_SPEEX = no
 845   then
 846     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 847       AC_CHECK_HEADER(speex/speex_jitter.h, [
 848         dnl speex 1.1.x :
 849         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 850           dnl speex 1.1.5 or + :
 851           HAVE_SPEEX="yes"
 852           SPEEX_LIBS="-lspeex"
 853           AC_SUBST(SPEEX_CFLAGS)
 854           AC_SUBST(SPEEX_LIBS)
 855         ],[
 856           HAVE_SPEEX="no"
 857         ])
 858       ],[
 859         dnl speex 1.0.x :
 860           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 861             dnl speex 1.0.4
 862             HAVE_SPEEX="yes"
 863             SPEEX_LIBS="-lspeex"
 864             AC_SUBST(SPEEX_CFLAGS)
 865             AC_SUBST(SPEEX_LIBS)
 866
 867             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 868               [defined if speex 1.0.x API detected])
 869         ],[
 870             HAVE_SPEEX="no"
 871             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 872         ], [
 873 #include <speex/speex.h>
 874         ])
 875       ])
 876     ])
 877   fi
 878 ])
 879
 880 dnl *** taglib ***
 881 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 882 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 883   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 884   if test "x$HAVE_CXX" != "xyes"; then
 885     USE_TAGLIB=false
 886     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 887   fi
 888 ])
 889
 890 dnl *** wavpack ***
 891 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 892 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 893   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 894     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 895       HAVE_WAVPACK=yes
 896       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 897     ],[
 898       HAVE_WAVPACK=no
 899       AC_MSG_RESULT(no)
 900     ])
 901   ])
 902   AC_SUBST(WAVPACK_CFLAGS)
 903   AC_SUBST(WAVPACK_LIBS)
 904 ])
 905
 906 dnl *** qtdemux & id3demux prefer to have zlib ***
 907 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 908 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 909   AG_GST_CHECK_LIBHEADER(ZLIB,
 910     z, uncompress,, zlib.h, [
 911     HAVE_ZLIB="yes"
 912     ZLIB_LIBS="-lz"
 913     AC_SUBST(ZLIB_LIBS)
 914   ])
 915 ])
 916
 917 else
 918
 919 dnl not building plugins with external dependencies,
 920 dnl but we still need to set the conditionals
 921 AM_CONDITIONAL(USE_GCONFTOOL, false)
 922 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 923 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 924 AM_CONDITIONAL(USE_OSS, false)
 925 AM_CONDITIONAL(USE_SUNAUDIO, false)
 926 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 927 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 928 AM_CONDITIONAL(USE_X, false)
 929 AM_CONDITIONAL(USE_XSHM, false)
 930 AM_CONDITIONAL(USE_AALIB, false)
 931 AM_CONDITIONAL(USE_ANNODEX, false)
 932 AM_CONDITIONAL(USE_CAIRO, false)
 933 AM_CONDITIONAL(USE_CDIO, false)
 934 AM_CONDITIONAL(USE_ESD, false)
 935 AM_CONDITIONAL(USE_FLAC, false)
 936 AM_CONDITIONAL(USE_GCONF, false)
 937 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 938 AM_CONDITIONAL(USE_HAL, false)
 939 AM_CONDITIONAL(USE_JPEG, false)
 940 AM_CONDITIONAL(USE_LADSPA, false)
 941 AM_CONDITIONAL(USE_LIBCACA, false)
 942 AM_CONDITIONAL(USE_LIBDV, false)
 943 AM_CONDITIONAL(USE_LIBPNG, false)
 944 AM_CONDITIONAL(USE_DV1394, false)
 945 AM_CONDITIONAL(USE_SHOUT2, false)
 946 AM_CONDITIONAL(USE_SPEEX, false)
 947 AM_CONDITIONAL(USE_TAGLIB, false)
 948 AM_CONDITIONAL(USE_WAVPACK, false)
 949 AM_CONDITIONAL(USE_ZLIB, false)
 950
 951 fi dnl of EXT plugins
 952
 953 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 954
 955 dnl Overview:
 956 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 957 dnl GST_*:              flags shared by all built objects
 958 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 959 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 960 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 961 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 962
 963 dnl GST_OPTION_CFLAGS
 964 if test "x$USE_DEBUG" = xyes; then
 965    PROFILE_CFLAGS="-g"
 966 fi
 967 AC_SUBST(PROFILE_CFLAGS)
 968
 969 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 970   dnl Define _only_ during CVS (not pre-releases or releases)
 971   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 972 else
 973   DEPRECATED_CFLAGS=""
 974 fi
 975 AC_SUBST(DEPRECATED_CFLAGS)
 976
 977 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 978 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 979 AC_SUBST(GST_OPTION_CFLAGS)
 980
 981 dnl our libraries need to be versioned correctly
 982 AC_SUBST(GST_LT_LDFLAGS)
 983
 984 dnl FIXME: do we want to rename to GST_ALL_* ?
 985 dnl prefer internal headers to already installed ones
 986 dnl also add builddir include for enumtypes and marshal
 987 dnl add ERROR_CFLAGS, but overridable
 988 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 989 AC_SUBST(GST_CFLAGS)
 990 AC_SUBST(GST_LIBS)
 991
 992 dnl LDFLAGS really should only contain flags, not libs - they get added before
 993 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 994 GST_ALL_LDFLAGS="-no-undefined"
 995 AC_SUBST(GST_ALL_LDFLAGS)
 996
 997 dnl this really should only contain flags, not libs - they get added before
 998 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 999 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1000 AC_SUBST(GST_PLUGIN_LDFLAGS)
1001
1002 dnl *** output files ***
1003
1004 dnl keep this alphabetic per directory, please
1005 AC_CONFIG_FILES(
1006 Makefile
1007 gst/Makefile
1008 gst/alpha/Makefile
1009 gst/apetag/Makefile
1010 gst/audiofx/Makefile
1011 gst/auparse/Makefile
1012 gst/autodetect/Makefile
1013 gst/avi/Makefile
1014 gst/cutter/Makefile
1015 gst/debug/Makefile
1016 gst/effectv/Makefile
1017 gst/equalizer/Makefile
1018 gst/id3demux/Makefile
1019 gst/icydemux/Makefile
1020 gst/goom/Makefile
1021 gst/law/Makefile
1022 gst/level/Makefile
1023 gst/matroska/Makefile
1024 gst/monoscope/Makefile
1025 gst/multipart/Makefile
1026 gst/qtdemux/Makefile
1027 gst/rtp/Makefile
1028 gst/rtsp/Makefile
1029 gst/smpte/Makefile
1030 gst/spectrum/Makefile
1031 gst/udp/Makefile
1032 gst/videobox/Makefile
1033 gst/videocrop/Makefile
1034 gst/videofilter/Makefile
1035 gst/videomixer/Makefile
1036 gst/wavenc/Makefile
1037 gst/wavparse/Makefile
1038 gst/flx/Makefile
1039 ext/jpeg/Makefile
1040 ext/Makefile
1041 ext/aalib/Makefile
1042 ext/annodex/Makefile
1043 ext/cairo/Makefile
1044 ext/cdio/Makefile
1045 ext/dv/Makefile
1046 ext/esd/Makefile
1047 ext/flac/Makefile
1048 ext/gconf/Makefile
1049 ext/gdk_pixbuf/Makefile
1050 ext/hal/Makefile
1051 ext/ladspa/Makefile
1052 ext/libcaca/Makefile
1053 ext/libpng/Makefile
1054 ext/raw1394/Makefile
1055 ext/shout2/Makefile
1056 ext/speex/Makefile
1057 ext/taglib/Makefile
1058 ext/wavpack/Makefile
1059 sys/Makefile
1060 sys/directdraw/Makefile
1061 sys/directsound/Makefile
1062 sys/oss/Makefile
1063 sys/sunaudio/Makefile
1064 sys/osxaudio/Makefile
1065 sys/osxvideo/Makefile
1066 sys/v4l2/Makefile
1067 sys/waveform/Makefile
1068 sys/ximage/Makefile
1069 po/Makefile.in
1070 tests/Makefile
1071 tests/check/Makefile
1072 tests/examples/Makefile
1073 tests/examples/equalizer/Makefile
1074 tests/examples/level/Makefile
1075 tests/examples/rtp/Makefile
1076 tests/examples/spectrum/Makefile
1077 tests/files/Makefile
1078 tests/icles/Makefile
1079 gconf/Makefile
1080 gconf/gstreamer.schemas
1081 common/Makefile
1082 common/m4/Makefile
1083 m4/Makefile
1084 docs/Makefile
1085 docs/plugins/Makefile
1086 docs/version.entities
1087 win32/common/config.h
1088 pkgconfig/Makefile
1089 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1090 gst-plugins-good.spec
1091 )
1092 AC_OUTPUT
1093
1094 AG_GST_OUTPUT_PLUGINS